libffi/configure.ac

   1 dnl Process this with autoconf to create configure
   2
   3
   4 AC_INIT([libffi], [3.99999], [http://github.com/atgreen/libffi/issues])
   5 AC_CONFIG_HEADERS([fficonfig.h])
   6
   7 AM_ENABLE_MULTILIB(, ..)
   8
   9 AC_CANONICAL_SYSTEM
  10 target_alias=${target_alias-$host_alias}
  11
  12 AM_INIT_AUTOMAKE([no-dist])
  13
  14 # See if makeinfo has been installed and is modern enough
  15 # that we can use it.
  16 ACX_CHECK_PROG_VER([MAKEINFO], [makeinfo], [--version],
  17                    [GNU texinfo.* \([0-9][0-9.]*\)],
  18                    [4.[4-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
  19 AM_CONDITIONAL(BUILD_INFO, test $gcc_cv_prog_makeinfo_modern = "yes")
  20
  21 # We would like our source tree to be readonly. However when releases or
  22 # pre-releases are generated, the flex/bison generated files as well as the
  23 # various formats of manuals need to be included along with the rest of the
  24 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
  25 # just that.
  26 AC_MSG_CHECKING(generated-files-in-srcdir)
  27 AC_ARG_ENABLE(generated-files-in-srcdir,
  28 AS_HELP_STRING([--enable-generated-files-in-srcdir],
  29  [put copies of generated files in source dir intended for creating source tarballs for users without texinfo bison or flex]),
  30 [case "$enableval" in
  31  yes) enable_generated_files_in_srcdir=yes ;;
  32  no)  enable_generated_files_in_srcdir=no ;;
  33  *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  34  esac],
  35 [enable_generated_files_in_srcdir=no])
  36 AC_MSG_RESULT($enable_generated_files_in_srcdir)
  37 AM_CONDITIONAL(GENINSRC, test "$enable_generated_files_in_srcdir" = yes)
  38
  39 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
  40 # We must force CC to /not/ be precious variables; otherwise
  41 # the wrong, non-multilib-adjusted value will be used in multilibs.
  42 # As a side effect, we have to subst CFLAGS ourselves.
  43 # Also save and restore CFLAGS, since AC_PROG_CC will come up with
  44 # defaults of its own if none are provided.
  45
  46 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
  47 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  48 save_CFLAGS=$CFLAGS
  49 AC_PROG_CC
  50 AC_PROG_CXX
  51 CFLAGS=$save_CFLAGS
  52 m4_undefine([_AC_ARG_VAR_PRECIOUS])
  53 m4_rename_force([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  54
  55 AC_SUBST(CFLAGS)
  56
  57 AM_PROG_AS
  58 AM_PROG_CC_C_O
  59 AC_PROG_LIBTOOL
  60
  61 # Test for 64-bit build.
  62 AC_CHECK_SIZEOF([size_t])
  63
  64 AM_MAINTAINER_MODE
  65
  66 AC_CHECK_HEADERS(sys/mman.h)
  67 AC_CHECK_FUNCS([mmap mkostemp])
  68 AC_FUNC_MMAP_BLACKLIST
  69
  70 dnl The -no-testsuite modules omit the test subdir.
  71 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
  72
  73 TARGETDIR="unknown"
  74 HAVE_LONG_DOUBLE_VARIANT=0
  75
  76 . ${srcdir}/configure.host
  77
  78 if test -n "${UNSUPPORTED}"; then
  79   AC_MSG_ERROR(["libffi has not been ported to $host."])
  80 fi
  81
  82 AC_SUBST(AM_RUNTESTFLAGS)
  83 AC_SUBST(AM_LTLDFLAGS)
  84
  85 AC_HEADER_STDC
  86 AC_CHECK_FUNCS(memcpy)
  87 AC_FUNC_ALLOCA
  88
  89 AC_CHECK_SIZEOF(double)
  90 AC_CHECK_SIZEOF(long double)
  91
  92 # Also AC_SUBST this variable for ffi.h.
  93 if test -z "$HAVE_LONG_DOUBLE"; then
  94   HAVE_LONG_DOUBLE=0
  95   if test $ac_cv_sizeof_long_double != 0; then
  96     if test $HAVE_LONG_DOUBLE_VARIANT != 0; then
  97       AC_DEFINE(HAVE_LONG_DOUBLE_VARIANT, 1, [Define if you support more than one size of the long double type])
  98       HAVE_LONG_DOUBLE=1
  99     else
 100       if test $ac_cv_sizeof_double != $ac_cv_sizeof_long_double; then
 101         HAVE_LONG_DOUBLE=1
 102         AC_DEFINE(HAVE_LONG_DOUBLE, 1, [Define if you have the long double type and it is bigger than a double])
 103       fi
 104     fi
 105   fi
 106 fi
 107 AC_SUBST(HAVE_LONG_DOUBLE)
 108 AC_SUBST(HAVE_LONG_DOUBLE_VARIANT)
 109
 110 AC_C_BIGENDIAN
 111
 112 GCC_AS_CFI_PSEUDO_OP
 113
 114 case "$TARGET" in
 115   SPARC)
 116     AC_CACHE_CHECK([assembler and linker support unaligned pc related relocs],
 117         libffi_cv_as_sparc_ua_pcrel, [
 118         save_CFLAGS="$CFLAGS"
 119         save_LDFLAGS="$LDFLAGS"
 120         CFLAGS="$CFLAGS -fpic"
 121         LDFLAGS="$LDFLAGS -shared"
 122         AC_TRY_LINK([asm (".text; foo: nop; .data; .align 4; .byte 0; .uaword %r_disp32(foo); .text");],,
 123                     [libffi_cv_as_sparc_ua_pcrel=yes],
 124                     [libffi_cv_as_sparc_ua_pcrel=no])
 125         CFLAGS="$save_CFLAGS"
 126         LDFLAGS="$save_LDFLAGS"])
 127     if test "x$libffi_cv_as_sparc_ua_pcrel" = xyes; then
 128         AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
 129                   [Define if your assembler and linker support unaligned PC relative relocs.])
 130     fi
 131
 132     AC_CACHE_CHECK([assembler .register pseudo-op support],
 133        libffi_cv_as_register_pseudo_op, [
 134        libffi_cv_as_register_pseudo_op=unknown
 135        # Check if we have .register
 136        AC_TRY_COMPILE(,[asm (".register %g2, #scratch");],
 137                        [libffi_cv_as_register_pseudo_op=yes],
 138                        [libffi_cv_as_register_pseudo_op=no])
 139     ])
 140     if test "x$libffi_cv_as_register_pseudo_op" = xyes; then
 141        AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
 142                [Define if your assembler supports .register.])
 143     fi
 144     ;;
 145
 146   X86*)
 147     AC_CACHE_CHECK([assembler supports pc related relocs],
 148         libffi_cv_as_x86_pcrel, [
 149         libffi_cv_as_x86_pcrel=no
 150         echo '.text; foo: nop; .data; .long foo-.; .text' > conftest.s
 151         if $CC $CFLAGS -c conftest.s > /dev/null 2>&1; then
 152             libffi_cv_as_x86_pcrel=yes
 153         fi
 154         ])
 155     if test "x$libffi_cv_as_x86_pcrel" = xyes; then
 156         AC_DEFINE(HAVE_AS_X86_PCREL, 1,
 157                   [Define if your assembler supports PC relative relocs.])
 158     fi
 159     ;;
 160
 161   S390)
 162     AC_CACHE_CHECK([compiler uses zarch features],
 163         libffi_cv_as_s390_zarch, [
 164         libffi_cv_as_s390_zarch=no
 165         echo 'void foo(void) { bar(); bar(); }' > conftest.c
 166         if $CC $CFLAGS -S conftest.c > /dev/null 2>&1; then
 167             if grep -q brasl conftest.s; then
 168                 libffi_cv_as_s390_zarch=yes
 169             fi
 170         fi
 171         ])
 172     if test "x$libffi_cv_as_s390_zarch" = xyes; then
 173         AC_DEFINE(HAVE_AS_S390_ZARCH, 1,
 174                   [Define if the compiler uses zarch features.])
 175     fi
 176     ;;
 177 esac
 178
 179 # On PaX enable kernels that have MPROTECT enable we can't use PROT_EXEC.
 180 AC_ARG_ENABLE(pax_emutramp,
 181   [  --enable-pax_emutramp       enable pax emulated trampolines, for we can't use PROT_EXEC],
 182   if test "$enable_pax_emutramp" = "yes"; then
 183     AC_DEFINE(FFI_MMAP_EXEC_EMUTRAMP_PAX, 1,
 184       [Define this if you want to enable pax emulated trampolines])
 185   fi)
 186
 187 FFI_EXEC_TRAMPOLINE_TABLE=0
 188 case "$target" in
 189      *arm*-apple-darwin* | aarch64-apple-darwin*)
 190        FFI_EXEC_TRAMPOLINE_TABLE=1
 191        AC_DEFINE(FFI_EXEC_TRAMPOLINE_TABLE, 1,
 192                  [Cannot use PROT_EXEC on this target, so, we revert to
 193                    alternative means])
 194      ;;
 195      *-apple-darwin1* | *-*-freebsd* | *-*-kfreebsd* | *-*-openbsd* | *-pc-solaris*)
 196        AC_DEFINE(FFI_MMAP_EXEC_WRIT, 1,
 197                  [Cannot use malloc on this target, so, we revert to
 198                    alternative means])
 199      ;;
 200 esac
 201 AM_CONDITIONAL(FFI_EXEC_TRAMPOLINE_TABLE, test x$FFI_EXEC_TRAMPOLINE_TABLE = x1)
 202 AC_SUBST(FFI_EXEC_TRAMPOLINE_TABLE)
 203
 204 if test x$TARGET = xX86_64; then
 205     AC_CACHE_CHECK([toolchain supports unwind section type],
 206         libffi_cv_as_x86_64_unwind_section_type, [
 207         cat  > conftest1.s << EOF
 208 .text
 209 .globl foo
 210 foo:
 211 jmp bar
 212 .section .eh_frame,"a",@unwind
 213 bar:
 214 EOF
 215
 216         cat > conftest2.c  << EOF
 217 extern void foo();
 218 int main(){foo();}
 219 EOF
 220
 221         libffi_cv_as_x86_64_unwind_section_type=no
 222         # we ensure that we can compile _and_ link an assembly file containing an @unwind section
 223         # since the compiler can support it and not the linker (ie old binutils)
 224         if $CC -Wa,--fatal-warnings $CFLAGS -c conftest1.s > /dev/null 2>&1 && \
 225            $CC conftest2.c conftest1.o > /dev/null 2>&1 ; then
 226             libffi_cv_as_x86_64_unwind_section_type=yes
 227         fi
 228         ])
 229     if test "x$libffi_cv_as_x86_64_unwind_section_type" = xyes; then
 230         AC_DEFINE(HAVE_AS_X86_64_UNWIND_SECTION_TYPE, 1,
 231                   [Define if your assembler supports unwind section type.])
 232     fi
 233 fi
 234
 235 if test "x$GCC" = "xyes"; then
 236   AC_CACHE_CHECK([whether .eh_frame section should be read-only],
 237       libffi_cv_ro_eh_frame, [
 238         libffi_cv_ro_eh_frame=no
 239         echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
 240         if $CC $CFLAGS -c -fpic -fexceptions -o conftest.o conftest.c > /dev/null 2>&1; then
 241             objdump -h conftest.o > conftest.dump 2>&1
 242             libffi_eh_frame_line=`grep -n eh_frame conftest.dump | cut -d: -f 1`
 243             if test "x$libffi_eh_frame_line" != "x"; then
 244                 libffi_test_line=`expr $libffi_eh_frame_line + 1`p
 245                 sed -n $libffi_test_line conftest.dump > conftest.line
 246                 if grep READONLY conftest.line > /dev/null; then
 247                     libffi_cv_ro_eh_frame=yes
 248                 fi
 249             fi
 250         fi
 251         rm -f conftest.*
 252       ])
 253   if test "x$libffi_cv_ro_eh_frame" = xyes; then
 254       AC_DEFINE(HAVE_RO_EH_FRAME, 1,
 255               [Define if .eh_frame sections should be read-only.])
 256       AC_DEFINE(EH_FRAME_FLAGS, "a",
 257               [Define to the flags needed for the .section .eh_frame directive.  ])
 258   else
 259       AC_DEFINE(EH_FRAME_FLAGS, "aw",
 260               [Define to the flags needed for the .section .eh_frame directive.  ])
 261   fi
 262
 263   AC_CACHE_CHECK([for __attribute__((visibility("hidden")))],
 264       libffi_cv_hidden_visibility_attribute, [
 265         echo 'int __attribute__ ((visibility ("hidden"))) foo (void) { return 1  ; }' > conftest.c
 266         libffi_cv_hidden_visibility_attribute=no
 267         if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
 268             if grep '\.hidden.*foo' conftest.s >/dev/null; then
 269                 libffi_cv_hidden_visibility_attribute=yes
 270             fi
 271         fi
 272         rm -f conftest.*
 273       ])
 274   if test $libffi_cv_hidden_visibility_attribute = yes; then
 275       AC_DEFINE(HAVE_HIDDEN_VISIBILITY_ATTRIBUTE, 1,
 276               [Define if __attribute__((visibility("hidden"))) is supported.])
 277   fi
 278 fi
 279
 280 AH_BOTTOM([
 281 #ifdef HAVE_HIDDEN_VISIBILITY_ATTRIBUTE
 282 #ifdef LIBFFI_ASM
 283 #define FFI_HIDDEN(name) .hidden name
 284 #else
 285 #define FFI_HIDDEN __attribute__ ((visibility ("hidden")))
 286 #endif
 287 #else
 288 #ifdef LIBFFI_ASM
 289 #define FFI_HIDDEN(name)
 290 #else
 291 #define FFI_HIDDEN
 292 #endif
 293 #endif
 294 ])
 295
 296 AC_SUBST(TARGET)
 297 AC_SUBST(TARGETDIR)
 298
 299 changequote(<,>)
 300 TARGET_OBJ=
 301 for i in $SOURCES; do
 302   TARGET_OBJ="${TARGET_OBJ} src/${TARGETDIR}/"`echo $i | sed 's/[cS]$/lo/'`
 303 done
 304 changequote([,])
 305 AC_SUBST(TARGET_OBJ)
 306
 307 AC_SUBST(SHELL)
 308
 309 AC_ARG_ENABLE(debug,
 310 [  --enable-debug          debugging mode],
 311   if test "$enable_debug" = "yes"; then
 312     AC_DEFINE(FFI_DEBUG, 1, [Define this if you want extra debugging.])
 313   fi)
 314 AM_CONDITIONAL(FFI_DEBUG, test "$enable_debug" = "yes")
 315
 316 AC_ARG_ENABLE(structs,
 317 [  --disable-structs       omit code for struct support],
 318   if test "$enable_structs" = "no"; then
 319     AC_DEFINE(FFI_NO_STRUCTS, 1, [Define this if you do not want support for aggregate types.])
 320   fi)
 321 AM_CONDITIONAL(FFI_DEBUG, test "$enable_debug" = "yes")
 322
 323 AC_ARG_ENABLE(raw-api,
 324 [  --disable-raw-api       make the raw api unavailable],
 325   if test "$enable_raw_api" = "no"; then
 326     AC_DEFINE(FFI_NO_RAW_API, 1, [Define this if you do not want support for the raw API.])
 327   fi)
 328
 329 AC_ARG_ENABLE(purify-safety,
 330 [  --enable-purify-safety  purify-safe mode],
 331   if test "$enable_purify_safety" = "yes"; then
 332     AC_DEFINE(USING_PURIFY, 1, [Define this if you are using Purify and want to suppress spurious messages.])
 333   fi)
 334
 335 GCC_WITH_TOOLEXECLIBDIR
 336
 337 if test -n "$with_cross_host" &&
 338    test x"$with_cross_host" != x"no"; then
 339   toolexecdir='$(exec_prefix)/$(target_alias)'
 340   case ${with_toolexeclibdir} in
 341     no)
 342       toolexeclibdir='$(toolexecdir)/lib'
 343       ;;
 344     *)
 345       toolexeclibdir=${with_toolexeclibdir}
 346       ;;
 347   esac
 348 else
 349   toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
 350   toolexeclibdir='$(libdir)'
 351 fi
 352 multi_os_directory=`$CC -print-multi-os-directory`
 353 case $multi_os_directory in
 354   .) ;; # Avoid trailing /.
 355   *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 356 esac
 357 AC_SUBST(toolexecdir)
 358 AC_SUBST(toolexeclibdir)
 359
 360 if test "${multilib}" = "yes"; then
 361   multilib_arg="--enable-multilib"
 362 else
 363   multilib_arg=
 364 fi
 365
 366 # Check linker support.
 367 LIBAT_ENABLE_SYMVERS
 368
 369 # Determine what GCC version number to use in filesystem paths.
 370 GCC_BASE_VER
 371
 372 AC_CONFIG_COMMANDS(include, [test -d include || mkdir include])
 373 AC_CONFIG_COMMANDS(src, [
 374 test -d src || mkdir src
 375 test -d src/$TARGETDIR || mkdir src/$TARGETDIR
 376 ], [TARGETDIR="$TARGETDIR"])
 377
 378 AC_CONFIG_LINKS(include/ffitarget.h:src/$TARGETDIR/ffitarget.h)
 379
 380 AC_CONFIG_FILES(include/Makefile include/ffi.h Makefile testsuite/Makefile man/Makefile libffi.pc)
 381
 382 AC_OUTPUT