gcc/ada/s-osinte-darwin.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                 GNAT RUN-TIME LIBRARY (GNARL) COMPONENTS                 --
   4 --                                                                          --
   5 --                   S Y S T E M . O S _ I N T E R F A C E                  --
   6 --                                                                          --
   7 --                                  S p e c                                 --
   8 --                                                                          --
   9 --             Copyright (C) 1991-1994, Florida State University            --
  10 --          Copyright (C) 1995-2015, Free Software Foundation, Inc.         --
  11 --                                                                          --
  12 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  13 -- terms of the  GNU General Public License as published  by the Free Soft- --
  14 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  15 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  16 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  17 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  18 --                                                                          --
  19 -- As a special exception under Section 7 of GPL version 3, you are granted --
  20 -- additional permissions described in the GCC Runtime Library Exception,   --
  21 -- version 3.1, as published by the Free Software Foundation.               --
  22 --                                                                          --
  23 -- You should have received a copy of the GNU General Public License and    --
  24 -- a copy of the GCC Runtime Library Exception along with this program;     --
  25 -- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
  26 -- <http://www.gnu.org/licenses/>.                                          --
  27 --                                                                          --
  28 -- GNARL was developed by the GNARL team at Florida State University.       --
  29 -- Extensive contributions were provided by Ada Core Technologies, Inc.     --
  30 --                                                                          --
  31 ------------------------------------------------------------------------------
  32
  33 --  This is Darwin pthreads version of this package
  34
  35 --  This package includes all direct interfaces to OS services that are needed
  36 --  by the tasking run-time (libgnarl).
  37
  38 --  PLEASE DO NOT add any with-clauses to this package or remove the pragma
  39 --  Elaborate_Body. It is designed to be a bottom-level (leaf) package.
  40
  41 with Interfaces.C;
  42 with System.OS_Constants;
  43
  44 package System.OS_Interface is
  45    pragma Preelaborate;
  46
  47    subtype int            is Interfaces.C.int;
  48    subtype short          is Interfaces.C.short;
  49    subtype long           is Interfaces.C.long;
  50    subtype unsigned       is Interfaces.C.unsigned;
  51    subtype unsigned_short is Interfaces.C.unsigned_short;
  52    subtype unsigned_long  is Interfaces.C.unsigned_long;
  53    subtype unsigned_char  is Interfaces.C.unsigned_char;
  54    subtype plain_char     is Interfaces.C.plain_char;
  55    subtype size_t         is Interfaces.C.size_t;
  56
  57    -----------
  58    -- Errno --
  59    -----------
  60
  61    function errno return int;
  62    pragma Import (C, errno, "__get_errno");
  63
  64    EINTR     : constant := 4;
  65    ENOMEM    : constant := 12;
  66    EINVAL    : constant := 22;
  67    EAGAIN    : constant := 35;
  68    ETIMEDOUT : constant := 60;
  69
  70    -------------
  71    -- Signals --
  72    -------------
  73
  74    Max_Interrupt : constant := 31;
  75    type Signal is new int range 0 .. Max_Interrupt;
  76    for Signal'Size use int'Size;
  77
  78    SIGHUP     : constant := 1; --  hangup
  79    SIGINT     : constant := 2; --  interrupt (rubout)
  80    SIGQUIT    : constant := 3; --  quit (ASCD FS)
  81    SIGILL     : constant := 4; --  illegal instruction (not reset)
  82    SIGTRAP    : constant := 5; --  trace trap (not reset)
  83    SIGIOT     : constant := 6; --  IOT instruction
  84    SIGABRT    : constant := 6; --  used by abort, replace SIGIOT in the  future
  85    SIGEMT     : constant := 7; --  EMT instruction
  86    SIGFPE     : constant := 8; --  floating point exception
  87    SIGKILL    : constant := 9; --  kill (cannot be caught or ignored)
  88    SIGBUS     : constant := 10; --  bus error
  89    SIGSEGV    : constant := 11; --  segmentation violation
  90    SIGSYS     : constant := 12; --  bad argument to system call
  91    SIGPIPE    : constant := 13; --  write on a pipe with no one to read it
  92    SIGALRM    : constant := 14; --  alarm clock
  93    SIGTERM    : constant := 15; --  software termination signal from kill
  94    SIGURG     : constant := 16; --  urgent condition on IO channel
  95    SIGSTOP    : constant := 17; --  stop (cannot be caught or ignored)
  96    SIGTSTP    : constant := 18; --  user stop requested from tty
  97    SIGCONT    : constant := 19; --  stopped process has been continued
  98    SIGCHLD    : constant := 20; --  child status change
  99    SIGTTIN    : constant := 21; --  background tty read attempted
 100    SIGTTOU    : constant := 22; --  background tty write attempted
 101    SIGIO      : constant := 23; --  I/O possible (Solaris SIGPOLL alias)
 102    SIGXCPU    : constant := 24; --  CPU time limit exceeded
 103    SIGXFSZ    : constant := 25; --  filesize limit exceeded
 104    SIGVTALRM  : constant := 26; --  virtual timer expired
 105    SIGPROF    : constant := 27; --  profiling timer expired
 106    SIGWINCH   : constant := 28; --  window size change
 107    SIGINFO    : constant := 29; --  information request
 108    SIGUSR1    : constant := 30; --  user defined signal 1
 109    SIGUSR2    : constant := 31; --  user defined signal 2
 110
 111    SIGADAABORT : constant := SIGABRT;
 112    --  Change this if you want to use another signal for task abort.
 113    --  SIGTERM might be a good one.
 114
 115    type Signal_Set is array (Natural range <>) of Signal;
 116
 117    Unmasked : constant Signal_Set :=
 118                 (SIGTTIN, SIGTTOU, SIGSTOP, SIGTSTP);
 119
 120    Reserved : constant Signal_Set :=
 121                 (SIGKILL, SIGSTOP);
 122
 123    Exception_Signals : constant Signal_Set :=
 124                          (SIGFPE, SIGILL, SIGSEGV, SIGBUS);
 125    --  These signals (when runtime or system) will be caught and converted
 126    --  into an Ada exception.
 127
 128    type sigset_t is private;
 129
 130    function sigaddset (set : access sigset_t; sig : Signal) return int;
 131    pragma Import (C, sigaddset, "sigaddset");
 132
 133    function sigdelset (set : access sigset_t; sig : Signal) return int;
 134    pragma Import (C, sigdelset, "sigdelset");
 135
 136    function sigfillset (set : access sigset_t) return int;
 137    pragma Import (C, sigfillset, "sigfillset");
 138
 139    function sigismember (set : access sigset_t; sig : Signal) return int;
 140    pragma Import (C, sigismember, "sigismember");
 141
 142    function sigemptyset (set : access sigset_t) return int;
 143    pragma Import (C, sigemptyset, "sigemptyset");
 144
 145    type siginfo_t is private;
 146    type ucontext_t is private;
 147
 148    type Signal_Handler is access procedure
 149      (signo   : Signal;
 150       info    : access siginfo_t;
 151       context : access ucontext_t);
 152
 153    type struct_sigaction is record
 154       sa_handler : System.Address;
 155       sa_mask    : sigset_t;
 156       sa_flags   : int;
 157    end record;
 158    pragma Convention (C, struct_sigaction);
 159    type struct_sigaction_ptr is access all struct_sigaction;
 160
 161    SIG_BLOCK   : constant := 1;
 162    SIG_UNBLOCK : constant := 2;
 163    SIG_SETMASK : constant := 3;
 164
 165    SIG_DFL : constant := 0;
 166    SIG_IGN : constant := 1;
 167
 168    SA_SIGINFO : constant := 16#0040#;
 169    SA_ONSTACK : constant := 16#0001#;
 170
 171    function sigaction
 172      (sig  : Signal;
 173       act  : struct_sigaction_ptr;
 174       oact : struct_sigaction_ptr) return int;
 175    pragma Import (C, sigaction, "sigaction");
 176
 177    ----------
 178    -- Time --
 179    ----------
 180
 181    Time_Slice_Supported : constant Boolean := True;
 182    --  Indicates whether time slicing is supported
 183
 184    type timespec is private;
 185
 186    type clockid_t is new int;
 187
 188    function clock_gettime
 189      (clock_id : clockid_t;
 190       tp       : access timespec) return int;
 191
 192    function clock_getres
 193      (clock_id : clockid_t;
 194       res      : access timespec) return int;
 195
 196    function To_Duration (TS : timespec) return Duration;
 197    pragma Inline (To_Duration);
 198
 199    function To_Timespec (D : Duration) return timespec;
 200    pragma Inline (To_Timespec);
 201
 202    -------------------------
 203    -- Priority Scheduling --
 204    -------------------------
 205
 206    SCHED_OTHER : constant := 1;
 207    SCHED_RR    : constant := 2;
 208    SCHED_FIFO  : constant := 4;
 209
 210    function To_Target_Priority
 211      (Prio : System.Any_Priority) return Interfaces.C.int;
 212    --  Maps System.Any_Priority to a POSIX priority
 213
 214    -------------
 215    -- Process --
 216    -------------
 217
 218    type pid_t is private;
 219
 220    function kill (pid : pid_t; sig : Signal) return int;
 221    pragma Import (C, kill, "kill");
 222
 223    function getpid return pid_t;
 224    pragma Import (C, getpid, "getpid");
 225
 226    ---------
 227    -- LWP --
 228    ---------
 229
 230    function lwp_self return System.Address;
 231    --  Return the mach thread bound to the current thread.  The value is not
 232    --  used by the run-time library but made available to debuggers.
 233
 234    -------------
 235    -- Threads --
 236    -------------
 237
 238    type Thread_Body is access
 239      function (arg : System.Address) return System.Address;
 240    pragma Convention (C, Thread_Body);
 241
 242    type pthread_t           is private;
 243    subtype Thread_Id        is pthread_t;
 244
 245    type pthread_mutex_t     is limited private;
 246    type pthread_cond_t      is limited private;
 247    type pthread_attr_t      is limited private;
 248    type pthread_mutexattr_t is limited private;
 249    type pthread_condattr_t  is limited private;
 250    type pthread_key_t       is private;
 251
 252    type pthread_mutex_ptr is access all pthread_mutex_t;
 253    type pthread_cond_ptr is access all pthread_cond_t;
 254
 255    PTHREAD_CREATE_DETACHED : constant := 2;
 256
 257    PTHREAD_SCOPE_PROCESS : constant := 2;
 258    PTHREAD_SCOPE_SYSTEM  : constant := 1;
 259
 260    --  Read/Write lock not supported on Darwin. To add support both types
 261    --  pthread_rwlock_t and pthread_rwlockattr_t must properly be defined
 262    --  with the associated routines pthread_rwlock_[init/destroy] and
 263    --  pthread_rwlock_[rdlock/wrlock/unlock].
 264
 265    subtype pthread_rwlock_t     is pthread_mutex_t;
 266    subtype pthread_rwlockattr_t is pthread_mutexattr_t;
 267
 268    -----------
 269    -- Stack --
 270    -----------
 271
 272    type stack_t is record
 273       ss_sp    : System.Address;
 274       ss_size  : size_t;
 275       ss_flags : int;
 276    end record;
 277    pragma Convention (C, stack_t);
 278
 279    function sigaltstack
 280      (ss  : not null access stack_t;
 281       oss : access stack_t) return int;
 282    pragma Import (C, sigaltstack, "sigaltstack");
 283
 284    Alternate_Stack : aliased System.Address;
 285    pragma Import (C, Alternate_Stack, "__gnat_alternate_stack");
 286    --  The alternate signal stack for stack overflows
 287
 288    Alternate_Stack_Size : constant := 32 * 1024;
 289    --  This must be in keeping with init.c:__gnat_alternate_stack
 290
 291    Stack_Base_Available : constant Boolean := False;
 292    --  Indicates whether the stack base is available on this target. This
 293    --  allows us to share s-osinte.adb between all the FSU run time. Note that
 294    --  this value can only be true if pthread_t has a complete definition that
 295    --  corresponds exactly to the C header files.
 296
 297    function Get_Stack_Base (thread : pthread_t) return System.Address;
 298    pragma Inline (Get_Stack_Base);
 299    --  returns the stack base of the specified thread. Only call this function
 300    --  when Stack_Base_Available is True.
 301
 302    function Get_Page_Size return int;
 303    pragma Import (C, Get_Page_Size, "getpagesize");
 304    --  Returns the size of a page
 305
 306    PROT_NONE  : constant := 0;
 307    PROT_READ  : constant := 1;
 308    PROT_WRITE : constant := 2;
 309    PROT_EXEC  : constant := 4;
 310    PROT_ALL   : constant := PROT_READ + PROT_WRITE + PROT_EXEC;
 311
 312    PROT_ON    : constant := PROT_NONE;
 313    PROT_OFF   : constant := PROT_ALL;
 314
 315    function mprotect
 316      (addr : System.Address;
 317       len  : size_t;
 318       prot : int) return int;
 319    pragma Import (C, mprotect);
 320
 321    ---------------------------------------
 322    -- Nonstandard Thread Initialization --
 323    ---------------------------------------
 324
 325    procedure pthread_init;
 326
 327    -------------------------
 328    -- POSIX.1c  Section 3 --
 329    -------------------------
 330
 331    function sigwait (set : access sigset_t; sig : access Signal) return int;
 332    pragma Import (C, sigwait, "sigwait");
 333
 334    function pthread_kill (thread : pthread_t; sig : Signal) return int;
 335    pragma Import (C, pthread_kill, "pthread_kill");
 336
 337    function pthread_sigmask
 338      (how  : int;
 339       set  : access sigset_t;
 340       oset : access sigset_t) return int;
 341    pragma Import (C, pthread_sigmask, "pthread_sigmask");
 342
 343    --------------------------
 344    -- POSIX.1c  Section 11 --
 345    --------------------------
 346
 347    function pthread_mutexattr_init
 348      (attr : access pthread_mutexattr_t) return int;
 349    pragma Import (C, pthread_mutexattr_init, "pthread_mutexattr_init");
 350
 351    function pthread_mutexattr_destroy
 352      (attr : access pthread_mutexattr_t) return int;
 353    pragma Import (C, pthread_mutexattr_destroy, "pthread_mutexattr_destroy");
 354
 355    function pthread_mutex_init
 356      (mutex : access pthread_mutex_t;
 357       attr  : access pthread_mutexattr_t) return int;
 358    pragma Import (C, pthread_mutex_init, "pthread_mutex_init");
 359
 360    function pthread_mutex_destroy (mutex : access pthread_mutex_t) return int;
 361    pragma Import (C, pthread_mutex_destroy, "pthread_mutex_destroy");
 362
 363    function pthread_mutex_lock (mutex : access pthread_mutex_t) return int;
 364    pragma Import (C, pthread_mutex_lock, "pthread_mutex_lock");
 365
 366    function pthread_mutex_unlock (mutex : access pthread_mutex_t) return int;
 367    pragma Import (C, pthread_mutex_unlock, "pthread_mutex_unlock");
 368
 369    function pthread_condattr_init
 370      (attr : access pthread_condattr_t) return int;
 371    pragma Import (C, pthread_condattr_init, "pthread_condattr_init");
 372
 373    function pthread_condattr_destroy
 374      (attr : access pthread_condattr_t) return int;
 375    pragma Import (C, pthread_condattr_destroy, "pthread_condattr_destroy");
 376
 377    function pthread_cond_init
 378      (cond : access pthread_cond_t;
 379       attr : access pthread_condattr_t) return int;
 380    pragma Import (C, pthread_cond_init, "pthread_cond_init");
 381
 382    function pthread_cond_destroy (cond : access pthread_cond_t) return int;
 383    pragma Import (C, pthread_cond_destroy, "pthread_cond_destroy");
 384
 385    function pthread_cond_signal (cond : access pthread_cond_t) return int;
 386    pragma Import (C, pthread_cond_signal, "pthread_cond_signal");
 387
 388    function pthread_cond_wait
 389      (cond  : access pthread_cond_t;
 390       mutex : access pthread_mutex_t) return int;
 391    pragma Import (C, pthread_cond_wait, "pthread_cond_wait");
 392
 393    function pthread_cond_timedwait
 394      (cond    : access pthread_cond_t;
 395       mutex   : access pthread_mutex_t;
 396       abstime : access timespec) return int;
 397    pragma Import (C, pthread_cond_timedwait, "pthread_cond_timedwait");
 398
 399    Relative_Timed_Wait : constant Boolean := False;
 400    --  pthread_cond_timedwait requires an absolute delay time
 401
 402    --------------------------
 403    -- POSIX.1c  Section 13 --
 404    --------------------------
 405
 406    PTHREAD_PRIO_NONE    : constant := 0;
 407    PTHREAD_PRIO_INHERIT : constant := 1;
 408    PTHREAD_PRIO_PROTECT : constant := 2;
 409
 410    function pthread_mutexattr_setprotocol
 411      (attr     : access pthread_mutexattr_t;
 412       protocol : int) return int;
 413    pragma Import
 414      (C, pthread_mutexattr_setprotocol, "pthread_mutexattr_setprotocol");
 415
 416    function pthread_mutexattr_setprioceiling
 417      (attr     : access pthread_mutexattr_t;
 418       prioceiling : int) return int;
 419    pragma Import
 420      (C, pthread_mutexattr_setprioceiling,
 421       "pthread_mutexattr_setprioceiling");
 422
 423    type padding is array (int range <>) of Interfaces.C.char;
 424
 425    type struct_sched_param is record
 426       sched_priority : int;  --  scheduling priority
 427       opaque         : padding (1 .. 4);
 428    end record;
 429    pragma Convention (C, struct_sched_param);
 430
 431    function pthread_setschedparam
 432      (thread : pthread_t;
 433       policy : int;
 434       param  : access struct_sched_param) return int;
 435    pragma Import (C, pthread_setschedparam, "pthread_setschedparam");
 436
 437    function pthread_attr_setscope
 438      (attr            : access pthread_attr_t;
 439       contentionscope : int) return int;
 440    pragma Import (C, pthread_attr_setscope, "pthread_attr_setscope");
 441
 442    function pthread_attr_setinheritsched
 443      (attr            : access pthread_attr_t;
 444       inheritsched : int) return int;
 445    pragma Import
 446      (C, pthread_attr_setinheritsched, "pthread_attr_setinheritsched");
 447
 448    function pthread_attr_setschedpolicy
 449      (attr   : access pthread_attr_t;
 450       policy : int) return int;
 451    pragma Import (C, pthread_attr_setschedpolicy, "pthread_attr_setsched");
 452
 453    function sched_yield return int;
 454
 455    ---------------------------
 456    -- P1003.1c - Section 16 --
 457    ---------------------------
 458
 459    function pthread_attr_init (attributes : access pthread_attr_t) return int;
 460    pragma Import (C, pthread_attr_init, "pthread_attr_init");
 461
 462    function pthread_attr_destroy
 463      (attributes : access pthread_attr_t) return int;
 464    pragma Import (C, pthread_attr_destroy, "pthread_attr_destroy");
 465
 466    function pthread_attr_setdetachstate
 467      (attr        : access pthread_attr_t;
 468       detachstate : int) return int;
 469    pragma Import
 470      (C, pthread_attr_setdetachstate, "pthread_attr_setdetachstate");
 471
 472    function pthread_attr_setstacksize
 473      (attr      : access pthread_attr_t;
 474       stacksize : size_t) return int;
 475    pragma Import
 476      (C, pthread_attr_setstacksize, "pthread_attr_setstacksize");
 477
 478    function pthread_create
 479      (thread        : access pthread_t;
 480       attributes    : access pthread_attr_t;
 481       start_routine : Thread_Body;
 482       arg           : System.Address) return int;
 483    pragma Import (C, pthread_create, "pthread_create");
 484
 485    procedure pthread_exit (status : System.Address);
 486    pragma Import (C, pthread_exit, "pthread_exit");
 487
 488    function pthread_self return pthread_t;
 489    pragma Import (C, pthread_self, "pthread_self");
 490
 491    --------------------------
 492    -- POSIX.1c  Section 17 --
 493    --------------------------
 494
 495    function pthread_setspecific
 496      (key   : pthread_key_t;
 497       value : System.Address) return int;
 498    pragma Import (C, pthread_setspecific, "pthread_setspecific");
 499
 500    function pthread_getspecific (key : pthread_key_t) return System.Address;
 501    pragma Import (C, pthread_getspecific, "pthread_getspecific");
 502
 503    type destructor_pointer is access procedure (arg : System.Address);
 504    pragma Convention (C, destructor_pointer);
 505
 506    function pthread_key_create
 507      (key        : access pthread_key_t;
 508       destructor : destructor_pointer) return int;
 509    pragma Import (C, pthread_key_create, "pthread_key_create");
 510
 511 private
 512
 513    type sigset_t is new unsigned;
 514
 515    type int32_t is new int;
 516
 517    type pid_t is new int32_t;
 518
 519    type time_t is new long;
 520
 521    type timespec is record
 522       tv_sec  : time_t;
 523       tv_nsec : long;
 524    end record;
 525    pragma Convention (C, timespec);
 526
 527    --
 528    --  Darwin specific signal implementation
 529    --
 530    type Pad_Type is array (1 .. 7) of unsigned_long;
 531    type siginfo_t is record
 532       si_signo  : int;               --  signal number
 533       si_errno  : int;               --  errno association
 534       si_code   : int;               --  signal code
 535       si_pid    : int;               --  sending process
 536       si_uid    : unsigned;          --  sender's ruid
 537       si_status : int;               --  exit value
 538       si_addr   : System.Address;    --  faulting instruction
 539       si_value  : System.Address;    --  signal value
 540       si_band   : long;              --  band event for SIGPOLL
 541       pad       : Pad_Type;          --  RFU
 542    end record;
 543    pragma Convention (C, siginfo_t);
 544
 545    type mcontext_t is new System.Address;
 546
 547    type ucontext_t is record
 548       uc_onstack  : int;
 549       uc_sigmask  : sigset_t;         --  Signal Mask Used By This Context
 550       uc_stack    : stack_t;          --  Stack Used By This Context
 551       uc_link     : System.Address;   --  Pointer To Resuming Context
 552       uc_mcsize   : size_t;           --  Size of The Machine Context
 553       uc_mcontext : mcontext_t;       --  Machine Specific Context
 554    end record;
 555    pragma Convention (C, ucontext_t);
 556
 557    --
 558    --  Darwin specific pthread implementation
 559    --
 560    type pthread_t is new System.Address;
 561
 562    type pthread_attr_t is record
 563       sig    : long;
 564       opaque : padding (1 .. System.OS_Constants.PTHREAD_ATTR_SIZE);
 565    end record;
 566    pragma Convention (C, pthread_attr_t);
 567
 568    type pthread_mutexattr_t is record
 569       sig    : long;
 570       opaque : padding (1 .. System.OS_Constants.PTHREAD_MUTEXATTR_SIZE);
 571    end record;
 572    pragma Convention (C, pthread_mutexattr_t);
 573
 574    type pthread_mutex_t is record
 575       sig    : long;
 576       opaque : padding (1 .. System.OS_Constants.PTHREAD_MUTEX_SIZE);
 577    end record;
 578    pragma Convention (C, pthread_mutex_t);
 579
 580    type pthread_condattr_t is record
 581       sig    : long;
 582       opaque : padding (1 .. System.OS_Constants.PTHREAD_CONDATTR_SIZE);
 583    end record;
 584    pragma Convention (C, pthread_condattr_t);
 585
 586    type pthread_cond_t is record
 587       sig    : long;
 588       opaque : padding (1 .. System.OS_Constants.PTHREAD_COND_SIZE);
 589    end record;
 590    pragma Convention (C, pthread_cond_t);
 591
 592    type pthread_once_t is record
 593       sig    : long;
 594       opaque : padding (1 .. System.OS_Constants.PTHREAD_ONCE_SIZE);
 595    end record;
 596    pragma Convention (C, pthread_once_t);
 597
 598    type pthread_key_t is new unsigned_long;
 599
 600 end System.OS_Interface;