gcc/ada/libgnat/s-casi64.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                    GNAT RUN-TIME LIBRARY COMPONENTS                      --
   4 --                                                                          --
   5 --        S Y S T E M . C O M P A R E _ A R R A Y _ S I G N E D _ 6 4       --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2002-2023, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  17 --                                                                          --
  18 -- As a special exception under Section 7 of GPL version 3, you are granted --
  19 -- additional permissions described in the GCC Runtime Library Exception,   --
  20 -- version 3.1, as published by the Free Software Foundation.               --
  21 --                                                                          --
  22 -- You should have received a copy of the GNU General Public License and    --
  23 -- a copy of the GCC Runtime Library Exception along with this program;     --
  24 -- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
  25 -- <http://www.gnu.org/licenses/>.                                          --
  26 --                                                                          --
  27 -- GNAT was originally developed  by the GNAT team at  New York University. --
  28 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  29 --                                                                          --
  30 ------------------------------------------------------------------------------
  31
  32 with System.Address_Operations; use System.Address_Operations;
  33 with System.Storage_Elements;   use System.Storage_Elements;
  34
  35 with Ada.Unchecked_Conversion;
  36
  37 package body System.Compare_Array_Signed_64 is
  38
  39    type Word is range -2**63 .. 2**63 - 1;
  40    for Word'Size use 64;
  41    --  Used to process operands by words
  42
  43    type Uword is new Word;
  44    for Uword'Alignment use 1;
  45    --  Used to process operands when unaligned
  46
  47    type WP is access Word;
  48    type UP is access Uword;
  49
  50    function W is new Ada.Unchecked_Conversion (Address, WP);
  51    function U is new Ada.Unchecked_Conversion (Address, UP);
  52
  53    -----------------------
  54    -- Compare_Array_S64 --
  55    -----------------------
  56
  57    pragma Annotate (Gnatcheck, Exempt_On, "Improper_Returns",
  58                     "early returns for performance");
  59
  60    function Compare_Array_S64
  61      (Left      : System.Address;
  62       Right     : System.Address;
  63       Left_Len  : Natural;
  64       Right_Len : Natural) return Integer
  65    is
  66       Clen : Natural := Natural'Min (Left_Len, Right_Len);
  67       --  Number of elements left to compare
  68
  69       L : Address := Left;
  70       R : Address := Right;
  71       --  Pointers to next elements to compare
  72
  73    begin
  74       --  Case of going by aligned double words
  75
  76       if ModA (OrA (Left, Right), 8) = 0 then
  77          while Clen /= 0 loop
  78             if W (L).all /= W (R).all then
  79                if W (L).all > W (R).all then
  80                   return +1;
  81                else
  82                   return -1;
  83                end if;
  84             end if;
  85
  86             Clen := Clen - 1;
  87             L := L + Storage_Offset (8);
  88             R := R + Storage_Offset (8);
  89          end loop;
  90
  91       --  Case of going by unaligned double words
  92
  93       else
  94          while Clen /= 0 loop
  95             if U (L).all /= U (R).all then
  96                if U (L).all > U (R).all then
  97                   return +1;
  98                else
  99                   return -1;
 100                end if;
 101             end if;
 102
 103             Clen := Clen - 1;
 104             L := L + Storage_Offset (8);
 105             R := R + Storage_Offset (8);
 106          end loop;
 107       end if;
 108
 109       --  Here if common section equal, result decided by lengths
 110
 111       if Left_Len = Right_Len then
 112          return 0;
 113       elsif Left_Len > Right_Len then
 114          return +1;
 115       else
 116          return -1;
 117       end if;
 118    end Compare_Array_S64;
 119
 120    pragma Annotate (Gnatcheck, Exempt_Off, "Improper_Returns");
 121 end System.Compare_Array_Signed_64;