gcc/ada/s-expgen.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUNTIME COMPONENTS                          --
   4 --                                                                          --
   5 --                       S Y S T E M . E X P _ G E N                        --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --                            $Revision: 1.1 $
  10 --                                                                          --
  11 --          Copyright (C) 1992-2001, Free Software Foundation, Inc.         --
  12 --                                                                          --
  13 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  14 -- terms of the  GNU General Public License as published  by the Free Soft- --
  15 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  16 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  17 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  18 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  19 -- for  more details.  You should have  received  a copy of the GNU General --
  20 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  21 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  22 -- MA 02111-1307, USA.                                                      --
  23 --                                                                          --
  24 -- As a special exception,  if other files  instantiate  generics from this --
  25 -- unit, or you link  this unit with other files  to produce an executable, --
  26 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  27 -- covered  by the  GNU  General  Public  License.  This exception does not --
  28 -- however invalidate  any other reasons why  the executable file  might be --
  29 -- covered by the  GNU Public License.                                      --
  30 --                                                                          --
  31 -- GNAT was originally developed  by the GNAT team at  New York University. --
  32 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  33 --                                                                          --
  34 ------------------------------------------------------------------------------
  35
  36 package body System.Exp_Gen is
  37
  38    --------------------
  39    -- Exp_Float_Type --
  40    --------------------
  41
  42    function Exp_Float_Type
  43      (Left  : Type_Of_Base;
  44       Right : Integer)
  45       return  Type_Of_Base
  46    is
  47       Result : Type_Of_Base := 1.0;
  48       Factor : Type_Of_Base := Left;
  49       Exp    : Integer := Right;
  50
  51    begin
  52       --  We use the standard logarithmic approach, Exp gets shifted right
  53       --  testing successive low order bits and Factor is the value of the
  54       --  base raised to the next power of 2. For positive exponents we
  55       --  multiply the result by this factor, for negative exponents, we
  56       --  divide by this factor.
  57
  58       if Exp >= 0 then
  59
  60          --  For a positive exponent, if we get a constraint error during
  61          --  this loop, it is an overflow, and the constraint error will
  62          --  simply be passed on to the caller.
  63
  64          loop
  65             if Exp rem 2 /= 0 then
  66                declare
  67                   pragma Unsuppress (All_Checks);
  68                begin
  69                   Result := Result * Factor;
  70                end;
  71             end if;
  72
  73             Exp := Exp / 2;
  74             exit when Exp = 0;
  75
  76             declare
  77                pragma Unsuppress (All_Checks);
  78             begin
  79                Factor := Factor * Factor;
  80             end;
  81          end loop;
  82
  83          return Result;
  84
  85       --  Now we know that the exponent is negative, check for case of
  86       --  base of 0.0 which always generates a constraint error.
  87
  88       elsif Factor = 0.0 then
  89          raise Constraint_Error;
  90
  91       --  Here we have a negative exponent with a non-zero base
  92
  93       else
  94
  95          --  For the negative exponent case, a constraint error during this
  96          --  calculation happens if Factor gets too large, and the proper
  97          --  response is to return 0.0, since what we essenmtially have is
  98          --  1.0 / infinity, and the closest model number will be zero.
  99
 100          begin
 101             loop
 102                if Exp rem 2 /= 0 then
 103                   declare
 104                      pragma Unsuppress (All_Checks);
 105                   begin
 106                      Result := Result * Factor;
 107                   end;
 108                end if;
 109
 110                Exp := Exp / 2;
 111                exit when Exp = 0;
 112
 113                declare
 114                   pragma Unsuppress (All_Checks);
 115                begin
 116                   Factor := Factor * Factor;
 117                end;
 118             end loop;
 119
 120             declare
 121                pragma Unsuppress (All_Checks);
 122             begin
 123                return 1.0 / Result;
 124             end;
 125
 126          exception
 127
 128             when Constraint_Error =>
 129                return 0.0;
 130          end;
 131       end if;
 132    end Exp_Float_Type;
 133
 134    ----------------------
 135    -- Exp_Integer_Type --
 136    ----------------------
 137
 138    --  Note that negative exponents get a constraint error because the
 139    --  subtype of the Right argument (the exponent) is Natural.
 140
 141    function Exp_Integer_Type
 142      (Left  : Type_Of_Base;
 143       Right : Natural)
 144       return  Type_Of_Base
 145    is
 146       Result : Type_Of_Base := 1;
 147       Factor : Type_Of_Base := Left;
 148       Exp    : Natural := Right;
 149
 150    begin
 151       --  We use the standard logarithmic approach, Exp gets shifted right
 152       --  testing successive low order bits and Factor is the value of the
 153       --  base raised to the next power of 2.
 154
 155       --  Note: it is not worth special casing the cases of base values -1,0,+1
 156       --  since the expander does this when the base is a literal, and other
 157       --  cases will be extremely rare.
 158
 159       if Exp /= 0 then
 160          loop
 161             if Exp rem 2 /= 0 then
 162                declare
 163                   pragma Unsuppress (All_Checks);
 164                begin
 165                   Result := Result * Factor;
 166                end;
 167             end if;
 168
 169             Exp := Exp / 2;
 170             exit when Exp = 0;
 171
 172             declare
 173                pragma Unsuppress (All_Checks);
 174             begin
 175                Factor := Factor * Factor;
 176             end;
 177          end loop;
 178       end if;
 179
 180       return Result;
 181    end Exp_Integer_Type;
 182
 183 end System.Exp_Gen;