gcc/ada/s-taskin.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                 GNAT RUN-TIME LIBRARY (GNARL) COMPONENTS                 --
   4 --                                                                          --
   5 --                        S Y S T E M . T A S K I N G                       --
   6 --                                                                          --
   7 --                                  B o d y                                 --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2016, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNARL is free software; you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  17 --                                                                          --
  18 -- As a special exception under Section 7 of GPL version 3, you are granted --
  19 -- additional permissions described in the GCC Runtime Library Exception,   --
  20 -- version 3.1, as published by the Free Software Foundation.               --
  21 --                                                                          --
  22 -- You should have received a copy of the GNU General Public License and    --
  23 -- a copy of the GCC Runtime Library Exception along with this program;     --
  24 -- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
  25 -- <http://www.gnu.org/licenses/>.                                          --
  26 --                                                                          --
  27 -- GNARL was developed by the GNARL team at Florida State University.       --
  28 -- Extensive contributions were provided by Ada Core Technologies, Inc.     --
  29 --                                                                          --
  30 ------------------------------------------------------------------------------
  31
  32 pragma Polling (Off);
  33 --  Turn off polling, we do not want ATC polling to take place during tasking
  34 --  operations. It causes infinite loops and other problems.
  35
  36 with System.Task_Primitives.Operations;
  37 with System.Storage_Elements;
  38
  39 package body System.Tasking is
  40
  41    package STPO renames System.Task_Primitives.Operations;
  42
  43    ---------------------
  44    -- Detect_Blocking --
  45    ---------------------
  46
  47    function Detect_Blocking return Boolean is
  48       GL_Detect_Blocking : Integer;
  49       pragma Import (C, GL_Detect_Blocking, "__gl_detect_blocking");
  50       --  Global variable exported by the binder generated file. A value equal
  51       --  to 1 indicates that pragma Detect_Blocking is active, while 0 is used
  52       --  for the pragma not being present.
  53
  54    begin
  55       return GL_Detect_Blocking = 1;
  56    end Detect_Blocking;
  57
  58    -----------------------
  59    -- Number_Of_Entries --
  60    -----------------------
  61
  62    function Number_Of_Entries (Self_Id : Task_Id) return Entry_Index is
  63    begin
  64       return Entry_Index (Self_Id.Entry_Num);
  65    end Number_Of_Entries;
  66
  67    ----------
  68    -- Self --
  69    ----------
  70
  71    function Self return Task_Id renames STPO.Self;
  72
  73    ------------------
  74    -- Storage_Size --
  75    ------------------
  76
  77    function Storage_Size (T : Task_Id) return System.Parameters.Size_Type is
  78    begin
  79       return
  80          System.Parameters.Size_Type
  81            (T.Common.Compiler_Data.Pri_Stack_Info.Size);
  82    end Storage_Size;
  83
  84    ---------------------
  85    -- Initialize_ATCB --
  86    ---------------------
  87
  88    procedure Initialize_ATCB
  89      (Self_ID              : Task_Id;
  90       Task_Entry_Point     : Task_Procedure_Access;
  91       Task_Arg             : System.Address;
  92       Parent               : Task_Id;
  93       Elaborated           : Access_Boolean;
  94       Base_Priority        : System.Any_Priority;
  95       Base_CPU             : System.Multiprocessors.CPU_Range;
  96       Domain               : Dispatching_Domain_Access;
  97       Task_Info            : System.Task_Info.Task_Info_Type;
  98       Stack_Size           : System.Parameters.Size_Type;
  99       Secondary_Stack_Size : System.Parameters.Size_Type;
 100       T                    : Task_Id;
 101       Success              : out Boolean)
 102    is
 103    begin
 104       T.Common.State := Unactivated;
 105
 106       --  Initialize T.Common.LL
 107
 108       STPO.Initialize_TCB (T, Success);
 109
 110       if not Success then
 111          return;
 112       end if;
 113
 114       --  Note that use of an aggregate here for this assignment
 115       --  would be illegal, because Common_ATCB is limited because
 116       --  Task_Primitives.Private_Data is limited.
 117
 118       T.Common.Parent                   := Parent;
 119       T.Common.Base_Priority            := Base_Priority;
 120       T.Common.Base_CPU                 := Base_CPU;
 121
 122       --  The Domain defaults to that of the activator. But that can be null in
 123       --  the case of foreign threads (see Register_Foreign_Thread), in which
 124       --  case we default to the System_Domain.
 125
 126       if Domain /= null then
 127          T.Common.Domain := Domain;
 128       elsif Self_ID.Common.Domain /= null then
 129          T.Common.Domain := Self_ID.Common.Domain;
 130       else
 131          T.Common.Domain := System_Domain;
 132       end if;
 133       pragma Assert (T.Common.Domain /= null);
 134
 135       T.Common.Current_Priority         := 0;
 136       T.Common.Protected_Action_Nesting := 0;
 137       T.Common.Call                     := null;
 138       T.Common.Task_Arg                 := Task_Arg;
 139       T.Common.Task_Entry_Point         := Task_Entry_Point;
 140       T.Common.Activator                := Self_ID;
 141       T.Common.Wait_Count               := 0;
 142       T.Common.Elaborated               := Elaborated;
 143       T.Common.Activation_Failed        := False;
 144       T.Common.Task_Info                := Task_Info;
 145       T.Common.Global_Task_Lock_Nesting := 0;
 146       T.Common.Fall_Back_Handler        := null;
 147       T.Common.Specific_Handler         := null;
 148       T.Common.Debug_Events             := (others => False);
 149       T.Common.Task_Image_Len           := 0;
 150       T.Common.Secondary_Stack_Size     := Secondary_Stack_Size;
 151
 152       if T.Common.Parent = null then
 153
 154          --  For the environment task, the adjusted stack size is meaningless.
 155          --  For example, an unspecified Stack_Size means that the stack size
 156          --  is determined by the environment, or can grow dynamically. The
 157          --  Stack_Checking algorithm therefore needs to use the requested
 158          --  size, or 0 in case of an unknown size.
 159
 160          T.Common.Compiler_Data.Pri_Stack_Info.Size :=
 161             Storage_Elements.Storage_Offset (Stack_Size);
 162
 163       else
 164          T.Common.Compiler_Data.Pri_Stack_Info.Size :=
 165            Storage_Elements.Storage_Offset
 166              (Parameters.Adjust_Storage_Size (Stack_Size));
 167       end if;
 168
 169       --  Link the task into the list of all tasks
 170
 171       T.Common.All_Tasks_Link := All_Tasks_List;
 172       All_Tasks_List := T;
 173    end Initialize_ATCB;
 174
 175    ----------------
 176    -- Initialize --
 177    ----------------
 178
 179    Main_Task_Image : constant String := "main_task";
 180    --  Image of environment task
 181
 182    Main_Priority : Integer;
 183    pragma Import (C, Main_Priority, "__gl_main_priority");
 184    --  Priority for main task. Note that this is of type Integer, not Priority,
 185    --  because we use the value -1 to indicate the default main priority, and
 186    --  that is of course not in Priority'range.
 187
 188    Main_CPU : Integer;
 189    pragma Import (C, Main_CPU, "__gl_main_cpu");
 190    --  Affinity for main task. Note that this is of type Integer, not
 191    --  CPU_Range, because we use the value -1 to indicate the unassigned
 192    --  affinity, and that is of course not in CPU_Range'Range.
 193
 194    Initialized : Boolean := False;
 195    --  Used to prevent multiple calls to Initialize
 196
 197    procedure Initialize is
 198       T             : Task_Id;
 199       Base_Priority : Any_Priority;
 200       Base_CPU      : System.Multiprocessors.CPU_Range;
 201       Success       : Boolean;
 202
 203       use type System.Multiprocessors.CPU_Range;
 204
 205    begin
 206       if Initialized then
 207          return;
 208       end if;
 209
 210       Initialized := True;
 211
 212       --  Initialize Environment Task
 213
 214       Base_Priority :=
 215         (if Main_Priority = Unspecified_Priority
 216          then Default_Priority
 217          else Priority (Main_Priority));
 218
 219       Base_CPU :=
 220         (if Main_CPU = Unspecified_CPU
 221          then System.Multiprocessors.Not_A_Specific_CPU
 222          else System.Multiprocessors.CPU_Range (Main_CPU));
 223
 224       --  At program start-up the environment task is allocated to the default
 225       --  system dispatching domain.
 226       --  Make sure that the processors which are not available are not taken
 227       --  into account. Use Number_Of_CPUs to know the exact number of
 228       --  processors in the system at execution time.
 229
 230       System_Domain :=
 231         new Dispatching_Domain'
 232           (Multiprocessors.CPU'First .. Multiprocessors.Number_Of_CPUs =>
 233              True);
 234
 235       T := STPO.New_ATCB (0);
 236       Initialize_ATCB
 237         (Self_ID              => null,
 238          Task_Entry_Point     => null,
 239          Task_Arg             => Null_Address,
 240          Parent               => Null_Task,
 241          Elaborated           => null,
 242          Base_Priority        => Base_Priority,
 243          Base_CPU             => Base_CPU,
 244          Domain               => System_Domain,
 245          Task_Info            => Task_Info.Unspecified_Task_Info,
 246          Stack_Size           => 0,
 247          Secondary_Stack_Size => Parameters.Unspecified_Size,
 248          T                    => T,
 249          Success              => Success);
 250       pragma Assert (Success);
 251
 252       STPO.Initialize (T);
 253       STPO.Set_Priority (T, T.Common.Base_Priority);
 254       T.Common.State := Runnable;
 255       T.Common.Task_Image_Len := Main_Task_Image'Length;
 256       T.Common.Task_Image (Main_Task_Image'Range) := Main_Task_Image;
 257
 258       Dispatching_Domain_Tasks :=
 259         new Array_Allocated_Tasks'
 260           (Multiprocessors.CPU'First .. Multiprocessors.Number_Of_CPUs => 0);
 261
 262       --  Signal that this task is being allocated to a processor
 263
 264       if Base_CPU /= System.Multiprocessors.Not_A_Specific_CPU then
 265
 266          --  Increase the number of tasks attached to the CPU to which this
 267          --  task is allocated.
 268
 269          Dispatching_Domain_Tasks (Base_CPU) :=
 270            Dispatching_Domain_Tasks (Base_CPU) + 1;
 271       end if;
 272
 273       --  Only initialize the first element since others are not relevant
 274       --  in ravenscar mode. Rest of the initialization is done in Init_RTS.
 275
 276       T.Entry_Calls (1).Self := T;
 277    end Initialize;
 278 end System.Tasking;