boehm-gc/configure.ac

   1 # Copyright (c) 1999, 2000, 2001, 2002, 2003, 2006 by Red Hat, Inc. All rights reserved.
   2 # Copyright 2004 Nathanael Nerode
   3 #
   4 # THIS MATERIAL IS PROVIDED AS IS, WITH ABSOLUTELY NO WARRANTY EXPRESSED
   5 # OR IMPLIED.  ANY USE IS AT YOUR OWN RISK.
   6 #
   7 # Permission is hereby granted to use or copy this program
   8 # for any purpose,  provided the above notices are retained on all copies.
   9 # Permission to modify the code and to distribute modified code is granted,
  10 # provided the above notices are retained, and a notice that the code was
  11 # modified is included with the above copyright notice.
  12 #
  13 # Original author: Tom Tromey
  14 # Modified by Nathanael Nerode
  15
  16 dnl Process this file with autoconf to produce configure.
  17
  18 AC_PREREQ(2.59)
  19 AC_INIT
  20 AC_CONFIG_SRCDIR(gcj_mlc.c)
  21 # This works around the fact that libtool configuration may change LD
  22 # for this particular configuration, but some shells, instead of
  23 # keeping the changes in LD private, export them just because LD is
  24 # exported.
  25 ORIGINAL_LD_FOR_MULTILIBS=$LD
  26
  27 AM_ENABLE_MULTILIB(, ..)
  28
  29 AC_CANONICAL_HOST
  30 AC_CANONICAL_TARGET
  31
  32 # Get the 'noncanonical' system names.
  33 ACX_NONCANONICAL_TARGET
  34
  35 # This works around an automake problem.
  36 mkinstalldirs="`cd $ac_aux_dir && ${PWDCMD-pwd}`/mkinstalldirs"
  37 AC_SUBST(mkinstalldirs)
  38
  39 AM_INIT_AUTOMAKE(gc, 6.6, no-define)
  40
  41 # The autoconf 2.5x version of the no-executables hack.
  42 GCC_NO_EXECUTABLES
  43
  44 # Yak.  We must force CC and CXX to /not/ be precious variables; otherwise
  45 # the wrong, non-multilib-adjusted value will be used in multilibs.
  46 # As a side effect, we have to subst CFLAGS and CXXFLAGS ourselves.
  47
  48 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
  49 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  50 AC_PROG_CC
  51 AC_PROG_CXX
  52 m4_rename([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  53
  54 AM_PROG_CC_C_O
  55
  56 AC_SUBST(CFLAGS)
  57 AC_SUBST(CXXFLAGS)
  58
  59 # Newer automakes demand CCAS and CCASFLAGS.
  60 : ${CCAS='$(CC)'}
  61 : ${CCASFLAGS='$(CFLAGS)'}
  62 AC_SUBST(CCAS)
  63 AC_SUBST(CCASFLAGS)
  64
  65 AC_CHECK_TOOL(AS, as)
  66 AC_CHECK_TOOL(AR, ar)
  67 AC_CHECK_TOOL(RANLIB, ranlib, :)
  68
  69 AC_PROG_INSTALL
  70
  71 AM_MAINTAINER_MODE
  72
  73 . ${srcdir}/configure.host
  74
  75 case ${gc_basedir} in
  76 /* | [A-Za-z]:[/\\]*) gc_flagbasedir=${gc_basedir} ;;
  77 *) gc_flagbasedir='$(top_builddir)/'${gc_basedir} ;;
  78 esac
  79
  80 gc_cflags="${gc_cflags} -Iinclude -I"'$(top_builddir)'"/./targ-include -I${gc_flagbasedir}/libc/include"
  81 case "${host}" in
  82   *-*-cygwin32*)
  83     gc_cflags="${gc_cflags} -I${gc_flagbasedir}/../winsup/include"
  84     ;;
  85 esac
  86
  87 dnl gc_cflags="${gc_cflags} -fno-builtin"
  88
  89 GC_CFLAGS=${gc_cflags}
  90 AC_SUBST(GC_CFLAGS)
  91
  92 AC_PROG_LIBTOOL
  93
  94 dnl We use these options to decide which functions to include.
  95 AC_ARG_WITH(target-subdir,
  96 [  --with-target-subdir=SUBDIR
  97                           configuring with a cross compiler])
  98 AC_ARG_WITH(cross-host,
  99 [  --with-cross-host=HOST  configuring with a cross compiler])
 100
 101 AC_MSG_CHECKING([for thread model used by GCC])
 102 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 103 if test -z "$THREADS"; then
 104    THREADS=no
 105 fi
 106 AC_MSG_RESULT([$THREADS])
 107
 108 AC_ARG_ENABLE(parallel-mark,
 109 [  --enable-parallel-mark       parallelize marking and free list construction],
 110    [case "$THREADS" in
 111       no | none | single)
 112         AC_MSG_ERROR([Parallel mark requires --enable-threads=x spec])
 113         ;;
 114     esac]
 115 )
 116
 117 AM_CPPFLAGS="-I`cd $srcdir && ${PWDCMD-pwd}`/include"
 118 THREADLIBS=
 119 case "$THREADS" in
 120  no | none | single)
 121     THREADS=none
 122     ;;
 123  posix | posix95 | pthreads)
 124     THREADS=posix
 125     THREADLIBS=-lpthread
 126     case "$host" in
 127      x86-*-linux* | ia64-*-linux* | i586-*-linux* | i686-*-linux* | x86_64-*-linux* | alpha-*-linux*)
 128         AC_DEFINE(GC_LINUX_THREADS,1,[support for Xavier Leroy's Linux threads])
 129         AC_DEFINE(_REENTRANT,1,[Use reentrant code])
 130         if test "${enable_parallel_mark}" = yes; then
 131           AC_DEFINE(PARALLEL_MARK,1,[allow the marker to run in multiple threads])
 132         fi
 133         AC_DEFINE(THREAD_LOCAL_ALLOC,1,[define GC_local_malloc() & GC_local_malloc_atomic()])
 134         ;;
 135      *-*-linux*)
 136         AC_DEFINE(GC_LINUX_THREADS,1)
 137         AC_DEFINE(_REENTRANT,1)
 138         ;;
 139      *-*-aix*)
 140         AC_DEFINE(GC_AIX_THREADS,1,[support AIX threads])
 141         AC_DEFINE(_REENTRANT,1)
 142         ;;
 143      *-*-hpux11*)
 144         AC_MSG_WARN("Only HP-UX 11 POSIX threads are supported.")
 145         AC_DEFINE(GC_HPUX_THREADS,1,[enables support for HP/UX 11 pthreads])
 146         AC_DEFINE(_POSIX_C_SOURCE,199506L,[POSIX version of C Source])
 147         if test "${enable_parallel_mark}" = yes; then
 148           AC_DEFINE(PARALLEL_MARK,1)
 149         fi
 150         AC_DEFINE(THREAD_LOCAL_ALLOC,1)
 151         THREADLIBS="-lpthread -lrt"
 152         # HPUX needs REENTRANT for the _r calls.
 153         AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 154         ;;
 155      *-*-hpux10*)
 156         AC_MSG_WARN("Only HP-UX 11 POSIX threads are supported.")
 157         ;;
 158       *-*-kfreebsd*-gnu)
 159        AC_DEFINE(GC_FREEBSD_THREADS)
 160        INCLUDES="$INCLUDES -pthread"
 161        THREADDLLIBS=-pthread
 162        AC_DEFINE(_REENTRANT)
 163          if test "${enable_parallel_mark}" = yes; then
 164          AC_DEFINE(PARALLEL_MARK)
 165        fi
 166        AC_DEFINE(THREAD_LOCAL_ALLOC)
 167        AC_DEFINE(USE_COMPILER_TLS, 1,[use tls for boehm])
 168                ;;
 169      *-*-freebsd*)
 170         AC_MSG_WARN("FreeBSD does not yet fully support threads with Boehm GC.")
 171         AC_DEFINE(GC_FREEBSD_THREADS,1,[support FreeBSD threads])
 172         AM_CPPFLAGS="$AM_CPPFLAGS -pthread"
 173         THREADLIBS=-pthread
 174         ;;
 175      *-*-solaris*)
 176         AC_DEFINE(GC_SOLARIS_THREADS,1,[support for Solaris (thr_) threads])
 177         AC_DEFINE(GC_SOLARIS_PTHREADS,1,[support for Solaris pthreads])
 178         ;;
 179      *-*-irix*)
 180         AC_DEFINE(GC_IRIX_THREADS,1,[support for Irix pthreads])
 181         ;;
 182      *-*-cygwin*)
 183         AC_DEFINE(GC_WIN32_THREADS,1,[support for win32 threads])
 184         ;;
 185      *-*-darwin*)
 186         AC_DEFINE(GC_DARWIN_THREADS,1,[support for Mac OS X pthreads])
 187         AC_DEFINE(THREAD_LOCAL_ALLOC,1)
 188         if test "${enable_parallel_mark}" = yes; then
 189           AC_DEFINE(PARALLEL_MARK,1)
 190         fi
 191         ;;
 192      *-*-osf*)
 193         AC_DEFINE(GC_OSF1_THREADS,1,[support for Tru64 pthreads])
 194         if test "${enable_parallel_mark}" = yes; then
 195           AC_DEFINE(PARALLEL_MARK,1)
 196           AC_DEFINE(THREAD_LOCAL_ALLOC,1)
 197           # May want to enable it in other cases, too.
 198           # Measurements havent yet been done.
 199         fi
 200         AM_CPPFLAGS="$AM_CPPFLAGS -pthread"
 201         THREADLIBS="-lpthread -lrt"
 202         ;;
 203     esac
 204     ;;
 205  win32)
 206     AC_DEFINE(GC_WIN32_THREADS,1)
 207     dnl Old wine getenv may not return NULL for missing entry.
 208     dnl Define EMPTY_GETENV_RESULTS here to work around the bug.
 209     ;;
 210  dgux386)
 211     THREADS=dgux386
 212 AC_MSG_RESULT($THREADLIBS)
 213     # Use pthread GCC  switch
 214     THREADLIBS=-pthread
 215     if test "${enable_parallel_mark}" = yes; then
 216         AC_DEFINE(PARALLEL_MARK,1)
 217     fi
 218     AC_DEFINE(THREAD_LOCAL_ALLOC,1)
 219     AC_DEFINE(GC_DGUX386_THREADS,1,[support for DB/UX on I386 threads])
 220     AC_DEFINE(DGUX_THREADS,1,[No description])
 221     # Enable _POSIX4A_DRAFT10_SOURCE with flag -pthread
 222     AM_CPPFLAGS="-pthread $AM_CPPFLAGS"
 223     ;;
 224  aix)
 225     THREADS=posix
 226     THREADLIBS=-lpthread
 227     AC_DEFINE(GC_AIX_THREADS,1)
 228     AC_DEFINE(_REENTRANT,1)
 229     ;;
 230  decosf1 | irix | mach | os2 | solaris | dce | vxworks)
 231     AC_MSG_ERROR(thread package $THREADS not yet supported)
 232     ;;
 233  *)
 234     AC_MSG_ERROR($THREADS is an unknown thread package)
 235     ;;
 236 esac
 237 AC_SUBST(THREADLIBS)
 238
 239 case "$host" in
 240    powerpc-*-darwin*)
 241       powerpc_darwin=true
 242       ;;
 243 esac
 244 AM_CONDITIONAL(POWERPC_DARWIN,test x$powerpc_darwin = xtrue)
 245
 246 # Darwin needs a few extra special tests to deal with variation in the
 247 # system headers.
 248 case "$host" in
 249   powerpc*-*-darwin*)
 250     AC_CHECK_MEMBER(ppc_thread_state_t.r0,
 251       AC_DEFINE(HAS_PPC_THREAD_STATE_R0,1,
 252         [ppc_thread_state_t has field r0]),,
 253       [#include <mach/thread_status.h>])
 254     AC_CHECK_MEMBER(ppc_thread_state_t.__r0,
 255       AC_DEFINE(HAS_PPC_THREAD_STATE___R0,1,dnl
 256         [ppc_thread_state_t has field __r0]),,
 257       [#include <mach/thread_status.h>])
 258     AC_CHECK_MEMBER(ppc_thread_state64_t.r0,
 259       AC_DEFINE(HAS_PPC_THREAD_STATE64_R0,1,dnl
 260         [ppc_thread_state64_t has field r0]),,
 261       [#include <mach/thread_status.h>])
 262     AC_CHECK_MEMBER(ppc_thread_state64_t.__r0,
 263       AC_DEFINE(HAS_PPC_THREAD_STATE64___R0,1,dnl
 264         [ppc_thread_state64_t has field __r0]),,
 265       [#include <mach/thread_status.h>])
 266     ;;
 267   i?86*-*-darwin*)
 268     AC_CHECK_MEMBER(x86_thread_state32_t.eax,
 269       AC_DEFINE(HAS_X86_THREAD_STATE32_EAX,1,dnl
 270         [x86_thread_state32_t has field eax]),,
 271       [#include <sys/cdefs.h>
 272       #include <mach/thread_status.h>])
 273     AC_CHECK_MEMBER(x86_thread_state32_t.__eax,
 274       AC_DEFINE(HAS_X86_THREAD_STATE32___EAX,1,dnl
 275         [x86_thread_state32_t has field __eax]),,
 276       [#include <sys/cdefs.h>
 277       #include <mach/thread_status.h>])
 278     ;;
 279   x86_64-*-darwin*)
 280     AC_CHECK_MEMBER(x86_thread_state64_t.rax,
 281       AC_DEFINE(HAS_X86_THREAD_STATE64_RAX,1,dnl
 282         [x86_thread_state64_t has field rax]),,
 283       [#include <sys/cdefs.h>
 284       #include <mach/thread_status.h>])
 285     AC_CHECK_MEMBER(x86_thread_state64_t.__rax,
 286       AC_DEFINE(HAS_X86_THREAD_STATE64___RAX,1,dnl
 287         [x86_thread_state64_t has field __rax]),,
 288       [#include <sys/cdefs.h>
 289       #include <mach/thread_status.h>])
 290      ;;
 291   *) ;;
 292 esac
 293
 294 # We never want libdl on darwin. It is a fake libdl that just ends up making
 295 # dyld calls anyway
 296 case "$host" in
 297   *-*-darwin*) ;;
 298   *)
 299     AC_CHECK_LIB(dl, dlopen, EXTRA_TEST_LIBS="$EXTRA_TEST_LIBS -ldl")
 300     ;;
 301 esac
 302
 303 # extra LD Flags which are required for targets
 304 case "${host}" in
 305   *-*-darwin*)
 306     extra_ldflags_libgc=-Wl,-single_module
 307     ;;
 308 esac
 309 AC_SUBST(extra_ldflags_libgc)
 310
 311 AC_SUBST(EXTRA_TEST_LIBS)
 312
 313 target_all=libgcjgc.la
 314 AC_SUBST(target_all)
 315
 316 dnl If the target is an eCos system, use the appropriate eCos
 317 dnl I/O routines.
 318 dnl FIXME: this should not be a local option but a global target
 319 dnl system; at present there is no eCos target.
 320 TARGET_ECOS="no"
 321 AC_ARG_WITH(ecos,
 322 [  --with-ecos             enable runtime eCos target support],
 323 TARGET_ECOS="$with_ecos"
 324 )
 325
 326 addobjs=
 327 addlibs=
 328 addincludes=
 329 addtests=
 330 case "$TARGET_ECOS" in
 331    no)
 332       ;;
 333    *)
 334       AC_DEFINE(ECOS,1,[Target is ECOS])
 335       AM_CPPFLAGS="${AM_CPPFLAGS} -I${TARGET_ECOS}/include"
 336       addobjs="$addobjs ecos.lo"
 337       ;;
 338 esac
 339
 340 if test "${enable_cplusplus}" = yes; then
 341       addincludes="$addincludes include/gc_cpp.h include/gc_allocator.h"
 342       addtests="$addtests test_cpp"
 343 fi
 344
 345 AM_CONDITIONAL(CPLUSPLUS, test "${enable_cplusplus}" = yes)
 346
 347 AC_SUBST(CXX)
 348
 349 AC_SUBST(AM_CPPFLAGS)
 350
 351 # Configuration of shared libraries
 352 #
 353 AC_MSG_CHECKING(whether to build shared libraries)
 354 AC_ENABLE_SHARED
 355
 356 case "$host" in
 357  alpha-*-openbsd*)
 358      enable_shared=no
 359      AC_MSG_RESULT(no)
 360      ;;
 361  *)
 362      AC_MSG_RESULT(yes)
 363      ;;
 364 esac
 365
 366 # Checks for pthreads functions
 367 #
 368 oldLIBS="$LIBS"
 369 LIBS="$LIBS $THREADLIBS"
 370 AC_CHECK_FUNCS([pthread_getattr_np])
 371 LIBS="$oldLIBS"
 372
 373 # Configuration of machine-dependent code
 374 #
 375 # Set NO_EXECUTE_PERMISSION by default because gcj already uses
 376 # ffi_closure_{alloc,free} which takes care of allocating trampolines
 377 # in executable memory.
 378 #
 379 AC_MSG_CHECKING(which machine-dependent code should be used)
 380 machdep=
 381 case "$host" in
 382  alpha*-*-openbsd*)
 383     machdep="alpha_mach_dep.lo"
 384     if test x"${ac_cv_lib_dl_dlopen}" != xyes ; then
 385        AC_MSG_WARN(OpenBSD/Alpha without dlopen(). Shared library support is disabled)
 386     fi
 387     ;;
 388  alpha*-*-linux*)
 389     machdep="alpha_mach_dep.lo"
 390     ;;
 391  i?86-*-solaris2.[[89]] | i?86-*-solaris2.1?)
 392     AC_DEFINE(SOLARIS25_PROC_VDB_BUG_FIXED,1,[PROC_VDB in Solaris 2.5 gives wrong values for dirty bits])
 393     ;;
 394  mipstx39-*-elf*)
 395     machdep="mips_ultrix_mach_dep.lo"
 396     AC_DEFINE(STACKBASE, __stackbase,[No description])
 397     AC_DEFINE(DATASTART_IS_ETEXT,1,[No description])
 398     ;;
 399  mips-dec-ultrix*)
 400     machdep="mips_ultrix_mach-dep.lo"
 401     ;;
 402  mips-nec-sysv*|mips-unknown-sysv*)
 403     ;;
 404  mips*-*-linux*)
 405     ;;
 406  mips-*-*)
 407     machdep="mips_sgi_mach_dep.lo"
 408     ;;
 409  sparc-*-netbsd*)
 410     machdep="sparc_netbsd_mach_dep.lo"
 411     ;;
 412  sparc-sun-solaris2.3)
 413     machdep="sparc_mach_dep.lo"
 414     AC_DEFINE(SUNOS53_SHARED_LIB,1,[Avoid Solaris 5.3 dynamic library bug])
 415     ;;
 416  sparc*-sun-solaris2.*)
 417     machdep="sparc_mach_dep.lo"
 418     ;;
 419  ia64-*-*)
 420     machdep="mach_dep.lo ia64_save_regs_in_stack.lo"
 421     ;;
 422 esac
 423 AC_DEFINE(NO_EXECUTE_PERMISSION,1,[cause some or all of the heap to not have execute permission])
 424 if test x"$machdep" = x; then
 425 AC_MSG_RESULT($machdep)
 426    machdep="mach_dep.lo"
 427 fi
 428 addobjs="$addobjs $machdep"
 429 AC_SUBST(addobjs)
 430 AC_SUBST(addincludes)
 431 AC_SUBST(addlibs)
 432 AC_SUBST(addtests)
 433
 434 #
 435 # Check for AViiON Machines running DGUX
 436 #
 437 AC_MSG_CHECKING(if host is AViiON running DGUX)
 438 ac_is_dgux=no
 439 AC_CHECK_HEADER(sys/dg_sys_info.h,
 440 [ac_is_dgux=yes;])
 441
 442 AC_MSG_RESULT($ac_is_dgux)
 443     ## :GOTCHA: we do not check anything but sys/dg_sys_info.h
 444 if test $ac_is_dgux = yes; then
 445     if test "$enable_full_debug" = "yes"; then
 446       CFLAGS="-g -mstandard -DDGUX -D_DGUX_SOURCE -Di386 -mno-legend -O2"
 447       CXXFLAGS="-g -mstandard -DDGUX -D_DGUX_SOURCE -Di386 -mno-legend -O2"
 448     else
 449       CFLAGS="-DDGUX -D_DGUX_SOURCE -Di386 -mno-legend -O2"
 450       CXXFLAGS="-DDGUX -D_DGUX_SOURCE -Di386 -mno-legend -O2"
 451     fi
 452     AC_SUBST(CFLAGS)
 453     AC_SUBST(CXXFLAGS)
 454 fi
 455
 456 dnl As of 4.13a2, the collector will not properly work on Solaris when
 457 dnl built with gcc and -O.  So we remove -O in the appropriate case.
 458 dnl Not needed anymore on Solaris.
 459 AC_MSG_CHECKING(whether Solaris gcc optimization fix is necessary)
 460 case "$host" in
 461  *aix*)
 462     if test "$GCC" = yes; then
 463        AC_MSG_RESULT(yes)
 464        new_CFLAGS=
 465        for i in $CFLAGS; do
 466           case "$i" in
 467            -O*)
 468               ;;
 469            *)
 470               new_CFLAGS="$new_CFLAGS $i"
 471               ;;
 472           esac
 473        done
 474        CFLAGS="$new_CFLAGS"
 475     else
 476        AC_MSG_RESULT(no)
 477     fi
 478     ;;
 479  *) AC_MSG_RESULT(no) ;;
 480 esac
 481
 482 dnl We need to override the top-level CFLAGS.  This is how we do it.
 483 MY_CFLAGS="$CFLAGS"
 484 AC_SUBST(MY_CFLAGS)
 485
 486 dnl Include defines that have become de facto standard.
 487 dnl ALL_INTERIOR_POINTERS can be overridden in startup code.
 488 AC_DEFINE(SILENT,1,[disables statistics printing])
 489 AC_DEFINE(NO_SIGNALS,1,[does not disable signals])
 490 AC_DEFINE(ALL_INTERIOR_POINTERS,1,[allows all pointers to the interior of objects to be recognized])
 491
 492 dnl By default, make the library as general as possible.
 493 AC_DEFINE(JAVA_FINALIZATION,1,[make it somewhat safer to finalize objects out of order])
 494 AC_DEFINE(GC_GCJ_SUPPORT,1,[include support for gcj])
 495 AC_DEFINE(ATOMIC_UNCOLLECTABLE,1,[include code for GC_malloc_atomic_uncollectable])
 496
 497 AC_ARG_ENABLE(gc-debug,
 498 [  --enable-gc-debug    include full support for pointer backtracing etc.],
 499 [ if test "$enable_gc_debug" = "yes"; then
 500     AC_MSG_WARN("Must define GC_DEBUG and use debug alloc. in clients.")
 501     AC_DEFINE(KEEP_BACK_PTRS,1,[Add code to save back pointers])
 502     AC_DEFINE(DBG_HDRS_ALL,1,[Make sure that all objects have debug headers])
 503     case $host in
 504       ia64-*-linux* )
 505         AC_DEFINE(MAKE_BACK_GRAPH,1,[Enable GC_PRINT_BACK_HEIGHT environment variable])
 506       ;;
 507       x86-*-linux* | i586-*-linux* | i686-*-linux* | x86_64-*-linux* )
 508         AC_DEFINE(MAKE_BACK_GRAPH,1)
 509         AC_MSG_WARN("Client must not use -fomit-frame-pointer.")
 510         AC_DEFINE(SAVE_CALL_COUNT, 8, [number of call frames saved with objects allocated through the debugging interface])
 511       ;;
 512       i[3456]86-*-dgux*)
 513         AC_DEFINE(MAKE_BACK_GRAPH,1)
 514       ;;
 515     esac
 516   fi])
 517
 518 if test "${gc_use_mmap}" = "yes"; then
 519   AC_DEFINE(USE_MMAP, 1, [use MMAP instead of sbrk to get new memory])
 520 fi
 521
 522 if test -n "$with_cross_host" &&
 523    test x"$with_cross_host" != x"no"; then
 524   toolexecdir='$(exec_prefix)/$(target_noncanonical)'
 525   toolexeclibdir='$(toolexecdir)/lib'
 526 else
 527   toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
 528   toolexeclibdir='$(libdir)'
 529 fi
 530 multi_os_directory=`$CC -print-multi-os-directory`
 531 case $multi_os_directory in
 532   .) ;; # Avoid trailing /.
 533   *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 534 esac
 535 AC_SUBST(toolexecdir)
 536 AC_SUBST(toolexeclibdir)
 537
 538 if test "${multilib}" = "yes"; then
 539   multilib_arg="--enable-multilib"
 540 else
 541   multilib_arg=
 542 fi
 543
 544 AC_CONFIG_HEADERS([include/gc_config.h include/gc_ext_config.h])
 545
 546 AC_CONFIG_FILES(Makefile include/Makefile)
 547 AC_OUTPUT