gcc/ada/libgnat/s-caun64.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                    GNAT RUN-TIME LIBRARY COMPONENTS                      --
   4 --                                                                          --
   5 --      S Y S T E M . C O M P A R E _ A R R A Y _ U N S I G N E D _ 6 4     --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2002-2023, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  17 --                                                                          --
  18 -- As a special exception under Section 7 of GPL version 3, you are granted --
  19 -- additional permissions described in the GCC Runtime Library Exception,   --
  20 -- version 3.1, as published by the Free Software Foundation.               --
  21 --                                                                          --
  22 -- You should have received a copy of the GNU General Public License and    --
  23 -- a copy of the GCC Runtime Library Exception along with this program;     --
  24 -- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
  25 -- <http://www.gnu.org/licenses/>.                                          --
  26 --                                                                          --
  27 -- GNAT was originally developed  by the GNAT team at  New York University. --
  28 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  29 --                                                                          --
  30 ------------------------------------------------------------------------------
  31
  32 with System.Address_Operations; use System.Address_Operations;
  33 with System.Storage_Elements;   use System.Storage_Elements;
  34
  35 with Ada.Unchecked_Conversion;
  36
  37 package body System.Compare_Array_Unsigned_64 is
  38
  39    type Word is mod 2 ** 64;
  40    --  Used to process operands by words
  41
  42    type Uword is new Word;
  43    for Uword'Alignment use 1;
  44    --  Used to process operands when unaligned
  45
  46    type WP is access Word;
  47    type UP is access Uword;
  48
  49    function W is new Ada.Unchecked_Conversion (Address, WP);
  50    function U is new Ada.Unchecked_Conversion (Address, UP);
  51
  52    -----------------------
  53    -- Compare_Array_U64 --
  54    -----------------------
  55
  56    pragma Annotate (Gnatcheck, Exempt_On, "Improper_Returns",
  57                     "early returns for performance");
  58
  59    function Compare_Array_U64
  60      (Left      : System.Address;
  61       Right     : System.Address;
  62       Left_Len  : Natural;
  63       Right_Len : Natural) return Integer
  64    is
  65       Clen : Natural := Natural'Min (Left_Len, Right_Len);
  66       --  Number of elements left to compare
  67
  68       L : Address := Left;
  69       R : Address := Right;
  70       --  Pointers to next elements to compare
  71
  72    begin
  73       --  Case of going by aligned double words
  74
  75       if ModA (OrA (Left, Right), 8) = 0 then
  76          while Clen /= 0 loop
  77             if W (L).all /= W (R).all then
  78                if W (L).all > W (R).all then
  79                   return +1;
  80                else
  81                   return -1;
  82                end if;
  83             end if;
  84
  85             Clen := Clen - 1;
  86             L := L + Storage_Offset (8);
  87             R := R + Storage_Offset (8);
  88          end loop;
  89
  90       --  Case of going by unaligned double words
  91
  92       else
  93          while Clen /= 0 loop
  94             if U (L).all /= U (R).all then
  95                if U (L).all > U (R).all then
  96                   return +1;
  97                else
  98                   return -1;
  99                end if;
 100             end if;
 101
 102             Clen := Clen - 1;
 103             L := L + Storage_Offset (8);
 104             R := R + Storage_Offset (8);
 105          end loop;
 106       end if;
 107
 108       --  Here if common section equal, result decided by lengths
 109
 110       if Left_Len = Right_Len then
 111          return 0;
 112       elsif Left_Len > Right_Len then
 113          return +1;
 114       else
 115          return -1;
 116       end if;
 117    end Compare_Array_U64;
 118
 119    pragma Annotate (Gnatcheck, Exempt_Off, "Improper_Returns");
 120 end System.Compare_Array_Unsigned_64;