gcc/ada/back_end.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                            B A C K _ E N D                               --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2008, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Atree;     use Atree;
  27 with Debug;     use Debug;
  28 with Elists;    use Elists;
  29 with Lib;       use Lib;
  30 with Osint;     use Osint;
  31 with Opt;       use Opt;
  32 with Osint.C;   use Osint.C;
  33 with Namet;     use Namet;
  34 with Nlists;    use Nlists;
  35 with Stand;     use Stand;
  36 with Sinput;    use Sinput;
  37 with Stringt;   use Stringt;
  38 with Switch;    use Switch;
  39 with Switch.C;  use Switch.C;
  40 with System;    use System;
  41 with Types;     use Types;
  42
  43 package body Back_End is
  44
  45    -------------------
  46    -- Call_Back_End --
  47    -------------------
  48
  49    procedure Call_Back_End (Mode : Back_End_Mode_Type) is
  50
  51       --  The Source_File_Record type has a lot of components that are
  52       --  meaningless to the back end, so a new record type is created
  53       --  here to contain the needed information for each file.
  54
  55       type File_Info_Type is record
  56          File_Name        : File_Name_Type;
  57          Num_Source_Lines : Nat;
  58       end record;
  59
  60       File_Info_Array : array (1 .. Last_Source_File) of File_Info_Type;
  61
  62       procedure gigi
  63         (gnat_root                     : Int;
  64          max_gnat_node                 : Int;
  65          number_name                   : Nat;
  66          nodes_ptr                     : Address;
  67
  68          next_node_ptr                 : Address;
  69          prev_node_ptr                 : Address;
  70          elists_ptr                    : Address;
  71          elmts_ptr                     : Address;
  72
  73          strings_ptr                   : Address;
  74          string_chars_ptr              : Address;
  75          list_headers_ptr              : Address;
  76          number_file                   : Nat;
  77
  78          file_info_ptr                 : Address;
  79          gigi_standard_integer         : Entity_Id;
  80          gigi_standard_long_long_float : Entity_Id;
  81          gigi_standard_exception_type  : Entity_Id;
  82          gigi_operating_mode           : Back_End_Mode_Type);
  83
  84       pragma Import (C, gigi);
  85
  86    begin
  87       --  Skip call if in -gnatdH mode
  88
  89       if Debug_Flag_HH then
  90          return;
  91       end if;
  92
  93       for J in 1 .. Last_Source_File loop
  94          File_Info_Array (J).File_Name        := Full_Debug_Name (J);
  95          File_Info_Array (J).Num_Source_Lines := Num_Source_Lines (J);
  96       end loop;
  97
  98       gigi
  99         (gnat_root          => Int (Cunit (Main_Unit)),
 100          max_gnat_node      => Int (Last_Node_Id - First_Node_Id + 1),
 101          number_name        => Name_Entries_Count,
 102          nodes_ptr          => Nodes_Address,
 103
 104          next_node_ptr      => Next_Node_Address,
 105          prev_node_ptr      => Prev_Node_Address,
 106          elists_ptr         => Elists_Address,
 107          elmts_ptr          => Elmts_Address,
 108
 109          strings_ptr        => Strings_Address,
 110          string_chars_ptr   => String_Chars_Address,
 111          list_headers_ptr   => Lists_Address,
 112          number_file        => Num_Source_Files,
 113
 114          file_info_ptr                 => File_Info_Array'Address,
 115          gigi_standard_integer         => Standard_Integer,
 116          gigi_standard_long_long_float => Standard_Long_Long_Float,
 117          gigi_standard_exception_type  => Standard_Exception_Type,
 118          gigi_operating_mode           => Mode);
 119    end Call_Back_End;
 120
 121    -----------------------------
 122    -- Scan_Compiler_Arguments --
 123    -----------------------------
 124
 125    procedure Scan_Compiler_Arguments is
 126       Next_Arg : Pos := 1;
 127
 128       type Arg_Array is array (Nat) of Big_String_Ptr;
 129       type Arg_Array_Ptr is access Arg_Array;
 130
 131       flag_stack_check : Int;
 132       pragma Import (C, flag_stack_check);
 133       --  Import from toplev.c
 134
 135       save_argc : Nat;
 136       pragma Import (C, save_argc);
 137       --  Import from toplev.c
 138
 139       save_argv : Arg_Array_Ptr;
 140       pragma Import (C, save_argv);
 141       --  Import from toplev.c
 142
 143       Output_File_Name_Seen : Boolean := False;
 144       --  Set to True after having scanned file_name for switch "-gnatO file"
 145
 146       --  Local functions
 147
 148       function Len_Arg (Arg : Pos) return Nat;
 149       --  Determine length of argument number Arg on the original command line
 150       --  from gnat1.
 151
 152       procedure Scan_Back_End_Switches (Switch_Chars : String);
 153       --  Procedure to scan out switches stored in Switch_Chars. The first
 154       --  character is known to be a valid switch character, and there are no
 155       --  blanks or other switch terminator characters in the string, so the
 156       --  entire string should consist of valid switch characters, except that
 157       --  an optional terminating NUL character is allowed.
 158       --
 159       --  Back end switches have already been checked and processed by GCC
 160       --  in toplev.c, so no errors can occur and control will always return.
 161       --  The switches must still be scanned to skip the arguments of the
 162       --  "-o" or the (undocumented) "-dumpbase" switch, by incrementing
 163       --  the Next_Arg variable. The "-dumpbase" switch is used to set the
 164       --  basename for GCC dumpfiles.
 165
 166       -------------
 167       -- Len_Arg --
 168       -------------
 169
 170       function Len_Arg (Arg : Pos) return Nat is
 171       begin
 172          for J in 1 .. Nat'Last loop
 173             if save_argv (Arg).all (Natural (J)) = ASCII.NUL then
 174                return J - 1;
 175             end if;
 176          end loop;
 177
 178          raise Program_Error;
 179       end Len_Arg;
 180
 181       ----------------------------
 182       -- Scan_Back_End_Switches --
 183       ----------------------------
 184
 185       procedure Scan_Back_End_Switches (Switch_Chars : String) is
 186          First : constant Positive := Switch_Chars'First + 1;
 187          Last  : Natural := Switch_Chars'Last;
 188
 189       begin
 190          if Last >= First
 191            and then Switch_Chars (Last) = ASCII.NUL
 192          then
 193             Last := Last - 1;
 194          end if;
 195
 196          --  For switches -o, -dumpbase, --param, skip following argument and
 197          --  do not store either the switch or the following argument.
 198
 199          if Switch_Chars (First .. Last) = "o"        or else
 200             Switch_Chars (First .. Last) = "dumpbase" or else
 201             Switch_Chars (First .. Last) = "-param"
 202          then
 203             Next_Arg := Next_Arg + 1;
 204
 205          --  Do not record -quiet switch
 206
 207          elsif Switch_Chars (First .. Last) = "quiet" then
 208             null;
 209
 210          --  Store any other GCC switches
 211
 212          else
 213             Store_Compilation_Switch (Switch_Chars);
 214
 215             --  Special check, the back end switch -fno-inline also sets the
 216             --  front end flag to entirely inhibit all inlining.
 217
 218             if Switch_Chars (First .. Last) = "fno-inline" then
 219                Opt.Suppress_All_Inlining := True;
 220             end if;
 221          end if;
 222       end Scan_Back_End_Switches;
 223
 224    --  Start of processing for Scan_Compiler_Arguments
 225
 226    begin
 227       --  Acquire stack checking mode directly from GCC
 228
 229       Opt.Stack_Checking_Enabled := (flag_stack_check /= 0);
 230
 231       --  Loop through command line arguments, storing them for later access
 232
 233       while Next_Arg < save_argc loop
 234          Look_At_Arg : declare
 235             Argv_Ptr : constant Big_String_Ptr := save_argv (Next_Arg);
 236             Argv_Len : constant Nat            := Len_Arg (Next_Arg);
 237             Argv     : constant String         :=
 238                          Argv_Ptr (1 .. Natural (Argv_Len));
 239
 240          begin
 241             --  If the previous switch has set the Output_File_Name_Present
 242             --  flag (that is we have seen a -gnatO), then the next argument
 243             --  is the name of the output object file.
 244
 245             if Output_File_Name_Present
 246               and then not Output_File_Name_Seen
 247             then
 248                if Is_Switch (Argv) then
 249                   Fail ("Object file name missing after -gnatO");
 250
 251                else
 252                   Set_Output_Object_File_Name (Argv);
 253                   Output_File_Name_Seen := True;
 254                end if;
 255
 256             --  If the previous switch has set the Search_Directory_Present
 257             --  flag (that is if we have just seen -I), then the next argument
 258             --  is a search directory path.
 259
 260             elsif Search_Directory_Present then
 261                if Is_Switch (Argv) then
 262                   Fail ("search directory missing after -I");
 263                else
 264                   Add_Src_Search_Dir (Argv);
 265                   Search_Directory_Present := False;
 266                end if;
 267
 268             elsif not Is_Switch (Argv) then -- must be a file name
 269                Add_File (Argv);
 270
 271             --  We must recognize -nostdinc to suppress visibility on the
 272             --  standard GNAT RTL sources. This is also a gcc switch.
 273
 274             elsif Argv (Argv'First + 1 .. Argv'Last) = "nostdinc" then
 275                Opt.No_Stdinc := True;
 276                Scan_Back_End_Switches (Argv);
 277
 278             --  We must recognize -nostdlib to suppress visibility on the
 279             --  standard GNAT RTL objects.
 280
 281             elsif Argv (Argv'First + 1 .. Argv'Last) = "nostdlib" then
 282                Opt.No_Stdlib := True;
 283
 284             elsif Is_Front_End_Switch (Argv) then
 285                Scan_Front_End_Switches (Argv);
 286
 287             --  All non-front-end switches are back-end switches
 288
 289             else
 290                Scan_Back_End_Switches (Argv);
 291             end if;
 292          end Look_At_Arg;
 293
 294          Next_Arg := Next_Arg + 1;
 295       end loop;
 296    end Scan_Compiler_Arguments;
 297
 298 end Back_End;