gcc/ada/libgnat/s-caun16.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                    GNAT RUN-TIME LIBRARY COMPONENTS                      --
   4 --                                                                          --
   5 --     S Y S T E M . C O M P A R E _ A R R A Y _ U N S I G N E D _ 1 6      --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2002-2023, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  17 --                                                                          --
  18 -- As a special exception under Section 7 of GPL version 3, you are granted --
  19 -- additional permissions described in the GCC Runtime Library Exception,   --
  20 -- version 3.1, as published by the Free Software Foundation.               --
  21 --                                                                          --
  22 -- You should have received a copy of the GNU General Public License and    --
  23 -- a copy of the GCC Runtime Library Exception along with this program;     --
  24 -- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
  25 -- <http://www.gnu.org/licenses/>.                                          --
  26 --                                                                          --
  27 -- GNAT was originally developed  by the GNAT team at  New York University. --
  28 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  29 --                                                                          --
  30 ------------------------------------------------------------------------------
  31
  32 with System.Address_Operations; use System.Address_Operations;
  33 with System.Storage_Elements;   use System.Storage_Elements;
  34
  35 with Ada.Unchecked_Conversion;
  36
  37 package body System.Compare_Array_Unsigned_16 is
  38
  39    type Word is mod 2 ** 32;
  40    --  Used to process operands by words
  41
  42    type Half is mod 2 ** 16;
  43    for Half'Size use 16;
  44    --  Used to process operands by half words
  45
  46    type Uhalf is new Half;
  47    for Uhalf'Alignment use 1;
  48    --  Used to process operands when unaligned
  49
  50    type WP is access Word;
  51    type HP is access Half;
  52    type UP is access Uhalf;
  53
  54    function W is new Ada.Unchecked_Conversion (Address, WP);
  55    function H is new Ada.Unchecked_Conversion (Address, HP);
  56    function U is new Ada.Unchecked_Conversion (Address, UP);
  57
  58    -----------------------
  59    -- Compare_Array_U16 --
  60    -----------------------
  61
  62    pragma Annotate (Gnatcheck, Exempt_On, "Improper_Returns",
  63                     "early returns for performance");
  64
  65    function Compare_Array_U16
  66      (Left      : System.Address;
  67       Right     : System.Address;
  68       Left_Len  : Natural;
  69       Right_Len : Natural) return Integer
  70    is
  71       Clen : Natural := Natural'Min (Left_Len, Right_Len);
  72       --  Number of elements left to compare
  73
  74       L : Address := Left;
  75       R : Address := Right;
  76       --  Pointers to next elements to compare
  77
  78    begin
  79       --  Go by words if possible
  80
  81       if ModA (OrA (Left, Right), 4) = 0 then
  82          while Clen > 1
  83            and then W (L).all = W (R).all
  84          loop
  85             Clen := Clen - 2;
  86             L := L + Storage_Offset (4);
  87             R := R + Storage_Offset (4);
  88          end loop;
  89       end if;
  90
  91       --  Case of going by aligned half words
  92
  93       if ModA (OrA (Left, Right), 2) = 0 then
  94          while Clen /= 0 loop
  95             if H (L).all /= H (R).all then
  96                if H (L).all > H (R).all then
  97                   return +1;
  98                else
  99                   return -1;
 100                end if;
 101             end if;
 102
 103             Clen := Clen - 1;
 104             L := L + Storage_Offset (2);
 105             R := R + Storage_Offset (2);
 106          end loop;
 107
 108       --  Case of going by unaligned half words
 109
 110       else
 111          while Clen /= 0 loop
 112             if U (L).all /= U (R).all then
 113                if U (L).all > U (R).all then
 114                   return +1;
 115                else
 116                   return -1;
 117                end if;
 118             end if;
 119
 120             Clen := Clen - 1;
 121             L := L + Storage_Offset (2);
 122             R := R + Storage_Offset (2);
 123          end loop;
 124       end if;
 125
 126       --  Here if common section equal, result decided by lengths
 127
 128       if Left_Len = Right_Len then
 129          return 0;
 130       elsif Left_Len > Right_Len then
 131          return +1;
 132       else
 133          return -1;
 134       end if;
 135    end Compare_Array_U16;
 136
 137    pragma Annotate (Gnatcheck, Exempt_Off, "Improper_Returns");
 138 end System.Compare_Array_Unsigned_16;