libstdc++-v3/configure.ac

   1 # Process this file with autoreconf to produce a configure script.
   2
   3 AC_INIT(package-unused, version-unused,, libstdc++)
   4 AC_CONFIG_SRCDIR(src/shared/hashtable-aux.cc)
   5 AC_CONFIG_HEADER(config.h)
   6
   7 # This works around the fact that libtool configuration may change LD
   8 # for this particular configuration, but some shells, instead of
   9 # keeping the changes in LD private, export them just because LD is
  10 # exported.  Only used at the end of this file.
  11 ### am handles this now?  ORIGINAL_LD_FOR_MULTILIBS=$LD
  12
  13 # Find the rest of the source tree framework.
  14 AM_ENABLE_MULTILIB(, ..)
  15
  16 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  17 #
  18 # You will slowly go insane if you do not grok the following fact:  when
  19 # building v3 as part of the compiler, the top-level /target/ becomes the
  20 # library's /host/.  configure then causes --target to default to --host,
  21 # exactly like any other package using autoconf.  Therefore, 'target' and
  22 # 'host' will always be the same.  This makes sense both for native and
  23 # cross compilers, just think about it for a little while.  :-)
  24 #
  25 # Also, if v3 is being configured as part of a cross compiler, the top-level
  26 # configure script will pass the "real" host as $with_cross_host.
  27 #
  28 # Do not delete or change the following two lines.  For why, see
  29 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  30 AC_CANONICAL_SYSTEM
  31 target_alias=${target_alias-$host_alias}
  32
  33 # Handy for debugging:
  34 #AC_MSG_NOTICE($build / $host / $target / $host_alias / $target_alias); sleep 5
  35
  36 if test "$build" != "$host"; then
  37   # We are being configured with some form of cross compiler.
  38   GLIBCXX_IS_NATIVE=false
  39   case "$host","$target" in
  40     # Darwin crosses can use the host system's libraries and headers,
  41     # because of the fat library support.  Of course, it must be the
  42     # same version of Darwin on both sides.  Allow the user to
  43     # just say --target=foo-darwin without a version number to mean
  44     # "the version on this system".
  45       *-*-darwin*,*-*-darwin*)
  46         hostos=`echo $host | sed 's/.*-darwin/darwin/'`
  47         targetos=`echo $target | sed 's/.*-darwin/darwin/'`
  48         if test $hostos = $targetos -o $targetos = darwin ; then
  49           GLIBCXX_IS_NATIVE=true
  50         fi
  51         ;;
  52
  53       *)
  54         GCC_NO_EXECUTABLES
  55         ;;
  56   esac
  57 else
  58   GLIBCXX_IS_NATIVE=true
  59 fi
  60
  61 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  62 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  63 #  1.x:  minimum required version
  64 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  65 #              of other PACKAGE_* variables will, however, and there's nothing
  66 #              we can do about that; they come from AC_INIT).
  67 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  68 #            file in the top srcdir, etc, etc), so stop complaining.
  69 #  no-dependencies:  turns off auto dependency generation (just for now)
  70 #  no-dist:  we don't want 'dist' and related rules.
  71 #  -Wall:  turns on all automake warnings...
  72 #  -Wno-portability:  ...except this one, since GNU make is now required.
  73 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dependencies no-dist -Wall -Wno-portability -Wno-override])
  74 AH_TEMPLATE(PACKAGE, [Name of package])
  75 AH_TEMPLATE(VERSION, [Version number of package])
  76
  77 # -fno-builtin must be present here so that a non-conflicting form of
  78 # std::exit can be guessed by AC_PROG_CXX, and used in later tests.
  79
  80 save_CXXFLAGS="$CXXFLAGS"
  81 CXXFLAGS="$CXXFLAGS -fno-builtin"
  82 AC_PROG_CC
  83 AC_PROG_CXX
  84 CXXFLAGS="$save_CXXFLAGS"
  85
  86 AC_SYS_LARGEFILE
  87
  88 # Runs configure.host, and assorted other critical bits.  Sets
  89 # up critical shell variables.
  90 GLIBCXX_CONFIGURE
  91
  92 # Libtool setup.
  93 if test "x${with_newlib}" != "xyes" && test "x${with_avrlibc}" != "xyes"; then
  94   AC_LIBTOOL_DLOPEN
  95 fi
  96 AM_PROG_LIBTOOL
  97 ACX_LT_HOST_FLAGS
  98 AC_SUBST(enable_shared)
  99 AC_SUBST(enable_static)
 100
 101 if test "$enable_vtable_verify" = yes; then
 102   predep_objects_CXX="${predep_objects_CXX} ${glibcxx_builddir}/../libgcc/vtv_start.o"
 103   postdep_objects_CXX="${postdep_objects_CXX} ${glibcxx_builddir}/../libgcc/vtv_end.o"
 104 fi
 105
 106
 107 # libtool variables for C++ shared and position-independent compiles.
 108 #
 109 # Use glibcxx_lt_pic_flag to designate the automake variable
 110 # used to encapsulate the default libtool approach to creating objects
 111 # with position-independent code. Default: -prefer-pic.
 112 #
 113 # Use glibcxx_compiler_shared_flag to designate a compile-time flags for
 114 # creating shared objects. Default: -D_GLIBCXX_SHARED.
 115 #
 116 # Use glibcxx_compiler_pic_flag to designate a compile-time flags for
 117 # creating position-independent objects. This varies with the target
 118 # hardware and operating system, but is often: -DPIC -fPIC.
 119 if test "$enable_shared" = yes; then
 120   glibcxx_lt_pic_flag="-prefer-pic"
 121   glibcxx_compiler_pic_flag="$lt_prog_compiler_pic_CXX"
 122   glibcxx_compiler_shared_flag="-D_GLIBCXX_SHARED"
 123
 124 else
 125   glibcxx_lt_pic_flag=
 126   glibcxx_compiler_pic_flag=
 127   glibcxx_compiler_shared_flag=
 128 fi
 129 AC_SUBST(glibcxx_lt_pic_flag)
 130 AC_SUBST(glibcxx_compiler_pic_flag)
 131 AC_SUBST(glibcxx_compiler_shared_flag)
 132
 133 # Override the libtool's pic_flag and pic_mode.
 134 # Do this step after AM_PROG_LIBTOOL, but before AC_OUTPUT.
 135 # NB: this impacts --with-pic and --without-pic.
 136 lt_prog_compiler_pic_CXX="$glibcxx_compiler_pic_flag $glibcxx_compiler_shared_flag"
 137 pic_mode='default'
 138
 139 # Eliminate -lstdc++ addition to postdeps for cross compiles.
 140 postdeps_CXX=`echo " $postdeps_CXX " | sed 's, -lstdc++ ,,g'`
 141
 142 # Possibly disable most of the library.
 143 ## TODO: Consider skipping unncessary tests altogether in this case, rather
 144 ## than just ignoring the results.  Faster /and/ more correct, win win.
 145 GLIBCXX_ENABLE_HOSTED
 146
 147 # Enable descriptive messages to standard output on termination.
 148 GLIBCXX_ENABLE_VERBOSE
 149
 150 # Enable compiler support that doesn't require linking.
 151 GLIBCXX_ENABLE_PCH($is_hosted)
 152 GLIBCXX_ENABLE_THREADS
 153 GLIBCXX_ENABLE_ATOMIC_BUILTINS
 154 GLIBCXX_ENABLE_LOCK_POLICY
 155 GLIBCXX_ENABLE_DECIMAL_FLOAT
 156 GLIBCXX_ENABLE_FLOAT128
 157 if test "$enable_float128" = yes; then
 158   port_specific_symbol_files="$port_specific_symbol_files \$(top_srcdir)/config/abi/pre/float128.ver"
 159 fi
 160
 161 # Checks for compiler support that doesn't require linking.
 162 GLIBCXX_CHECK_COMPILER_FEATURES
 163
 164 # Enable all the variable C++ runtime options that don't require linking.
 165 GLIBCXX_ENABLE_CSTDIO
 166 GLIBCXX_ENABLE_CLOCALE
 167 GLIBCXX_ENABLE_ALLOCATOR
 168 GLIBCXX_ENABLE_CHEADERS($c_model)  dnl c_model from configure.host
 169 GLIBCXX_ENABLE_LONG_LONG([yes])
 170 GLIBCXX_ENABLE_WCHAR_T([yes])
 171 GLIBCXX_ENABLE_C99([yes])
 172 GLIBCXX_ENABLE_CONCEPT_CHECKS([no])
 173 GLIBCXX_ENABLE_DEBUG_FLAGS(["-gdwarf-4 -g3 -O0 -D_GLIBCXX_ASSERTIONS"])
 174 GLIBCXX_ENABLE_DEBUG([no])
 175 GLIBCXX_ENABLE_PARALLEL([yes])
 176 GLIBCXX_ENABLE_CXX_FLAGS
 177 GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING([no])
 178 GLIBCXX_ENABLE_EXTERN_TEMPLATE([yes])
 179 GLIBCXX_ENABLE_PYTHON
 180 GLIBCXX_ENABLE_WERROR([no])
 181 GLIBCXX_ENABLE_VTABLE_VERIFY([no])
 182
 183 # Checks for operating systems support that doesn't require linking.
 184 GLIBCXX_CHECK_STDIO_PROTO
 185 GLIBCXX_CHECK_MATH11_PROTO
 186 GLIBCXX_CHECK_UCHAR_H
 187
 188 # For LFS support.
 189 GLIBCXX_CHECK_LFS
 190
 191 # For showmanyc_helper().
 192 AC_CHECK_HEADERS(sys/ioctl.h sys/filio.h)
 193 GLIBCXX_CHECK_POLL
 194 GLIBCXX_CHECK_S_ISREG_OR_S_IFREG
 195
 196 # For xsputn_2().
 197 AC_CHECK_HEADERS(sys/uio.h)
 198 GLIBCXX_CHECK_WRITEV
 199
 200 # Check for fenv.h and complex.h before GLIBCXX_CHECK_C99_TR1
 201 # so that the check is done with the C compiler (not C++).
 202 # Checking with C++ can break a canadian cross build if either
 203 # file does not exist in C but does in C++.
 204 AC_CHECK_HEADERS(fenv.h complex.h)
 205
 206 # For C99 support to TR1.
 207 GLIBCXX_CHECK_C99_TR1
 208
 209 # For the EOF, SEEK_CUR, and SEEK_END integer constants.
 210 GLIBCXX_COMPUTE_STDIO_INTEGER_CONSTANTS
 211
 212 # For gettimeofday support.
 213 GLIBCXX_CHECK_GETTIMEOFDAY
 214
 215 # For clock_gettime, nanosleep and sched_yield support.
 216 GLIBCXX_ENABLE_LIBSTDCXX_TIME
 217
 218 # Check for tmpnam which is obsolescent in POSIX.1-2008
 219 GLIBCXX_CHECK_TMPNAM
 220
 221 # For pthread_cond_clockwait
 222 GLIBCXX_CHECK_PTHREAD_COND_CLOCKWAIT
 223
 224 # For pthread_mutex_clocklock
 225 GLIBCXX_CHECK_PTHREAD_MUTEX_CLOCKLOCK
 226
 227 # For pthread_rwlock_clockrdlock and pthread_rwlock_clockwrlock
 228 GLIBCXX_CHECK_PTHREAD_RWLOCK_CLOCKLOCK
 229
 230 AC_LC_MESSAGES
 231
 232 # For hardware_concurrency
 233 AC_CHECK_HEADERS(sys/sysinfo.h)
 234 GLIBCXX_CHECK_GET_NPROCS
 235 AC_CHECK_HEADERS(unistd.h)
 236 GLIBCXX_CHECK_SC_NPROCESSORS_ONLN
 237 GLIBCXX_CHECK_SC_NPROC_ONLN
 238 GLIBCXX_CHECK_PTHREADS_NUM_PROCESSORS_NP
 239 GLIBCXX_CHECK_SYSCTL_HW_NCPU
 240 GLIBCXX_CHECK_SDT_H
 241
 242 # Check for available headers.
 243 AC_CHECK_HEADERS([endian.h execinfo.h float.h fp.h ieeefp.h inttypes.h \
 244 locale.h machine/endian.h machine/param.h nan.h stdint.h stdlib.h string.h \
 245 strings.h sys/ipc.h sys/isa_defs.h sys/machine.h sys/param.h \
 246 sys/resource.h sys/sem.h sys/stat.h sys/time.h sys/types.h unistd.h \
 247 wchar.h wctype.h linux/types.h])
 248
 249 AC_CHECK_HEADERS([linux/random.h], [], [],
 250 [[#ifdef HAVE_LINUX_TYPES_H
 251 # include <linux/types.h>
 252 #endif
 253 ]])
 254
 255 AC_CHECK_HEADERS([xlocale.h])
 256
 257 # Only do link tests if native. Else, hardcode.
 258 if $GLIBCXX_IS_NATIVE; then
 259
 260   # We can do more elaborate tests that assume a working linker.
 261   CANADIAN=no
 262
 263   GLIBCXX_CHECK_LINKER_FEATURES
 264   GLIBCXX_CHECK_MATH_SUPPORT
 265   GLIBCXX_CHECK_STDLIB_SUPPORT
 266
 267   # For /dev/random and /dev/urandom for std::random_device.
 268   GLIBCXX_CHECK_DEV_RANDOM
 269
 270   # For TLS support.
 271   GCC_CHECK_TLS
 272
 273   AC_CHECK_FUNCS(__cxa_thread_atexit_impl __cxa_thread_atexit)
 274   AC_CHECK_FUNCS(aligned_alloc posix_memalign memalign _aligned_malloc)
 275   AC_CHECK_FUNCS(_wfopen)
 276   AC_CHECK_FUNCS(secure_getenv)
 277
 278   # C11 functions for C++17 library
 279   AC_CHECK_FUNCS(timespec_get)
 280
 281   # For Networking TS.
 282   AC_CHECK_FUNCS(sockatmark)
 283
 284   # Non-standard functions used by C++17 std::from_chars
 285   AC_CHECK_FUNCS(uselocale)
 286
 287   # For iconv support.
 288   AM_ICONV
 289
 290 else
 291
 292   # This lets us hard-code the functionality we know we'll have in the cross
 293   # target environment.  "Let" is a sugar-coated word placed on an especially
 294   # dull and tedious hack, actually.
 295   #
 296   # Here's why GLIBCXX_CHECK_MATH_SUPPORT, and other autoconf macros
 297   # that involve linking, can't be used:
 298   #    "cannot open sim-crt0.o"
 299   #    "cannot open crt0.o"
 300   # etc.  All this is because there currently exists no unified, consistent
 301   # way for top level CC information to be passed down to target directories:
 302   # newlib includes, newlib linking info, libgloss versus newlib crt0.o, etc.
 303   # When all of that is done, all of this hokey, excessive AC_DEFINE junk for
 304   # crosses can be removed.
 305
 306   # If Canadian cross, then don't pick up tools from the build directory.
 307   # Used only in GLIBCXX_EXPORT_INCLUDES.
 308   if test -n "$with_cross_host" &&
 309      test x"$build_alias" != x"$with_cross_host" &&
 310      test x"$build" != x"$target";
 311   then
 312     CANADIAN=yes
 313   else
 314     CANADIAN=no
 315   fi
 316
 317   # Construct crosses by hand, eliminating bits that need ld...
 318   # GLIBCXX_CHECK_MATH_SUPPORT
 319
 320   # First, test for "known" system libraries.  We may be using newlib even
 321   # on a hosted environment.
 322   if test "x${with_newlib}" = "xyes"; then
 323     os_include_dir="os/newlib"
 324     AC_DEFINE(HAVE_HYPOT)
 325
 326     # GLIBCXX_CHECK_STDLIB_SUPPORT
 327     AC_DEFINE(HAVE_STRTOF)
 328
 329     AC_DEFINE(HAVE_ACOSF)
 330     AC_DEFINE(HAVE_ASINF)
 331     AC_DEFINE(HAVE_ATAN2F)
 332     AC_DEFINE(HAVE_ATANF)
 333     AC_DEFINE(HAVE_CEILF)
 334     AC_DEFINE(HAVE_COSF)
 335     AC_DEFINE(HAVE_COSHF)
 336     AC_DEFINE(HAVE_EXPF)
 337     AC_DEFINE(HAVE_FABSF)
 338     AC_DEFINE(HAVE_FLOORF)
 339     AC_DEFINE(HAVE_FMODF)
 340     AC_DEFINE(HAVE_FREXPF)
 341     AC_DEFINE(HAVE_LDEXPF)
 342     AC_DEFINE(HAVE_LOG10F)
 343     AC_DEFINE(HAVE_LOGF)
 344     AC_DEFINE(HAVE_MODFF)
 345     AC_DEFINE(HAVE_POWF)
 346     AC_DEFINE(HAVE_SINF)
 347     AC_DEFINE(HAVE_SINHF)
 348     AC_DEFINE(HAVE_SQRTF)
 349     AC_DEFINE(HAVE_TANF)
 350     AC_DEFINE(HAVE_TANHF)
 351
 352     AC_DEFINE(HAVE_ICONV)
 353     AC_DEFINE(HAVE_MEMALIGN)
 354   else
 355     GLIBCXX_CROSSCONFIG
 356   fi
 357
 358   # At some point, we should differentiate between architectures
 359   # like x86, which have long double versions, and alpha/powerpc/etc.,
 360   # which don't. For the time being, punt.
 361   if test x"long_double_math_on_this_cpu" = x"yes"; then
 362     AC_DEFINE(HAVE_ACOSL)
 363     AC_DEFINE(HAVE_ASINL)
 364     AC_DEFINE(HAVE_ATAN2L)
 365     AC_DEFINE(HAVE_ATANL)
 366     AC_DEFINE(HAVE_CEILL)
 367     AC_DEFINE(HAVE_COSL)
 368     AC_DEFINE(HAVE_COSHL)
 369     AC_DEFINE(HAVE_EXPL)
 370     AC_DEFINE(HAVE_FABSL)
 371     AC_DEFINE(HAVE_FLOORL)
 372     AC_DEFINE(HAVE_FMODL)
 373     AC_DEFINE(HAVE_FREXPL)
 374     AC_DEFINE(HAVE_LDEXPL)
 375     AC_DEFINE(HAVE_LOG10L)
 376     AC_DEFINE(HAVE_LOGL)
 377     AC_DEFINE(HAVE_MODFL)
 378     AC_DEFINE(HAVE_POWL)
 379     AC_DEFINE(HAVE_SINCOSL)
 380     AC_DEFINE(HAVE_SINL)
 381     AC_DEFINE(HAVE_SINHL)
 382     AC_DEFINE(HAVE_SQRTL)
 383     AC_DEFINE(HAVE_TANL)
 384     AC_DEFINE(HAVE_TANHL)
 385   fi
 386 fi
 387
 388 # Check for _Unwind_GetIPInfo.
 389 GCC_CHECK_UNWIND_GETIPINFO
 390
 391 GCC_LINUX_FUTEX([AC_DEFINE(HAVE_LINUX_FUTEX, 1, [Define if futex syscall is available.])])
 392
 393 GCC_HEADER_STDINT(include/gstdint.h)
 394
 395 GLIBCXX_ENABLE_SYMVERS([yes])
 396 AC_SUBST(libtool_VERSION)
 397
 398 GLIBCXX_ENABLE_LIBSTDCXX_VISIBILITY([yes])
 399
 400 GLIBCXX_ENABLE_LIBSTDCXX_DUAL_ABI([yes])
 401 GLIBCXX_DEFAULT_ABI
 402
 403 ac_ldbl_compat=no
 404 ac_ldbl_alt128_compat=no
 405 ac_ldbl_ieee128_default=no
 406 LONG_DOUBLE_COMPAT_FLAGS="-mlong-double-64"
 407 LONG_DOUBLE_128_FLAGS=
 408 LONG_DOUBLE_ALT128_COMPAT_FLAGS=
 409 case "$target" in
 410   powerpc*-*-linux* | \
 411   sparc*-*-linux* | \
 412   s390*-*-linux* | \
 413   alpha*-*-linux*)
 414   AC_TRY_COMPILE(, [
 415 #if !defined __LONG_DOUBLE_128__ || (defined(__sparc__) && defined(__arch64__))
 416 #error no need for long double compatibility
 417 #endif
 418   ], [ac_ldbl_compat=yes], [ac_ldbl_compat=no])
 419   if test "$ac_ldbl_compat" = yes; then
 420     AC_DEFINE([_GLIBCXX_LONG_DOUBLE_COMPAT],1,
 421               [Define if compatibility should be provided for -mlong-double-64.])
 422     port_specific_symbol_files="\$(top_srcdir)/config/os/gnu-linux/ldbl-extra.ver"
 423     case "$target" in
 424       powerpc*-*-linux*)
 425         LONG_DOUBLE_COMPAT_FLAGS="$LONG_DOUBLE_COMPAT_FLAGS -mno-gnu-attribute"
 426         # Check for IEEE128 support in libm:
 427         AC_CHECK_LIB(m, __frexpieee128,
 428                      [ac_ldbl_ieee128_in_libc=yes],
 429                      [ac_ldbl_ieee128_in_libc=no])
 430         if test $ac_ldbl_ieee128_in_libc = yes; then
 431           # Determine which long double format is the compiler's default:
 432           AC_TRY_COMPILE(, [
 433             #ifndef __LONG_DOUBLE_IEEE128__
 434             #error compiler defaults to ibm128
 435             #endif
 436           ], [ac_ldbl_ieee128_default=yes], [ac_ldbl_ieee128_default=no])
 437           # Library objects should use default long double format.
 438           if test "$ac_ldbl_ieee128_default" = yes; then
 439             LONG_DOUBLE_128_FLAGS="-mno-gnu-attribute"
 440             # Except for the ones that explicitly use these flags:
 441             LONG_DOUBLE_ALT128_COMPAT_FLAGS="-mabi=ibmlongdouble -mno-gnu-attribute -Wno-psabi"
 442           else
 443             LONG_DOUBLE_128_FLAGS="-mno-gnu-attribute"
 444             LONG_DOUBLE_ALT128_COMPAT_FLAGS="-mabi=ieeelongdouble -mno-gnu-attribute -Wno-psabi"
 445           fi
 446           AC_DEFINE([_GLIBCXX_LONG_DOUBLE_ALT128_COMPAT],1,
 447                 [Define if compatibility should be provided for alternative 128-bit long double formats.])
 448           port_specific_symbol_files="$port_specific_symbol_files \$(top_srcdir)/config/os/gnu-linux/ldbl-ieee128-extra.ver"
 449           ac_ldbl_alt128_compat=yes
 450         else
 451           ac_ldbl_alt128_compat=no
 452         fi
 453         ;;
 454     esac
 455   fi
 456 esac
 457 AC_SUBST(LONG_DOUBLE_COMPAT_FLAGS)
 458 AC_SUBST(LONG_DOUBLE_128_FLAGS)
 459 AC_SUBST(LONG_DOUBLE_ALT128_COMPAT_FLAGS)
 460 GLIBCXX_CONDITIONAL(GLIBCXX_LDBL_COMPAT, test $ac_ldbl_compat = yes)
 461 GLIBCXX_CONDITIONAL(GLIBCXX_LDBL_ALT128_COMPAT, test $ac_ldbl_alt128_compat = yes)
 462
 463 # Check if assembler supports disabling hardware capability support.
 464 GCC_CHECK_ASSEMBLER_HWCAP
 465
 466 # Check if assembler supports rdrand opcode.
 467 GLIBCXX_CHECK_X86_RDRAND
 468 # Check if assembler supports rdseed opcode.
 469 GLIBCXX_CHECK_X86_RDSEED
 470
 471 # Check for other random number APIs
 472 GLIBCXX_CHECK_GETENTROPY
 473 GLIBCXX_CHECK_ARC4RANDOM
 474
 475 # This depends on GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE.
 476 GLIBCXX_CONFIGURE_TESTSUITE
 477
 478 # For gthread support.  Depends on GLIBCXX_ENABLE_SYMVERS.
 479 GLIBCXX_CHECK_GTHREADS
 480
 481 # For Filesystem TS.
 482 AC_CHECK_HEADERS([fcntl.h dirent.h sys/statvfs.h utime.h])
 483 GLIBCXX_ENABLE_FILESYSTEM_TS
 484 GLIBCXX_CHECK_FILESYSTEM_DEPS
 485
 486 # For Networking TS.
 487 AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/socket.h sys/uio.h poll.h netdb.h arpa/inet.h netinet/in.h netinet/tcp.h])
 488 AC_CHECK_DECL(F_GETFL,,,[#include <fcntl.h>])
 489 AC_CHECK_DECL(F_SETFL,,,[#include <fcntl.h>])
 490 if test "$ac_cv_have_decl_F_GETFL$ac_cv_have_decl_F_SETFL" = yesyes ; then
 491   AC_CHECK_DECL(O_NONBLOCK,,,[#include <fcntl.h>])
 492 fi
 493
 494 # For Transactional Memory TS
 495 GLIBCXX_CHECK_SIZE_T_MANGLING
 496
 497 # Check which release added std::exception_ptr for the target
 498 GLIBCXX_CHECK_EXCEPTION_PTR_SYMVER
 499
 500 # Define documentation rules conditionally.
 501
 502 # See if makeinfo has been installed and is modern enough
 503 # that we can use it.
 504 ACX_CHECK_PROG_VER([MAKEINFO], [makeinfo], [--version],
 505                    [GNU texinfo.* \([0-9][0-9.]*\)],
 506                    [4.[4-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
 507 AM_CONDITIONAL(BUILD_INFO, test $gcc_cv_prog_makeinfo_modern = "yes")
 508
 509 # Check for doxygen
 510 AC_CHECK_PROG([DOXYGEN], doxygen, yes, no)
 511 AC_CHECK_PROG([DOT], dot, yes, no)
 512
 513 # Check for docbook
 514 AC_CHECK_PROG([XMLCATALOG], xmlcatalog, yes, no)
 515 AC_CHECK_PROG([XSLTPROC], xsltproc, yes, no)
 516 AC_CHECK_PROG([XMLLINT], xmllint, yes, no)
 517 GLIBCXX_CONFIGURE_DOCBOOK
 518
 519 # Check for xml/html dependencies.
 520 AM_CONDITIONAL(BUILD_XML,
 521                test $ac_cv_prog_DOXYGEN = "yes" &&
 522                test $ac_cv_prog_DOT = "yes" &&
 523                test $ac_cv_prog_XSLTPROC = "yes" &&
 524                test $ac_cv_prog_XMLLINT = "yes" &&
 525                test $glibcxx_stylesheets = "yes")
 526
 527 AM_CONDITIONAL(BUILD_HTML,
 528                test $ac_cv_prog_DOXYGEN = "yes" &&
 529                test $ac_cv_prog_DOT = "yes" &&
 530                test $ac_cv_prog_XSLTPROC = "yes" &&
 531                test $ac_cv_prog_XMLLINT = "yes" &&
 532                test $glibcxx_stylesheets = "yes")
 533
 534 # Check for man dependencies.
 535 AM_CONDITIONAL(BUILD_MAN,
 536                test $ac_cv_prog_DOXYGEN = "yes" &&
 537                test $ac_cv_prog_DOT = "yes")
 538
 539 # Check for pdf dependencies.
 540 AC_CHECK_PROG([DBLATEX], dblatex, yes, no)
 541 AC_CHECK_PROG([PDFLATEX], pdflatex, yes, no)
 542 AM_CONDITIONAL(BUILD_PDF,
 543                test $ac_cv_prog_DOXYGEN = "yes" &&
 544                test $ac_cv_prog_DOT = "yes" &&
 545                test $ac_cv_prog_XSLTPROC = "yes" &&
 546                test $ac_cv_prog_XMLLINT = "yes" &&
 547                test $ac_cv_prog_DBLATEX = "yes" &&
 548                test $ac_cv_prog_PDFLATEX = "yes")
 549
 550 case "$build" in
 551  *-*-darwin* ) glibcxx_include_dir_notparallel=yes ;;
 552  * ) glibcxx_include_dir_notparallel=no ;;
 553 esac
 554 AM_CONDITIONAL(INCLUDE_DIR_NOTPARALLEL,
 555                test $glibcxx_include_dir_notparallel = "yes")
 556
 557 # Propagate the target-specific source directories through the build chain.
 558 ATOMICITY_SRCDIR=config/${atomicity_dir}
 559 ATOMIC_WORD_SRCDIR=config/${atomic_word_dir}
 560 ATOMIC_FLAGS=${atomic_flags}
 561 CPU_DEFINES_SRCDIR=config/${cpu_defines_dir}
 562 OS_INC_SRCDIR=config/${os_include_dir}
 563 ERROR_CONSTANTS_SRCDIR=config/${error_constants_dir}
 564 ABI_TWEAKS_SRCDIR=config/${abi_tweaks_dir}
 565 CPU_OPT_EXT_RANDOM=config/${cpu_opt_ext_random}
 566 CPU_OPT_BITS_RANDOM=config/${cpu_opt_bits_random}
 567 AC_SUBST(ATOMICITY_SRCDIR)
 568 AC_SUBST(ATOMIC_WORD_SRCDIR)
 569 AC_SUBST(ATOMIC_FLAGS)
 570 AC_SUBST(CPU_DEFINES_SRCDIR)
 571 AC_SUBST(ABI_TWEAKS_SRCDIR)
 572 AC_SUBST(OS_INC_SRCDIR)
 573 AC_SUBST(ERROR_CONSTANTS_SRCDIR)
 574 AC_SUBST(CPU_OPT_EXT_RANDOM)
 575 AC_SUBST(CPU_OPT_BITS_RANDOM)
 576
 577 # Conditionalize the makefile for this target machine.
 578 tmake_file_=
 579 for f in ${tmake_file}
 580 do
 581         if test -f ${srcdir}/config/$f
 582         then
 583                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
 584         fi
 585 done
 586 tmake_file="${tmake_file_}"
 587 AC_SUBST(tmake_file)
 588
 589 # Add CET specific flags if Intel CET is enabled.
 590 GCC_CET_FLAGS(CET_FLAGS)
 591 EXTRA_CXX_FLAGS="$EXTRA_CXX_FLAGS $CET_FLAGS"
 592 EXTRA_CFLAGS="$EXTRA_CFLAGS $CET_FLAGS"
 593 AC_SUBST(EXTRA_CFLAGS)
 594 AC_SUBST(EXTRA_CXX_FLAGS)
 595
 596 # Determine cross-compile flags and AM_CONDITIONALs.
 597 #AC_SUBST(GLIBCXX_IS_NATIVE)
 598 #AM_CONDITIONAL(CANADIAN, test $CANADIAN = yes)
 599 GLIBCXX_EVALUATE_CONDITIONALS
 600
 601 AC_CACHE_SAVE
 602
 603 if test ${multilib} = yes; then
 604   multilib_arg="--enable-multilib"
 605 else
 606   multilib_arg=
 607 fi
 608
 609 # Export all the install information.
 610 GLIBCXX_EXPORT_INSTALL_INFO
 611
 612 # Export all the include and flag information to Makefiles.
 613 GLIBCXX_EXPORT_INCLUDES
 614 GLIBCXX_EXPORT_FLAGS
 615
 616 # Determine what GCC version number to use in filesystem paths.
 617 GCC_BASE_VER
 618
 619 dnl In autoconf 2.5x, AC_OUTPUT is replaced by four AC_CONFIG_* macros,
 620 dnl which can all be called multiple times as needed, plus one (different)
 621 dnl AC_OUTPUT macro.  This one lists the files to be created:
 622 AC_CONFIG_FILES(Makefile)
 623 AC_CONFIG_FILES([scripts/testsuite_flags],[chmod +x scripts/testsuite_flags])
 624 AC_CONFIG_FILES([scripts/extract_symvers],[chmod +x scripts/extract_symvers])
 625 AC_CONFIG_FILES([doc/xsl/customization.xsl])
 626
 627 # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 628 # that multilib installs will end up installed in the correct place.
 629 # The testsuite needs it for multilib-aware ABI baseline files.
 630 # To work around this not being passed down from config-ml.in ->
 631 # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 632 # append it here.  Only modify Makefiles that have just been created.
 633 #
 634 # Also, get rid of this simulated-VPATH thing that automake does.
 635 AC_CONFIG_FILES(AC_FOREACH([DIR], glibcxx_SUBDIRS, [DIR/Makefile ]),
 636   [cat > vpsed$$ << \_EOF
 637 s!`test -f '$<' || echo '$(srcdir)/'`!!
 638 _EOF
 639    sed -f vpsed$$ $ac_file > tmp$$
 640    mv tmp$$ $ac_file
 641    rm vpsed$$
 642    echo 'MULTISUBDIR =' >> $ac_file
 643    ml_norecursion=yes
 644    . ${multi_basedir}/config-ml.in
 645    AS_UNSET([ml_norecursion])
 646 ])
 647
 648 AC_CONFIG_COMMANDS([generate-headers],
 649   [(cd include && ${MAKE-make} pch_build= )])
 650
 651 dnl And this actually makes things happen:
 652 AC_OUTPUT