gcc/ada/widechar.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             W I D E C H A R                              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2005 Free Software Foundation, Inc.          --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  20 -- MA 02111-1307, USA.                                                      --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 --  Note: this package uses the generic subprograms in System.Wch_Cnv, which
  35 --  completely encapsulate the set of wide character encoding methods, so no
  36 --  modifications are required when adding new encoding methods.
  37
  38 with Opt; use Opt;
  39
  40 with System.WCh_Cnv; use System.WCh_Cnv;
  41 with System.WCh_Con; use System.WCh_Con;
  42
  43 package body Widechar is
  44
  45    ---------------------------
  46    -- Is_Start_Of_Wide_Char --
  47    ---------------------------
  48
  49    function Is_Start_Of_Wide_Char
  50      (S : Source_Buffer_Ptr;
  51       P : Source_Ptr) return Boolean
  52    is
  53    begin
  54       case Wide_Character_Encoding_Method is
  55          when WCEM_Hex =>
  56             return S (P) = ASCII.ESC;
  57
  58          when WCEM_Upper     |
  59               WCEM_Shift_JIS |
  60               WCEM_EUC       |
  61               WCEM_UTF8      =>
  62             return S (P) >= Character'Val (16#80#);
  63
  64          when WCEM_Brackets =>
  65             return P <= S'Last - 2
  66               and then S (P) = '['
  67               and then S (P + 1) = '"'
  68               and then S (P + 2) /= '"';
  69       end case;
  70    end Is_Start_Of_Wide_Char;
  71
  72    -----------------
  73    -- Length_Wide --
  74    -----------------
  75
  76    function Length_Wide return Nat is
  77    begin
  78       return WC_Longest_Sequence;
  79    end Length_Wide;
  80
  81    ---------------
  82    -- Scan_Wide --
  83    ---------------
  84
  85    procedure Scan_Wide
  86      (S   : Source_Buffer_Ptr;
  87       P   : in out Source_Ptr;
  88       C   : out Char_Code;
  89       Err : out Boolean)
  90    is
  91       function In_Char return Character;
  92       --  Function to obtain characters of wide character escape sequence
  93
  94       -------------
  95       -- In_Char --
  96       -------------
  97
  98       function In_Char return Character is
  99       begin
 100          P := P + 1;
 101          return S (P - 1);
 102       end In_Char;
 103
 104       function WC_In is new Char_Sequence_To_UTF_32 (In_Char);
 105
 106    --  Start of processingf for Scan_Wide
 107
 108    begin
 109       C := Char_Code (WC_In (In_Char, Wide_Character_Encoding_Method));
 110       Err := False;
 111
 112    exception
 113       when Constraint_Error =>
 114          C := Char_Code (0);
 115          P := P - 1;
 116          Err := True;
 117    end Scan_Wide;
 118
 119    --------------
 120    -- Set_Wide --
 121    --------------
 122
 123    procedure Set_Wide
 124      (C : Char_Code;
 125       S : in out String;
 126       P : in out Natural)
 127    is
 128       procedure Out_Char (C : Character);
 129       --  Procedure to store one character of wide character sequence
 130
 131       --------------
 132       -- Out_Char --
 133       --------------
 134
 135       procedure Out_Char (C : Character) is
 136       begin
 137          P := P + 1;
 138          S (P) := C;
 139       end Out_Char;
 140
 141       procedure WC_Out is new UTF_32_To_Char_Sequence (Out_Char);
 142
 143    --  Start of processing for Set_Wide
 144
 145    begin
 146       WC_Out (UTF_32_Code (C), Wide_Character_Encoding_Method);
 147    end Set_Wide;
 148
 149    ---------------
 150    -- Skip_Wide --
 151    ---------------
 152
 153    procedure Skip_Wide (S : String; P : in out Natural) is
 154       function Skip_Char return Character;
 155       --  Function to skip one character of wide character escape sequence
 156
 157       ---------------
 158       -- Skip_Char --
 159       ---------------
 160
 161       function Skip_Char return Character is
 162       begin
 163          P := P + 1;
 164          return S (P - 1);
 165       end Skip_Char;
 166
 167       function WC_Skip is new Char_Sequence_To_UTF_32 (Skip_Char);
 168
 169       Discard : UTF_32_Code;
 170       pragma Warnings (Off, Discard);
 171
 172    --  Start of processing for Skip_Wide
 173
 174    begin
 175       Discard := WC_Skip (Skip_Char, Wide_Character_Encoding_Method);
 176    end Skip_Wide;
 177
 178    ---------------
 179    -- Skip_Wide --
 180    ---------------
 181
 182    procedure Skip_Wide (S : Source_Buffer_Ptr; P : in out Source_Ptr) is
 183       function Skip_Char return Character;
 184       --  Function to skip one character of wide character escape sequence
 185
 186       ---------------
 187       -- Skip_Char --
 188       ---------------
 189
 190       function Skip_Char return Character is
 191       begin
 192          P := P + 1;
 193          return S (P - 1);
 194       end Skip_Char;
 195
 196       function WC_Skip is new Char_Sequence_To_UTF_32 (Skip_Char);
 197
 198       Discard : UTF_32_Code;
 199       pragma Warnings (Off, Discard);
 200
 201    --  Start of processing for Skip_Wide
 202
 203    begin
 204       Discard := WC_Skip (Skip_Char, Wide_Character_Encoding_Method);
 205    end Skip_Wide;
 206
 207 end Widechar;