gcc/mkmap-flat.awk

   1 # Generate a flat list of symbols to export.
   2 #       Copyright (C) 2007, 2008  Free Software Foundation, Inc.
   3 #       Contributed by Richard Henderson <rth@cygnus.com>
   4 #
   5 # This file is part of GCC.
   6 #
   7 # GCC is free software; you can redistribute it and/or modify it under
   8 # the terms of the GNU General Public License as published by the Free
   9 # Software Foundation; either version 3, or (at your option) any later
  10 # version.
  11 #
  12 # GCC is distributed in the hope that it will be useful, but WITHOUT
  13 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  14 # or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public
  15 # License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with GCC; see the file COPYING3.  If not see
  19 # <http://www.gnu.org/licenses/>.
  20
  21 # Options:
  22 #   "-v leading_underscore=1" : Symbols in map need leading underscore.
  23 #   "-v pe_dll=1"             : Create .DEF file for Windows PECOFF
  24 #                               DLL link instead of map file.
  25
  26 BEGIN {
  27   state = "nm";
  28   excluding = 0;
  29   if (leading_underscore)
  30     prefix = "_";
  31   else
  32     prefix = "";
  33 }
  34
  35 # Remove comment and blank lines.
  36 /^ *#/ || /^ *$/ {
  37   next;
  38 }
  39
  40 # We begin with nm input.  Collect the set of symbols that are present
  41 # so that we can elide undefined symbols.
  42
  43 state == "nm" && /^%%/ {
  44   state = "ver";
  45   next;
  46 }
  47
  48 state == "nm" && ($1 == "U" || $2 == "U") {
  49   next;
  50 }
  51
  52 state == "nm" && NF == 3 {
  53   def[$3] = 1;
  54   next;
  55 }
  56
  57 state == "nm" {
  58   next;
  59 }
  60
  61 # Now we process a simplified variant of the Solaris symbol version
  62 # script.  We have one symbol per line, no semicolons, simple markers
  63 # for beginning and ending each section, and %inherit markers for
  64 # describing version inheritance.  A symbol may appear in more than
  65 # one symbol version, and the last seen takes effect.
  66 # The magic version name '%exclude' causes all the symbols given that
  67 # version to be dropped from the output (unless a later version overrides).
  68
  69 NF == 3 && $1 == "%inherit" {
  70   next;
  71 }
  72
  73 NF == 2 && $2 == "{" {
  74   if ($1 == "%exclude")
  75     excluding = 1;
  76   next;
  77 }
  78
  79 $1 == "}" {
  80   excluding = 0;
  81   next;
  82 }
  83
  84 {
  85   sym = prefix $1;
  86   if (excluding)
  87     delete export[sym];
  88   else
  89     export[sym] = 1;
  90   next;
  91 }
  92
  93 END {
  94
  95   if (pe_dll) {
  96     print "LIBRARY " pe_dll;
  97     print "EXPORTS";
  98   }
  99
 100   for (sym in export)
 101     if (def[sym] || (pe_dll && def["_" sym]))
 102       print sym;
 103 }