gcc/ada/a-cgcaso.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT LIBRARY COMPONENTS                          --
   4 --                                                                          --
   5 --              ADA.CONTAINERS.GENERIC_CONSTRAINED_ARRAY_SORT               --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2004-2008, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- This unit has originally being developed by Matthew J Heaney.            --
  30 ------------------------------------------------------------------------------
  31
  32 --  This algorithm was adapted from GNAT.Heap_Sort_G (see g-hesorg.ad[sb])
  33
  34 with System;
  35
  36 procedure Ada.Containers.Generic_Constrained_Array_Sort
  37   (Container : in out Array_Type)
  38 is
  39    type T is range System.Min_Int .. System.Max_Int;
  40
  41    function To_Index (J : T) return Index_Type;
  42    pragma Inline (To_Index);
  43
  44    procedure Sift (S : T);
  45
  46    A : Array_Type renames Container;
  47
  48    --------------
  49    -- To_Index --
  50    --------------
  51
  52    function To_Index (J : T) return Index_Type is
  53       K : constant T'Base := Index_Type'Pos (A'First) + J - T'(1);
  54    begin
  55       return Index_Type'Val (K);
  56    end To_Index;
  57
  58    Max  : T := A'Length;
  59    Temp : Element_Type;
  60
  61    ----------
  62    -- Sift --
  63    ----------
  64
  65    procedure Sift (S : T) is
  66       C   : T := S;
  67       Son : T;
  68
  69    begin
  70       loop
  71          Son := 2 * C;
  72
  73          exit when Son > Max;
  74
  75          declare
  76             Son_Index : Index_Type := To_Index (Son);
  77
  78          begin
  79             if Son < Max then
  80                if A (Son_Index) < A (Index_Type'Succ (Son_Index)) then
  81                   Son := Son + 1;
  82                   Son_Index := Index_Type'Succ (Son_Index);
  83                end if;
  84             end if;
  85
  86             A (To_Index (C)) := A (Son_Index);  -- Move (Son, C);
  87          end;
  88
  89          C := Son;
  90       end loop;
  91
  92       while C /= S loop
  93          declare
  94             Father : constant T := C / 2;
  95          begin
  96             if A (To_Index (Father)) < Temp then           -- Lt (Father, 0)
  97                A (To_Index (C)) := A (To_Index (Father));  -- Move (Father, C)
  98                C := Father;
  99             else
 100                exit;
 101             end if;
 102          end;
 103       end loop;
 104
 105       A (To_Index (C)) := Temp; -- Move (0, C);
 106    end Sift;
 107
 108 --  Start of processing for Generic_Constrained_Array_Sort
 109
 110 begin
 111    for J in reverse 1 .. Max / 2 loop
 112       Temp := Container (To_Index (J)); --  Move (J, 0);
 113       Sift (J);
 114    end loop;
 115
 116    while Max > 1 loop
 117       Temp := A (To_Index (Max));         --  Move (Max, 0);
 118       A (To_Index (Max)) := A (A'First);  --  Move (1, Max);
 119
 120       Max := Max - 1;
 121       Sift (1);
 122    end loop;
 123 end Ada.Containers.Generic_Constrained_Array_Sort;