zlib/configure.ac

   1 dnl Process this with autoconf to create configure
   2
   3 AC_INIT([zlib], [1.1.4])
   4 AC_CONFIG_SRCDIR([zlib.h])
   5
   6 if test -n "${with_target_subdir}"; then
   7   AM_ENABLE_MULTILIB(, ..)
   8 fi
   9
  10 AC_CANONICAL_SYSTEM
  11
  12 # This works around an automake problem.
  13 mkinstalldirs="`cd $ac_aux_dir && ${PWDCMD-pwd}`/mkinstalldirs"
  14 AC_SUBST(mkinstalldirs)
  15
  16 AM_INIT_AUTOMAKE
  17
  18 AM_MAINTAINER_MODE
  19
  20 dnl We use these options to decide which functions to include.
  21 AC_ARG_WITH(target-subdir,
  22 [  --with-target-subdir=SUBDIR
  23                           configuring in a subdirectory])
  24
  25 if test -z "$with_target_subdir" || test "$with_target_subdir" = "."; then
  26    COMPPATH=.
  27 else
  28    COMPPATH=..
  29 fi
  30 AC_SUBST(COMPPATH)
  31
  32 AC_ARG_WITH(cross-host,
  33 [  --with-cross-host=HOST  configuring with a cross compiler])
  34
  35 dnl Default to --enable-multilib
  36 AC_ARG_ENABLE(multilib,
  37 [  --enable-multilib       build many library versions (default)],
  38 [case "${enableval}" in
  39   yes) multilib=yes ;;
  40   no)  multilib=no ;;
  41   *)   AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
  42  esac], [test -z "$with_target_subdir" && multilib=no || multilib=yes])dnl
  43
  44 AC_ARG_WITH(system-zlib,
  45 [  --with-system-zlib      use installed libz])
  46
  47 # Make sure we don't test executables when making cross-tools.
  48 GCC_NO_EXECUTABLES
  49
  50 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
  51 # We must force CC to /not/ be precious variables; otherwise
  52 # the wrong, non-multilib-adjusted value will be used in multilibs.
  53 # As a side effect, we have to subst CFLAGS ourselves.
  54
  55 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
  56 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  57 AC_PROG_CC
  58 m4_rename_force([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  59
  60 AC_SUBST(CFLAGS)
  61
  62 AC_PROG_LIBTOOL
  63
  64 # Find CPP now so that any conditional tests below won't do it and
  65 # thereby make the resulting definitions conditional.
  66 AC_PROG_CPP
  67
  68 if test -n "$with_cross_host"; then
  69    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
  70    # may not work correctly, because the compiler may not be able to
  71    # link executables.
  72
  73    # We assume newlib.  This lets us hard-code the functions we know
  74    # we'll have.
  75    AC_DEFINE(HAVE_MEMCPY)
  76    AC_DEFINE(HAVE_STRERROR)
  77 else
  78    AC_FUNC_MMAP
  79    AC_CHECK_FUNCS(memcpy strerror)
  80 fi
  81
  82 AC_CHECK_HEADERS(unistd.h)
  83
  84 if test -n "$with_cross_host" &&
  85    test x"$with_cross_host" != x"no"; then
  86   toolexecdir='$(exec_prefix)/$(target_alias)'
  87   toolexeclibdir='$(toolexecdir)/lib'
  88 else
  89   toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
  90   toolexeclibdir='$(libdir)'
  91 fi
  92 if test "$GCC" = yes && $CC -print-multi-os-directory > /dev/null 2>&1; then
  93   multiosdir=/`$CC -print-multi-os-directory`
  94   case $multiosdir in
  95     /.) multiosdir= ;; # Avoid trailing /.
  96   esac
  97 else
  98   multiosdir=
  99 fi
 100 toolexeclibdir=${toolexeclibdir}${multiosdir}
 101 AC_SUBST(toolexecdir)
 102 AC_SUBST(toolexeclibdir)
 103
 104 AM_CONDITIONAL(TARGET_LIBRARY, test -n "$with_target_subdir")
 105
 106 if test "${multilib}" = "yes"; then
 107   multilib_arg="--enable-multilib"
 108 else
 109   multilib_arg=
 110 fi
 111
 112 AC_ARG_ENABLE(host-shared,
 113 [AS_HELP_STRING([--enable-host-shared],
 114                 [build host code as shared libraries])],
 115 [PICFLAG=-fPIC], [PICFLAG=])
 116 AC_SUBST(PICFLAG)
 117
 118 AC_CONFIG_FILES([Makefile])
 119 AC_OUTPUT