gcc/ada/lib-sort.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             L I B . S O R T                              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2023, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with GNAT.Heap_Sort_G;
  27
  28 separate (Lib)
  29 procedure Sort (Tbl : in out Unit_Ref_Table) is
  30
  31    T : array (0 .. Integer (Tbl'Last - Tbl'First + 1)) of Unit_Number_Type;
  32    --  Actual sort is done on this copy of the array with 0's origin
  33    --  subscripts. Location 0 is used as a temporary by the sorting algorithm.
  34    --  Also the addressing of the table is more efficient with 0's origin,
  35    --  even though we have to copy Tbl back and forth.
  36
  37    function Lt_Uname (C1, C2 : Natural) return Boolean;
  38    --  Comparison routine for comparing Unames. Needed by the sorting routine
  39
  40    procedure Move_Uname (From : Natural; To : Natural);
  41    --  Move routine needed by the sorting routine below
  42
  43    package Sorting is new GNAT.Heap_Sort_G (Move_Uname, Lt_Uname);
  44
  45    --------------
  46    -- Lt_Uname --
  47    --------------
  48
  49    function Lt_Uname (C1, C2 : Natural) return Boolean is
  50    begin
  51       --  Preprocessing data and definition files are not sorted, they are
  52       --  at the bottom of the list. They are recognized because they are
  53       --  the only ones without a Unit_Name.
  54
  55       if Units.Table (T (C1)).Unit_Name = No_Unit_Name then
  56          return False;
  57
  58       elsif Units.Table (T (C2)).Unit_Name = No_Unit_Name then
  59          return True;
  60
  61       else
  62          return
  63            Uname_Lt
  64              (Units.Table (T (C1)).Unit_Name, Units.Table (T (C2)).Unit_Name);
  65       end if;
  66    end Lt_Uname;
  67
  68    ----------------
  69    -- Move_Uname --
  70    ----------------
  71
  72    procedure Move_Uname (From : Natural; To : Natural) is
  73    begin
  74       T (To) := T (From);
  75    end Move_Uname;
  76
  77 --  Start of processing for Sort
  78
  79 begin
  80    if T'Last > 0 then
  81       for I in 1 .. T'Last loop
  82          T (I) := Tbl (Int (I) - 1 + Tbl'First);
  83       end loop;
  84
  85       Sorting.Sort (T'Last);
  86
  87    --  Sort is complete, copy result back into place
  88
  89       for I in 1 .. T'Last loop
  90          Tbl (Int (I) - 1 + Tbl'First) := T (I);
  91       end loop;
  92    end if;
  93 end Sort;