libiberty/configure.in

   1 dnl Process this file with autoconf to produce a configure script
   2
   3 AC_PREREQ(2.57)
   4 AC_INIT(xmalloc.c)
   5
   6 # This works around the fact that libtool configuration may change LD
   7 # for this particular configuration, but some shells, instead of
   8 # keeping the changes in LD private, export them just because LD is
   9 # exported.  We don't use libtool yet, but some day we might, so...
  10 ORIGINAL_LD_FOR_MULTILIBS=$LD
  11
  12 dnl We use these options to decide which functions to include.
  13 AC_ARG_WITH(target-subdir,
  14 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory for target])
  15 AC_ARG_WITH(build-subdir,
  16 [  --with-build-subdir=SUBDIR       Configuring in a subdirectory for build])
  17 AC_ARG_WITH(cross-host,
  18 [  --with-cross-host=HOST           Configuring with a cross compiler])
  19 AC_ARG_WITH(newlib,
  20 [  --with-newlib                    Configuring with newlib])
  21
  22 if test "${srcdir}" = "."; then
  23   if test -n "${with_build_subdir}"; then
  24     libiberty_topdir="${srcdir}/../.."
  25     with_target_subdir=
  26   elif test -z "${with_target_subdir}"; then
  27     libiberty_topdir="${srcdir}/.."
  28   else
  29     if test "${with_target_subdir}" != "."; then
  30       libiberty_topdir="${srcdir}/${with_multisrctop}../.."
  31     else
  32       libiberty_topdir="${srcdir}/${with_multisrctop}.."
  33     fi
  34   fi
  35 else
  36   libiberty_topdir="${srcdir}/.."
  37 fi
  38 AC_SUBST(libiberty_topdir)
  39 AC_CONFIG_AUX_DIR($libiberty_topdir)
  40
  41 dnl Very limited version of automake's enable-maintainer-mode
  42
  43 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
  44   dnl maintainer-mode is disabled by default
  45   AC_ARG_ENABLE(maintainer-mode,
  46 [  --enable-maintainer-mode
  47                           enable make rules and dependencies not useful
  48                           (and sometimes confusing) to the casual installer],
  49       maintainer_mode=$enableval,
  50       maintainer_mode=no)
  51
  52 AC_MSG_RESULT($maintainer_mode)
  53
  54 if test "$maintainer_mode" = "yes"; then
  55   MAINT=''
  56   NOTMAINT='#'
  57 else
  58   MAINT='#'
  59   NOTMAINT=''
  60 fi
  61 AC_SUBST(MAINT)dnl
  62 AC_SUBST(NOTMAINT)dnl
  63
  64 # Do we have a single-tree copy of texinfo?  Even if we do, we can't
  65 # rely on it - libiberty is built before texinfo.
  66 AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo, )
  67 if test "x$MAKEINFO" = "x"; then
  68     MAKEINFO="@echo makeinfo missing; true"
  69     BUILD_INFO=
  70 else
  71     BUILD_INFO=info
  72     case x"`$MAKEINFO --version | grep 'GNU texinfo'`" in
  73       x*\ [[1-3]].* )
  74         MAKEINFO="@echo $MAKEINFO is too old, 4.0 or newer required; true"
  75         BUILD_INFO=
  76         AC_MSG_WARN([
  77 *** Makeinfo is too old. Info documentation will not be built.])
  78         ;;
  79     esac
  80 fi
  81 AC_SUBST(MAKEINFO)
  82 AC_SUBST(BUILD_INFO)
  83
  84 AC_CHECK_PROG(PERL, perl, perl, )
  85 if test x"$PERL" = x""; then
  86   HAVE_PERL='#'
  87 else
  88   HAVE_PERL=''
  89 fi
  90 AC_SUBST(HAVE_PERL)
  91
  92 AC_CANONICAL_HOST
  93
  94 dnl When we start using automake:
  95 dnl AM_INIT_AUTOMAKE(libiberty, 1.0)
  96
  97 dnl These must be called before AM_PROG_LIBTOOL, because it may want
  98 dnl to call AC_CHECK_PROG.
  99 AC_CHECK_TOOL(AR, ar)
 100 AC_CHECK_TOOL(RANLIB, ranlib, :)
 101
 102 GCC_NO_EXECUTABLES
 103 AC_PROG_CC
 104 AC_PROG_CPP_WERROR
 105
 106 if test x$GCC = xyes; then
 107   ac_libiberty_warn_cflags='-W -Wall -Wtraditional -pedantic'
 108 fi
 109 AC_SUBST(ac_libiberty_warn_cflags)
 110
 111 AC_PROG_CC_C_O
 112 # autoconf is lame and doesn't give us any substitution variable for this.
 113 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 114   NO_MINUS_C_MINUS_O=yes
 115 else
 116   OUTPUT_OPTION='-o $@'
 117 fi
 118 AC_SUBST(NO_MINUS_C_MINUS_O)
 119 AC_SUBST(OUTPUT_OPTION)
 120
 121 AC_C_CONST
 122 AC_C_INLINE
 123 AC_C_BIGENDIAN_CROSS
 124
 125 dnl When we start using libtool:
 126 dnl Default to a non shared library.  This may be overridden by the
 127 dnl configure option --enable-shared.
 128 dnl AM_DISABLE_SHARED
 129
 130 dnl When we start using libtool:
 131 dnl AM_PROG_LIBTOOL
 132
 133 dnl When we start using automake:
 134 dnl AM_CONFIG_HEADER(config.h:config.in)
 135 AC_CONFIG_HEADER(config.h:config.in)
 136
 137 dnl When we start using automake:
 138 dnl AM_MAINTAINER_MODE
 139 dnl AC_EXEEXT
 140
 141 dnl When we start using automake:
 142 dnl AM_PROG_INSTALL
 143 AC_PROG_INSTALL
 144
 145 . ${srcdir}/config.table
 146 host_makefile_frag=${frag}
 147 AC_SUBST_FILE(host_makefile_frag)
 148
 149 # It's OK to check for header files.  Although the compiler may not be
 150 # able to link anything, it had better be able to at least compile
 151 # something.
 152 AC_CHECK_HEADERS(sys/file.h sys/param.h limits.h stdlib.h malloc.h string.h unistd.h strings.h sys/time.h time.h sys/resource.h sys/stat.h sys/mman.h fcntl.h alloca.h sys/pstat.h sys/sysmp.h sys/sysinfo.h machine/hal_sysinfo.h sys/table.h sys/sysctl.h sys/systemcfg.h)
 153 AC_HEADER_SYS_WAIT
 154 AC_HEADER_TIME
 155
 156 libiberty_AC_DECLARE_ERRNO
 157
 158 AC_CHECK_TYPE(uintptr_t, unsigned long)
 159 # Given the above check, we always have uintptr_t or a fallback
 160 # definition.  So define HAVE_UINTPTR_T in case any imported code
 161 # relies on it.
 162 AC_DEFINE(HAVE_UINTPTR_T, 1, [Define if you have the \`uintptr_t' type.])
 163
 164 AC_TYPE_PID_T
 165
 166 # This is the list of functions which libiberty will provide if they
 167 # are not available on the host.
 168
 169 funcs="asprintf"
 170 funcs="$funcs atexit"
 171 funcs="$funcs basename"
 172 funcs="$funcs bcmp"
 173 funcs="$funcs bcopy"
 174 funcs="$funcs bsearch"
 175 funcs="$funcs bzero"
 176 funcs="$funcs calloc"
 177 funcs="$funcs clock"
 178 funcs="$funcs ffs"
 179 funcs="$funcs getcwd"
 180 funcs="$funcs getpagesize"
 181 funcs="$funcs index"
 182 funcs="$funcs insque"
 183 funcs="$funcs memchr"
 184 funcs="$funcs memcmp"
 185 funcs="$funcs memcpy"
 186 funcs="$funcs memmove"
 187 funcs="$funcs mempcpy"
 188 funcs="$funcs memset"
 189 funcs="$funcs mkstemps"
 190 funcs="$funcs putenv"
 191 funcs="$funcs random"
 192 funcs="$funcs rename"
 193 funcs="$funcs rindex"
 194 funcs="$funcs setenv"
 195 funcs="$funcs snprintf"
 196 funcs="$funcs sigsetmask"
 197 funcs="$funcs stpcpy"
 198 funcs="$funcs stpncpy"
 199 funcs="$funcs strcasecmp"
 200 funcs="$funcs strchr"
 201 funcs="$funcs strdup"
 202 funcs="$funcs strncasecmp"
 203 funcs="$funcs strrchr"
 204 funcs="$funcs strstr"
 205 funcs="$funcs strtod"
 206 funcs="$funcs strtol"
 207 funcs="$funcs strtoul"
 208 funcs="$funcs tmpnam"
 209 funcs="$funcs vasprintf"
 210 funcs="$funcs vfprintf"
 211 funcs="$funcs vprintf"
 212 funcs="$funcs vsnprintf"
 213 funcs="$funcs vsprintf"
 214 funcs="$funcs waitpid"
 215
 216 # Also in the old function.def file: alloca, vfork, getopt.
 217
 218 vars="sys_errlist sys_nerr sys_siglist"
 219
 220 checkfuncs="getrusage on_exit psignal strerror strsignal sysconf times sbrk gettimeofday"
 221 checkfuncs="$checkfuncs realpath canonicalize_file_name pstat_getstatic pstat_getdynamic sysmp"
 222 checkfuncs="$checkfuncs getsysinfo table sysctl"
 223
 224 # These are neither executed nor required, but they help keep
 225 # autoheader happy without adding a bunch of text to acconfig.h.
 226 if test "x" = "y"; then
 227   AC_CHECK_FUNCS(asprintf atexit basename bcmp bcopy bsearch bzero calloc clock \
 228   getcwd getpagesize index insque mkstemps memchr memcmp memcpy \
 229   memmove mempcpy memset putenv random rename rindex sigsetmask \
 230   strcasecmp setenv stpcpy stpncpy strchr strdup strncasecmp strrchr strstr \
 231   strtod strtol strtoul tmpnam vasprintf vfprintf vprintf \
 232   vsprintf waitpid getrusage on_exit psignal strerror strsignal \
 233   sysconf times sbrk gettimeofday ffs snprintf vsnprintf \
 234   pstat_getstatic pstat_getdynamic sysmp getsysinfo table sysctl \
 235   realpath canonicalize_file_name)
 236   AC_DEFINE(HAVE_SYS_ERRLIST, 1, [Define if you have the sys_errlist variable.])
 237   AC_DEFINE(HAVE_SYS_NERR,    1, [Define if you have the sys_nerr variable.])
 238   AC_DEFINE(HAVE_SYS_SIGLIST, 1, [Define if you have the sys_siglist variable.])
 239 fi
 240
 241 # For each of these functions, if the host does not provide the
 242 # function we want to put FN.o in LIBOBJS, and if the host does
 243 # provide the function, we want to define HAVE_FN in config.h.
 244
 245 setobjs=
 246 CHECK=
 247 target_header_dir=
 248 if test -n "${with_target_subdir}"; then
 249
 250   # We are being configured as a target library.  AC_REPLACE_FUNCS
 251   # may not work correctly, because the compiler may not be able to
 252   # link executables.  Note that we may still be being configured
 253   # native.
 254
 255   # If we are being configured for newlib, we know which functions
 256   # newlib provide and which ones we will be expected to provide.
 257
 258   if test "x${with_newlib}" = "xyes"; then
 259     AC_LIBOBJ([asprintf])
 260     AC_LIBOBJ([basename])
 261     AC_LIBOBJ([insque])
 262     AC_LIBOBJ([random])
 263     AC_LIBOBJ([strdup])
 264     AC_LIBOBJ([vasprintf])
 265
 266     for f in $funcs; do
 267       case "$f" in
 268         asprintf | basename | insque | random | strdup | vasprintf)
 269           ;;
 270         *)
 271           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 272           AC_DEFINE_UNQUOTED($n)
 273           ;;
 274       esac
 275     done
 276
 277     # newlib doesnt provide any of the variables in $vars, so we
 278     # dont have to check them here.
 279
 280     # Of the functions in $checkfuncs, newlib only has strerror.
 281     AC_DEFINE_NOAUTOHEADER(HAVE_STRERROR)
 282
 283     setobjs=yes
 284
 285   fi
 286
 287   # We may wish to install the target headers somewhere.
 288   AC_ARG_ENABLE(install-libiberty,
 289   [  --enable-install-libiberty       Install headers for end users],
 290   enable_install_libiberty=$enableval,
 291   enable_install_libiberty=no)dnl
 292
 293   # Option parsed, now set things appropriately.
 294   case x"$enable_install_libiberty" in
 295     xyes|x)
 296       target_header_dir=libiberty
 297       ;;
 298     xno)
 299       target_header_dir=
 300       ;;
 301     *)
 302       # This could be sanity-checked in various ways...
 303       target_header_dir="${enable_install_libiberty}"
 304       ;;
 305   esac
 306
 307
 308 else
 309
 310    # Not a target library, so we set things up to run the test suite.
 311    CHECK=check-cplus-dem
 312
 313 fi
 314
 315 AC_SUBST(CHECK)
 316 AC_SUBST(target_header_dir)
 317
 318 case "${host}" in
 319   *-*-cygwin* | *-*-mingw*)
 320     AC_DEFINE_NOAUTOHEADER(HAVE_SYS_ERRLIST)
 321     AC_DEFINE_NOAUTOHEADER(HAVE_SYS_NERR)
 322     ;;
 323 esac
 324
 325 if test -z "${setobjs}"; then
 326   case "${host}" in
 327
 328   *-*-vxworks*)
 329     # Handle VxWorks configuration specially, since on VxWorks the
 330     # libraries are actually on the target board, not in the file
 331     # system.
 332     AC_LIBOBJ([basename])
 333     AC_LIBOBJ([getpagesize])
 334     AC_LIBOBJ([insque])
 335     AC_LIBOBJ([random])
 336     AC_LIBOBJ([strcasecmp])
 337     AC_LIBOBJ([strncasecmp])
 338     AC_LIBOBJ([strdup])
 339     AC_LIBOBJ([vfork])
 340     AC_LIBOBJ([waitpid])
 341     AC_LIBOBJ([vasprintf])
 342     for f in $funcs; do
 343       case "$f" in
 344         basename | getpagesize | insque | random | strcasecmp)
 345           ;;
 346         strncasecmp | strdup | vfork | waitpid | vasprintf)
 347           ;;
 348         *)
 349           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 350           AC_DEFINE_UNQUOTED($n)
 351           ;;
 352       esac
 353     done
 354
 355     # VxWorks doesn't provide any of the variables in $vars, so we
 356     # don't have to check them here.
 357
 358     # Of the functions in $checkfuncs, VxWorks only has strerror.
 359     AC_DEFINE_NOAUTOHEADER(HAVE_STRERROR)
 360
 361     setobjs=yes
 362     ;;
 363
 364   esac
 365 fi
 366
 367 if test -z "${setobjs}"; then
 368
 369   case "${host}" in
 370
 371   *-*-cygwin*)
 372     # The Cygwin library actually uses a couple of files from
 373     # libiberty when it is built.  If we are building a native
 374     # Cygwin, and we run the tests, we will appear to have these
 375     # files.  However, when we go on to build winsup, we will wind up
 376     # with a library which does not have the files, since they should
 377     # have come from libiberty.
 378
 379     # We handle this by removing the functions the winsup library
 380     # provides from our shell variables, so that they appear to be
 381     # missing.
 382
 383     # DJ - only if we're *building* cygwin, not just building *with* cygwin
 384
 385     if test -n "${with_target_subdir}"
 386     then
 387       funcs="`echo $funcs | sed -e 's/random//'`"
 388       AC_LIBOBJ([random])
 389       vars="`echo $vars | sed -e 's/sys_siglist//'`"
 390       checkfuncs="`echo $checkfuncs | sed -e 's/strsignal//' -e 's/psignal//'`"
 391     fi
 392     ;;
 393
 394   *-*-mingw32*)
 395     # Under mingw32, sys_nerr and sys_errlist exist, but they are
 396     # macros, so the test below won't find them.
 397     libiberty_cv_var_sys_nerr=yes
 398     libiberty_cv_var_sys_errlist=yes
 399     ;;
 400
 401   *-*-uwin*)
 402     # Under some versions of uwin, vfork is notoriously buggy and the test
 403     # can hang configure; on other versions, vfork exists just as a stub.
 404     # FIXME: This should be removed once vfork in uwin's runtime is fixed.
 405     ac_cv_func_vfork_works=no
 406     # Under uwin 2.0+, sys_nerr and sys_errlist exist, but they are
 407     # macros (actually, these are imported from a DLL, but the end effect
 408     # is the same), so the test below won't find them.
 409     libiberty_cv_var_sys_nerr=yes
 410     libiberty_cv_var_sys_errlist=yes
 411     ;;
 412
 413   *-*-*vms*)
 414     # Under VMS, vfork works very different than on Unix. The standard test
 415     # won't work, and it isn't easily adaptable. It makes more sense to
 416     # just force it.
 417     ac_cv_func_vfork_works=yes
 418     ;;
 419
 420   esac
 421
 422   # We haven't set the list of objects yet.  Use the standard autoconf
 423   # tests.  This will only work if the compiler works.
 424   AC_ISC_POSIX
 425   AC_REPLACE_FUNCS($funcs)
 426   libiberty_AC_FUNC_C_ALLOCA
 427   AC_FUNC_VFORK
 428   if test $ac_cv_func_vfork_works = no; then
 429     AC_LIBOBJ([vfork])
 430   fi
 431   # We only need _doprnt if we might use it to implement v*printf.
 432   if test $ac_cv_func_vprintf != yes \
 433      || test $ac_cv_func_vfprintf != yes \
 434      || test $ac_cv_func_vsprintf != yes; then
 435     AC_REPLACE_FUNCS(_doprnt)
 436   else
 437     AC_CHECK_FUNCS(_doprnt)
 438   fi
 439
 440   for v in $vars; do
 441     AC_MSG_CHECKING([for $v])
 442     AC_CACHE_VAL(libiberty_cv_var_$v,
 443       [AC_TRY_LINK([int *p;], [extern int $v []; p = $v;],
 444                    [eval "libiberty_cv_var_$v=yes"],
 445                    [eval "libiberty_cv_var_$v=no"])])
 446     if eval "test \"`echo '$libiberty_cv_var_'$v`\" = yes"; then
 447       AC_MSG_RESULT(yes)
 448       n=HAVE_`echo $v | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 449       AC_DEFINE_UNQUOTED($n)
 450     else
 451       AC_MSG_RESULT(no)
 452     fi
 453   done
 454
 455   # special check for _system_configuration because AIX <4.3.2 do not
 456   # contain the `physmem' member.
 457   AC_MSG_CHECKING([for external symbol _system_configuration])
 458   AC_TRY_COMPILE([#include <sys/systemcfg.h>],
 459                  [double x = _system_configuration.physmem;],
 460     [AC_MSG_RESULT([yes])
 461     AC_DEFINE(HAVE__SYSTEM_CONFIGURATION, 1,
 462               [Define if you have the _system_configuration variable.])],
 463     [AC_MSG_RESULT([no])])
 464
 465   AC_CHECK_FUNCS($checkfuncs)
 466   libiberty_NEED_DECLARATION(canonicalize_file_name)
 467 fi
 468
 469 # Figure out which version of pexecute to use.
 470 case "${host}" in
 471      *-*-mingw* | *-*-winnt*)   pexecute=pex-win32.o  ;;
 472      *-*-msdosdjgpp*)           pexecute=pex-djgpp.o  ;;
 473      *-*-msdos*)                pexecute=pex-msdos.o  ;;
 474      *-*-os2-emx*)              pexecute=pex-os2.o    ;;
 475      *)                         pexecute=pex-unix.o   ;;
 476 esac
 477 AC_SUBST(pexecute)
 478
 479 libiberty_AC_FUNC_STRNCMP
 480
 481 # Install a library built with a cross compiler in $(tooldir) rather
 482 # than $(libdir).
 483 if test -z "${with_cross_host}"; then
 484   INSTALL_DEST=libdir
 485 else
 486   INSTALL_DEST=tooldir
 487 fi
 488 AC_SUBST(INSTALL_DEST)
 489
 490 # We need multilib support, but only if configuring for the target.
 491 AC_OUTPUT(Makefile testsuite/Makefile,
 492 [test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 493 if test -n "$CONFIG_FILES"; then
 494   if test -n "${with_build_subdir}" || test -n "${with_target_subdir}"; then
 495     # FIXME: We shouldn't need to set ac_file
 496     ac_file=Makefile
 497     LD="${ORIGINAL_LD_FOR_MULTILIBS}"
 498     . ${libiberty_topdir}/config-ml.in
 499   fi
 500 fi],
 501 srcdir=${srcdir}
 502 host=${host}
 503 target=${target}
 504 with_target_subdir=${with_target_subdir}
 505 with_build_subdir=${with_build_subdir}
 506 with_multisubdir=${with_multisubdir}
 507 ac_configure_args="--enable-multilib ${ac_configure_args}"
 508 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 509 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
 510 libiberty_topdir=${libiberty_topdir}
 511 )