gcc/ada/exp_ch8.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                              E X P _ C H 8                               --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --                                                                          --
  10 --          Copyright (C) 1992-2001 Free Software Foundation, Inc.          --
  11 --                                                                          --
  12 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  13 -- terms of the  GNU General Public License as published  by the Free Soft- --
  14 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  15 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  16 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  17 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  18 -- for  more details.  You should have  received  a copy of the GNU General --
  19 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  20 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  21 -- MA 02111-1307, USA.                                                      --
  22 --                                                                          --
  23 -- GNAT was originally developed  by the GNAT team at  New York University. --
  24 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  25 --                                                                          --
  26 ------------------------------------------------------------------------------
  27
  28 with Atree;    use Atree;
  29 with Einfo;    use Einfo;
  30 with Exp_Dbug; use Exp_Dbug;
  31 with Exp_Util; use Exp_Util;
  32 with Nlists;   use Nlists;
  33 with Sem;      use Sem;
  34 with Sem_Ch8;  use Sem_Ch8;
  35 with Sinfo;    use Sinfo;
  36 with Stand;    use Stand;
  37
  38 package body Exp_Ch8 is
  39
  40    ---------------------------------------------
  41    -- Expand_N_Exception_Renaming_Declaration --
  42    ---------------------------------------------
  43
  44    procedure Expand_N_Exception_Renaming_Declaration (N : Node_Id) is
  45       Decl : constant Node_Id := Debug_Renaming_Declaration (N);
  46
  47    begin
  48       if Present (Decl) then
  49          Insert_Action (N, Decl);
  50       end if;
  51    end Expand_N_Exception_Renaming_Declaration;
  52
  53    ------------------------------------------
  54    -- Expand_N_Object_Renaming_Declaration --
  55    ------------------------------------------
  56
  57    --  Most object renaming cases can be done by just capturing the address
  58    --  of the renamed object. The cases in which this is not true are when
  59    --  this address is not computable, since it involves extraction of a
  60    --  packed array element, or of a record component to which a component
  61    --  clause applies (that can specify an arbitrary bit boundary), or where
  62    --  the enclosing record itself has a non-standard representation.
  63
  64    --  In these two cases, we pre-evaluate the renaming expression, by
  65    --  extracting and freezing the values of any subscripts, and then we
  66    --  set the flag Is_Renaming_Of_Object which means that any reference
  67    --  to the object will be handled by macro substitution in the front
  68    --  end, and the back end will know to ignore the renaming declaration.
  69
  70    --  An additional odd case that requires processing by expansion is
  71    --  the renaming of a discriminant of a mutable record type. The object
  72    --  is a constant because it renames something that cannot be assigned to,
  73    --  but in fact the underlying value can change and must be reevaluated
  74    --  at each reference. Gigi does have a notion of a "constant view" of
  75    --  an object, and therefore the front-end must perform the expansion.
  76    --  For simplicity, and to bypass some obscure code-generation problem,
  77    --  we use macro substitution for all renamed discriminants, whether the
  78    --  enclosing type is constrained or not.
  79
  80    --  The other special processing required is for the case of renaming
  81    --  of an object of a class wide type, where it is necessary to build
  82    --  the appropriate subtype for the renamed object.
  83    --  More comments needed for this para ???
  84
  85    procedure Expand_N_Object_Renaming_Declaration (N : Node_Id) is
  86       Nam  : Node_Id := Name (N);
  87       T    : Entity_Id;
  88       Decl : Node_Id;
  89
  90       procedure Evaluate_Name (Fname : Node_Id);
  91       --  A recursive procedure used to freeze a name in the sense described
  92       --  above, i.e. any variable references or function calls are removed.
  93       --  Of course the outer level variable reference must not be removed.
  94       --  For example in A(J,F(K)), A is left as is, but J and F(K) are
  95       --  evaluated and removed.
  96
  97       function Evaluation_Required (Nam : Node_Id) return Boolean;
  98       --  Determines whether it is necessary to do static name evaluation
  99       --  for renaming of Nam. It is considered necessary if evaluating the
 100       --  name involves indexing a packed array, or extracting a component
 101       --  of a record to which a component clause applies. Note that we are
 102       --  only interested in these operations if they occur as part of the
 103       --  name itself, subscripts are just values that are computed as part
 104       --  of the evaluation, so their form is unimportant.
 105
 106       -------------------
 107       -- Evaluate_Name --
 108       -------------------
 109
 110       procedure Evaluate_Name (Fname : Node_Id) is
 111          K : constant Node_Kind := Nkind (Fname);
 112          E : Node_Id;
 113
 114       begin
 115          --  For an explicit dereference, we simply force the evaluation
 116          --  of the name expression. The dereference provides a value that
 117          --  is the address for the renamed object, and it is precisely
 118          --  this value that we want to preserve.
 119
 120          if K = N_Explicit_Dereference then
 121             Force_Evaluation (Prefix (Fname));
 122
 123          --  For a selected component, we simply evaluate the prefix
 124
 125          elsif K = N_Selected_Component then
 126             Evaluate_Name (Prefix (Fname));
 127
 128          --  For an indexed component, or an attribute reference, we evaluate
 129          --  the prefix, which is itself a name, recursively, and then force
 130          --  the evaluation of all the subscripts (or attribute expressions).
 131
 132          elsif K = N_Indexed_Component
 133            or else K = N_Attribute_Reference
 134          then
 135             Evaluate_Name (Prefix (Fname));
 136
 137             E := First (Expressions (Fname));
 138             while Present (E) loop
 139                Force_Evaluation (E);
 140
 141                if Original_Node (E) /= E then
 142                   Set_Do_Range_Check (E, Do_Range_Check (Original_Node (E)));
 143                end if;
 144
 145                Next (E);
 146             end loop;
 147
 148          --  For a slice, we evaluate the prefix, as for the indexed component
 149          --  case and then, if there is a range present, either directly or
 150          --  as the constraint of a discrete subtype indication, we evaluate
 151          --  the two bounds of this range.
 152
 153          elsif K = N_Slice then
 154             Evaluate_Name (Prefix (Fname));
 155
 156             declare
 157                DR     : constant Node_Id := Discrete_Range (Fname);
 158                Constr : Node_Id;
 159                Rexpr  : Node_Id;
 160
 161             begin
 162                if Nkind (DR) = N_Range then
 163                   Force_Evaluation (Low_Bound (DR));
 164                   Force_Evaluation (High_Bound (DR));
 165
 166                elsif Nkind (DR) = N_Subtype_Indication then
 167                   Constr := Constraint (DR);
 168
 169                   if Nkind (Constr) = N_Range_Constraint then
 170                      Rexpr := Range_Expression (Constr);
 171
 172                      Force_Evaluation (Low_Bound (Rexpr));
 173                      Force_Evaluation (High_Bound (Rexpr));
 174                   end if;
 175                end if;
 176             end;
 177
 178          --  For a type conversion, the expression of the conversion must be
 179          --  the name of an object, and we simply need to evaluate this name.
 180
 181          elsif K = N_Type_Conversion then
 182             Evaluate_Name (Expression (Fname));
 183
 184          --  For a function call, we evaluate the call.
 185
 186          elsif K = N_Function_Call then
 187             Force_Evaluation (Fname);
 188
 189          --  The remaining cases are direct name, operator symbol and
 190          --  character literal. In all these cases, we do nothing, since
 191          --  we want to reevaluate each time the renamed object is used.
 192
 193          else
 194             return;
 195          end if;
 196       end Evaluate_Name;
 197
 198       -------------------------
 199       -- Evaluation_Required --
 200       -------------------------
 201
 202       function Evaluation_Required (Nam : Node_Id) return Boolean is
 203       begin
 204          if Nkind (Nam) = N_Indexed_Component
 205            or else Nkind (Nam) = N_Slice
 206          then
 207             if Is_Packed (Etype (Prefix (Nam))) then
 208                return True;
 209             else
 210                return Evaluation_Required (Prefix (Nam));
 211             end if;
 212
 213          elsif Nkind (Nam) = N_Selected_Component then
 214             declare
 215                Rec_Type : Entity_Id := Etype (Prefix (Nam));
 216
 217             begin
 218                if Present (Component_Clause (Entity (Selector_Name (Nam))))
 219                  or else Has_Non_Standard_Rep (Rec_Type)
 220                then
 221                   return True;
 222
 223                elsif Ekind (Entity (Selector_Name (Nam))) = E_Discriminant
 224                  and then Is_Record_Type (Rec_Type)
 225                  and then not Is_Concurrent_Record_Type (Rec_Type)
 226                then
 227                   return True;
 228
 229                else
 230                   return Evaluation_Required (Prefix (Nam));
 231                end if;
 232             end;
 233
 234          else
 235             return False;
 236          end if;
 237       end Evaluation_Required;
 238
 239    --  Start of processing for Expand_N_Object_Renaming_Declaration
 240
 241    begin
 242       --  Perform name evaluation if required
 243
 244       if Evaluation_Required (Nam) then
 245          Evaluate_Name (Nam);
 246          Set_Is_Renaming_Of_Object (Defining_Identifier (N));
 247       end if;
 248
 249       --  Deal with construction of subtype in class-wide case
 250
 251       T := Etype (Defining_Identifier (N));
 252
 253       if Is_Class_Wide_Type (T) then
 254          Expand_Subtype_From_Expr (N, T, Subtype_Mark (N), Name (N));
 255          Find_Type (Subtype_Mark (N));
 256          Set_Etype (Defining_Identifier (N), Entity (Subtype_Mark (N)));
 257       end if;
 258
 259       --  Create renaming entry for debug information
 260
 261       Decl := Debug_Renaming_Declaration (N);
 262
 263       if Present (Decl) then
 264          Insert_Action (N, Decl);
 265       end if;
 266    end Expand_N_Object_Renaming_Declaration;
 267
 268    -------------------------------------------
 269    -- Expand_N_Package_Renaming_Declaration --
 270    -------------------------------------------
 271
 272    procedure Expand_N_Package_Renaming_Declaration (N : Node_Id) is
 273       Decl : constant Node_Id := Debug_Renaming_Declaration (N);
 274
 275    begin
 276       if Present (Decl) then
 277
 278          --  If we are in a compilation unit, then this is an outer
 279          --  level declaration, and must have a scope of Standard
 280
 281          if Nkind (Parent (N)) = N_Compilation_Unit then
 282             declare
 283                Aux : constant Node_Id := Aux_Decls_Node (Parent (N));
 284
 285             begin
 286                New_Scope (Standard_Standard);
 287
 288                if No (Actions (Aux)) then
 289                   Set_Actions (Aux, New_List (Decl));
 290                else
 291                   Append (Decl, Actions (Aux));
 292                end if;
 293
 294                Analyze (Decl);
 295                Pop_Scope;
 296             end;
 297
 298          --  Otherwise, just insert after the package declaration
 299
 300          else
 301             Insert_Action (N, Decl);
 302          end if;
 303       end if;
 304    end Expand_N_Package_Renaming_Declaration;
 305
 306 end Exp_Ch8;