gcc/ada/sem_ch6.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                              S E M _ C H 6                               --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2013, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Types; use Types;
  27 package Sem_Ch6 is
  28
  29    type Conformance_Type is
  30      (Type_Conformant, Mode_Conformant, Subtype_Conformant, Fully_Conformant);
  31    --  pragma Ordered (Conformance_Type);
  32    --  Why is above line commented out ???
  33    --  Conformance type used in conformance checks between specs and bodies,
  34    --  and for overriding. The literals match the RM definitions of the
  35    --  corresponding terms. This is an ordered type, since each conformance
  36    --  type is stronger than the ones preceding it.
  37
  38    procedure Analyze_Abstract_Subprogram_Declaration (N : Node_Id);
  39    procedure Analyze_Expression_Function             (N : Node_Id);
  40    procedure Analyze_Extended_Return_Statement       (N : Node_Id);
  41    procedure Analyze_Function_Call                   (N : Node_Id);
  42    procedure Analyze_Operator_Symbol                 (N : Node_Id);
  43    procedure Analyze_Parameter_Association           (N : Node_Id);
  44    procedure Analyze_Procedure_Call                  (N : Node_Id);
  45    procedure Analyze_Simple_Return_Statement         (N : Node_Id);
  46    procedure Analyze_Subprogram_Declaration          (N : Node_Id);
  47    procedure Analyze_Subprogram_Body                 (N : Node_Id);
  48
  49    procedure Analyze_Subprogram_Body_Contract (Body_Id : Entity_Id);
  50    --  Analyze all delayed aspects chained on the contract of subprogram body
  51    --  Body_Id as if they appeared at the end of a declarative region. The
  52    --  aspects in question are:
  53    --    Refined_Depends
  54    --    Refined_Global
  55
  56    procedure Analyze_Subprogram_Contract (Subp : Entity_Id);
  57    --  Analyze all delayed aspects chained on the contract of subprogram Subp
  58    --  as if they appeared at the end of a declarative region. The aspects in
  59    --  question are:
  60    --    Contract_Cases
  61    --    Postcondition
  62    --    Precondition
  63    --    Test_Case
  64
  65    function Analyze_Subprogram_Specification (N : Node_Id) return Entity_Id;
  66    --  Analyze subprogram specification in both subprogram declarations
  67    --  and body declarations. Returns the defining entity for the
  68    --  specification N.
  69
  70    procedure Cannot_Inline
  71      (Msg        : String;
  72       N          : Node_Id;
  73       Subp       : Entity_Id;
  74       Is_Serious : Boolean := False);
  75    --  This procedure is called if the node N, an instance of a call to
  76    --  subprogram Subp, cannot be inlined. Msg is the message to be issued,
  77    --  which ends with ? (it does not end with ?p?, this routine takes care of
  78    --  the need to change ? to ?p?). Temporarily the behavior of this routine
  79    --  depends on the value of -gnatd.k:
  80    --
  81    --    * If -gnatd.k is not set (ie. old inlining model) then if Subp has
  82    --      a pragma Always_Inlined, then an error message is issued (by
  83    --      removing the last character of Msg). If Subp is not Always_Inlined,
  84    --      then a warning is issued if the flag Ineffective_Inline_Warnings
  85    --      is set, adding ?p to the msg, and if not, the call has no effect.
  86    --
  87    --    * If -gnatd.k is set (ie. new inlining model) then:
  88    --      - If Is_Serious is true, then an error is reported (by removing the
  89    --        last character of Msg);
  90    --
  91    --      - otherwise:
  92    --
  93    --        * Compiling without optimizations if Subp has a pragma
  94    --          Always_Inlined, then an error message is issued; if Subp is
  95    --          not Always_Inlined, then a warning is issued if the flag
  96    --          Ineffective_Inline_Warnings is set (adding p?), and if not,
  97    --          the call has no effect.
  98    --
  99    --        * Compiling with optimizations then a warning is issued if the
 100    --          flag Ineffective_Inline_Warnings is set (adding p?); otherwise
 101    --          no effect since inlining may be performed by the backend.
 102
 103    procedure Check_Conventions (Typ : Entity_Id);
 104    --  Ada 2005 (AI-430): Check that the conventions of all inherited and
 105    --  overridden dispatching operations of type Typ are consistent with their
 106    --  respective counterparts.
 107
 108    procedure Check_Delayed_Subprogram (Designator : Entity_Id);
 109    --  Designator can be a E_Subprogram_Type, E_Procedure or E_Function. If a
 110    --  type in its profile depends on a private type without a full
 111    --  declaration, indicate that the subprogram or type is delayed.
 112
 113    procedure Check_Discriminant_Conformance
 114      (N        : Node_Id;
 115       Prev     : Entity_Id;
 116       Prev_Loc : Node_Id);
 117    --  Check that the discriminants of a full type N fully conform to the
 118    --  discriminants of the corresponding partial view Prev. Prev_Loc indicates
 119    --  the source location of the partial view, which may be different than
 120    --  Prev in the case of private types.
 121
 122    procedure Check_Fully_Conformant
 123      (New_Id  : Entity_Id;
 124       Old_Id  : Entity_Id;
 125       Err_Loc : Node_Id := Empty);
 126    --  Check that two callable entities (subprograms, entries, literals)
 127    --  are fully conformant, post error message if not (RM 6.3.1(17)) with
 128    --  the flag being placed on the Err_Loc node if it is specified, and
 129    --  on the appropriate component of the New_Id construct if not. Note:
 130    --  when checking spec/body conformance, New_Id must be the body entity
 131    --  and Old_Id is the spec entity (the code in the implementation relies
 132    --  on this ordering, and in any case, this makes sense, since if flags
 133    --  are to be placed on the construct, they clearly belong on the body.
 134
 135    procedure Check_Mode_Conformant
 136      (New_Id   : Entity_Id;
 137       Old_Id   : Entity_Id;
 138       Err_Loc  : Node_Id := Empty;
 139       Get_Inst : Boolean := False);
 140    --  Check that two callable entities (subprograms, entries, literals)
 141    --  are mode conformant, post error message if not (RM 6.3.1(15)) with
 142    --  the flag being placed on the Err_Loc node if it is specified, and
 143    --  on the appropriate component of the New_Id construct if not. The
 144    --  argument Get_Inst is set to True when this is a check against a
 145    --  formal access-to-subprogram type, indicating that mapping of types
 146    --  is needed.
 147
 148    procedure Check_Overriding_Indicator
 149      (Subp            : Entity_Id;
 150       Overridden_Subp : Entity_Id;
 151       Is_Primitive    : Boolean);
 152    --  Verify the consistency of an overriding_indicator given for subprogram
 153    --  declaration, body, renaming, or instantiation.  Overridden_Subp is set
 154    --  if the scope where we are introducing the subprogram contains a
 155    --  type-conformant subprogram that becomes hidden by the new subprogram.
 156    --  Is_Primitive indicates whether the subprogram is primitive.
 157
 158    procedure Check_Subtype_Conformant
 159      (New_Id                   : Entity_Id;
 160       Old_Id                   : Entity_Id;
 161       Err_Loc                  : Node_Id := Empty;
 162       Skip_Controlling_Formals : Boolean := False;
 163       Get_Inst                 : Boolean := False);
 164    --  Check that two callable entities (subprograms, entries, literals)
 165    --  are subtype conformant, post error message if not (RM 6.3.1(16)),
 166    --  the flag being placed on the Err_Loc node if it is specified, and
 167    --  on the appropriate component of the New_Id construct if not.
 168    --  Skip_Controlling_Formals is True when checking the conformance of
 169    --  a subprogram that implements an interface operation. In that case,
 170    --  only the non-controlling formals can (and must) be examined. The
 171    --  argument Get_Inst is set to True when this is a check against a
 172    --  formal access-to-subprogram type, indicating that mapping of types
 173    --  is needed.
 174
 175    procedure Check_Type_Conformant
 176      (New_Id  : Entity_Id;
 177       Old_Id  : Entity_Id;
 178       Err_Loc : Node_Id := Empty);
 179    --  Check that two callable entities (subprograms, entries, literals)
 180    --  are type conformant, post error message if not (RM 6.3.1(14)) with
 181    --  the flag being placed on the Err_Loc node if it is specified, and
 182    --  on the appropriate component of the New_Id construct if not.
 183
 184    function Conforming_Types
 185      (T1       : Entity_Id;
 186       T2       : Entity_Id;
 187       Ctype    : Conformance_Type;
 188       Get_Inst : Boolean := False) return Boolean;
 189    --  Check that the types of two formal parameters are conforming. In most
 190    --  cases this is just a name comparison, but within an instance it involves
 191    --  generic actual types, and in the presence of anonymous access types
 192    --  it must examine the designated types. The argument Get_Inst is set to
 193    --  True when this is a check against a formal access-to-subprogram type,
 194    --  indicating that mapping of types is needed.
 195
 196    procedure Create_Extra_Formals (E : Entity_Id);
 197    --  For each parameter of a subprogram or entry that requires an additional
 198    --  formal (such as for access parameters and indefinite discriminated
 199    --  parameters), creates the appropriate formal and attach it to its
 200    --  associated parameter. Each extra formal will also be appended to
 201    --  the end of Subp's parameter list (with each subsequent extra formal
 202    --  being attached to the preceding extra formal).
 203
 204    function Find_Corresponding_Spec
 205      (N          : Node_Id;
 206       Post_Error : Boolean := True) return Entity_Id;
 207    --  Use the subprogram specification in the body to retrieve the previous
 208    --  subprogram declaration, if any.
 209
 210    function Fully_Conformant (New_Id, Old_Id : Entity_Id) return Boolean;
 211    --  Determine whether two callable entities (subprograms, entries,
 212    --  literals) are fully conformant (RM 6.3.1(17))
 213
 214    function Fully_Conformant_Expressions
 215      (Given_E1 : Node_Id;
 216       Given_E2 : Node_Id) return Boolean;
 217    --  Determines if two (non-empty) expressions are fully conformant
 218    --  as defined by (RM 6.3.1(18-21))
 219
 220    function Fully_Conformant_Discrete_Subtypes
 221       (Given_S1 : Node_Id;
 222        Given_S2 : Node_Id) return Boolean;
 223    --  Determines if two subtype definitions are fully conformant. Used
 224    --  for entry family conformance checks (RM 6.3.1 (24)).
 225
 226    procedure Install_Entity (E : Entity_Id);
 227    --  Place a single entity on the visibility chain
 228
 229    procedure Install_Formals (Id : Entity_Id);
 230    --  On entry to a subprogram body, make the formals visible. Note that
 231    --  simply placing the subprogram on the scope stack is not sufficient:
 232    --  the formals must become the current entities for their names. This
 233    --  procedure is also used to get visibility to the formals when analyzing
 234    --  preconditions and postconditions appearing in the spec.
 235
 236    function Is_Interface_Conformant
 237      (Tagged_Type : Entity_Id;
 238       Iface_Prim  : Entity_Id;
 239       Prim        : Entity_Id) return Boolean;
 240    --  Returns true if both primitives have a matching name (including support
 241    --  for names of inherited private primitives --which have suffix 'P'), they
 242    --  are type conformant, and Prim is defined in the scope of Tagged_Type.
 243    --  Special management is done for functions returning interfaces.
 244
 245    procedure List_Inherited_Pre_Post_Aspects (E : Entity_Id);
 246    --  E is the entity for a subprogram or generic subprogram spec. This call
 247    --  lists all inherited Pre/Post aspects if List_Inherited_Pre_Post is True.
 248
 249    procedure May_Need_Actuals (Fun : Entity_Id);
 250    --  Flag functions that can be called without parameters, i.e. those that
 251    --  have no parameters, or those for which defaults exist for all parameters
 252    --  Used for subprogram declarations and for access subprogram declarations,
 253    --  where they apply to the anonymous designated type. On return the flag
 254    --  Set_Needs_No_Actuals is set appropriately in Fun.
 255
 256    function Mode_Conformant (New_Id, Old_Id : Entity_Id) return Boolean;
 257    --  Determine whether two callable entities (subprograms, entries,
 258    --  literals) are mode conformant (RM 6.3.1(15))
 259
 260    procedure New_Overloaded_Entity
 261      (S            : Entity_Id;
 262       Derived_Type : Entity_Id := Empty);
 263    --  Process new overloaded entity. Overloaded entities are created by
 264    --  enumeration type declarations, subprogram specifications, entry
 265    --  declarations, and (implicitly) by type derivations. If Derived_Type
 266    --  is non-empty then this is a subprogram derived for that type.
 267
 268    procedure Process_Formals (T : List_Id; Related_Nod : Node_Id);
 269    --  Enter the formals in the scope of the subprogram or entry, and
 270    --  analyze default expressions if any. The implicit types created for
 271    --  access parameter are attached to the Related_Nod which comes from the
 272    --  context.
 273
 274    procedure Reference_Body_Formals (Spec : Entity_Id; Bod : Entity_Id);
 275    --  If there is a separate spec for a subprogram or generic subprogram, the
 276    --  formals of the body are treated as references to the corresponding
 277    --  formals of the spec. This reference does not count as an actual use of
 278    --  the formal, in order to diagnose formals that are unused in the body.
 279    --  This procedure is also used in renaming_as_body declarations, where
 280    --  the formals of the specification must be treated as body formals that
 281    --  correspond to the previous subprogram declaration, and not as new
 282    --  entities with their defining entry in the cross-reference information.
 283
 284    procedure Set_Actual_Subtypes (N : Node_Id; Subp : Entity_Id);
 285    --  If the formals of a subprogram are unconstrained, build a subtype
 286    --  declaration that uses the bounds or discriminants of the actual to
 287    --  construct an actual subtype for them. This is an optimization that
 288    --  is done only in some cases where the actual subtype cannot change
 289    --  during execution of the subprogram. By setting the actual subtype
 290    --  once, we avoid recomputing it unnecessarily.
 291
 292    procedure Set_Formal_Mode (Formal_Id : Entity_Id);
 293    --  Set proper Ekind to reflect formal mode (in, out, in out)
 294
 295    function Subtype_Conformant
 296      (New_Id                   : Entity_Id;
 297       Old_Id                   : Entity_Id;
 298       Skip_Controlling_Formals : Boolean := False) return Boolean;
 299    --  Determine whether two callable entities (subprograms, entries, literals)
 300    --  are subtype conformant (RM 6.3.1(16)). Skip_Controlling_Formals is True
 301    --  when checking the conformance of a subprogram that implements an
 302    --  interface operation. In that case, only the non-controlling formals
 303    --  can (and must) be examined.
 304
 305    function Type_Conformant
 306      (New_Id                   : Entity_Id;
 307       Old_Id                   : Entity_Id;
 308       Skip_Controlling_Formals : Boolean := False) return Boolean;
 309    --  Determine whether two callable entities (subprograms, entries, literals)
 310    --  are type conformant (RM 6.3.1(14)). Skip_Controlling_Formals is True
 311    --  when checking the conformance of a subprogram that implements an
 312    --  interface operation. In that case, only the non-controlling formals
 313    --  can (and must) be examined.
 314
 315    procedure Valid_Operator_Definition (Designator : Entity_Id);
 316    --  Verify that an operator definition has the proper number of formals
 317
 318 end Sem_Ch6;