libjava/configure.ac

   1 dnl # Process this with autoconf to create configure
   2 AC_PREREQ(2.59)
   3 # Still use "libjava" here to placate dejagnu.
   4 AC_INIT([libjava], [version-unused],, [libjava])
   5
   6 AC_CONFIG_SRCDIR(java/lang/System.java)
   7
   8 GCC_TOPLEV_SUBDIRS
   9
  10 # We use these options to decide which functions to include.
  11 AC_ARG_WITH(target-subdir,
  12   AS_HELP_STRING([--with-target-subdir=SUBDIR],
  13                  [configure in a subdirectory]))
  14
  15 # We may get other options which we don't document:
  16 # --with-target-subdir, --with-multisrctop, --with-multisubdir
  17
  18 # Find the rest of the source tree framework.
  19 AM_ENABLE_MULTILIB(, ..)
  20
  21 AC_CANONICAL_SYSTEM
  22 _GCC_TOPLEV_NONCANONICAL_BUILD
  23 _GCC_TOPLEV_NONCANONICAL_TARGET
  24
  25 AC_SUBST(target_noncanonical)
  26
  27 # This works around the fact that libtool configuration may change LD
  28 # for this particular configuration, but some shells, instead of
  29 # keeping the changes in LD private, export them just because LD is
  30 # exported.
  31 ORIGINAL_LD_FOR_MULTILIBS=$LD
  32
  33 AC_PROG_LN_S
  34
  35 # This works around an automake problem.
  36 mkinstalldirs="`cd $ac_aux_dir && ${PWDCMD-pwd}`/mkinstalldirs"
  37 AC_SUBST(mkinstalldirs)
  38
  39 AC_ARG_WITH(cross-host,
  40   AS_HELP_STRING([--with-cross-host=HOST],
  41                  [configure with a cross compiler from HOST]))
  42
  43 AC_ARG_WITH(newlib,
  44   AS_HELP_STRING([--with-newlib],
  45                  [configure with newlib]))
  46
  47 AC_ARG_ENABLE(version-specific-runtime-libs,
  48   AS_HELP_STRING([--enable-version-specific-runtime-libs],
  49                  [specify that runtime libraries should be installed in a compiler-specific directory]),
  50     [case "$enableval" in
  51       yes) version_specific_libs=yes ;;
  52       no)  version_specific_libs=no ;;
  53       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  54      esac],
  55     [version_specific_libs=no]
  56 )
  57
  58 AC_ARG_ENABLE(plugin,
  59   AS_HELP_STRING([--enable-plugin],
  60                  [build gcjwebplugin web browser plugin]),
  61     [case "$enableval" in
  62       yes) plugin_enabled=yes ;;
  63       no)  plugin_enabled=no ;;
  64       *)   AC_MSG_ERROR([Unknown argument to enable/disable plugin]);;
  65      esac],
  66     [plugin_enabled=no]
  67 )
  68
  69 AC_ARG_ENABLE(gconf-peer,
  70   AS_HELP_STRING([--enable-gconf-peer],
  71                  [compile GConf native peers for util.preferences]),
  72     [case "$enableval" in
  73       yes) gconf_enabled=yes ;;
  74       no)  gconf_enabled=no ;;
  75       *)   AC_MSG_ERROR([Unknown argument to enable/disable gconf-peer]);;
  76      esac],
  77     [gconf_enabled=no]
  78 )
  79
  80 # It may not be safe to run linking tests in AC_PROG_CC/AC_PROG_CXX.
  81 GCC_NO_EXECUTABLES
  82
  83 # (1) We use an abnormal CXX (without library references), so we
  84 # must cache it under a different name.
  85 # (2) CC, CFLAGS, CXX, CXXFLAGS, LDFLAGS must not be 'precious', or
  86 # the non-multilib-adjusted value will be used in multilibs.
  87 # (3) As a side effect, we must SUBST CXXFLAGS, CFLAGS, and LDFLAGS ourselves.
  88 # (4) As another side effect, automake doesn't automatically include them
  89 # in Makefile.in.
  90 # (5) For libstdc++-v3, -fno-builtin must be present here so that a
  91 # non-conflicting form of std::exit can be guessed by AC_PROG_CXX, and
  92 # used in later tests.  This may not be necessary in libjava; I don't know.
  93 m4_define([ac_cv_prog_CXX],[glibcxx_cv_prog_CXX])
  94 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
  95 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  96 save_CXXFLAGS="$CXXFLAGS"
  97 CXXFLAGS="$CXXFLAGS -fno-builtin"
  98 AC_PROG_CC
  99 AC_PROG_CXX
 100 CXXFLAGS="$save_CXXFLAGS"
 101 m4_rename([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 102 AC_SUBST(CFLAGS)
 103 AC_SUBST(CXXFLAGS)
 104 AC_SUBST(LDFLAGS)
 105
 106 AM_INIT_AUTOMAKE([1.9.0])
 107
 108 AC_CHECK_TOOL(AS, as)
 109 AC_CHECK_TOOL(LD, ld)
 110 AC_CHECK_TOOL(AR, ar)
 111 AC_CHECK_TOOL(RANLIB, ranlib, :)
 112 AC_PROG_AWK
 113 AC_CHECK_PROGS([JAR], [jar fastjar], no)
 114 AC_PATH_PROG([ZIP], [zip], no)
 115 AC_PATH_PROG([UNZIP], [unzip], unzip)
 116 AM_CONDITIONAL(BASH_JAR, test "$JAR" = no)
 117 if test "$ZIP" = no; then
 118   if test "$JAR" = no; then
 119     AC_MSG_ERROR([cannot find neither zip nor jar, cannot continue])
 120   fi
 121 else
 122   # InfoZIP available, use the 'guaranteed' Bourne-shell JAR to build libjava
 123   JAR=`pwd`/scripts/jar
 124 fi
 125
 126 AC_PROG_INSTALL
 127
 128 AM_MAINTAINER_MODE
 129
 130 AC_EXEEXT
 131
 132 # configure.host sets the following important variables
 133 #       libgcj_cflags    - host specific C compiler flags
 134 #       libgcj_cxxflags  - host specific C++ compiler flags
 135 #       libgcj_javaflags - host specific Java compiler flags
 136
 137 libgcj_cflags=
 138 libgcj_cxxflags=
 139 libgcj_javaflags=
 140
 141 . ${srcdir}/configure.host
 142
 143 LIBGCJ_CFLAGS="${libgcj_cflags}"
 144 LIBGCJ_CXXFLAGS="${libgcj_cxxflags}"
 145 LIBGCJ_JAVAFLAGS="${libgcj_javaflags}"
 146 LIBGCJ_LD_SYMBOLIC="${libgcj_ld_symbolic}"
 147 AC_SUBST(LIBGCJ_CFLAGS)
 148 AC_SUBST(LIBGCJ_CXXFLAGS)
 149 AC_SUBST(LIBGCJ_JAVAFLAGS)
 150 AC_SUBST(LIBGCJ_LD_SYMBOLIC)
 151
 152 # Only use libltdl for non-newlib builds.
 153 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 154    AC_LTDL_SHLIBPATH
 155 fi
 156
 157 AC_CONFIG_HEADERS([include/config.h gcj/libgcj-config.h])
 158
 159 # See if the user has requested runtime debugging.
 160 LIBGCJDEBUG="disable"
 161 AC_SUBST(LIBGCJDEBUG)
 162 AC_ARG_ENABLE(libgcj-debug,
 163   AS_HELP_STRING([--enable-libgcj-debug],
 164                  [enable runtime debugging code]),
 165   [if test "$enable_libgcj_debug" = yes; then
 166     AC_DEFINE(DEBUG, 1, [Define this if you want runtime debugging enabled.])
 167     LIBGCJDEBUG="enable"
 168   fi])
 169
 170 # Determine which AWT peer libraries to build
 171 AC_ARG_ENABLE(java-awt,
 172   AS_HELP_STRING([--enable-java-awt],
 173                  [list of AWT peer implementations to be built]))
 174
 175 peerlibs="`echo ${enable_java_awt} | tr ',' ' '`"
 176 use_xlib_awt=""
 177 use_gtk_awt=""
 178 use_qt_awt=""
 179 # The default toolkit to use is the first one specified.
 180 TOOLKIT=
 181 AC_SUBST(TOOLKIT)
 182
 183 for peer in $peerlibs ; do
 184   case $peer in
 185     xlib)
 186       if test "$no_x" = yes; then
 187         echo "*** xlib peers requested but no X library available" 1>&2
 188         exit 1
 189       else
 190         use_xlib_awt="yes"
 191         if test -z "$TOOLKIT"; then
 192            TOOLKIT=gnu.awt.xlib.XToolkit
 193         fi
 194       fi
 195       ;;
 196     gtk)
 197       if test "$no_x" = yes; then
 198          echo "*** gtk peers requested but no X library available" 1>&2
 199          exit 1
 200       else
 201          use_gtk_awt=yes
 202          if test -z "$TOOLKIT"; then
 203             TOOLKIT=gnu.java.awt.peer.gtk.GtkToolkit
 204          fi
 205       fi
 206       ;;
 207     qt)
 208       if test "$no_x" = yes; then
 209          # Perhaps we should admit the possibility of embedded Qt.
 210          echo "*** Qt peers requested but no X library available" 1>&2
 211          exit 1
 212       else
 213          use_qt_awt=yes
 214          if test -z "$TOOLKIT"; then
 215             TOOLKIT=gnu.java.awt.peer.qt.QtToolkit
 216          fi
 217       fi
 218       ;;
 219     no)
 220       use_xlib_awt=
 221       use_gtk_awt=
 222       use_qt_awt=
 223       break
 224       ;;
 225     *)
 226       echo "*** unrecognised argument \"${peer}\" for --enable-java-awt" 1>&2
 227       exit 1
 228   esac
 229 done
 230
 231 AM_CONDITIONAL(XLIB_AWT, test "$use_xlib_awt" = yes)
 232
 233 # Create standard.omit based on decisions we just made.
 234 cp $srcdir/standard.omit.in standard.omit
 235 if test "$use_xlib_awt" != yes; then
 236    echo gnu/awt/xlib >> standard.omit
 237    echo gnu/gcj/xlib >> standard.omit
 238 fi
 239
 240 if test -z "${with_multisubdir}"; then
 241    builddotdot=.
 242 else
 243    builddotdot=`echo ${with_multisubdir} | sed -e 's:[[^/]][[^/]]*:..:g'`
 244 fi
 245
 246 NATIVE=yes
 247
 248 # Which gcj do we use?
 249 which_gcj=default
 250 built_gcc_dir="`cd ${builddotdot}/../../${host_subdir}/gcc && ${PWDCMD-pwd}`"
 251 if test -n "${with_cross_host}"; then
 252   # We are being configured with a cross compiler. We can't
 253   # use ac_exeext, because that is for the target platform.
 254   NATIVE=no
 255   cross_host_exeext=
 256   case "${with_cross_host}" in
 257      *mingw* | *cygwin*)
 258          cross_host_exeext=.exe
 259      ;;
 260   esac
 261   if test -x "${built_gcc_dir}/gcj${cross_host_exeext}"; then
 262      if test x"$build_noncanonical" = x"$with_cross_host"; then
 263         # Ordinary cross (host!=target and host=build)
 264         which_gcj=built
 265      else
 266         # Canadian cross (host!=target and host!=build)
 267         which_gcj=cross
 268      fi
 269   else
 270      which_gcj=cross
 271   fi
 272 else
 273   # We are being configured with a native or crossed-native compiler
 274   if test -x "${built_gcc_dir}/gcj${ac_exeext}"; then
 275      if test x"$build" = x"$host"; then
 276         # True native build (host=target and host=build)
 277         which_gcj=built
 278      else
 279         # Crossed-native build (host=target and host!=build)
 280         which_gcj=cross
 281      fi
 282   else
 283      which_gcj=path
 284   fi
 285 fi
 286 case "${which_gcj}" in
 287    built)
 288       GCJ="$built_gcc_dir/gcj -B`${PWDCMD-pwd}`/ -B$built_gcc_dir/"
 289       GCJH='$(top_builddir)/$(MULTIBUILDTOP)../../$(host_subdir)/gcc/gcjh'
 290    ;;
 291    cross)
 292       if test "x${with_newlib}" = "xyes"; then
 293          # FIXME (comment): Why is this needed?
 294          GCC_UNWIND_INCLUDE=
 295          GCJ="${target_noncanonical}-gcj"
 296       else
 297          GCJ="${target_noncanonical}-gcj -B`${PWDCMD-pwd}`/"
 298       fi
 299       GCJH='$(target_noncanonical)-gcjh'
 300    ;;
 301    path)
 302       GCJ="gcj -B`${PWDCMD-pwd}`/"
 303       GCJH=gcjh
 304    ;;
 305 esac
 306
 307 AC_SUBST(GCJH)
 308
 309 # Create it, so that compile/link tests don't fail
 310 test -f libgcj.spec || touch libgcj.spec
 311
 312
 313
 314 # Set up to configure Classpath.
 315 # FIXME: no supported way to pass args in autoconf.
 316 ac_configure_args="$ac_configure_args --with-fastjar=$JAR"
 317 ac_configure_args="$ac_configure_args --enable-tool-wrappers"
 318 ac_configure_args="$ac_configure_args --disable-load-library"
 319 ac_configure_args="$ac_configure_args --${LIBGCJDEBUG}-debug"
 320 ac_configure_args="$ac_configure_args --enable-default-toolkit=$TOOLKIT"
 321 dir1=`cd $srcdir && pwd`
 322 dir2=`pwd`
 323 ac_configure_args="$ac_configure_args --with-vm-classes=$dir1:$dir2"
 324 ac_configure_args="$ac_configure_args --disable-core-jni"
 325 dnl FIXME?
 326 ac_configure_args="$ac_configure_args --disable-examples"
 327 ac_configure_args="$ac_configure_args --with-glibj=build"
 328 if test "$plugin_enabled" != yes; then
 329   ac_configure_args="$ac_configure_args --disable-plugin"
 330 fi
 331 if test "$gconf_enabled" != yes; then
 332   ac_configure_args="$ac_configure_args --disable-gconf-peer"
 333   ac_configure_args="$ac_configure_args --enable-default-preferences-peer=gnu.java.util.prefs.FileBasedFactory"
 334 fi
 335 if test "$use_gtk_awt" != yes; then
 336   ac_configure_args="$ac_configure_args --disable-gtk-peer"
 337 fi
 338 if test "$use_qt_awt" != yes; then
 339   ac_configure_args="$ac_configure_args --disable-qt-peer"
 340 else
 341   # We need this as qt is disabled by default in classpath.
 342   ac_configure_args="$ac_configure_args --enable-qt-peer"
 343 fi
 344 dnl --with-gcj=$GCJ
 345 dnl --with-javah=$GCJH
 346 dnl gjdoc?
 347 dnl gtk-cairo -- just export here...
 348 dnl --enable-regen-headers?
 349
 350 # Only use libltdl for non-newlib builds.
 351 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 352    AC_LIBLTDL_CONVENIENCE
 353    AC_LIBTOOL_DLOPEN
 354    DIRLTDL=libltdl
 355    AC_DEFINE(USE_LTDL, 1, [Define if libltdl is in use.])
 356    # Sigh.  Libtool's macro doesn't do the right thing.
 357    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
 358    # FIXME: this is a hack.
 359    sub_auxdir="`cd $ac_aux_dir && ${PWDCMD-pwd}`"
 360    ac_configure_args="$ac_configure_args --with-auxdir=$sub_auxdir"
 361 fi
 362 AC_SUBST(INCLTDL)
 363 AC_SUBST(LIBLTDL)
 364 AC_SUBST(DIRLTDL)
 365 AC_PROG_LIBTOOL
 366 AM_PROG_GCJ
 367 AM_PROG_CC_C_O
 368
 369 AC_CONFIG_SUBDIRS(classpath libltdl)
 370
 371 # The -no-testsuite modules omit the test subdir.
 372 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
 373
 374 # Should the runtime set system properties by examining the
 375 # environment variable GCJ_PROPERTIES?
 376 AC_ARG_ENABLE(getenv-properties,
 377   AS_HELP_STRING([--disable-getenv-properties],
 378                  [don't set system properties from GCJ_PROPERTIES]))
 379
 380 # Whether GCJ_PROPERTIES is used depends on the target.
 381 if test -z "$enable_getenv_properties"; then
 382    enable_getenv_properties=${enable_getenv_properties_default-yes}
 383 fi
 384 if test "$enable_getenv_properties" = no; then
 385    AC_DEFINE(DISABLE_GETENV_PROPERTIES, 1,
 386      [Define if system properties shouldn't be read from getenv("GCJ_PROPERTIES").])
 387 fi
 388
 389 # Whether we should use arguments to main()
 390 if test -z "$enable_main_args"; then
 391    enable_main_args=${enable_main_args_default-yes}
 392 fi
 393 if test "$enable_main_args" = no; then
 394    AC_DEFINE(DISABLE_MAIN_ARGS, 1, [Define if we should ignore arguments to main().])
 395 fi
 396
 397
 398 # Should we use hashtable-based synchronization?
 399 # Currently works only for Linux X86/ia64
 400 # Typically faster and more space-efficient
 401 AC_ARG_ENABLE(hash-synchronization,
 402   AS_HELP_STRING([--enable-hash-synchronization],
 403                  [use global hash table for monitor locks]))
 404
 405 if test -z "$enable_hash_synchronization"; then
 406    enable_hash_synchronization=$enable_hash_synchronization_default
 407 fi
 408
 409 AC_ARG_WITH(java-home,
 410   AS_HELP_STRING([--with-java-home=DIRECTORY],
 411                  [value of java.home system property]),
 412                  [JAVA_HOME="${withval}"], [JAVA_HOME=""])
 413 AM_CONDITIONAL(JAVA_HOME_SET, test ! -z "$JAVA_HOME")
 414 AC_SUBST(JAVA_HOME)
 415
 416 # What is the native OS API for MinGW?
 417 AC_ARG_WITH(win32-nlsapi,
 418   AS_HELP_STRING([--with-win32-nlsapi=ansi or unicows or unicode],
 419                  [native MinGW libgcj Win32 OS API (default is ansi)]),
 420 [case "${withval}" in
 421   ansi) with_win32_nlsapi=ansi ;;
 422   unicows) with_win32_nlsapi=unicows ;;
 423   unicode) with_win32_nlsapi=unicode ;;
 424   *) AC_MSG_ERROR(Bad value ${withval} for --with-win32-nlsapi.) ;;
 425 esac],[with_win32_nlsapi=ansi])
 426
 427 case "${with_win32_nlsapi}" in
 428   unicows | unicode)
 429     AC_DEFINE(MINGW_LIBGCJ_UNICODE, 1,
 430       [Define if MinGW libgcj uses the Windows UNICODE OS API.])
 431     ;;
 432 esac
 433
 434 # configure.host sets slow_pthread_self if the synchronization code should
 435 # try to avoid pthread_self calls by caching thread IDs in a hashtable.
 436 if test "${slow_pthread_self}" = "yes"; then
 437   AC_DEFINE(SLOW_PTHREAD_SELF, 1,
 438     [Define if if the synchronization code should try to avoid pthread_self calls by caching thread IDs in a hashtable.])
 439 fi
 440
 441 # Check for gc debugging.  This option is handled both here and in the GC.
 442 AC_ARG_ENABLE(gc-debug,
 443    AS_HELP_STRING([--enable-gc-debug],
 444                   [include full support for pointer backtracing etc.]),
 445 [ if test "$enable_gc_debug" = "yes"; then
 446     AC_DEFINE(LIBGCJ_GC_DEBUG, 1,
 447               [Define if we want to use debug calls into the garbage collector.])
 448   fi])
 449
 450 # See if the user has the interpreter included.
 451 AC_ARG_ENABLE(interpreter,
 452   AS_HELP_STRING([--enable-interpreter],
 453                  [enable interpreter]),
 454   [if test "$enable_interpreter" = yes; then
 455     # This can also be set in configure.host.
 456     libgcj_interpreter=yes
 457   elif test "$enable_interpreter" = no; then
 458     libgcj_interpreter=no
 459   fi])
 460
 461 if test "$libgcj_interpreter" = yes; then
 462    AC_DEFINE(INTERPRETER, 1, [Define if you want a bytecode interpreter.])
 463 fi
 464 INTERPRETER="$libgcj_interpreter"
 465 AC_SUBST(INTERPRETER)
 466
 467 AC_MSG_CHECKING([for exception model to use])
 468 AC_LANG_PUSH(C++)
 469 AC_ARG_ENABLE(sjlj-exceptions,
 470   AS_HELP_STRING([--enable-sjlj-exceptions],
 471                  [force use of builtin_setjmp for exceptions]),
 472 [:],
 473 [dnl Botheration.  Now we've got to detect the exception model.
 474 dnl Link tests against libgcc.a are problematic since -- at least
 475 dnl as of this writing -- we've not been given proper -L bits for
 476 dnl single-tree newlib and libgloss.
 477 dnl
 478 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 479 dnl conftest files before we got a change to grep them first.
 480 cat > conftest.$ac_ext << EOF
 481 [#]line __oline__ "configure"
 482 struct S { ~S(); };
 483 void bar();
 484 void foo()
 485 {
 486   S s;
 487   bar();
 488 }
 489 EOF
 490 old_CXXFLAGS="$CXXFLAGS"
 491 CXXFLAGS=-S
 492 if AC_TRY_EVAL(ac_compile); then
 493   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 494     enable_sjlj_exceptions=yes
 495   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 496     enable_sjlj_exceptions=no
 497   fi
 498 fi
 499 CXXFLAGS="$old_CXXFLAGS"
 500 rm -f conftest*])
 501 if test x$enable_sjlj_exceptions = xyes; then
 502   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 503         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 504   ac_exception_model_name=sjlj
 505 elif test x$enable_sjlj_exceptions = xno; then
 506   ac_exception_model_name="call frame"
 507 else
 508   AC_MSG_ERROR([unable to detect exception model])
 509 fi
 510 AC_LANG_POP(C++)
 511 AC_MSG_RESULT($ac_exception_model_name)
 512
 513 # If we are non using SJLJ exceptions, and this host does not have support
 514 # for unwinding from a signal handler, enable checked dereferences and divides.
 515 if test $can_unwind_signal = no && test $enable_sjlj_exceptions = no; then
 516   CHECKREFSPEC=-fcheck-references
 517   DIVIDESPEC=-fuse-divide-subroutine
 518   EXCEPTIONSPEC=
 519 fi
 520
 521 # See if the user wants to disable java.net.  This is the mildly
 522 # ugly way that we admit that target-side configuration sucks.
 523 AC_ARG_ENABLE(java-net,
 524   AS_HELP_STRING([--disable-java-net],
 525                  [disable java.net]))
 526
 527 # Whether java.net is built by default can depend on the target.
 528 if test -z "$enable_java_net"; then
 529    enable_java_net=${enable_java_net_default-yes}
 530 fi
 531 if test "$enable_java_net" = no; then
 532    AC_DEFINE(DISABLE_JAVA_NET, 1, [Define if java.net native functions should be stubbed out.])
 533 fi
 534
 535 # See if the user wants to configure without libffi.  Some
 536 # architectures don't support it, and default values are set in
 537 # configure.host.
 538 AC_ARG_WITH(libffi,
 539   AS_HELP_STRING([--without-libffi],
 540                  [don't use libffi]),
 541   [:],
 542   [with_libffi=${with_libffi_default-yes}])
 543
 544 LIBFFI=
 545 LIBFFIINCS=
 546 if test "$with_libffi" != no; then
 547    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 548    LIBFFI=../libffi/libffi_convenience.la
 549    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 550 fi
 551 AC_SUBST(LIBFFI)
 552 AC_SUBST(LIBFFIINCS)
 553
 554 # See if the user wants to disable JVMPI support.
 555 AC_ARG_ENABLE(jvmpi,
 556   AS_HELP_STRING([--disable-jvmpi],
 557                  [disable JVMPI support]))
 558
 559 if test "$enable_jvmpi" != no; then
 560     AC_DEFINE(ENABLE_JVMPI, 1, [Define if you are using JVMPI.])
 561 fi
 562
 563 # If the target is an eCos system, use the appropriate eCos
 564 # I/O routines.
 565 # FIXME: this should not be a local option but a global target
 566 # system; at present there is no eCos target.
 567 TARGET_ECOS=${PROCESS-"no"}
 568 AC_ARG_WITH(ecos,
 569 [  --with-ecos             enable runtime eCos target support],
 570 TARGET_ECOS="$with_ecos"
 571 )
 572
 573 PLATFORM_INNER_NAT_HDRS=
 574 case "$TARGET_ECOS" in
 575    no) case "$host" in
 576       *mingw*)
 577             PLATFORM=Win32
 578             PLATFORMNET=Win32
 579             PLATFORMH=win32.h
 580         CHECK_FOR_BROKEN_MINGW_LD
 581       ;;
 582       *)
 583             PLATFORM=Posix
 584             PLATFORMNET=Posix
 585             PLATFORMH=posix.h
 586             PLATFORM_INNER_NAT_HDRS='java/lang/ConcreteProcess$$ProcessManager.h'
 587       ;;
 588       esac
 589       ;;
 590    *)
 591       PLATFORM=Ecos
 592       PLATFORMNET=NoNet
 593       AC_DEFINE(ECOS, 1, [Define if you're running eCos.])
 594       PLATFORMH=posix.h
 595       ;;
 596 esac
 597 AC_SUBST(PLATFORM_INNER_NAT_HDRS)
 598 AC_CONFIG_LINKS(include/platform.h:include/$PLATFORMH)
 599
 600 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 601                                       [Define if you have int32_t and uint32_t.]))
 602 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 603                                         [Define if you have int32_t and uint32_t.]))
 604 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 605                                           [Define if you have u_int32_t]))
 606 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 607                                            [Define if you have u_int32_t]))
 608
 609 AM_CONDITIONAL(USING_WIN32_PLATFORM, test "$PLATFORM" = Win32)
 610 AM_CONDITIONAL(USING_POSIX_PLATFORM, test "$PLATFORM" = Posix || test "$PLATFORM" = Ecos)
 611
 612 case "$host" in
 613   *-darwin*) DARWIN_CRT=true ;;
 614   *) DARWIN_CRT=false ;;
 615 esac
 616 AM_CONDITIONAL(USING_DARWIN_CRT, $DARWIN_CRT)
 617
 618 # These may not be defined in a non-ANS conformant embedded system.
 619 # FIXME: Should these case a runtime exception in that case?
 620 AC_EGREP_HEADER(mktime, time.h, AC_DEFINE(HAVE_MKTIME, 1,
 621                                   [Define is you have 'mktime' in <time.h>]))
 622 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME, 1,
 623                                   [Define is you have 'localtime' in <time.h>]))
 624
 625 # Create the subdirectory for natFile.cc, or the attempt
 626 # to create the link will fail.
 627 test -d java || mkdir java
 628 test -d java/io || mkdir java/io
 629 test -d gnu || mkdir gnu
 630 AC_CONFIG_LINKS(java/io/natFile.cc:java/io/natFile${FILE-${PLATFORM}}.cc)
 631
 632 # Likewise for ConcreteProcess.java and natConcreteProcess.cc.
 633 test -d java/lang || mkdir java/lang
 634 AC_CONFIG_LINKS(java/lang/ConcreteProcess.java:java/lang/${PLATFORM}Process.java)
 635 AC_CONFIG_LINKS(java/lang/natConcreteProcess.cc:java/lang/nat${PLATFORM}Process.cc)
 636
 637 # Likewise for natInetAddress.cc and natVMNetworkInterface.cc.
 638 test -d java/net || mkdir java/net
 639 AC_CONFIG_LINKS(java/net/natInetAddress.cc:java/net/natInetAddress${PLATFORMNET}.cc)
 640 AC_CONFIG_LINKS(java/net/natVMNetworkInterface.cc:java/net/natVMNetworkInterface${PLATFORMNET}.cc)
 641
 642 # Likewise for natPlainSocketImpl.cc and natPlainDatagramSocketImpl.cc.
 643 test -d gnu/java || mkdir gnu/java
 644 test -d gnu/java/net || mkdir gnu/java/net
 645 AC_CONFIG_LINKS(gnu/java/net/natPlainSocketImpl.cc:gnu/java/net/natPlainSocketImpl${PLATFORMNET}.cc)
 646 AC_CONFIG_LINKS(gnu/java/net/natPlainDatagramSocketImpl.cc:gnu/java/net/natPlainDatagramSocketImpl${PLATFORMNET}.cc)
 647
 648 # Likewise for natPipeImpl.cc and natSelectorImpl.cc.
 649 test -d gnu/java/nio || mkdir gnu/java/nio
 650 AC_CONFIG_LINKS(gnu/java/nio/natPipeImpl.cc:gnu/java/nio/natPipeImpl${PLATFORM}.cc)
 651 AC_CONFIG_LINKS(gnu/java/nio/natSelectorImpl.cc:gnu/java/nio/natSelectorImpl${PLATFORM}.cc)
 652 test -d gnu/java/nio/channels || mkdir gnu/java/nio/channels
 653 AC_CONFIG_LINKS(gnu/java/nio/channels/natFileChannelImpl.cc:gnu/java/nio/channels/natFileChannel${FILE-${PLATFORM}}.cc)
 654
 655 case "${host}" in
 656     *mingw*)
 657       SYSTEMSPEC="-lgdi32 -lws2_32"
 658       if test "${with_win32_nlsapi}" = "unicows"; then
 659         SYSTEMSPEC="-lunicows $SYSTEMSPEC"
 660       fi
 661     ;;
 662     *)
 663       SYSTEMSPEC=
 664     ;;
 665 esac
 666 AC_SUBST(SYSTEMSPEC)
 667
 668 LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -rpath `${PWDCMD-pwd}`/.libs"
 669 AC_SUBST(LIBGCJTESTSPEC)
 670
 671 AC_ARG_WITH(system-zlib,
 672   AS_HELP_STRING([--with-system-zlib],
 673                  [use installed libz]))
 674 ZLIBSPEC=
 675 AC_SUBST(ZLIBSPEC)
 676 ZLIBTESTSPEC=
 677 AC_SUBST(ZLIBTESTSPEC)
 678
 679 AC_PATH_XTRA
 680
 681 # FIXME: this should be _libs on some hosts.
 682 libsubdir=.libs
 683
 684 # extra LD Flags which are required for targets
 685 case "${host}" in
 686 *-*-darwin[[0-7]].*)
 687     # For now we have to disable it on darwin[8-9] because it slows down
 688     # the linking phase. A possible bug in ld?
 689     # on Darwin -single_module speeds up loading of the dynamic libraries.
 690     extra_ldflags_libjava=-Wl,-single_module
 691     ;;
 692 esac
 693 AC_SUBST(extra_ldflags_libjava)
 694
 695 # Allow the GC to be disabled.  Can be useful when debugging.
 696 AC_MSG_CHECKING([for garbage collector to use])
 697 AC_ARG_ENABLE(java-gc,
 698   AS_HELP_STRING([--enable-java-gc=TYPE],
 699                  [choose garbage collector (default is boehm)]),
 700   [GC=$enableval],
 701   [GC=boehm])
 702 GCLIBS=
 703 GCINCS=
 704 GCDEPS=
 705 GCSPEC=
 706 JC1GCSPEC=
 707 GCTESTSPEC=
 708 case "$GC" in
 709  boehm)
 710     AC_MSG_RESULT(boehm)
 711     GCLIBS=../boehm-gc/libgcjgc_convenience.la
 712     JC1GCSPEC='-fuse-boehm-gc'
 713     GCTESTSPEC="-L`${PWDCMD-pwd}`/../boehm-gc/.libs -rpath `${PWDCMD-pwd}`/../boehm-gc/.libs"
 714     GCINCS='-I$(top_srcdir)/../boehm-gc/include -I../boehm-gc/include'
 715     GCOBJS=boehm.lo
 716     GCHDR=boehm-gc.h
 717     # The POSIX thread support needs to know this.
 718     AC_DEFINE(HAVE_BOEHM_GC, 1, [Define if Boehm GC in use.])
 719     ;;
 720  no)
 721     AC_MSG_RESULT(none)
 722     GCHDR=no-gc.h
 723     ;;
 724  *)
 725     AC_MSG_ERROR([unrecognized collector "$GC"])
 726     ;;
 727 esac
 728 AC_SUBST(GCLIBS)
 729 AC_SUBST(GCINCS)
 730 AC_SUBST(GCDEPS)
 731 AC_SUBST(GCSPEC)
 732 AC_SUBST(JC1GCSPEC)
 733 AC_SUBST(GCTESTSPEC)
 734 AC_CONFIG_LINKS(include/java-gc.h:include/$GCHDR)
 735 AM_CONDITIONAL(USING_BOEHMGC, test "$GC" = boehm)
 736 AM_CONDITIONAL(USING_NOGC, test "$GC" = no)
 737
 738
 739 AC_MSG_CHECKING([for thread model used by GCC])
 740 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 741 AC_MSG_RESULT([$THREADS])
 742
 743 case "$THREADS" in
 744  no | none | single)
 745     THREADS=none
 746     ;;
 747  posix | posix95 | pthreads)
 748     THREADS=posix
 749     case "$host" in
 750      *-*-linux*)
 751         AC_DEFINE(LINUX_THREADS, 1, [Define if using POSIX threads on Linux.])
 752         ;;
 753     esac
 754     ;;
 755  win32)
 756     ;;
 757  decosf1 | irix | mach | os2 | solaris | dce | vxworks)
 758     AC_MSG_ERROR(thread package $THREADS not yet supported)
 759     ;;
 760  *)
 761     AC_MSG_ERROR($THREADS is an unknown thread package)
 762     ;;
 763 esac
 764
 765 THREADCXXFLAGS=
 766 THREADLDFLAGS=
 767 THREADLIBS=
 768 THREADINCS=
 769 THREADDEPS=
 770 THREADH=
 771 THREADSPEC=
 772 THREADSTARTFILESPEC=
 773 case "$THREADS" in
 774  posix)
 775     case "$host" in
 776      *-*-cygwin*)
 777         # Don't set THREADLIBS here.  Cygwin doesn't have -lpthread.
 778         ;;
 779      *-*-freebsd[[1234]]*)
 780         # Before FreeBSD 5, it didn't have -lpthread (or any library which
 781         # merely adds pthread_* functions) but it does have a -pthread switch
 782         # which is required at link-time to select -lc_r *instead* of -lc.
 783         THREADLDFLAGS=-pthread
 784         # Don't set THREADSPEC here as might be expected since -pthread is
 785         # not processed when found within a spec file, it must come from
 786         # the command line.  For now, the user must provide the -pthread
 787         # switch to link code compiled with gcj.  In future, consider adding
 788         # support for weak references to pthread_* functions ala gthr.h API.
 789         THREADSPEC='%{!pthread: %{!shared: %eUnder this configuration, the user must provide -pthread when linking.}}'
 790         ;;
 791      *-*-freebsd*)
 792         # FreeBSD >=5.3 implements a model much closer to other modern UNIX
 793         # systems which support threads and -lpthread.
 794         THREADLDFLAGS=-pthread
 795         THREADSPEC=-lpthread
 796         ;;
 797      alpha*-dec-osf* | hppa*-hp-hpux*)
 798         THREADCXXFLAGS=-pthread
 799         # boehm-gc needs some functions from librt, so link that too.
 800         THREADLIBS='-lpthread -lrt'
 801         THREADSPEC='-lpthread -lrt'
 802         ;;
 803      *)
 804         THREADLIBS=-lpthread
 805         THREADSPEC=-lpthread
 806         ;;
 807     esac
 808     THREADH=posix-threads.h
 809     # MIT pthreads doesn't seem to have the mutexattr functions.
 810     # But for now we don't check for it.  We just assume you aren't
 811     # using MIT pthreads.
 812     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
 813
 814     # If we're using the Boehm GC, then we happen to know that it
 815     # defines _REENTRANT, so we don't bother.  Eww.
 816     if test "$GC" != boehm; then
 817        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 818     fi
 819     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
 820     ;;
 821
 822  win32)
 823     THREADH=win32-threads.h
 824     THREADCXXFLAGS=-mthreads
 825     # We need thread-safe exception handling so _CRT_MT should be set to 1.
 826     # But we do not want the executables created to be dependent on
 827     # mingwm10.dll which provides a __mingwthr_key_dtor() that cleans up
 828     # exception handling contexts.  The following kludge achieves this effect
 829     # and causes a dummy __mingwthr_key_dtor() to be linked in from
 830     # libmingw32.a.  This causes a memory leak of about 24 bytes per thread.
 831     # A workaround is to explicitly use -mthreads while linking Java programs.
 832     # See PR libgcj/28263.
 833     #
 834     # FIXME: In Java we are able to detect thread death at the end of
 835     # Thread.run() so we should be able to clean up the exception handling
 836     # contexts ourselves.
 837     THREADSTARTFILESPEC='crtmt%O%s'
 838     ;;
 839
 840  none)
 841     THREADH=no-threads.h
 842     ;;
 843 esac
 844 AC_CONFIG_LINKS(include/java-threads.h:include/$THREADH)
 845 AC_SUBST(THREADLIBS)
 846 AC_SUBST(THREADINCS)
 847 AC_SUBST(THREADDEPS)
 848 AC_SUBST(THREADSPEC)
 849 AC_SUBST(THREADSTARTFILESPEC)
 850 AC_SUBST(THREADLDFLAGS)
 851 AC_SUBST(THREADCXXFLAGS)
 852 AM_CONDITIONAL(USING_POSIX_THREADS, test "$THREADS" = posix)
 853 AM_CONDITIONAL(USING_WIN32_THREADS, test "$THREADS" = win32)
 854 AM_CONDITIONAL(USING_NO_THREADS, test "$THREADS" = none)
 855 AM_CONDITIONAL(USE_LIBGCJ_BC, test "$use_libgcj_bc" = yes)
 856
 857 if test -d sysdep; then true; else mkdir sysdep; fi
 858 AC_CONFIG_LINKS(sysdep/locks.h:sysdep/$sysdeps_dir/locks.h)
 859 AC_CONFIG_LINKS(sysdep/backtrace.h:$fallback_backtrace_h)
 860 AC_CONFIG_LINKS(sysdep/descriptor.h:$descriptor_h)
 861
 862 LIBGCJ_SPEC="%{s-bc-abi:} -lgcj"
 863 if test "$use_libgcj_bc" = yes; then
 864   LIBGCJ_SPEC="%{s-bc-abi:-lgcj_bc;:-lgcj}"
 865 fi
 866 AC_SUBST(LIBGCJ_SPEC)
 867
 868 HASH_SYNC_SPEC=
 869 # Hash synchronization is only useful with posix threads right now.
 870 if test "$enable_hash_synchronization" = yes && test "$THREADS" != "none"; then
 871    HASH_SYNC_SPEC=-fhash-synchronization
 872    AC_DEFINE(JV_HASH_SYNCHRONIZATION, 1, [Define if hash synchronization is in use])
 873 fi
 874 AC_SUBST(HASH_SYNC_SPEC)
 875
 876 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
 877
 878 # We're in the tree with gcc, and need to include some of its headers.
 879 GCC_UNWIND_INCLUDE='-I$(multi_basedir)/./libjava/../gcc'
 880
 881 if test "x${with_newlib}" = "xyes"; then
 882    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
 883    # may not work correctly, because the compiler may not be able to
 884    # link executables.
 885
 886    # We assume newlib.  This lets us hard-code the functions we know
 887    # we'll have.
 888    AC_DEFINE(HAVE_MEMMOVE, 1, [Define if you have memmove.])
 889    AC_DEFINE(HAVE_MEMCPY, 1, [Define if you have memcpy.])
 890    AC_DEFINE(HAVE_STRERROR, 1, [Define if you have strerror.])
 891    AC_DEFINE(HAVE_TIME, 1, [Define if you have time.])
 892    AC_DEFINE(HAVE_GMTIME_R, 1, [Define if you have the 'gmtime_r' function])
 893    AC_DEFINE(HAVE_LOCALTIME_R, 1, [Define if you have the 'localtime_r' function.])
 894    AC_DEFINE(HAVE_USLEEP_DECL, 1, [Define if usleep is declared in <unistd.h>.])
 895    # This is only for POSIX threads.
 896    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
 897    # We also assume we are using gcc, which provides alloca.
 898    AC_DEFINE(HAVE_ALLOCA)
 899
 900    # Assume we do not have getuid and friends.
 901    AC_DEFINE(NO_GETUID, 1, [Define if getuid() and friends are missing.])
 902    PLATFORMNET=NoNet
 903 else
 904    AC_CHECK_FUNCS([strerror ioctl select fstat open fsync sleep opendir \
 905                    gmtime_r localtime_r readdir_r getpwuid_r getcwd \
 906                    access stat lstat mkdir rename rmdir unlink utime chmod readlink \
 907                    nl_langinfo setlocale \
 908                    inet_pton uname inet_ntoa \
 909                    fork execvp getrlimit pipe sigaction ftruncate mmap \
 910                    getifaddrs])
 911    AC_CHECK_FUNCS(inet_aton inet_addr, break)
 912    AC_CHECK_HEADERS(execinfo.h unistd.h dlfcn.h sys/resource.h)
 913    # Do an additional check on dld, HP-UX for example has dladdr in libdld.sl
 914    AC_CHECK_LIB(dl, dladdr, [
 915        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])], [
 916        AC_CHECK_LIB(dld, dladdr, [
 917        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])])])
 918
 919    if test x"$cross_compiling" = x"no"; then
 920      AC_CHECK_FILES(/proc/self/exe, [
 921        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])])
 922    else
 923      case $host in
 924      *-linux*)
 925        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])
 926        ;;
 927      esac
 928    fi
 929
 930    AM_ICONV
 931    AM_LC_MESSAGES
 932    AC_STRUCT_TIMEZONE
 933
 934    AC_CHECK_FUNCS(gethostbyname_r, [
 935      AC_DEFINE(HAVE_GETHOSTBYNAME_R, 1,
 936        [Define if you have the 'gethostbyname_r' function.])
 937      # There are two different kinds of gethostbyname_r.
 938      # We look for the one that returns `int'.
 939      # Hopefully this check is robust enough.
 940      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
 941        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT, 1, [Define if gethostbyname_r returns 'int'.])])
 942
 943      case " $GCINCS " in
 944      *" -D_REENTRANT "*) ;;
 945      *)
 946         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
 947         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
 948         [libjava_cv_gethostbyname_r_needs_reentrant],
 949         [ AC_LANG_PUSH(C++)
 950           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
 951             [[gethostbyname_r("", 0, 0);]])],
 952             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
 953                 CPPFLAGS_SAVE="$CPPFLAGS"
 954                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
 955                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]], [[gethostbyname_r("", 0, 0);]])],
 956                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
 957                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
 958                 CPPFLAGS="$CPPFLAGS_SAVE"
 959           ])
 960           AC_LANG_POP(C++)
 961         ])
 962         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
 963           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 964         fi
 965      ;;
 966      esac
 967
 968      AC_CACHE_CHECK([for struct hostent_data],
 969         [libjava_cv_struct_hostent_data], [dnl
 970         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 971 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
 972 # define _REENTRANT 1
 973 #endif
 974 #include <netdb.h>]], [[struct hostent_data data;]])],
 975           [libjava_cv_struct_hostent_data=yes],
 976           [libjava_cv_struct_hostent_data=no])])
 977      if test "x$libjava_cv_struct_hostent_data" = xyes; then
 978        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
 979          [Define if struct hostent_data is defined in netdb.h])
 980      fi
 981    ])
 982
 983    # FIXME: libjava source code expects to find a prototype for
 984    # gethostbyaddr_r in netdb.h.  The outer check ensures that
 985    # HAVE_GETHOSTBYADDR_R will not be defined if the prototype fails
 986    # to exist where expected.  (The root issue: AC_CHECK_FUNCS assumes C
 987    # linkage check is enough, yet C++ code requires proper prototypes.)
 988    AC_EGREP_HEADER(gethostbyaddr_r, netdb.h, [
 989    AC_CHECK_FUNCS(gethostbyaddr_r, [
 990      AC_DEFINE(HAVE_GETHOSTBYADDR_R, 1,
 991        [Define if you have the 'gethostbyaddr_r' function.])
 992      # There are two different kinds of gethostbyaddr_r.
 993      # We look for the one that returns `int'.
 994      # Hopefully this check is robust enough.
 995      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
 996        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT, 1,
 997          [Define if gethostbyaddr_r returns 'int'.])])])])
 998
 999    AC_CHECK_FUNCS(gethostname, [
1000      AC_DEFINE(HAVE_GETHOSTNAME, 1,
1001        [Define if you have the 'gethostname' function.])
1002      AC_EGREP_HEADER(gethostname, unistd.h, [
1003        AC_DEFINE(HAVE_GETHOSTNAME_DECL, 1,
1004          [Define if gethostname is declared in <unistd.h>.])])])
1005
1006    AC_CHECK_FUNCS(usleep, [
1007      AC_EGREP_HEADER(usleep, unistd.h, [
1008        AC_DEFINE(HAVE_USLEEP_DECL, 1,
1009           [Define if usleep is declared in <unistd.h>.])])])
1010
1011    # Look for these functions in the thread library, but only bother
1012    # if using POSIX threads.
1013    if test "$THREADS" = posix; then
1014       save_LIBS="$LIBS"
1015       LIBS="$LIBS $THREADLIBS"
1016       # Some POSIX thread systems don't have pthread_mutexattr_settype.
1017       # E.g., Solaris.
1018       AC_CHECK_FUNCS(pthread_mutexattr_settype pthread_mutexattr_setkind_np)
1019
1020       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
1021       # Solaris 7 the name librt is preferred.
1022       AC_CHECK_FUNCS(sched_yield, , [
1023         AC_CHECK_LIB(rt, sched_yield, [
1024           AC_DEFINE(HAVE_SCHED_YIELD)
1025           THREADLIBS="$THREADLIBS -lrt"
1026           THREADSPEC="$THREADSPEC -lrt"], [
1027           AC_CHECK_LIB(posix4, sched_yield, [
1028             AC_DEFINE(HAVE_SCHED_YIELD)
1029             THREADLIBS="$THREADLIBS -lposix4"
1030             THREADSPEC="$THREADSPEC -lposix4"])])])
1031
1032       AC_CHECK_LIB(rt, clock_gettime, [
1033          AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Define if you have clock_gettime()])
1034          case "$THREADSPEC" in
1035            *-lrt*) ;;
1036            *)
1037              THREADSPEC="$THREADSPEC -lrt"
1038              THREADLIBS="$THREADLIBS -lrt"
1039              ;;
1040          esac])
1041
1042       LIBS="$save_LIBS"
1043
1044       # We can save a little space at runtime if the mutex has m_count
1045       # or __m_count.  This is a nice hack for Linux.
1046       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1047           extern pthread_mutex_t *mutex; int q = mutex->m_count;
1048         ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT, 1,
1049              [Define if pthread_mutex_t has m_count member.]), [
1050         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1051             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
1052           ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT, 1,
1053             [Define if pthread_mutex_t has __m_count member.]))])
1054    fi
1055
1056    # We require a way to get the time.
1057    time_found=no
1058    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
1059    if test "$time_found" = no; then
1060       AC_MSG_ERROR([no function found to get the time])
1061    fi
1062
1063    AC_CHECK_FUNCS(memmove)
1064
1065    # We require memcpy.
1066    memcpy_found=no
1067    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
1068    if test "$memcpy_found" = no; then
1069       AC_MSG_ERROR([memcpy is required])
1070    fi
1071    # Do an additional check on dld, HP-UX for example has dlopen in libdld.sl
1072    AC_CHECK_LIB(dl, dlopen, [
1073        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])], [
1074        AC_CHECK_LIB(dld, dlopen, [
1075        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])])])
1076
1077    # Some library-finding code we stole from Tcl.
1078    #--------------------------------------------------------------------
1079    #    Check for the existence of the -lsocket and -lnsl libraries.
1080    #    The order here is important, so that they end up in the right
1081    #    order in the command line generated by make.  Here are some
1082    #    special considerations:
1083    #    1. Use "connect" and "accept" to check for -lsocket, and
1084    #       "gethostbyname" to check for -lnsl.
1085    #    2. Use each function name only once:  can't redo a check because
1086    #       autoconf caches the results of the last check and won't redo it.
1087    #    3. Use -lnsl and -lsocket only if they supply procedures that
1088    #       aren't already present in the normal libraries.  This is because
1089    #       IRIX 5.2 has libraries, but they aren't needed and they're
1090    #       bogus:  they goof up name resolution if used.
1091    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
1092    #       To get around this problem, check for both libraries together
1093    #       if -lsocket doesn't work by itself.
1094    #--------------------------------------------------------------------
1095
1096    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
1097     [gcj_cv_lib_sockets=
1098      gcj_checkBoth=0
1099      unset ac_cv_func_connect
1100      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
1101      if test "$gcj_checkSocket" = 1; then
1102          unset ac_cv_func_connect
1103          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
1104                       gcj_checkBoth=1)
1105      fi
1106      if test "$gcj_checkBoth" = 1; then
1107          gcj_oldLibs=$LIBS
1108          LIBS="$LIBS -lsocket -lnsl"
1109          unset ac_cv_func_accept
1110          AC_CHECK_FUNC(accept,
1111                        [gcj_checkNsl=0
1112                         gcj_cv_lib_sockets="-lsocket -lnsl"])
1113          unset ac_cv_func_accept
1114          LIBS=$gcj_oldLibs
1115      fi
1116      unset ac_cv_func_gethostbyname
1117      gcj_oldLibs=$LIBS
1118      LIBS="$LIBS $gcj_cv_lib_sockets"
1119      AC_CHECK_FUNC(gethostbyname, ,
1120                    [AC_CHECK_LIB(nsl, main,
1121                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
1122      unset ac_cv_func_gethostbyname
1123      LIBS=$gcj_oldLIBS
1124    ])
1125    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
1126
1127    if test "$with_system_zlib" = yes; then
1128       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=)
1129    fi
1130
1131    # Test for Gtk stuff, if asked for.
1132    if test "$use_gtk_awt" = yes; then
1133       PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.4)
1134       AC_SUBST(GTK_CFLAGS)
1135       AC_SUBST(GTK_LIBS)
1136
1137       PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.4 gthread-2.0 >= 2.4)
1138       AC_SUBST(GLIB_CFLAGS)
1139       AC_SUBST(GLIB_LIBS)
1140
1141       PKG_CHECK_MODULES(LIBART, libart-2.0 >= 2.1)
1142       AC_SUBST(LIBART_CFLAGS)
1143       AC_SUBST(LIBART_LIBS)
1144
1145       # We require the XTest Extension to support java.awt.Robot.
1146       AC_CHECK_LIB([Xtst], [XTestQueryExtension], [true],
1147                    [AC_MSG_ERROR([libXtst not found, required by java.awt.Robot])],
1148                    [${X_LIBS}])
1149    fi
1150
1151    # On Solaris, and maybe other architectures, the Boehm collector
1152    # requires -ldl.
1153    if test "$GC" = boehm; then
1154       AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
1155    fi
1156 fi
1157
1158 # Use a semicolon as CLASSPATH separator for MinGW, otherwise a colon.
1159 case $build in
1160     *-mingw32) CLASSPATH_SEPARATOR=';' ;;
1161     *)         CLASSPATH_SEPARATOR=':' ;;
1162 esac
1163 AC_SUBST(CLASSPATH_SEPARATOR)
1164
1165 # We must search the source tree for java.lang, since we still don't
1166 # have libgcj.jar nor java/lang/*.class
1167 GCJ_SAVE_CPPFLAGS=$CPPFLAGS
1168 CPPFLAGS="$CPPFLAGS -I`${PWDCMD-pwd}` -I`cd $srcdir && ${PWDCMD-pwd}`"
1169
1170 # Since some classes depend on this one, we need its source available
1171 # before we can do any GCJ compilation test :-(
1172 if test ! -f gnu/classpath/Configuration.java; then
1173   test -d gnu || mkdir gnu
1174   test -d gnu/classpath || mkdir gnu/classpath
1175   # Note that it is not crucial that all the values here be correct.
1176   sed -e "s,@prefix@,$prefix," \
1177       -e "s,@VERSION@,$VERSION," \
1178       -e "s,@LIBDEBUG@,false," \
1179       -e "s,@INIT_LOAD_LIBRARY@,false," \
1180       -e "s,@@,$LIBGCJDEBUG," \
1181       -e "s,@default_toolkit@,$TOOLKIT," \
1182       -e "s,@JAVA_LANG_SYSTEM_EXPLICIT_INITIALIZATION@,false," \
1183       -e "s,@GTK_CAIRO_ENABLED@,false," \
1184         < $srcdir/classpath/gnu/classpath/Configuration.java.in \
1185         > gnu/classpath/Configuration.java
1186   # We do not want to redirect the output of the grep below to /dev/null,
1187   # but we add /dev/null to the input list so that grep will print the
1188   # filename of Configuration.java in case it finds any matches.
1189   if grep '@.*@' gnu/classpath/Configuration.java /dev/null; then
1190     AC_MSG_ERROR([configure.ac is missing the substitutions above])
1191   fi
1192 fi
1193
1194 LT_AC_PROG_GCJ
1195
1196 # Now remove it.
1197 rm -f gnu/classpath/Configuration.java
1198
1199 CPPFLAGS=$GCJ_SAVE_CPPFLAGS
1200
1201 AC_CHECK_SIZEOF(void *)
1202
1203 AC_C_BIGENDIAN
1204
1205 ZLIBS=
1206 SYS_ZLIBS=
1207 ZINCS=
1208
1209 if test -z "$ZLIBSPEC"; then
1210    # Use zlib from the GCC tree.
1211    ZINCS='-I$(top_srcdir)/../zlib'
1212    ZLIBS=../zlib/libzgcj_convenience.la
1213 else
1214    # System's zlib.
1215    SYS_ZLIBS="$ZLIBSPEC"
1216 fi
1217 AC_SUBST(ZLIBS)
1218 AC_SUBST(SYS_ZLIBS)
1219 AC_SUBST(ZINCS)
1220 AC_SUBST(DIVIDESPEC)
1221 AC_SUBST(CHECKREFSPEC)
1222 AC_SUBST(EXCEPTIONSPEC)
1223 AC_SUBST(BACKTRACESPEC)
1224 AC_SUBST(IEEESPEC)
1225
1226 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes)
1227 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
1228 AC_SUBST(GCC_UNWIND_INCLUDE)
1229
1230 # Process the option "--enable-version-specific-runtime-libs"
1231 # Calculate toolexeclibdir
1232 case ${version_specific_libs} in
1233   yes)
1234     # Need the gcc compiler version to know where to install libraries
1235     # and header files if --enable-version-specific-runtime-libs option
1236     # is selected.
1237     includedir='$(libdir)/gcc/$(target_noncanonical)/$(gcc_version)/include/'
1238     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
1239     toolexecmainlibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
1240     toolexeclibdir=$toolexecmainlibdir
1241     ;;
1242   no)
1243     if test -n "$with_cross_host" &&
1244        test x"$with_cross_host" != x"no"; then
1245       # Install a library built with a cross compiler in tooldir, not libdir.
1246       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
1247       toolexecmainlibdir='$(toolexecdir)/lib'
1248     else
1249       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
1250       toolexecmainlibdir='$(libdir)'
1251     fi
1252     multi_os_directory=`$CC -print-multi-os-directory`
1253     case $multi_os_directory in
1254       .) toolexeclibdir=$toolexecmainlibdir ;; # Avoid trailing /.
1255       *) toolexeclibdir=$toolexecmainlibdir/$multi_os_directory ;;
1256     esac
1257     ;;
1258 esac
1259 AC_SUBST(toolexecdir)
1260 AC_SUBST(toolexecmainlibdir)
1261 AC_SUBST(toolexeclibdir)
1262
1263 # Determine where the standard .db file and GNU Classpath JNI
1264 # libraries are found.
1265 multi_os_directory=`$CC -print-multi-os-directory`
1266 case $multi_os_directory in
1267   .)
1268    dbexecdir='$(libdir)/gcj-$(gcc_version)' # Avoid /.
1269    ;;
1270   *)
1271    dbexecdir='$(libdir)/'$multi_os_directory'/gcj-$(gcc_version)'
1272    ;;
1273 esac
1274 AC_SUBST(dbexecdir)
1275
1276 # Determine gcj version number.
1277 gcjversion=`$GCJ -v 2>&1 | sed -n 's/^.*version \([[^ ]]*\).*$/\1/p'`
1278 GCJVERSION=$gcjversion
1279 AC_SUBST(GCJVERSION)
1280 AC_DEFINE_UNQUOTED(GCJVERSION, "$GCJVERSION", [Short GCJ version ID])
1281
1282 AC_DEFINE(JV_VERSION, "1.4.2", [Compatibility version string])
1283 AC_DEFINE(JV_API_VERSION, "1.4", [API compatibility version string])
1284
1285 TL_AC_GXX_INCLUDE_DIR
1286
1287 # We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
1288 # On that system, sys/ioctl.h will not include sys/filio.h unless
1289 # BSD_COMP is defined; just including sys/filio.h is simpler.
1290 # We avoid AC_HEADER_DIRENT since we really only care about dirent.h
1291 # for now.  If you change this, you also must update natFile.cc.
1292 AC_CHECK_HEADERS([unistd.h bstring.h sys/time.h sys/types.h fcntl.h \
1293                   sys/ioctl.h sys/filio.h sys/stat.h sys/select.h \
1294                   sys/socket.h netinet/in.h arpa/inet.h netdb.h net/if.h \
1295                   pwd.h sys/config.h stdint.h langinfo.h locale.h \
1296                   dirent.h sys/rw_lock.h ifaddrs.h])
1297 AC_CHECK_HEADERS(inttypes.h, [
1298     AC_DEFINE(HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1299     AC_DEFINE(JV_HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1300 ])
1301 AC_HEADER_SYS_WAIT
1302
1303 AC_CHECK_TYPE([ssize_t], [int])
1304
1305 AC_MSG_CHECKING([for in_addr_t])
1306 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1307 #if STDC_HEADERS
1308 #include <stdlib.h>
1309 #include <stddef.h>
1310 #endif
1311 #if HAVE_NETINET_IN_H
1312 #include <netinet/in.h>
1313 #endif]], [[in_addr_t foo;]])],
1314   [AC_DEFINE(HAVE_IN_ADDR_T, 1,
1315      [Define to 1 if 'in_addr_t' is defined in sys/types.h or netinet/in.h.])
1316    AC_MSG_RESULT(yes)],
1317   [AC_MSG_RESULT(no)])
1318
1319 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
1320 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ip_mreq mreq;]])],
1321   [AC_DEFINE(HAVE_STRUCT_IP_MREQ, 1,
1322      [Define if struct ip_mreq is defined in netinet/in.h.])
1323    AC_MSG_RESULT(yes)],
1324   [AC_MSG_RESULT(no)])
1325
1326 AC_MSG_CHECKING([whether struct ipv6_mreq is in netinet/in.h])
1327 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ipv6_mreq mreq6;]])],
1328   [AC_DEFINE(HAVE_STRUCT_IPV6_MREQ, 1,
1329      [Define if struct ipv6_mreq is defined in netinet/in.h.])
1330    AC_MSG_RESULT(yes)],
1331   [AC_MSG_RESULT(no)])
1332
1333 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
1334 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct sockaddr_in6 addr6;]])],
1335   [AC_DEFINE(HAVE_INET6, 1,
1336      [Define if inet6 structures are defined in netinet/in.h.])
1337    AC_MSG_RESULT(yes)],
1338   [AC_MSG_RESULT(no)])
1339
1340 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
1341 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _POSIX_PII_SOCKET
1342 #include <sys/types.h>
1343 #include <sys/socket.h>]], [[socklen_t x = 5;]])],
1344   [AC_DEFINE(HAVE_SOCKLEN_T, 1, [Define it socklen_t typedef is in sys/socket.h.])
1345    AC_MSG_RESULT(yes)],
1346   [AC_MSG_RESULT(no)])
1347
1348 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
1349 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[struct tm tim; tim.tm_gmtoff = 0;]])],
1350   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF, 1, [Define if struct tm has tm_gmtoff field.])
1351    AC_MSG_RESULT(yes)],
1352   [AC_MSG_RESULT(no)
1353    AC_MSG_CHECKING([for global timezone variable])
1354    dnl FIXME: we don't want a link check here because that won't work
1355    dnl when cross-compiling.  So instead we make an assumption that
1356    dnl the header file will mention timezone if it exists.
1357    dnl Don't find the win32 function timezone
1358    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[void i(){long z2 = 2*timezone;}]])],
1359      [AC_DEFINE(HAVE_TIMEZONE, 1, [Define if global 'timezone' exists.])
1360       AC_MSG_RESULT(yes)],
1361      [AC_MSG_RESULT(no)
1362        AC_MSG_CHECKING([for global _timezone variable])
1363        dnl FIXME: As above, don't want link check
1364        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[long z2 = _timezone;]])],
1365          [AC_DEFINE(HAVE_UNDERSCORE_TIMEZONE, 1,
1366             [Define if your platform has the global _timezone variable.])
1367           AC_MSG_RESULT(yes)],
1368           [AC_MSG_RESULT(no)])])])
1369
1370 AC_FUNC_ALLOCA
1371
1372 AC_CHECK_PROGS(PERL, perl, false)
1373
1374 SYSDEP_SOURCES=
1375 SIGNAL_HANDLER_AUX=
1376
1377 case "${host}" in
1378  i?86-*-linux*)
1379     SIGNAL_HANDLER=include/i386-signal.h
1380     ;;
1381  sparc*-sun-solaris*)
1382     SIGNAL_HANDLER=include/sparc-signal.h
1383     ;;
1384 # ia64-*)
1385 #    SYSDEP_SOURCES=sysdep/ia64.c
1386 #    test -d sysdep || mkdir sysdep
1387 #    ;;
1388  hppa*-*-linux*)
1389     SIGNAL_HANDLER=include/pa-signal.h
1390     ;;
1391  hppa*-hp-hpux*)
1392     SIGNAL_HANDLER=include/hppa-signal.h
1393     ;;
1394  ia64-*-linux*)
1395     SIGNAL_HANDLER=include/dwarf2-signal.h
1396     ;;
1397  powerpc*-*-linux*)
1398     SIGNAL_HANDLER=include/powerpc-signal.h
1399     ;;
1400  alpha*-*-linux*)
1401     SIGNAL_HANDLER=include/dwarf2-signal.h
1402     ;;
1403  s390*-*-linux*)
1404     SIGNAL_HANDLER=include/s390-signal.h
1405     ;;
1406  x86_64*-*-linux*)
1407     SIGNAL_HANDLER=include/x86_64-signal.h
1408     SIGNAL_HANDLER_AUX=include/i386-signal.h
1409     ;;
1410  sparc*-*-linux*)
1411     SIGNAL_HANDLER=include/dwarf2-signal.h
1412     ;;
1413  sh*-*-linux*)
1414     SIGNAL_HANDLER=include/sh-signal.h
1415     ;;
1416  *mingw*)
1417     SIGNAL_HANDLER=include/win32-signal.h
1418     ;;
1419  mips*-*-linux*)
1420     SIGNAL_HANDLER=include/mips-signal.h
1421     ;;
1422  powerpc*-*-darwin*)
1423     SIGNAL_HANDLER=include/darwin-signal.h
1424     ;;
1425  *)
1426     SIGNAL_HANDLER=include/default-signal.h
1427     ;;
1428 esac
1429
1430 # If we're using sjlj exceptions, forget what we just learned.
1431 if test "$enable_sjlj_exceptions" = yes; then
1432    SIGNAL_HANDLER=include/default-signal.h
1433    SIGNAL_HANDLER_AUX=
1434 fi
1435
1436 AC_SUBST(SYSDEP_SOURCES)
1437
1438 if test -z "$SIGNAL_HANDLER_AUX"; then
1439   SIGNAL_HANDLER_AUX=$SIGNAL_HANDLER
1440 fi
1441
1442 AC_CONFIG_LINKS(include/java-signal.h:$SIGNAL_HANDLER
1443                 include/java-signal-aux.h:$SIGNAL_HANDLER_AUX)
1444
1445 if test "${multilib}" = "yes"; then
1446   multilib_arg="--enable-multilib"
1447 else
1448   multilib_arg=
1449 fi
1450
1451 # See if we support thread-local storage.
1452 GCC_CHECK_TLS
1453
1454 # For _Unwind_GetIPInfo.
1455 GCC_CHECK_UNWIND_GETIPINFO
1456
1457 # Check if linker supports static linking on a per library basis
1458 LD_START_STATIC_SPEC=
1459 LD_FINISH_STATIC_SPEC=
1460 if $LD --help 2>&1 | grep -q -e -call_shared ; then
1461   if $LD --help 2>&1 | grep -q -e -non_shared ; then
1462     LD_START_STATIC_SPEC='%{static-libgcj:-non_shared}'
1463     LD_FINISH_STATIC_SPEC='%{static-libgcj:-call_shared}'
1464   fi
1465 fi
1466 AC_SUBST(LD_START_STATIC_SPEC)
1467 AC_SUBST(LD_FINISH_STATIC_SPEC)
1468
1469 here=`${PWDCMD-pwd}`
1470 AC_SUBST(here)
1471
1472 # We get this from the environment.
1473 AC_SUBST(GCJFLAGS)
1474
1475 AC_CONFIG_FILES([
1476 Makefile
1477 libgcj.pc
1478 libgcj.spec
1479 libgcj-test.spec
1480 gcj/Makefile
1481 include/Makefile
1482 testsuite/Makefile
1483 ])
1484
1485 AC_CONFIG_FILES([scripts/jar], [chmod +x scripts/jar])
1486
1487 AC_CONFIG_COMMANDS([default],
1488 [# Only add multilib support code if we just rebuilt top-level Makefile.
1489 case " $CONFIG_FILES " in
1490  *" Makefile "*)
1491    LD="${ORIGINAL_LD_FOR_MULTILIBS}"
1492    ac_file=Makefile . ${multi_basedir}/./libjava/../config-ml.in
1493    ;;
1494 esac
1495 for ac_multi_file in $CONFIG_FILES; do
1496   case $ac_multi_file in
1497   */Makefile)
1498     grep "^MULTI[[^ ]]* =" Makefile >> "$ac_multi_file" ;;
1499   esac
1500 done
1501 ],
1502 srcdir=${srcdir}
1503 host=${host}
1504 target=${target}
1505 with_multisubdir=${with_multisubdir}
1506 ac_configure_args="${multilib_arg} ${ac_configure_args}"
1507 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
1508 multi_basedir=${multi_basedir}
1509 CC="${CC}"
1510 CXX="${CXX}"
1511 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
1512 )
1513
1514 AC_OUTPUT