| blob | 6e531007cac8e4ec5cd25aad1ebe823552d853cb |
2 dnl
3 dnl GLIBCXX_CONDITIONAL (NAME, SHELL-TEST)
4 dnl
5 dnl Exactly like AM_CONDITIONAL, but delays evaluation of the test until the
6 dnl end of configure. This lets tested variables be reassigned, and the
7 dnl conditional will depend on the final state of the variable. For a simple
8 dnl example of why this is needed, see GLIBCXX_ENABLE_HOSTED.
9 dnl
10 m4_define([_m4_divert(glibcxx_diversion)], 8000)dnl
11 AC_DEFUN([GLIBCXX_CONDITIONAL], [dnl
12 m4_divert_text([glibcxx_diversion],dnl
13 AM_CONDITIONAL([$1],[$2])
14 )dnl
15 ])dnl
16 AC_DEFUN([GLIBCXX_EVALUATE_CONDITIONALS], [m4_undivert([glibcxx_diversion])])dnl
19 dnl
20 dnl Check to see what architecture and operating system we are compiling
21 dnl for. Also, if architecture- or OS-specific flags are required for
22 dnl compilation, pick them up here.
23 dnl
24 AC_DEFUN([GLIBCXX_CHECK_HOST], [
25 . $glibcxx_srcdir/configure.host
26 AC_MSG_NOTICE([CPU config directory is $cpu_include_dir])
27 AC_MSG_NOTICE([OS config directory is $os_include_dir])
28 ])
30 dnl
31 dnl Initialize the rest of the library configury. At this point we have
32 dnl variables like $host.
33 dnl
34 dnl Sets:
35 dnl gcc_version (x.y.z format)
36 dnl SUBDIRS
37 dnl Substs:
38 dnl glibcxx_builddir (absolute path)
39 dnl glibcxx_srcdir (absolute path)
40 dnl toplevel_srcdir (absolute path)
41 dnl with_cross_host
42 dnl with_newlib
43 dnl with_target_subdir
44 dnl plus
45 dnl - the variables in GLIBCXX_CHECK_HOST / configure.host
46 dnl - default settings for all AM_CONFITIONAL test variables
47 dnl - lots of tools, like CC and CXX
48 dnl
49 AC_DEFUN([GLIBCXX_CONFIGURE], [
50 # Keep these sync'd with the list in Makefile.am. The first provides an
51 # expandable list at autoconf time; the second provides an expandable list
52 # (i.e., shell variable) at configure time.
53 m4_define([glibcxx_SUBDIRS],[include libmath libsupc++ src po testsuite])
54 SUBDIRS='glibcxx_SUBDIRS'
56 # These need to be absolute paths, yet at the same time need to
57 # canonicalize only relative paths, because then amd will not unmount
58 # drives. Thus the use of PWDCMD: set it to 'pawd' or 'amq -w' if using amd.
59 glibcxx_builddir=`${PWDCMD-pwd}`
60 case $srcdir in
61 [\\/$]* | ?:[\\/]*) glibcxx_srcdir=${srcdir} ;;
62 *) glibcxx_srcdir=`cd "$srcdir" && ${PWDCMD-pwd} || echo "$srcdir"` ;;
63 esac
64 toplevel_srcdir=${glibcxx_srcdir}/..
65 AC_SUBST(glibcxx_builddir)
66 AC_SUBST(glibcxx_srcdir)
67 AC_SUBST(toplevel_srcdir)
69 # We use these options to decide which functions to include. They are
70 # set from the top level.
71 AC_ARG_WITH([target-subdir],
72 AC_HELP_STRING([--with-target-subdir=SUBDIR],
73 [configuring in a subdirectory]))
75 AC_ARG_WITH([cross-host],
76 AC_HELP_STRING([--with-cross-host=HOST],
77 [configuring with a cross compiler]))
79 AC_ARG_WITH([newlib],
80 AC_HELP_STRING([--with-newlib],
81 [assume newlib as a system C library]))
83 # We're almost certainly being configured before anything else which uses
84 # C++, so all of our AC_PROG_* discoveries will be cached. It's vital that
85 # we not cache the value of CXX that we "discover" here, because it's set
86 # to something unique for us and libjava. Other target libraries need to
87 # find CXX for themselves. We yank the rug out from under the normal AC_*
88 # process by sneakily renaming the cache variable. This also lets us debug
89 # the value of "our" CXX in postmortems.
90 #
91 # We must also force CXX to /not/ be a precious variable, otherwise the
92 # wrong (non-multilib-adjusted) value will be used in multilibs. This
93 # little trick also affects CPPFLAGS, CXXFLAGS, and LDFLAGS. And as a side
94 # effect, CXXFLAGS is no longer automagically subst'd, so we have to do
95 # that ourselves. Un-preciousing AC_PROG_CC also affects CC and CFLAGS.
96 #
97 # -fno-builtin must be present here so that a non-conflicting form of
98 # std::exit can be guessed by AC_PROG_CXX, and used in later tests.
100 m4_define([ac_cv_prog_CXX],[glibcxx_cv_prog_CXX])
101 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
102 m4_define([_AC_ARG_VAR_PRECIOUS],[])
103 save_CXXFLAGS="$CXXFLAGS"
104 CXXFLAGS="$CXXFLAGS -fno-builtin"
105 AC_PROG_CC
106 AC_PROG_CXX
107 CXXFLAGS="$save_CXXFLAGS"
108 m4_rename([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
109 AC_SUBST(CFLAGS)
110 AC_SUBST(CXXFLAGS)
112 # For directory versioning (e.g., headers) and other variables.
113 AC_MSG_CHECKING([for GCC version number])
114 gcc_version=`$CXX -dumpversion`
115 AC_MSG_RESULT($gcc_version)
117 # Will set LN_S to either 'ln -s', 'ln', or 'cp -p' (if linking isn't
118 # available). Uncomment the next line to force a particular method.
119 AC_PROG_LN_S
120 #LN_S='cp -p'
122 AC_CHECK_TOOL(AS, as)
123 AC_CHECK_TOOL(AR, ar)
124 AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
126 AM_MAINTAINER_MODE
128 # Set up safe default values for all subsequent AM_CONDITIONAL tests
129 # which are themselves conditionally expanded.
130 ## (Right now, this only matters for enable_wchar_t, but nothing prevents
131 ## other macros from doing the same. This should be automated.) -pme
132 need_libmath=no
133 enable_wchar_t=no
134 #enable_libstdcxx_debug=no
135 #enable_libstdcxx_pch=no
136 #enable_cheaders=c
137 #c_compatibility=no
138 #enable_abi_check=no
139 #enable_symvers=no
140 #enable_hosted_libstdcxx=yes
142 # Find platform-specific directories containing configuration info.
143 # Also possibly modify flags used elsewhere, as needed by the platform.
144 GLIBCXX_CHECK_HOST
145 ])
148 m4_include([linkage.m4])
149 m4_include([../config/no-executables.m4])
152 dnl
153 dnl Tests for newer compiler features, or features that are present in newer
154 dnl compiler versions but not older compiler versions still in use, should
155 dnl be placed here.
156 dnl
157 dnl Defines:
158 dnl WERROR='-Werror' if requested and possible; g++'s that lack the
159 dnl new inlining code or the new system_header pragma will die on -Werror.
160 dnl Leave it out by default and use maint-mode to use it.
161 dnl SECTION_FLAGS='-ffunction-sections -fdata-sections' if
162 dnl compiler supports it and the user has not requested debug mode.
163 dnl
164 AC_DEFUN([GLIBCXX_CHECK_COMPILER_FEATURES], [
165 # All these tests are for C++; save the language and the compiler flags.
166 # The CXXFLAGS thing is suspicious, but based on similar bits previously
167 # found in GLIBCXX_CONFIGURE.
168 AC_LANG_SAVE
169 AC_LANG_CPLUSPLUS
170 ac_test_CXXFLAGS="${CXXFLAGS+set}"
171 ac_save_CXXFLAGS="$CXXFLAGS"
173 # Check for maintainer-mode bits.
174 if test x"$USE_MAINTAINER_MODE" = xno; then
175 WERROR=''
176 else
177 WERROR='-Werror'
178 fi
180 # Check for -ffunction-sections -fdata-sections
181 AC_MSG_CHECKING([for g++ that supports -ffunction-sections -fdata-sections])
182 CXXFLAGS='-Werror -ffunction-sections -fdata-sections'
183 AC_TRY_COMPILE(, [int foo;], [ac_fdsections=yes], [ac_fdsections=no])
184 if test "$ac_test_CXXFLAGS" = set; then
185 CXXFLAGS="$ac_save_CXXFLAGS"
186 else
187 # this is the suspicious part
188 CXXFLAGS=''
189 fi
190 if test x"$ac_fdsections" = x"yes"; then
191 SECTION_FLAGS='-ffunction-sections -fdata-sections'
192 fi
193 AC_MSG_RESULT($ac_fdsections)
195 AC_LANG_RESTORE
196 AC_SUBST(WERROR)
197 AC_SUBST(SECTION_FLAGS)
198 ])
201 dnl
202 dnl If GNU ld is in use, check to see if tricky linker opts can be used. If
203 dnl the native linker is in use, all variables will be defined to something
204 dnl safe (like an empty string).
205 dnl
206 dnl Defines:
207 dnl SECTION_LDFLAGS='-Wl,--gc-sections' if possible
208 dnl OPT_LDFLAGS='-Wl,-O1' if possible
209 dnl LD (as a side effect of testing)
210 dnl Sets:
211 dnl with_gnu_ld
212 dnl glibcxx_gnu_ld_version (possibly)
213 dnl
214 dnl The last will be a single integer, e.g., version 1.23.45.0.67.89 will
215 dnl set glibcxx_gnu_ld_version to 12345. Zeros cause problems.
216 dnl
217 AC_DEFUN([GLIBCXX_CHECK_LINKER_FEATURES], [
218 # If we're not using GNU ld, then there's no point in even trying these
219 # tests. Check for that first. We should have already tested for gld
220 # by now (in libtool), but require it now just to be safe...
221 test -z "$SECTION_LDFLAGS" && SECTION_LDFLAGS=''
222 test -z "$OPT_LDFLAGS" && OPT_LDFLAGS=''
223 AC_REQUIRE([AC_PROG_LD])
224 AC_REQUIRE([AC_PROG_AWK])
226 # The name set by libtool depends on the version of libtool. Shame on us
227 # for depending on an impl detail, but c'est la vie. Older versions used
228 # ac_cv_prog_gnu_ld, but now it's lt_cv_prog_gnu_ld, and is copied back on
229 # top of with_gnu_ld (which is also set by --with-gnu-ld, so that actually
230 # makes sense). We'll test with_gnu_ld everywhere else, so if that isn't
231 # set (hence we're using an older libtool), then set it.
232 if test x${with_gnu_ld+set} != xset; then
233 if test x${ac_cv_prog_gnu_ld+set} != xset; then
234 # We got through "ac_require(ac_prog_ld)" and still not set? Huh?
235 with_gnu_ld=no
236 else
237 with_gnu_ld=$ac_cv_prog_gnu_ld
238 fi
239 fi
241 # Start by getting the version number. I think the libtool test already
242 # does some of this, but throws away the result.
243 changequote(,)
244 ldver=`$LD --version 2>/dev/null | head -1 | \
245 sed -e 's/GNU ld version \([0-9.][0-9.]*\).*/\1/'`
246 changequote([,])
247 glibcxx_gnu_ld_version=`echo $ldver | \
248 $AWK -F. '{ if (NF<3) [$]3=0; print ([$]1*100+[$]2)*100+[$]3 }'`
250 # Set --gc-sections.
251 if test "$with_gnu_ld" = "notbroken"; then
252 # GNU ld it is! Joy and bunny rabbits!
254 # All these tests are for C++; save the language and the compiler flags.
255 # Need to do this so that g++ won't try to link in libstdc++
256 ac_test_CFLAGS="${CFLAGS+set}"
257 ac_save_CFLAGS="$CFLAGS"
258 CFLAGS='-x c++ -Wl,--gc-sections'
260 # Check for -Wl,--gc-sections
261 # XXX This test is broken at the moment, as symbols required for linking
262 # are now in libsupc++ (not built yet). In addition, this test has
263 # cored on solaris in the past. In addition, --gc-sections doesn't
264 # really work at the moment (keeps on discarding used sections, first
265 # .eh_frame and now some of the glibc sections for iconv).
266 # Bzzzzt. Thanks for playing, maybe next time.
267 AC_MSG_CHECKING([for ld that supports -Wl,--gc-sections])
268 AC_TRY_RUN([
269 int main(void)
270 {
271 try { throw 1; }
272 catch (...) { };
273 return 0;
274 }
275 ], [ac_sectionLDflags=yes],[ac_sectionLDflags=no], [ac_sectionLDflags=yes])
276 if test "$ac_test_CFLAGS" = set; then
277 CFLAGS="$ac_save_CFLAGS"
278 else
279 # this is the suspicious part
280 CFLAGS=''
281 fi
282 if test "$ac_sectionLDflags" = "yes"; then
283 SECTION_LDFLAGS="-Wl,--gc-sections $SECTION_LDFLAGS"
284 fi
285 AC_MSG_RESULT($ac_sectionLDflags)
286 fi
288 # Set linker optimization flags.
289 if test x"$with_gnu_ld" = x"yes"; then
290 OPT_LDFLAGS="-Wl,-O1 $OPT_LDFLAGS"
291 fi
293 AC_SUBST(SECTION_LDFLAGS)
294 AC_SUBST(OPT_LDFLAGS)
295 ])
298 dnl
299 dnl Check to see if this target can enable the wchar_t parts.
300 dnl If --disable-c-mbchar was given, no wchar_t stuff is enabled. (This
301 dnl must have been previously checked.) By default, wide characters are
302 dnl disabled.
303 dnl
304 dnl Defines:
305 dnl HAVE_MBSTATE_T if mbstate_t is not in wchar.h
306 dnl _GLIBCXX_USE_WCHAR_T if all the bits are found.
307 dnl Substs:
308 dnl LIBICONV to a -l string containing the iconv library, if needed.
309 dnl
310 AC_DEFUN([GLIBCXX_CHECK_WCHAR_T_SUPPORT], [
311 # Test wchar.h for mbstate_t, which is needed for char_traits and
312 # others even if wchar_t support is not on.
313 AC_MSG_CHECKING([for mbstate_t])
314 AC_TRY_COMPILE([#include <wchar.h>],
315 [mbstate_t teststate;],
316 have_mbstate_t=yes, have_mbstate_t=no)
317 AC_MSG_RESULT($have_mbstate_t)
318 if test x"$have_mbstate_t" = xyes; then
319 AC_DEFINE(HAVE_MBSTATE_T)
320 fi
322 # Sanity check for existence of ISO C99 headers for extended encoding.
323 AC_CHECK_HEADERS(wchar.h, ac_has_wchar_h=yes, ac_has_wchar_h=no)
324 AC_CHECK_HEADERS(wctype.h, ac_has_wctype_h=yes, ac_has_wctype_h=no)
326 # Only continue checking if the ISO C99 headers exist and support is on.
327 if test x"$ac_has_wchar_h" = xyes &&
328 test x"$ac_has_wctype_h" = xyes &&
329 test x"$enable_c_mbchar" != xno; then
331 # Test wchar.h for WCHAR_MIN, WCHAR_MAX, which is needed before
332 # numeric_limits can instantiate type_traits<wchar_t>
333 AC_MSG_CHECKING([for WCHAR_MIN and WCHAR_MAX])
334 AC_TRY_COMPILE([#include <wchar.h>],
335 [int i = WCHAR_MIN; int j = WCHAR_MAX;],
336 has_wchar_minmax=yes, has_wchar_minmax=no)
337 AC_MSG_RESULT($has_wchar_minmax)
339 # Test wchar.h for WEOF, which is what we use to determine whether
340 # to specialize for char_traits<wchar_t> or not.
341 AC_MSG_CHECKING([for WEOF])
342 AC_TRY_COMPILE([
343 #include <wchar.h>
344 #include <stddef.h>],
345 [wint_t i = WEOF;],
346 has_weof=yes, has_weof=no)
347 AC_MSG_RESULT($has_weof)
349 # Tests for wide character functions used in char_traits<wchar_t>.
350 ac_wfuncs=yes
351 AC_CHECK_FUNCS([wcslen wmemchr wmemcmp wmemcpy wmemmove wmemset],
352 [],[ac_wfuncs=no])
354 # Checks for names injected into std:: by the c_std headers.
355 AC_CHECK_FUNCS([btowc wctob fgetwc fgetws fputwc fputws fwide \
356 fwprintf fwscanf swprintf swscanf vfwprintf vswprintf \
357 vwprintf wprintf wscanf getwc getwchar mbsinit mbrlen mbrtowc \
358 mbsrtowcs wcsrtombs putwc putwchar ungetwc wcrtomb wcstod wcstol \
359 wcstoul wcscpy wcsncpy wcscat wcsncat wcscmp wcscoll wcsncmp wcsxfrm \
360 wcscspn wcsspn wcstok wcsftime wcschr wcspbrk wcsrchr wcsstr],
361 [],[ac_wfuncs=no])
363 # Checks for wide character functions that are not required
364 # for basic wchar_t support. Don't disable support if they are missing.
365 # Injection of these is wrapped with guard macros.
366 AC_CHECK_FUNCS([vfwscanf vswscanf vwscanf wcstof iswblank],[],[])
368 AC_MSG_CHECKING([for ISO C99 wchar_t support])
369 if test x"$has_weof" = xyes &&
370 test x"$has_wchar_minmax" = xyes &&
371 test x"$ac_wfuncs" = xyes;
372 then
373 ac_isoC99_wchar_t=yes
374 else
375 ac_isoC99_wchar_t=no
376 fi
377 AC_MSG_RESULT($ac_isoC99_wchar_t)
379 # Use iconv for wchar_t to char conversions. As such, check for
380 # X/Open Portability Guide, version 2 features (XPG2).
381 AC_CHECK_HEADER(iconv.h, ac_has_iconv_h=yes, ac_has_iconv_h=no)
382 AC_CHECK_HEADER(langinfo.h, ac_has_langinfo_h=yes, ac_has_langinfo_h=no)
384 # Check for existence of libiconv.a providing XPG2 wchar_t support.
385 AC_CHECK_LIB(iconv, iconv, LIBICONV="-liconv")
386 ac_save_LIBS="$LIBS"
387 LIBS="$LIBS $LIBICONV"
388 AC_SUBST(LIBICONV)
390 AC_CHECK_FUNCS([iconv_open iconv_close iconv nl_langinfo],
391 [ac_XPG2funcs=yes], [ac_XPG2funcs=no])
393 LIBS="$ac_save_LIBS"
395 AC_MSG_CHECKING([for XPG2 wchar_t support])
396 if test x"$ac_has_iconv_h" = xyes &&
397 test x"$ac_has_langinfo_h" = xyes &&
398 test x"$ac_XPG2funcs" = xyes;
399 then
400 ac_XPG2_wchar_t=yes
401 else
402 ac_XPG2_wchar_t=no
403 fi
404 AC_MSG_RESULT($ac_XPG2_wchar_t)
406 # At the moment, only enable wchar_t specializations if all the
407 # above support is present.
408 if test x"$ac_isoC99_wchar_t" = xyes &&
409 test x"$ac_XPG2_wchar_t" = xyes;
410 then
411 AC_DEFINE(_GLIBCXX_USE_WCHAR_T)
412 enable_wchar_t=yes
413 fi
414 fi
415 AC_MSG_CHECKING([for enabled wchar_t specializations])
416 AC_MSG_RESULT($enable_wchar_t)
417 ])
420 dnl
421 dnl Check for headers for, and arguments to, the setrlimit() function.
422 dnl Used only in testsuite_hooks.h. Called from GLIBCXX_CONFIGURE_TESTSUITE.
423 dnl
424 dnl Defines:
425 dnl _GLIBCXX_RES_LIMITS if we can set artificial resource limits
426 dnl various HAVE_LIMIT_* for individual limit names
427 dnl
428 AC_DEFUN([GLIBCXX_CHECK_SETRLIMIT_ancilliary], [
429 AC_TRY_COMPILE(
430 [#include <unistd.h>
431 #include <sys/time.h>
432 #include <sys/resource.h>
433 ],
434 [ int f = RLIMIT_$1 ; ],
435 [glibcxx_mresult=1], [glibcxx_mresult=0])
436 AC_DEFINE_UNQUOTED(HAVE_LIMIT_$1, $glibcxx_mresult,
437 [Only used in build directory testsuite_hooks.h.])
438 ])
440 AC_DEFUN([GLIBCXX_CHECK_SETRLIMIT], [
441 setrlimit_have_headers=yes
442 AC_CHECK_HEADERS(unistd.h sys/time.h sys/resource.h,
443 [],
444 [setrlimit_have_headers=no])
445 # If don't have the headers, then we can't run the tests now, and we
446 # won't be seeing any of these during testsuite compilation.
447 if test $setrlimit_have_headers = yes; then
448 # Can't do these in a loop, else the resulting syntax is wrong.
449 GLIBCXX_CHECK_SETRLIMIT_ancilliary(DATA)
450 GLIBCXX_CHECK_SETRLIMIT_ancilliary(RSS)
451 GLIBCXX_CHECK_SETRLIMIT_ancilliary(VMEM)
452 GLIBCXX_CHECK_SETRLIMIT_ancilliary(AS)
453 GLIBCXX_CHECK_SETRLIMIT_ancilliary(FSIZE)
455 # Check for rlimit, setrlimit.
456 AC_CACHE_VAL(ac_setrlimit, [
457 AC_TRY_COMPILE(
458 [#include <unistd.h>
459 #include <sys/time.h>
460 #include <sys/resource.h>
461 ],
462 [struct rlimit r;
463 setrlimit(0, &r);],
464 [ac_setrlimit=yes], [ac_setrlimit=no])
465 ])
466 fi
468 AC_MSG_CHECKING([for testsuite resource limits support])
469 if test $setrlimit_have_headers = yes && test $ac_setrlimit = yes; then
470 ac_res_limits=yes
471 AC_DEFINE(_GLIBCXX_RES_LIMITS)
472 else
473 ac_res_limits=no
474 fi
475 AC_MSG_RESULT($ac_res_limits)
476 ])
479 dnl
480 dnl Check whether S_ISREG (Posix) or S_IFREG is available in <sys/stat.h>.
481 dnl Define HAVE_S_ISREG / HAVE_S_IFREG appropriately.
482 dnl
483 AC_DEFUN([GLIBCXX_CHECK_S_ISREG_OR_S_IFREG], [
484 AC_CACHE_VAL(glibcxx_cv_S_ISREG, [
485 AC_TRY_LINK(
486 [#include <sys/stat.h>],
487 [struct stat buffer;
488 fstat(0, &buffer);
489 S_ISREG(buffer.st_mode);],
490 [glibcxx_cv_S_ISREG=yes],
491 [glibcxx_cv_S_ISREG=no])
492 ])
493 AC_CACHE_VAL(glibcxx_cv_S_IFREG, [
494 AC_TRY_LINK(
495 [#include <sys/stat.h>],
496 [struct stat buffer;
497 fstat(0, &buffer);
498 S_IFREG & buffer.st_mode;],
499 [glibcxx_cv_S_IFREG=yes],
500 [glibcxx_cv_S_IFREG=no])
501 ])
502 if test $glibcxx_cv_S_ISREG = yes; then
503 AC_DEFINE(HAVE_S_ISREG)
504 elif test $glibcxx_cv_S_IFREG = yes; then
505 AC_DEFINE(HAVE_S_IFREG)
506 fi
507 ])
510 dnl
511 dnl Check whether poll is available in <poll.h>, and define HAVE_POLL.
512 dnl
513 AC_DEFUN([GLIBCXX_CHECK_POLL], [
514 AC_CACHE_VAL(glibcxx_cv_POLL, [
515 AC_TRY_LINK(
516 [#include <poll.h>],
517 [struct pollfd pfd[1];
518 pfd[0].events = POLLIN;
519 poll(pfd, 1, 0);],
520 [glibcxx_cv_POLL=yes],
521 [glibcxx_cv_POLL=no])
522 ])
523 if test $glibcxx_cv_POLL = yes; then
524 AC_DEFINE(HAVE_POLL)
525 fi
526 ])
529 dnl
530 dnl Check whether writev is available in <sys/uio.h>, and define HAVE_WRITEV.
531 dnl
532 AC_DEFUN([GLIBCXX_CHECK_WRITEV], [
533 AC_CACHE_VAL(glibcxx_cv_WRITEV, [
534 AC_TRY_LINK(
535 [#include <sys/uio.h>],
536 [struct iovec iov[2];
537 writev(0, iov, 0);],
538 [glibcxx_cv_WRITEV=yes],
539 [glibcxx_cv_WRITEV=no])
540 ])
541 if test $glibcxx_cv_WRITEV = yes; then
542 AC_DEFINE(HAVE_WRITEV)
543 fi
544 ])
547 dnl
548 dnl Check whether int64_t is available in <stdint.h>, and define HAVE_INT64_T.
549 dnl
550 AC_DEFUN([GLIBCXX_CHECK_INT64_T], [
551 AC_CACHE_VAL(glibcxx_cv_INT64_T, [
552 AC_TRY_COMPILE(
553 [#include <stdint.h>],
554 [int64_t var;],
555 [glibcxx_cv_INT64_T=yes],
556 [glibcxx_cv_INT64_T=no])
557 ])
558 if test $glibcxx_cv_INT64_T = yes; then
559 AC_DEFINE(HAVE_INT64_T)
560 fi
561 ])
564 dnl
565 dnl Check whether LFS support is available.
566 dnl
567 AC_DEFUN([GLIBCXX_CHECK_LFS], [
568 AC_LANG_SAVE
569 AC_LANG_CPLUSPLUS
570 ac_save_CXXFLAGS="$CXXFLAGS"
571 CXXFLAGS="$CXXFLAGS -fno-exceptions"
572 AC_CACHE_VAL(glibcxx_cv_LFS, [
573 AC_TRY_LINK(
574 [#include <unistd.h>
575 #include <stdio.h>
576 #include <sys/stat.h>
577 ],
578 [FILE* fp;
579 fopen64("t", "w");
580 fseeko64(fp, 0, SEEK_CUR);
581 ftello64(fp);
582 lseek64(1, 0, SEEK_CUR);
583 struct stat64 buf;
584 fstat64(1, &buf);],
585 [glibcxx_cv_LFS=yes],
586 [glibcxx_cv_LFS=no])
587 ])
588 if test $glibcxx_cv_LFS = yes; then
589 AC_DEFINE(_GLIBCXX_USE_LFS)
590 fi
591 CXXFLAGS="$ac_save_CXXFLAGS"
592 AC_LANG_RESTORE
593 ])
596 dnl
597 dnl Does any necessary configuration of the testsuite directory. Generates
598 dnl the testsuite_hooks.h header.
599 dnl
600 dnl GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE must be done before this.
601 dnl
602 dnl Sets:
603 dnl enable_abi_check / GLIBCXX_TEST_ABI
604 dnl Substs:
605 dnl baseline_dir
606 dnl
607 AC_DEFUN([GLIBCXX_CONFIGURE_TESTSUITE], [
608 if $GLIBCXX_IS_NATIVE && test $is_hosted = yes; then
609 # Do checks for resource limit functions.
610 GLIBCXX_CHECK_SETRLIMIT
612 # Look for setenv, so that extended locale tests can be performed.
613 GLIBCXX_CHECK_STDLIB_DECL_AND_LINKAGE_3(setenv)
615 if test $enable_symvers = no; then
616 enable_abi_check=no
617 else
618 case "$host" in
619 *-*-cygwin*)
620 enable_abi_check=no ;;
621 *)
622 enable_abi_check=yes ;;
623 esac
624 fi
625 else
626 # Only build this as native, since automake does not understand
627 # CXX_FOR_BUILD.
628 enable_abi_check=no
629 fi
631 # Export file names for ABI checking.
632 baseline_dir="$glibcxx_srcdir/config/abi/${abi_baseline_pair}\$(MULTISUBDIR)"
633 AC_SUBST(baseline_dir)
635 GLIBCXX_CONDITIONAL(GLIBCXX_TEST_WCHAR_T, test $enable_wchar_t = yes)
636 GLIBCXX_CONDITIONAL(GLIBCXX_TEST_ABI, test $enable_abi_check = yes)
637 ])
640 dnl
641 dnl Set up *_INCLUDES variables for all sundry Makefile.am's.
642 dnl
643 dnl Substs:
644 dnl GLIBCXX_INCLUDES
645 dnl TOPLEVEL_INCLUDES
646 dnl
647 AC_DEFUN([GLIBCXX_EXPORT_INCLUDES], [
648 # Used for every C++ compile we perform.
649 GLIBCXX_INCLUDES="\
650 -I$glibcxx_builddir/include/$host_alias \
651 -I$glibcxx_builddir/include \
652 -I$glibcxx_srcdir/libsupc++"
654 # For Canadian crosses, pick this up too.
655 if test $CANADIAN = yes; then
656 GLIBCXX_INCLUDES="$GLIBCXX_INCLUDES -I\${includedir}"
657 fi
659 # Stuff in the actual top level. Currently only used by libsupc++ to
660 # get unwind* headers from the gcc dir.
661 #TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/gcc -I$(toplevel_srcdir)/include'
662 TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/gcc'
664 # Now, export this to all the little Makefiles....
665 AC_SUBST(GLIBCXX_INCLUDES)
666 AC_SUBST(TOPLEVEL_INCLUDES)
667 ])
670 dnl
671 dnl Set up *_FLAGS and *FLAGS variables for all sundry Makefile.am's.
672 dnl (SECTION_FLAGS is done under CHECK_COMPILER_FEATURES.)
673 dnl
674 dnl Substs:
675 dnl OPTIMIZE_CXXFLAGS
676 dnl WARN_FLAGS
677 dnl
678 AC_DEFUN([GLIBCXX_EXPORT_FLAGS], [
679 # Optimization flags that are probably a good idea for thrill-seekers. Just
680 # uncomment the lines below and make, everything else is ready to go...
681 # OPTIMIZE_CXXFLAGS = -O3 -fstrict-aliasing -fvtable-gc
682 OPTIMIZE_CXXFLAGS=
683 AC_SUBST(OPTIMIZE_CXXFLAGS)
685 WARN_FLAGS='-Wall -Wextra -Wwrite-strings -Wcast-qual'
686 AC_SUBST(WARN_FLAGS)
687 ])
690 dnl
691 dnl All installation directory information is determined here.
692 dnl
693 dnl Substs:
694 dnl gxx_install_dir
695 dnl glibcxx_prefixdir
696 dnl glibcxx_toolexecdir
697 dnl glibcxx_toolexeclibdir
698 dnl
699 dnl Assumes cross_compiling bits already done, and with_cross_host in
700 dnl particular.
701 dnl
702 AC_DEFUN([GLIBCXX_EXPORT_INSTALL_INFO], [
703 glibcxx_toolexecdir=no
704 glibcxx_toolexeclibdir=no
705 glibcxx_prefixdir=$prefix
707 AC_MSG_CHECKING([for gxx-include-dir])
708 AC_ARG_WITH([gxx-include-dir],
709 AC_HELP_STRING([--with-gxx-include-dir=DIR],
710 [installation directory for include files]),
711 [case "$withval" in
712 yes) AC_MSG_ERROR([Missing directory for --with-gxx-include-dir]) ;;
713 no) gxx_include_dir=no ;;
714 *) gxx_include_dir=$withval ;;
715 esac],
716 [gxx_include_dir=no])
717 AC_MSG_RESULT($gxx_include_dir)
719 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
720 AC_ARG_ENABLE([version-specific-runtime-libs],
721 AC_HELP_STRING([--enable-version-specific-runtime-libs],
722 [Specify that runtime libraries should be installed in a compiler-specific directory]),
723 [case "$enableval" in
724 yes) version_specific_libs=yes ;;
725 no) version_specific_libs=no ;;
726 *) AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
727 esac],
728 [version_specific_libs=no])
729 AC_MSG_RESULT($version_specific_libs)
731 # Default case for install directory for include files.
732 if test $version_specific_libs = no && test $gxx_include_dir = no; then
733 gxx_include_dir='${prefix}'/include/c++/${gcc_version}
734 fi
736 # Version-specific runtime libs processing.
737 if test $version_specific_libs = yes; then
738 # Need the gcc compiler version to know where to install libraries
739 # and header files if --enable-version-specific-runtime-libs option
740 # is selected. FIXME: these variables are misnamed, there are
741 # no executables installed in _toolexecdir or _toolexeclibdir.
742 if test x"$gxx_include_dir" = x"no"; then
743 gxx_include_dir='${libdir}/gcc/${host_alias}/'$gcc_version/include/c++
744 fi
745 glibcxx_toolexecdir='${libdir}/gcc/${host_alias}'
746 glibcxx_toolexeclibdir='${toolexecdir}/'$gcc_version'$(MULTISUBDIR)'
747 fi
749 # Calculate glibcxx_toolexecdir, glibcxx_toolexeclibdir
750 # Install a library built with a cross compiler in tooldir, not libdir.
751 if test x"$glibcxx_toolexecdir" = x"no"; then
752 if test -n "$with_cross_host" &&
753 test x"$with_cross_host" != x"no"; then
754 glibcxx_toolexecdir='${exec_prefix}/${host_alias}'
755 glibcxx_toolexeclibdir='${toolexecdir}/lib'
756 else
757 glibcxx_toolexecdir='${libdir}/gcc/${host_alias}'
758 glibcxx_toolexeclibdir='${libdir}'
759 fi
760 multi_os_directory=`$CXX -print-multi-os-directory`
761 case $multi_os_directory in
762 .) ;; # Avoid trailing /.
763 *) glibcxx_toolexeclibdir=$glibcxx_toolexeclibdir/$multi_os_directory ;;
764 esac
765 fi
767 AC_MSG_CHECKING([for install location])
768 AC_MSG_RESULT($gxx_include_dir)
770 AC_SUBST(glibcxx_prefixdir)
771 AC_SUBST(gxx_include_dir)
772 AC_SUBST(glibcxx_toolexecdir)
773 AC_SUBST(glibcxx_toolexeclibdir)
774 ])
777 dnl
778 dnl GLIBCXX_ENABLE
779 dnl (FEATURE, DEFAULT, HELP-ARG, HELP-STRING)
780 dnl (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, permit a|b|c)
781 dnl (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, SHELL-CODE-HANDLER)
782 dnl
783 dnl See docs/html/17_intro/configury.html#enable for documentation.
784 dnl
785 m4_define([GLIBCXX_ENABLE],[dnl
786 m4_define([_g_switch],[--enable-$1])dnl
787 m4_define([_g_help],[AC_HELP_STRING(_g_switch$3,[$4 @<:@default=$2@:>@])])dnl
788 AC_ARG_ENABLE($1,_g_help,
789 m4_bmatch([$5],
790 [^permit ],
791 [[
792 case "$enableval" in
793 m4_bpatsubst([$5],[permit ])) ;;
794 *) AC_MSG_ERROR(Unknown argument to enable/disable $1) ;;
795 dnl Idea for future: generate a URL pointing to
796 dnl "onlinedocs/configopts.html#whatever"
797 esac
798 ]],
799 [^$],
800 [[
801 case "$enableval" in
802 yes|no) ;;
803 *) AC_MSG_ERROR(Argument to enable/disable $1 must be yes or no) ;;
804 esac
805 ]],
806 [[$5]]),
807 [enable_]m4_bpatsubst([$1],-,_)[=][$2])
808 m4_undefine([_g_switch])dnl
809 m4_undefine([_g_help])dnl
810 ])
813 dnl
814 dnl Check for ISO/IEC 9899:1999 "C99" support.
815 dnl
816 dnl --enable-c99 defines _GLIBCXX_USE_C99
817 dnl --disable-c99 leaves _GLIBCXX_USE_C99 undefined
818 dnl + Usage: GLIBCXX_ENABLE_C99[(DEFAULT)]
819 dnl Where DEFAULT is either `yes' or `no'.
820 dnl + If 'C99' stuff is not available, ignores DEFAULT and sets `no'.
821 dnl
822 AC_DEFUN([GLIBCXX_ENABLE_C99], [
823 GLIBCXX_ENABLE(c99,$1,,[turns on ISO/IEC 9899:1999 support])
825 AC_LANG_SAVE
826 AC_LANG_CPLUSPLUS
828 # Check for the existence of <math.h> functions used if C99 is enabled.
829 ac_c99_math=yes;
830 AC_MSG_CHECKING([for ISO C99 support in <math.h>])
831 AC_TRY_COMPILE([#include <math.h>],[fpclassify(0.0);],, [ac_c99_math=no])
832 AC_TRY_COMPILE([#include <math.h>],[isfinite(0.0);],, [ac_c99_math=no])
833 AC_TRY_COMPILE([#include <math.h>],[isinf(0.0);],, [ac_c99_math=no])
834 AC_TRY_COMPILE([#include <math.h>],[isnan(0.0);],, [ac_c99_math=no])
835 AC_TRY_COMPILE([#include <math.h>],[isnormal(0.0);],, [ac_c99_math=no])
836 AC_TRY_COMPILE([#include <math.h>],[signbit(0.0);],, [ac_c99_math=no])
837 AC_TRY_COMPILE([#include <math.h>],[isgreater(0.0,0.0);],, [ac_c99_math=no])
838 AC_TRY_COMPILE([#include <math.h>],
839 [isgreaterequal(0.0,0.0);],, [ac_c99_math=no])
840 AC_TRY_COMPILE([#include <math.h>],[isless(0.0,0.0);],, [ac_c99_math=no])
841 AC_TRY_COMPILE([#include <math.h>],[islessequal(0.0,0.0);],,[ac_c99_math=no])
842 AC_TRY_COMPILE([#include <math.h>],
843 [islessgreater(0.0,0.0);],, [ac_c99_math=no])
844 AC_TRY_COMPILE([#include <math.h>],
845 [isunordered(0.0,0.0);],, [ac_c99_math=no])
846 AC_MSG_RESULT($ac_c99_math)
848 if test x"$ac_c99_math" = x"yes"; then
849 AC_DEFINE(_GLIBCXX_USE_C99_MATH)
850 fi
852 # Check for the existence in <stdio.h> of vscanf, et. al.
853 ac_c99_stdio=yes;
854 AC_MSG_CHECKING([for ISO C99 support in <stdio.h>])
855 AC_TRY_COMPILE([#include <stdio.h>],
856 [snprintf("12", 0, "%i");],, [ac_c99_stdio=no])
857 AC_TRY_COMPILE([#include <stdio.h>
858 #include <stdarg.h>
859 void foo(char* fmt, ...)
860 {va_list args; va_start(args, fmt);
861 vfscanf(stderr, "%i", args);}],
862 [],, [ac_c99_stdio=no])
863 AC_TRY_COMPILE([#include <stdio.h>
864 #include <stdarg.h>
865 void foo(char* fmt, ...)
866 {va_list args; va_start(args, fmt);
867 vscanf("%i", args);}],
868 [],, [ac_c99_stdio=no])
869 AC_TRY_COMPILE([#include <stdio.h>
870 #include <stdarg.h>
871 void foo(char* fmt, ...)
872 {va_list args; va_start(args, fmt);
873 vsnprintf(fmt, 0, "%i", args);}],
874 [],, [ac_c99_stdio=no])
875 AC_TRY_COMPILE([#include <stdio.h>
876 #include <stdarg.h>
877 void foo(char* fmt, ...)
878 {va_list args; va_start(args, fmt);
879 vsscanf(fmt, "%i", args);}],
880 [],, [ac_c99_stdio=no])
881 AC_MSG_RESULT($ac_c99_stdio)
883 # Check for the existence in <stdlib.h> of lldiv_t, et. al.
884 ac_c99_stdlib=yes;
885 AC_MSG_CHECKING([for lldiv_t declaration])
886 AC_CACHE_VAL(ac_c99_lldiv_t, [
887 AC_TRY_COMPILE([#include <stdlib.h>],
888 [ lldiv_t mydivt;],
889 [ac_c99_lldiv_t=yes], [ac_c99_lldiv_t=no])
890 ])
891 AC_MSG_RESULT($ac_c99_lldiv_t)
893 AC_MSG_CHECKING([for ISO C99 support in <stdlib.h>])
894 AC_TRY_COMPILE([#include <stdlib.h>],
895 [char* tmp; strtof("gnu", &tmp);],, [ac_c99_stdlib=no])
896 AC_TRY_COMPILE([#include <stdlib.h>],
897 [char* tmp; strtold("gnu", &tmp);],, [ac_c99_stdlib=no])
898 AC_TRY_COMPILE([#include <stdlib.h>], [llabs(10);],, [ac_c99_stdlib=no])
899 AC_TRY_COMPILE([#include <stdlib.h>], [lldiv(10,1);],, [ac_c99_stdlib=no])
900 AC_TRY_COMPILE([#include <stdlib.h>], [atoll("10");],, [ac_c99_stdlib=no])
901 AC_TRY_COMPILE([#include <stdlib.h>], [_Exit(0);],, [ac_c99_stdlib=no])
902 if test x"$ac_c99_lldiv_t" = x"no"; then
903 ac_c99_stdlib=no;
904 fi;
905 AC_MSG_RESULT($ac_c99_stdlib)
907 # Check for the existence of <wchar.h> functions used if C99 is enabled.
908 # XXX the wchar.h checks should be rolled into the general C99 bits.
909 ac_c99_wchar=yes;
910 AC_MSG_CHECKING([for additional ISO C99 support in <wchar.h>])
911 AC_TRY_COMPILE([#include <wchar.h>],
912 [wcstold(L"10.0", NULL);],, [ac_c99_wchar=no])
913 AC_TRY_COMPILE([#include <wchar.h>],
914 [wcstoll(L"10", NULL, 10);],, [ac_c99_wchar=no])
915 AC_TRY_COMPILE([#include <wchar.h>],
916 [wcstoull(L"10", NULL, 10);],, [ac_c99_wchar=no])
917 AC_MSG_RESULT($ac_c99_wchar)
919 AC_MSG_CHECKING([for enabled ISO C99 support])
920 if test x"$ac_c99_math" = x"no" ||
921 test x"$ac_c99_stdio" = x"no" ||
922 test x"$ac_c99_stdlib" = x"no" ||
923 test x"$ac_c99_wchar" = x"no"; then
924 enable_c99=no;
925 fi;
926 AC_MSG_RESULT($enable_c99)
928 if test x"$ac_99_math" = x"yes"; then
929 AC_DEFINE(_GLIBCXX_USE_C99_MATH)
930 fi
932 # Option parsed, now set things appropriately
933 if test x"$enable_c99" = x"yes"; then
934 AC_DEFINE(_GLIBCXX_USE_C99)
935 fi
937 AC_LANG_RESTORE
938 ])
941 dnl
942 dnl Check for what type of C headers to use.
943 dnl
944 dnl --enable-cheaders= [does stuff].
945 dnl --disable-cheaders [does not do anything, really].
946 dnl + Usage: GLIBCXX_ENABLE_CHEADERS[(DEFAULT)]
947 dnl Where DEFAULT is either `c' or `c_std'.
948 dnl
949 AC_DEFUN([GLIBCXX_ENABLE_CHEADERS], [
950 GLIBCXX_ENABLE(cheaders,$1,[=KIND],
951 [construct "C" headers for g++], [permit c|c_std])
952 AC_MSG_NOTICE("C" header strategy set to $enable_cheaders)
954 C_INCLUDE_DIR='${glibcxx_srcdir}/include/'$enable_cheaders
956 AC_SUBST(C_INCLUDE_DIR)
957 GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C, test $enable_cheaders = c)
958 GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C_STD, test $enable_cheaders = c_std)
959 GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_COMPATIBILITY, test $c_compatibility = yes)
960 ])
963 dnl
964 dnl Check for which locale library to use. The choice is mapped to
965 dnl a subdirectory of config/locale.
966 dnl
967 dnl Default is generic.
968 dnl
969 AC_DEFUN([GLIBCXX_ENABLE_CLOCALE], [
970 AC_MSG_CHECKING([for C locale to use])
971 GLIBCXX_ENABLE(clocale,auto,[@<:@=MODEL@:>@],
972 [use MODEL for target locale package],
973 [permit generic|gnu|ieee_1003.1-2001|yes|no|auto])
975 # If they didn't use this option switch, or if they specified --enable
976 # with no specific model, we'll have to look for one. If they
977 # specified --disable (???), do likewise.
978 if test $enable_clocale = no || test $enable_clocale = yes; then
979 enable_clocale=auto
980 fi
982 # Either a known package, or "auto"
983 enable_clocale_flag=$enable_clocale
985 # Probe for locale support if no specific model is specified.
986 # Default to "generic".
987 if test $enable_clocale_flag = auto; then
988 case ${target_os} in
989 linux* | gnu* | kfreebsd*-gnu | knetbsd*-gnu)
990 AC_EGREP_CPP([_GLIBCXX_ok], [
991 #include <features.h>
992 #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 2)
993 _GLIBCXX_ok
994 #endif
995 ], enable_clocale_flag=gnu, enable_clocale_flag=generic)
997 # Test for bugs early in glibc-2.2.x series
998 if test $enable_clocale_flag = gnu; then
999 AC_TRY_RUN([
1000 #define _GNU_SOURCE 1
1001 #include <locale.h>
1002 #include <string.h>
1003 #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ > 2)
1004 extern __typeof(newlocale) __newlocale;
1005 extern __typeof(duplocale) __duplocale;
1006 extern __typeof(strcoll_l) __strcoll_l;
1007 #endif
1008 int main()
1009 {
1010 const char __one[] = "Äuglein Augmen";
1011 const char __two[] = "Äuglein";
1012 int i;
1013 int j;
1014 __locale_t loc;
1015 __locale_t loc_dup;
1016 loc = __newlocale(1 << LC_ALL, "de_DE", 0);
1017 loc_dup = __duplocale(loc);
1018 i = __strcoll_l(__one, __two, loc);
1019 j = __strcoll_l(__one, __two, loc_dup);
1020 return 0;
1021 }
1022 ],
1023 [enable_clocale_flag=gnu],[enable_clocale_flag=generic],
1024 [enable_clocale_flag=generic])
1025 fi
1027 # ... at some point put __strxfrm_l tests in as well.
1028 ;;
1029 *)
1030 enable_clocale_flag=generic
1031 ;;
1032 esac
1033 fi
1035 # Deal with gettext issues. Default to not using it (=no) until we detect
1036 # support for it later. Let the user turn it off via --e/d, but let that
1037 # default to on for easier handling.
1038 USE_NLS=no
1039 AC_ARG_ENABLE(nls,
1040 AC_HELP_STRING([--enable-nls],[use Native Language Support (default)]),
1041 [],
1042 [enable_nls=yes])
1044 # Set configure bits for specified locale package
1045 case ${enable_clocale_flag} in
1046 generic)
1047 AC_MSG_RESULT(generic)
1049 CLOCALE_H=config/locale/generic/c_locale.h
1050 CLOCALE_CC=config/locale/generic/c_locale.cc
1051 CCODECVT_H=config/locale/generic/codecvt_specializations.h
1052 CCODECVT_CC=config/locale/generic/codecvt_members.cc
1053 CCOLLATE_CC=config/locale/generic/collate_members.cc
1054 CCTYPE_CC=config/locale/generic/ctype_members.cc
1055 CMESSAGES_H=config/locale/generic/messages_members.h
1056 CMESSAGES_CC=config/locale/generic/messages_members.cc
1057 CMONEY_CC=config/locale/generic/monetary_members.cc
1058 CNUMERIC_CC=config/locale/generic/numeric_members.cc
1059 CTIME_H=config/locale/generic/time_members.h
1060 CTIME_CC=config/locale/generic/time_members.cc
1061 CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1062 ;;
1063 gnu)
1064 AC_MSG_RESULT(gnu)
1066 # Declare intention to use gettext, and add support for specific
1067 # languages.
1068 # For some reason, ALL_LINGUAS has to be before AM-GNU-GETTEXT
1069 ALL_LINGUAS="de fr"
1071 # Don't call AM-GNU-GETTEXT here. Instead, assume glibc.
1072 AC_CHECK_PROG(check_msgfmt, msgfmt, yes, no)
1073 if test x"$check_msgfmt" = x"yes" && test x"$enable_nls" = x"yes"; then
1074 USE_NLS=yes
1075 fi
1076 # Export the build objects.
1077 for ling in $ALL_LINGUAS; do \
1078 glibcxx_MOFILES="$glibcxx_MOFILES $ling.mo"; \
1079 glibcxx_POFILES="$glibcxx_POFILES $ling.po"; \
1080 done
1081 AC_SUBST(glibcxx_MOFILES)
1082 AC_SUBST(glibcxx_POFILES)
1084 CLOCALE_H=config/locale/gnu/c_locale.h
1085 CLOCALE_CC=config/locale/gnu/c_locale.cc
1086 CCODECVT_H=config/locale/ieee_1003.1-2001/codecvt_specializations.h
1087 CCODECVT_CC=config/locale/gnu/codecvt_members.cc
1088 CCOLLATE_CC=config/locale/gnu/collate_members.cc
1089 CCTYPE_CC=config/locale/gnu/ctype_members.cc
1090 CMESSAGES_H=config/locale/gnu/messages_members.h
1091 CMESSAGES_CC=config/locale/gnu/messages_members.cc
1092 CMONEY_CC=config/locale/gnu/monetary_members.cc
1093 CNUMERIC_CC=config/locale/gnu/numeric_members.cc
1094 CTIME_H=config/locale/gnu/time_members.h
1095 CTIME_CC=config/locale/gnu/time_members.cc
1096 CLOCALE_INTERNAL_H=config/locale/gnu/c++locale_internal.h
1097 ;;
1098 ieee_1003.1-2001)
1099 AC_MSG_RESULT(IEEE 1003.1)
1101 CLOCALE_H=config/locale/ieee_1003.1-2001/c_locale.h
1102 CLOCALE_CC=config/locale/ieee_1003.1-2001/c_locale.cc
1103 CCODECVT_H=config/locale/ieee_1003.1-2001/codecvt_specializations.h
1104 CCODECVT_CC=config/locale/generic/codecvt_members.cc
1105 CCOLLATE_CC=config/locale/generic/collate_members.cc
1106 CCTYPE_CC=config/locale/generic/ctype_members.cc
1107 CMESSAGES_H=config/locale/ieee_1003.1-2001/messages_members.h
1108 CMESSAGES_CC=config/locale/ieee_1003.1-2001/messages_members.cc
1109 CMONEY_CC=config/locale/generic/monetary_members.cc
1110 CNUMERIC_CC=config/locale/generic/numeric_members.cc
1111 CTIME_H=config/locale/generic/time_members.h
1112 CTIME_CC=config/locale/generic/time_members.cc
1113 CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1114 ;;
1115 esac
1117 # This is where the testsuite looks for locale catalogs, using the
1118 # -DLOCALEDIR define during testsuite compilation.
1119 glibcxx_localedir=${glibcxx_builddir}/po/share/locale
1120 AC_SUBST(glibcxx_localedir)
1122 # A standalone libintl (e.g., GNU libintl) may be in use.
1123 if test $USE_NLS = yes; then
1124 AC_CHECK_HEADERS([libintl.h], [], USE_NLS=no)
1125 AC_SEARCH_LIBS(gettext, intl, [], USE_NLS=no)
1126 fi
1127 if test $USE_NLS = yes; then
1128 AC_DEFINE(_GLIBCXX_USE_NLS)
1129 fi
1131 AC_SUBST(USE_NLS)
1132 AC_SUBST(CLOCALE_H)
1133 AC_SUBST(CCODECVT_H)
1134 AC_SUBST(CMESSAGES_H)
1135 AC_SUBST(CCODECVT_CC)
1136 AC_SUBST(CCOLLATE_CC)
1137 AC_SUBST(CCTYPE_CC)
1138 AC_SUBST(CMESSAGES_CC)
1139 AC_SUBST(CMONEY_CC)
1140 AC_SUBST(CNUMERIC_CC)
1141 AC_SUBST(CTIME_H)
1142 AC_SUBST(CTIME_CC)
1143 AC_SUBST(CLOCALE_CC)
1144 AC_SUBST(CLOCALE_INTERNAL_H)
1145 ])
1148 dnl
1149 dnl Check for which std::allocator base class to use. The choice is
1150 dnl mapped from a subdirectory of include/ext.
1151 dnl
1152 dnl Default is new.
1153 dnl
1154 AC_DEFUN([GLIBCXX_ENABLE_ALLOCATOR], [
1155 AC_MSG_CHECKING([for std::allocator base class to use])
1156 GLIBCXX_ENABLE(libstdcxx-allocator,auto,[=KIND],
1157 [use KIND for target std::allocator base],
1158 [permit new|malloc|mt|bitmap|pool|yes|no|auto])
1160 # If they didn't use this option switch, or if they specified --enable
1161 # with no specific model, we'll have to look for one. If they
1162 # specified --disable (???), do likewise.
1163 if test $enable_libstdcxx_allocator = no ||
1164 test $enable_libstdcxx_allocator = yes;
1165 then
1166 enable_libstdcxx_allocator=auto
1167 fi
1169 # Either a known package, or "auto". Auto implies the default choice
1170 # for a particular platform.
1171 enable_libstdcxx_allocator_flag=$enable_libstdcxx_allocator
1173 # Probe for host-specific support if no specific model is specified.
1174 # Default to "new".
1175 if test $enable_libstdcxx_allocator_flag = auto; then
1176 case ${target_os} in
1177 linux* | gnu* | kfreebsd*-gnu | knetbsd*-gnu)
1178 enable_libstdcxx_allocator_flag=mt
1179 ;;
1180 *)
1181 enable_libstdcxx_allocator_flag=new
1182 ;;
1183 esac
1184 fi
1185 AC_MSG_RESULT($enable_libstdcxx_allocator_flag)
1188 # Set configure bits for specified locale package
1189 case ${enable_libstdcxx_allocator_flag} in
1190 bitmap)
1191 ALLOCATOR_H=config/allocator/bitmap_allocator_base.h
1192 ALLOCATOR_NAME=__gnu_cxx::bitmap_allocator
1193 ;;
1194 malloc)
1195 ALLOCATOR_H=config/allocator/malloc_allocator_base.h
1196 ALLOCATOR_NAME=__gnu_cxx::malloc_allocator
1197 ;;
1198 mt)
1199 ALLOCATOR_H=config/allocator/mt_allocator_base.h
1200 ALLOCATOR_NAME=__gnu_cxx::__mt_alloc
1201 ;;
1202 new)
1203 ALLOCATOR_H=config/allocator/new_allocator_base.h
1204 ALLOCATOR_NAME=__gnu_cxx::new_allocator
1205 ;;
1206 pool)
1207 ALLOCATOR_H=config/allocator/pool_allocator_base.h
1208 ALLOCATOR_NAME=__gnu_cxx::__pool_alloc
1209 ;;
1210 esac
1212 AC_SUBST(ALLOCATOR_H)
1213 AC_SUBST(ALLOCATOR_NAME)
1214 ])
1217 dnl
1218 dnl Check for whether the Boost-derived checks should be turned on.
1219 dnl
1220 dnl --enable-concept-checks turns them on.
1221 dnl --disable-concept-checks leaves them off.
1222 dnl + Usage: GLIBCXX_ENABLE_CONCEPT_CHECKS[(DEFAULT)]
1223 dnl Where DEFAULT is either `yes' or `no'.
1224 dnl
1225 AC_DEFUN([GLIBCXX_ENABLE_CONCEPT_CHECKS], [
1226 GLIBCXX_ENABLE(concept-checks,$1,,[use Boost-derived template checks])
1227 if test $enable_concept_checks = yes; then
1228 AC_DEFINE(_GLIBCXX_CONCEPT_CHECKS)
1229 fi
1230 ])
1233 dnl
1234 dnl Check for which I/O library to use: stdio, or something specific.
1235 dnl
1236 dnl Default is stdio.
1237 dnl
1238 AC_DEFUN([GLIBCXX_ENABLE_CSTDIO], [
1239 AC_MSG_CHECKING([for underlying I/O to use])
1240 GLIBCXX_ENABLE(cstdio,stdio,[=PACKAGE],
1241 [use target-specific I/O package], [permit stdio])
1243 # Now that libio has been removed, you can have any color you want as long
1244 # as it's black. This is one big no-op until other packages are added, but
1245 # showing the framework never hurts.
1246 case ${enable_cstdio} in
1247 stdio)
1248 CSTDIO_H=config/io/c_io_stdio.h
1249 BASIC_FILE_H=config/io/basic_file_stdio.h
1250 BASIC_FILE_CC=config/io/basic_file_stdio.cc
1251 AC_MSG_RESULT(stdio)
1252 ;;
1253 esac
1255 AC_SUBST(CSTDIO_H)
1256 AC_SUBST(BASIC_FILE_H)
1257 AC_SUBST(BASIC_FILE_CC)
1258 ])
1261 dnl
1262 dnl Check for "unusual" flags to pass to the compiler while building.
1263 dnl
1264 dnl --enable-cxx-flags='-foo -bar -baz' is a general method for passing
1265 dnl experimental flags such as -fpch, -fIMI, -Dfloat=char, etc.
1266 dnl --disable-cxx-flags passes nothing.
1267 dnl + See http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00131.html
1268 dnl http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00284.html
1269 dnl http://gcc.gnu.org/ml/libstdc++/2000-q1/msg00035.html
1270 dnl + Usage: GLIBCXX_ENABLE_CXX_FLAGS(default flags)
1271 dnl If "default flags" is an empty string, the effect is the same
1272 dnl as --disable or --enable=no.
1273 dnl
1274 AC_DEFUN([GLIBCXX_ENABLE_CXX_FLAGS], [dnl
1275 AC_MSG_CHECKING([for extra compiler flags for building])
1276 GLIBCXX_ENABLE(cxx-flags,$1,[=FLAGS],
1277 [pass compiler FLAGS when building library],
1278 [case "x$enable_cxx_flags" in
1279 xno | x) enable_cxx_flags= ;;
1280 x-*) ;;
1281 *) AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
1282 esac])
1284 # Run through flags (either default or command-line) and set anything
1285 # extra (e.g., #defines) that must accompany particular g++ options.
1286 if test -n "$enable_cxx_flags"; then
1287 for f in $enable_cxx_flags; do
1288 case "$f" in
1289 -fhonor-std) ;;
1290 -*) ;;
1291 *) # and we're trying to pass /what/ exactly?
1292 AC_MSG_ERROR([compiler flags start with a -]) ;;
1293 esac
1294 done
1295 fi
1297 EXTRA_CXX_FLAGS="$enable_cxx_flags"
1298 AC_MSG_RESULT($EXTRA_CXX_FLAGS)
1299 AC_SUBST(EXTRA_CXX_FLAGS)
1300 ])
1303 dnl
1304 dnl Check for wide character support. Has the same effect as the option
1305 dnl in gcc's configure, but in a form that autoconf can mess with.
1306 dnl
1307 dnl --enable-c-mbchar requests all the wchar_t stuff.
1308 dnl --disable-c-mbchar doesn't.
1309 dnl + Usage: GLIBCXX_ENABLE_C_MBCHAR[(DEFAULT)]
1310 dnl Where DEFAULT is either `yes' or `no'.
1311 dnl
1312 AC_DEFUN([GLIBCXX_ENABLE_C_MBCHAR], [
1313 GLIBCXX_ENABLE(c-mbchar,$1,,[enable multibyte (wide) characters])
1314 # Option parsed, now other scripts can test enable_c_mbchar for yes/no.
1315 ])
1318 dnl
1319 dnl Check to see if debugging libraries are to be built.
1320 dnl
1321 dnl --enable-libstdcxx-debug
1322 dnl builds a separate set of debugging libraries in addition to the
1323 dnl normal (shared, static) libstdc++ binaries.
1324 dnl
1325 dnl --disable-libstdcxx-debug
1326 dnl builds only one (non-debug) version of libstdc++.
1327 dnl
1328 dnl --enable-libstdcxx-debug-flags=FLAGS
1329 dnl iff --enable-debug == yes, then use FLAGS to build the debug library.
1330 dnl
1331 dnl + Usage: GLIBCXX_ENABLE_DEBUG[(DEFAULT)]
1332 dnl Where DEFAULT is either `yes' or `no'.
1333 dnl
1334 AC_DEFUN([GLIBCXX_ENABLE_DEBUG], [
1335 AC_MSG_CHECKING([for additional debug build])
1336 GLIBCXX_ENABLE(libstdcxx-debug,$1,,[build extra debug library])
1337 AC_MSG_RESULT($enable_libstdcxx_debug)
1338 GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_DEBUG, test $enable_libstdcxx_debug = yes)
1339 ])
1342 dnl
1343 dnl Check for explicit debug flags.
1344 dnl
1345 dnl --enable-libstdcxx-debug-flags='-O1'
1346 dnl is a general method for passing flags to be used when
1347 dnl building debug libraries with --enable-debug.
1348 dnl
1349 dnl --disable-libstdcxx-debug-flags does nothing.
1350 dnl + Usage: GLIBCXX_ENABLE_DEBUG_FLAGS(default flags)
1351 dnl If "default flags" is an empty string, the effect is the same
1352 dnl as --disable or --enable=no.
1353 dnl
1354 AC_DEFUN([GLIBCXX_ENABLE_DEBUG_FLAGS], [
1355 GLIBCXX_ENABLE(libstdcxx-debug-flags,[$1],[=FLAGS],
1356 [pass compiler FLAGS when building debug library],
1357 [case "x$enable_libstdcxx_debug_flags" in
1358 xno | x) enable_libstdcxx_debug_flags= ;;
1359 x-*) ;;
1360 *) AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
1361 esac])
1363 # Option parsed, now set things appropriately
1364 DEBUG_FLAGS="$enable_libstdcxx_debug_flags"
1365 AC_SUBST(DEBUG_FLAGS)
1367 AC_MSG_NOTICE([Debug build flags set to $DEBUG_FLAGS])
1368 ])
1371 dnl
1372 dnl Check if the user only wants a freestanding library implementation.
1373 dnl
1374 dnl --disable-hosted-libstdcxx will turn off most of the library build,
1375 dnl installing only the headers required by [17.4.1.3] and the language
1376 dnl support library. More than that will be built (to keep the Makefiles
1377 dnl conveniently clean), but not installed.
1378 dnl
1379 dnl Sets:
1380 dnl is_hosted (yes/no)
1381 dnl
1382 dnl Defines:
1383 dnl _GLIBCXX_HOSTED (always defined, either to 1 or 0)
1384 dnl
1385 AC_DEFUN([GLIBCXX_ENABLE_HOSTED], [
1386 AC_ARG_ENABLE([hosted-libstdcxx],
1387 AC_HELP_STRING([--disable-hosted-libstdcxx],
1388 [only build freestanding C++ runtime support]),,
1389 [case "$host" in
1390 arm*-*-symbianelf*)
1391 enable_hosted_libstdcxx=no
1392 ;;
1393 *)
1394 enable_hosted_libstdcxx=yes
1395 ;;
1396 esac])
1397 if test "$enable_hosted_libstdcxx" = no; then
1398 AC_MSG_NOTICE([Only freestanding libraries will be built])
1399 is_hosted=no
1400 hosted_define=0
1401 enable_abi_check=no
1402 enable_libstdcxx_pch=no
1403 else
1404 is_hosted=yes
1405 hosted_define=1
1406 fi
1407 GLIBCXX_CONDITIONAL(GLIBCXX_HOSTED, test $is_hosted = yes)
1408 AC_DEFINE_UNQUOTED(_GLIBCXX_HOSTED, $hosted_define,
1409 [Define to 1 if a full hosted library is built, or 0 if freestanding.])
1410 ])
1413 dnl
1414 dnl Check for template specializations for the 'long long' type extension.
1415 dnl The result determines only whether 'long long' I/O is enabled; things
1416 dnl like numeric_limits<> specializations are always available.
1417 dnl
1418 dnl --enable-long-long defines _GLIBCXX_USE_LONG_LONG
1419 dnl --disable-long-long leaves _GLIBCXX_USE_LONG_LONG undefined
1420 dnl + Usage: GLIBCXX_ENABLE_LONG_LONG[(DEFAULT)]
1421 dnl Where DEFAULT is either `yes' or `no'.
1422 dnl
1423 AC_DEFUN([GLIBCXX_ENABLE_LONG_LONG], [
1424 GLIBCXX_ENABLE(long-long,$1,,[enables I/O support for 'long long'])
1425 if test $enable_long_long = yes; then
1426 AC_DEFINE(_GLIBCXX_USE_LONG_LONG)
1427 fi
1428 ])
1431 dnl
1432 dnl Check to see if building and using a C++ precompiled header can be done.
1433 dnl
1434 dnl --enable-libstdcxx-pch=yes
1435 dnl default, this shows intent to use stdc++.h.gch If it looks like it
1436 dnl may work, after some light-hearted attempts to puzzle out compiler
1437 dnl support, flip bits on in include/Makefile.am
1438 dnl
1439 dnl --disable-libstdcxx-pch
1440 dnl turns off attempts to use or build stdc++.h.gch.
1441 dnl
1442 dnl Substs:
1443 dnl glibcxx_PCHFLAGS
1444 dnl
1445 AC_DEFUN([GLIBCXX_ENABLE_PCH], [
1446 AC_MSG_CHECKING([for enabled PCH])
1447 GLIBCXX_ENABLE(libstdcxx-pch,$1,,[build pre-compiled libstdc++ headers])
1448 AC_MSG_RESULT([$enable_libstdcxx_pch])
1450 if test $enable_libstdcxx_pch = yes; then
1451 AC_CACHE_CHECK([for compiler with PCH support],
1452 [glibcxx_cv_prog_CXX_pch],
1453 [ac_save_CXXFLAGS="$CXXFLAGS"
1454 CXXFLAGS="$CXXFLAGS -Werror -Winvalid-pch -Wno-deprecated"
1455 AC_LANG_SAVE
1456 AC_LANG_CPLUSPLUS
1457 echo '#include <math.h>' > conftest.h
1458 if $CXX $CXXFLAGS $CPPFLAGS -x c++-header conftest.h \
1459 -o conftest.h.gch 1>&5 2>&1 &&
1460 echo '#error "pch failed"' > conftest.h &&
1461 echo '#include "conftest.h"' > conftest.cc &&
1462 $CXX -c $CXXFLAGS $CPPFLAGS conftest.cc 1>&5 2>&1 ;
1463 then
1464 glibcxx_cv_prog_CXX_pch=yes
1465 else
1466 glibcxx_cv_prog_CXX_pch=no
1467 fi
1468 rm -f conftest*
1469 CXXFLAGS=$ac_save_CXXFLAGS
1470 AC_LANG_RESTORE
1471 ])
1472 enable_libstdcxx_pch=$glibcxx_cv_prog_CXX_pch
1473 fi
1475 GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_PCH, test $enable_libstdcxx_pch = yes)
1476 if test $enable_libstdcxx_pch = yes; then
1477 glibcxx_PCHFLAGS="-include bits/stdc++.h"
1478 else
1479 glibcxx_PCHFLAGS=""
1480 fi
1481 AC_SUBST(glibcxx_PCHFLAGS)
1482 ])
1485 dnl
1486 dnl Check for exception handling support. If an explicit enable/disable
1487 dnl sjlj exceptions is given, we don't have to detect. Otherwise the
1488 dnl target may or may not support call frame exceptions.
1489 dnl
1490 dnl --enable-sjlj-exceptions forces the use of builtin setjmp.
1491 dnl --disable-sjlj-exceptions forces the use of call frame unwinding.
1492 dnl Neither one forces an attempt at detection.
1493 dnl
1494 dnl Defines:
1495 dnl _GLIBCXX_SJLJ_EXCEPTIONS if the compiler is configured for it
1496 dnl
1497 AC_DEFUN([GLIBCXX_ENABLE_SJLJ_EXCEPTIONS], [
1498 AC_MSG_CHECKING([for exception model to use])
1499 AC_LANG_SAVE
1500 AC_LANG_CPLUSPLUS
1501 GLIBCXX_ENABLE(sjlj-exceptions,auto,,
1502 [force use of builtin_setjmp for exceptions],
1503 [permit yes|no|auto])
1505 if test $enable_sjlj_exceptions = auto; then
1506 # Botheration. Now we've got to detect the exception model. Link tests
1507 # against libgcc.a are problematic since we've not been given proper -L
1508 # bits for single-tree newlib and libgloss.
1509 #
1510 # Fake what AC_TRY_COMPILE does. XXX Look at redoing this new-style.
1511 cat > conftest.$ac_ext << EOF
1512 [#]line __oline__ "configure"
1513 struct S { ~S(); };
1514 void bar();
1515 void foo()
1516 {
1517 S s;
1518 bar();
1519 }
1520 EOF
1521 old_CXXFLAGS="$CXXFLAGS"
1522 CXXFLAGS=-S
1523 if AC_TRY_EVAL(ac_compile); then
1524 if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
1525 enable_sjlj_exceptions=yes
1526 elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
1527 enable_sjlj_exceptions=no
1528 fi
1529 fi
1530 CXXFLAGS="$old_CXXFLAGS"
1531 rm -f conftest*
1532 fi
1534 # This is a tad weird, for hysterical raisins. We have to map enable/disable
1535 # to two different models.
1536 case $enable_sjlj_exceptions in
1537 yes)
1538 AC_DEFINE(_GLIBCXX_SJLJ_EXCEPTIONS, 1,
1539 [Define if the compiler is configured for setjmp/longjmp exceptions.])
1540 ac_exception_model_name=sjlj
1541 ;;
1542 no)
1543 ac_exception_model_name="call frame"
1544 ;;
1545 *)
1546 AC_MSG_ERROR([unable to detect exception model])
1547 ;;
1548 esac
1549 AC_LANG_RESTORE
1550 AC_MSG_RESULT($ac_exception_model_name)
1551 ])
1554 dnl
1555 dnl Add version tags to symbols in shared library (or not), additionally
1556 dnl marking other symbols as private/local (or not).
1557 dnl
1558 dnl --enable-symvers=style adds a version script to the linker call when
1559 dnl creating the shared library. The choice of version script is
1560 dnl controlled by 'style'.
1561 dnl --disable-symvers does not.
1562 dnl + Usage: GLIBCXX_ENABLE_SYMVERS[(DEFAULT)]
1563 dnl Where DEFAULT is either 'yes' or 'no'. Passing `yes' tries to
1564 dnl choose a default style based on linker characteristics. Passing
1565 dnl 'no' disables versioning.
1566 dnl
1567 AC_DEFUN([GLIBCXX_ENABLE_SYMVERS], [
1569 GLIBCXX_ENABLE(symvers,$1,[=STYLE],
1570 [enables symbol versioning of the shared library],
1571 [permit yes|no|gnu])
1573 # If we never went through the GLIBCXX_CHECK_LINKER_FEATURES macro, then we
1574 # don't know enough about $LD to do tricks...
1575 AC_REQUIRE([GLIBCXX_CHECK_LINKER_FEATURES])
1576 # FIXME The following test is too strict, in theory.
1577 if test $enable_shared = no ||
1578 test "x$LD" = x ||
1579 test x$glibcxx_gnu_ld_version = x; then
1580 enable_symvers=no
1581 fi
1583 # Check to see if libgcc_s exists, indicating that shared libgcc is possible.
1584 if test $enable_symvers != no; then
1585 AC_MSG_CHECKING([for shared libgcc])
1586 ac_save_CFLAGS="$CFLAGS"
1587 CFLAGS=' -lgcc_s'
1588 AC_TRY_LINK(, [return 0;], glibcxx_shared_libgcc=yes, glibcxx_shared_libgcc=no)
1589 CFLAGS="$ac_save_CFLAGS"
1590 if test $glibcxx_shared_libgcc = no; then
1591 cat > conftest.c <<EOF
1592 int main (void) { return 0; }
1593 EOF
1594 changequote(,)dnl
1595 glibcxx_libgcc_s_suffix=`${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1596 -shared -shared-libgcc -o conftest.so \
1597 conftest.c -v 2>&1 >/dev/null \
1598 | sed -n 's/^.* -lgcc_s\([^ ]*\) .*$/\1/p'`
1599 changequote([,])dnl
1600 rm -f conftest.c conftest.so
1601 if test x${glibcxx_libgcc_s_suffix+set} = xset; then
1602 CFLAGS=" -lgcc_s$glibcxx_libgcc_s_suffix"
1603 AC_TRY_LINK(, [return 0;], glibcxx_shared_libgcc=yes)
1604 CFLAGS="$ac_save_CFLAGS"
1605 fi
1606 fi
1607 AC_MSG_RESULT($glibcxx_shared_libgcc)
1608 fi
1610 # For GNU ld, we need at least this version. The format is described in
1611 # GLIBCXX_CHECK_LINKER_FEATURES above.
1612 glibcxx_min_gnu_ld_version=21400
1613 # XXXXXXXXXXX glibcxx_gnu_ld_version=21390
1615 # Check to see if unspecified "yes" value can win, given results above.
1616 # Change "yes" into either "no" or a style name.
1617 if test $enable_symvers = yes; then
1618 if test $with_gnu_ld = yes &&
1619 test $glibcxx_shared_libgcc = yes;
1620 then
1621 if test $glibcxx_gnu_ld_version -ge $glibcxx_min_gnu_ld_version ; then
1622 enable_symvers=gnu
1623 else
1624 # The right tools, the right setup, but too old. Fallbacks?
1625 AC_MSG_WARN(=== Linker version $glibcxx_gnu_ld_version is too old for)
1626 AC_MSG_WARN(=== full symbol versioning support in this release of GCC.)
1627 AC_MSG_WARN(=== You would need to upgrade your binutils to version)
1628 AC_MSG_WARN(=== $glibcxx_min_gnu_ld_version or later and rebuild GCC.)
1629 if test $glibcxx_gnu_ld_version -ge 21200 ; then
1630 # Globbing fix is present, proper block support is not.
1631 dnl AC_MSG_WARN([=== Dude, you are soooo close. Maybe we can fake it.])
1632 dnl enable_symvers=???
1633 AC_MSG_WARN([=== Symbol versioning will be disabled.])
1634 enable_symvers=no
1635 else
1636 # 2.11 or older.
1637 AC_MSG_WARN([=== Symbol versioning will be disabled.])
1638 enable_symvers=no
1639 fi
1640 fi
1641 else
1642 # just fail for now
1643 AC_MSG_WARN([=== You have requested some kind of symbol versioning, but])
1644 AC_MSG_WARN([=== either you are not using a supported linker, or you are])
1645 AC_MSG_WARN([=== not building a shared libgcc_s (which is required).])
1646 AC_MSG_WARN([=== Symbol versioning will be disabled.])
1647 enable_symvers=no
1648 fi
1649 fi
1651 # Everything parsed; figure out what file to use.
1652 case $enable_symvers in
1653 no)
1654 SYMVER_MAP=config/linker-map.dummy
1655 ;;
1656 gnu)
1657 SYMVER_MAP=config/linker-map.gnu
1658 AC_DEFINE(_GLIBCXX_SYMVER)
1659 ;;
1660 esac
1662 AC_SUBST(SYMVER_MAP)
1663 AC_SUBST(port_specific_symbol_files)
1664 GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_VERSIONED_SHLIB, test $enable_symvers != no)
1665 AC_MSG_NOTICE(versioning on shared library symbols is $enable_symvers)
1666 ])
1669 dnl
1670 dnl Setup to use the gcc gthr.h thread-specific memory and mutex model.
1671 dnl We must stage the required headers so that they will be installed
1672 dnl with the library (unlike libgcc, the STL implementation is provided
1673 dnl solely within headers). Since we must not inject random user-space
1674 dnl macro names into user-provided C++ code, we first stage into <file>-in
1675 dnl and process to <file> with an output command. The reason for a two-
1676 dnl stage process here is to correctly handle $srcdir!=$objdir without
1677 dnl having to write complex code (the sed commands to clean the macro
1678 dnl namespace are complex and fragile enough as it is). We must also
1679 dnl add a relative path so that -I- is supported properly.
1680 dnl
1681 dnl Substs:
1682 dnl glibcxx_thread_h
1683 dnl
1684 dnl Defines:
1685 dnl HAVE_GTHR_DEFAULT
1686 dnl
1687 AC_DEFUN([GLIBCXX_ENABLE_THREADS], [
1688 AC_MSG_CHECKING([for thread model used by GCC])
1689 target_thread_file=`$CXX -v 2>&1 | sed -n 's/^Thread model: //p'`
1690 AC_MSG_RESULT([$target_thread_file])
1692 if test $target_thread_file != single; then
1693 AC_DEFINE(HAVE_GTHR_DEFAULT)
1694 fi
1696 glibcxx_thread_h=gthr-$target_thread_file.h
1697 AC_SUBST(glibcxx_thread_h)
1698 ])
1701 # Check whether LC_MESSAGES is available in <locale.h>.
1702 # Ulrich Drepper <drepper@cygnus.com>, 1995.
1703 #
1704 # This file file be copied and used freely without restrictions. It can
1705 # be used in projects which are not available under the GNU Public License
1706 # but which still want to provide support for the GNU gettext functionality.
1707 # Please note that the actual code is *not* freely available.
1709 # serial 1
1710 AC_DEFUN([AC_LC_MESSAGES], [
1711 AC_CHECK_HEADER(locale.h, [
1712 AC_CACHE_CHECK([for LC_MESSAGES], ac_cv_val_LC_MESSAGES,
1713 [AC_TRY_LINK([#include <locale.h>], [return LC_MESSAGES],
1714 ac_cv_val_LC_MESSAGES=yes, ac_cv_val_LC_MESSAGES=no)])
1715 if test $ac_cv_val_LC_MESSAGES = yes; then
1716 AC_DEFINE(HAVE_LC_MESSAGES)
1717 fi
1718 ])
1719 ])
1722 sinclude([../libtool.m4])
1723 dnl The lines below arrange for aclocal not to bring an installed
1724 dnl libtool.m4 into aclocal.m4, while still arranging for automake to
1725 dnl add a definition of LIBTOOL to Makefile.in.
1726 ifelse(,,,[AC_SUBST(LIBTOOL)
1727 AC_DEFUN([AM_PROG_LIBTOOL])
1728 AC_DEFUN([AC_LIBTOOL_DLOPEN])
1729 AC_DEFUN([AC_PROG_LD])
1730 ])
1732 dnl vim:et:ts=2:sw=2