libiberty/configure.ac

   1 dnl Process this file with autoconf to produce a configure script
   2
   3 AC_PREREQ(2.64)
   4 AC_INIT
   5 AC_CONFIG_SRCDIR([xmalloc.c])
   6
   7 # This works around the fact that libtool configuration may change LD
   8 # for this particular configuration, but some shells, instead of
   9 # keeping the changes in LD private, export them just because LD is
  10 # exported.  We don't use libtool yet, but some day we might, so...
  11 ORIGINAL_LD_FOR_MULTILIBS=$LD
  12
  13 dnl We use these options to decide which functions to include.
  14 AC_ARG_WITH(target-subdir,
  15 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory for target])
  16 AC_ARG_WITH(build-subdir,
  17 [  --with-build-subdir=SUBDIR       Configuring in a subdirectory for build])
  18 AC_ARG_WITH(cross-host,
  19 [  --with-cross-host=HOST           Configuring with a cross compiler])
  20 AC_ARG_WITH(newlib,
  21 [  --with-newlib                    Configuring with newlib])
  22
  23 if test "${srcdir}" = "."; then
  24   if test -n "${with_build_subdir}"; then
  25     libiberty_topdir="${srcdir}/../.."
  26     with_target_subdir=
  27   elif test -z "${with_target_subdir}"; then
  28     libiberty_topdir="${srcdir}/.."
  29   else
  30     if test "${with_target_subdir}" != "."; then
  31       libiberty_topdir="${srcdir}/${with_multisrctop}../.."
  32     else
  33       libiberty_topdir="${srcdir}/${with_multisrctop}.."
  34     fi
  35   fi
  36 else
  37   libiberty_topdir="${srcdir}/.."
  38 fi
  39 AC_SUBST(libiberty_topdir)
  40 AC_CONFIG_AUX_DIR($libiberty_topdir)
  41
  42 dnl Very limited version of automake's enable-maintainer-mode
  43
  44 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
  45   dnl maintainer-mode is disabled by default
  46   AC_ARG_ENABLE(maintainer-mode,
  47 [  --enable-maintainer-mode
  48                           enable make rules and dependencies not useful
  49                           (and sometimes confusing) to the casual installer],
  50       maintainer_mode=$enableval,
  51       maintainer_mode=no)
  52
  53 AC_MSG_RESULT($maintainer_mode)
  54
  55 if test "$maintainer_mode" = "yes"; then
  56   MAINT=''
  57   NOTMAINT='#'
  58 else
  59   MAINT='#'
  60   NOTMAINT=''
  61 fi
  62 AC_SUBST(MAINT)dnl
  63 AC_SUBST(NOTMAINT)dnl
  64
  65 # Do we have a single-tree copy of texinfo?  Even if we do, we can't
  66 # rely on it - libiberty is built before texinfo.
  67 AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo, )
  68 if test "x$MAKEINFO" = "x"; then
  69     MAKEINFO="@echo makeinfo missing; true"
  70     BUILD_INFO=
  71 else
  72     BUILD_INFO=info
  73     case "$MAKEINFO" in
  74       */missing\ makeinfo*)
  75         BUILD_INFO=
  76         AC_MSG_WARN([
  77 *** Makeinfo is missing. Info documentation will not be built.])
  78         ;;
  79       *)
  80         case x"`$MAKEINFO --version | grep 'GNU texinfo'`" in
  81           x*\ [[1-3]].* )
  82             MAKEINFO="@echo $MAKEINFO is too old, 4.0 or newer required; true"
  83             BUILD_INFO=
  84             AC_MSG_WARN([
  85 *** Makeinfo is too old. Info documentation will not be built.])
  86           ;;
  87         esac
  88         ;;
  89     esac
  90 fi
  91 AC_SUBST(MAKEINFO)
  92 AC_SUBST(BUILD_INFO)
  93
  94 AC_CHECK_PROG(PERL, perl, perl, )
  95 if test x"$PERL" = x""; then
  96   HAVE_PERL='#'
  97 else
  98   HAVE_PERL=''
  99 fi
 100 AC_SUBST(HAVE_PERL)
 101
 102 AC_CANONICAL_HOST
 103
 104 dnl When we start using automake:
 105 dnl AM_INIT_AUTOMAKE(libiberty, 1.0)
 106
 107 dnl These must be called before AM_PROG_LIBTOOL, because it may want
 108 dnl to call AC_CHECK_PROG.
 109 AC_CHECK_TOOL(AR, ar)
 110 AC_CHECK_TOOL(RANLIB, ranlib, :)
 111
 112 dnl When switching to automake, replace the following with AM_ENABLE_MULTILIB.
 113 # Add --enable-multilib to configure.
 114 # Default to --enable-multilib
 115 AC_ARG_ENABLE(multilib,
 116 [  --enable-multilib       build many library versions (default)],
 117 [case "$enableval" in
 118   yes) multilib=yes ;;
 119   no)  multilib=no ;;
 120   *)   AC_MSG_ERROR([bad value $enableval for multilib option]) ;;
 121  esac],
 122               [multilib=yes])
 123
 124 # Even if the default multilib is not a cross compilation,
 125 # it may be that some of the other multilibs are.
 126 if test $cross_compiling = no && test $multilib = yes \
 127    && test "x${with_multisubdir}" != x ; then
 128    cross_compiling=maybe
 129 fi
 130
 131 GCC_NO_EXECUTABLES
 132 AC_PROG_CC
 133 AC_SYS_LARGEFILE
 134 AC_PROG_CPP_WERROR
 135
 136 ACX_PROG_CC_WARNING_OPTS([-W -Wall -Wwrite-strings -Wc++-compat \
 137                           -Wstrict-prototypes], [ac_libiberty_warn_cflags])
 138 ACX_PROG_CC_WARNING_ALMOST_PEDANTIC([], [ac_libiberty_warn_cflags])
 139
 140 AC_PROG_CC_C_O
 141 # autoconf is lame and doesn't give us any substitution variable for this.
 142 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 143   NO_MINUS_C_MINUS_O=yes
 144 else
 145   OUTPUT_OPTION='-o $@'
 146 fi
 147 AC_SUBST(NO_MINUS_C_MINUS_O)
 148 AC_SUBST(OUTPUT_OPTION)
 149
 150 AC_C_CONST
 151 AC_C_INLINE
 152 AC_C_BIGENDIAN
 153
 154 dnl When we start using libtool:
 155 dnl Default to a non shared library.  This may be overridden by the
 156 dnl configure option --enable-shared.
 157 dnl AM_DISABLE_SHARED
 158
 159 dnl When we start using libtool:
 160 dnl AM_PROG_LIBTOOL
 161
 162 dnl When we start using automake:
 163 dnl AM_CONFIG_HEADER(config.h:config.in)
 164 AC_CONFIG_HEADER(config.h:config.in)
 165
 166 dnl When we start using automake:
 167 dnl AM_MAINTAINER_MODE
 168 dnl AC_EXEEXT
 169
 170 dnl When we start using automake:
 171 dnl AM_PROG_INSTALL
 172 AC_PROG_INSTALL
 173
 174 # Don't build the shared library for build.
 175 if [[ -n "${with_build_subdir}" ]]; then
 176   enable_shared=no
 177 fi
 178
 179 frag=
 180 case "${host}" in
 181   rs6000-ibm-aix3.1 | rs6000-ibm-aix)
 182                         frag=mh-aix ;;
 183   *-*-cxux7*)           frag=mh-cxux7 ;;
 184   *-*-freebsd2.1.*)     frag=mh-fbsd21 ;;
 185   *-*-freebsd2.2.[[012]])       frag=mh-fbsd21 ;;
 186   i370-*-opened*)       frag=mh-openedition ;;
 187   i[[34567]]86-*-windows*)      frag=mh-windows ;;
 188 esac
 189
 190 if [[ -n "${frag}" ]]; then
 191   frag=${libiberty_topdir}/libiberty/config/$frag
 192 fi
 193
 194 GCC_PICFLAG
 195
 196 # If they didn't specify --enable-shared, don't generate shared libs.
 197 case "${enable_shared}" in
 198   yes) shared=yes ;;
 199   no) shared=no ;;
 200   "") shared=no ;;
 201   *) shared=yes ;;
 202 esac
 203 if [[ "${shared}" != "yes" ]]; then
 204   PICFLAG=
 205 fi
 206 AC_SUBST(PICFLAG)
 207
 208 echo "# Warning: this fragment is automatically generated" > temp-frag
 209
 210 if [[ -n "${frag}" ]] && [[ -f "${frag}" ]]; then
 211   echo "Appending ${frag} to xhost-mkfrag"
 212   echo "# Following fragment copied from ${frag}" >> temp-frag
 213   cat ${frag} >> temp-frag
 214 fi
 215
 216 # record if we want to build shared libs.
 217 if [[ "${shared}" = "yes" ]]; then
 218   echo enable_shared = yes >> temp-frag
 219 else
 220   echo enable_shared = no >> temp-frag
 221 fi
 222
 223 frag=xhost-mkfrag
 224 ${CONFIG_SHELL-/bin/sh} ${libiberty_topdir}/move-if-change temp-frag xhost-mkfrag
 225
 226 host_makefile_frag=${frag}
 227 AC_SUBST_FILE(host_makefile_frag)
 228
 229 # It's OK to check for header files.  Although the compiler may not be
 230 # able to link anything, it had better be able to at least compile
 231 # something.
 232 AC_CHECK_HEADERS(sys/file.h sys/param.h limits.h stdlib.h malloc.h string.h unistd.h strings.h sys/time.h time.h sys/resource.h sys/stat.h sys/mman.h fcntl.h alloca.h sys/pstat.h sys/sysmp.h sys/sysinfo.h machine/hal_sysinfo.h sys/table.h sys/sysctl.h sys/systemcfg.h stdint.h stdio_ext.h process.h sys/prctl.h)
 233 AC_HEADER_SYS_WAIT
 234 AC_HEADER_TIME
 235
 236 libiberty_AC_DECLARE_ERRNO
 237
 238 # Determine the size of an int for struct fibnode.
 239 AC_CHECK_SIZEOF([int])
 240
 241 # Look for a 64-bit type.
 242 AC_MSG_CHECKING([for a 64-bit type])
 243 AC_CACHE_VAL(liberty_cv_uint64,
 244 [AC_TRY_COMPILE(
 245 [#ifdef HAVE_STDINT_H
 246 #include <stdint.h>
 247 #endif],
 248 [extern uint64_t foo;],
 249 liberty_cv_uint64=uint64_t,
 250 [AC_TRY_COMPILE(
 251 [#ifdef HAVE_LIMITS_H
 252 #include <limits.h>
 253 #endif
 254 #ifndef CHAR_BIT
 255 #define CHAR_BIT 8
 256 #endif],
 257 [extern char foo[sizeof(long) * CHAR_BIT >= 64 ? 1 : -1];],
 258 liberty_cv_uint64="unsigned long",
 259 [AC_TRY_COMPILE(
 260 [#ifdef HAVE_LIMITS_H
 261 #include <limits.h>
 262 #endif
 263 #ifndef CHAR_BIT
 264 #define CHAR_BIT 8
 265 #endif],
 266 [extern char foo[sizeof(long long) * CHAR_BIT >= 64 ? 1 : -1];],
 267 liberty_cv_uint64="unsigned long long", liberty_cv_uint64=none)])])])
 268 AC_MSG_RESULT($liberty_cv_uint64)
 269 if test "$liberty_cv_uint64" != none; then
 270   AC_DEFINE_UNQUOTED(UNSIGNED_64BIT_TYPE, $liberty_cv_uint64,
 271                      [Define to an unsigned 64-bit type available in the compiler.])
 272 fi
 273
 274 AC_TYPE_INTPTR_T
 275 AC_TYPE_UINTPTR_T
 276 AC_TYPE_SSIZE_T
 277
 278 # Given the above check, we always have uintptr_t or a fallback
 279 # definition.  So define HAVE_UINTPTR_T in case any imported code
 280 # relies on it.
 281 AC_DEFINE(HAVE_UINTPTR_T, 1, [Define if you have the \`uintptr_t' type.])
 282
 283 AC_TYPE_PID_T
 284
 285 # This is the list of functions which libiberty will provide if they
 286 # are not available on the host.
 287
 288 funcs="asprintf"
 289 funcs="$funcs atexit"
 290 funcs="$funcs basename"
 291 funcs="$funcs bcmp"
 292 funcs="$funcs bcopy"
 293 funcs="$funcs bsearch"
 294 funcs="$funcs bzero"
 295 funcs="$funcs calloc"
 296 funcs="$funcs clock"
 297 funcs="$funcs ffs"
 298 funcs="$funcs getcwd"
 299 funcs="$funcs getpagesize"
 300 funcs="$funcs gettimeofday"
 301 funcs="$funcs index"
 302 funcs="$funcs insque"
 303 funcs="$funcs memchr"
 304 funcs="$funcs memcmp"
 305 funcs="$funcs memcpy"
 306 funcs="$funcs memmem"
 307 funcs="$funcs memmove"
 308 funcs="$funcs mempcpy"
 309 funcs="$funcs memset"
 310 funcs="$funcs mkstemps"
 311 funcs="$funcs putenv"
 312 funcs="$funcs random"
 313 funcs="$funcs rename"
 314 funcs="$funcs rindex"
 315 funcs="$funcs setenv"
 316 funcs="$funcs snprintf"
 317 funcs="$funcs sigsetmask"
 318 funcs="$funcs stpcpy"
 319 funcs="$funcs stpncpy"
 320 funcs="$funcs strcasecmp"
 321 funcs="$funcs strchr"
 322 funcs="$funcs strdup"
 323 funcs="$funcs strncasecmp"
 324 funcs="$funcs strndup"
 325 funcs="$funcs strnlen"
 326 funcs="$funcs strrchr"
 327 funcs="$funcs strstr"
 328 funcs="$funcs strtod"
 329 funcs="$funcs strtol"
 330 funcs="$funcs strtoul"
 331 funcs="$funcs strverscmp"
 332 funcs="$funcs tmpnam"
 333 funcs="$funcs vasprintf"
 334 funcs="$funcs vfprintf"
 335 funcs="$funcs vprintf"
 336 funcs="$funcs vsnprintf"
 337 funcs="$funcs vsprintf"
 338 funcs="$funcs waitpid"
 339 funcs="$funcs setproctitle"
 340
 341 # Also in the old function.def file: alloca, vfork, getopt.
 342
 343 vars="sys_errlist sys_nerr sys_siglist"
 344
 345 checkfuncs="__fsetlocking canonicalize_file_name dup3 getrlimit getrusage \
 346  getsysinfo gettimeofday on_exit psignal pstat_getdynamic pstat_getstatic \
 347  realpath setrlimit sbrk spawnve spawnvpe strerror strsignal sysconf sysctl \
 348  sysmp table times wait3 wait4"
 349
 350 # These are neither executed nor required, but they help keep
 351 # autoheader happy without adding a bunch of text to acconfig.h.
 352 if test "x" = "y"; then
 353   AC_CHECK_FUNCS(asprintf atexit \
 354     basename bcmp bcopy bsearch bzero \
 355     calloc canonicalize_file_name clock \
 356     dup3 \
 357     ffs __fsetlocking \
 358     getcwd getpagesize getrlimit getrusage getsysinfo gettimeofday \
 359     index insque \
 360     memchr memcmp memcpy memmem memmove memset mkstemps \
 361     on_exit \
 362     psignal pstat_getdynamic pstat_getstatic putenv \
 363     random realpath rename rindex \
 364     sbrk setenv setproctitle setrlimit sigsetmask snprintf spawnve spawnvpe \
 365      stpcpy stpncpy strcasecmp strchr strdup \
 366      strerror strncasecmp strndup strnlen strrchr strsignal strstr strtod \
 367      strtol strtoul strverscmp sysconf sysctl sysmp \
 368     table times tmpnam \
 369     vasprintf vfprintf vprintf vsprintf \
 370     wait3 wait4 waitpid)
 371   AC_CHECK_DECLS([basename(char *), ffs, asprintf, vasprintf, snprintf, vsnprintf])
 372   AC_DEFINE(HAVE_SYS_ERRLIST, 1, [Define if you have the sys_errlist variable.])
 373   AC_DEFINE(HAVE_SYS_NERR,    1, [Define if you have the sys_nerr variable.])
 374   AC_DEFINE(HAVE_SYS_SIGLIST, 1, [Define if you have the sys_siglist variable.])
 375 fi
 376
 377 # For each of these functions, if the host does not provide the
 378 # function we want to put FN.o in LIBOBJS, and if the host does
 379 # provide the function, we want to define HAVE_FN in config.h.
 380
 381 setobjs=
 382 CHECK=
 383 target_header_dir=
 384 if test -n "${with_target_subdir}"; then
 385
 386   # We are being configured as a target library.  AC_REPLACE_FUNCS
 387   # may not work correctly, because the compiler may not be able to
 388   # link executables.  Note that we may still be being configured
 389   # native.
 390
 391   # If we are being configured for newlib, we know which functions
 392   # newlib provide and which ones we will be expected to provide.
 393
 394   if test "x${with_newlib}" = "xyes"; then
 395     AC_LIBOBJ([asprintf])
 396     AC_LIBOBJ([basename])
 397     AC_LIBOBJ([insque])
 398     AC_LIBOBJ([random])
 399     AC_LIBOBJ([strdup])
 400     AC_LIBOBJ([vasprintf])
 401
 402     for f in $funcs; do
 403       case "$f" in
 404         asprintf | basename | insque | random | strdup | vasprintf)
 405           ;;
 406         *)
 407           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 408           AC_DEFINE_UNQUOTED($n)
 409           ;;
 410       esac
 411     done
 412
 413     # newlib doesnt provide any of the variables in $vars, so we
 414     # dont have to check them here.
 415
 416     # Of the functions in $checkfuncs, newlib only has strerror.
 417     AC_DEFINE(HAVE_STRERROR)
 418
 419     setobjs=yes
 420
 421   fi
 422
 423   # If we are being configured for Mingw, we know which functions
 424   # Mingw provides and which ones we will be expected to provide.
 425
 426   case "${host}" in
 427   *-*-mingw*)
 428     AC_LIBOBJ([asprintf])
 429     AC_LIBOBJ([basename])
 430     AC_LIBOBJ([bcmp])
 431     AC_LIBOBJ([bcopy])
 432     AC_LIBOBJ([bzero])
 433     AC_LIBOBJ([clock])
 434     AC_LIBOBJ([ffs])
 435     AC_LIBOBJ([getpagesize])
 436     AC_LIBOBJ([index])
 437     AC_LIBOBJ([insque])
 438     AC_LIBOBJ([mempcpy])
 439     AC_LIBOBJ([mkstemps])
 440     AC_LIBOBJ([random])
 441     AC_LIBOBJ([rindex])
 442     AC_LIBOBJ([sigsetmask])
 443     AC_LIBOBJ([stpcpy])
 444     AC_LIBOBJ([stpncpy])
 445     AC_LIBOBJ([strndup])
 446     AC_LIBOBJ([strnlen])
 447     AC_LIBOBJ([strverscmp])
 448     AC_LIBOBJ([vasprintf])
 449     AC_LIBOBJ([waitpid])
 450
 451     for f in $funcs; do
 452       case "$f" in
 453         asprintf | basename | bcmp | bcopy | bzero | clock | ffs | getpagesize | index | insque | mempcpy | mkstemps | random | rindex | sigsetmask | stpcpy | stpncpy | strdup | strndup | strnlen | strverscmp | vasprintf | waitpid)
 454           ;;
 455         *)
 456           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 457           AC_DEFINE_UNQUOTED($n)
 458           ;;
 459       esac
 460     done
 461
 462     # Mingw doesnt provide any of the variables in $vars, so we
 463     # dont have to check them here.
 464
 465     # Of the functions in $checkfuncs, Mingw only has strerror.
 466     AC_DEFINE(HAVE_STRERROR)
 467
 468     setobjs=yes
 469     ;;
 470
 471   *-*-msdosdjgpp)
 472     AC_LIBOBJ([vasprintf])
 473     AC_LIBOBJ([vsnprintf])
 474     AC_LIBOBJ([snprintf])
 475     AC_LIBOBJ([asprintf])
 476
 477     for f in atexit basename bcmp bcopy bsearch bzero calloc clock ffs \
 478              getcwd getpagesize getrusage gettimeofday \
 479              index insque memchr memcmp memcpy memmove memset psignal \
 480              putenv random rename rindex sbrk setenv stpcpy strcasecmp \
 481              strchr strdup strerror strncasecmp strrchr strstr strtod \
 482              strtol strtoul sysconf times tmpnam vfprintf vprintf \
 483              vsprintf waitpid
 484     do
 485       n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 486       AC_DEFINE_UNQUOTED($n)
 487     done
 488
 489
 490     setobjs=yes
 491     ;;
 492
 493   esac
 494
 495   # We may wish to install the target headers somewhere.
 496   AC_ARG_ENABLE(install-libiberty,
 497   [  --enable-install-libiberty       Install headers for end users],
 498   enable_install_libiberty=$enableval,
 499   enable_install_libiberty=no)dnl
 500
 501   # Option parsed, now set things appropriately.
 502   case x"$enable_install_libiberty" in
 503     xyes|x)
 504       target_header_dir=libiberty
 505       ;;
 506     xno)
 507       target_header_dir=
 508       ;;
 509     *)
 510       # This could be sanity-checked in various ways...
 511       target_header_dir="${enable_install_libiberty}"
 512       ;;
 513   esac
 514
 515
 516 else
 517
 518    # Not a target library, so we set things up to run the test suite.
 519    CHECK=really-check
 520
 521 fi
 522
 523 AC_SUBST(CHECK)
 524 AC_SUBST(target_header_dir)
 525
 526 case "${host}" in
 527   *-*-cygwin* | *-*-mingw*)
 528     AC_DEFINE(HAVE_SYS_ERRLIST)
 529     AC_DEFINE(HAVE_SYS_NERR)
 530     ;;
 531 esac
 532
 533 if test -z "${setobjs}"; then
 534   case "${host}" in
 535
 536   *-*-vxworks*)
 537     # Handle VxWorks configuration specially, since on VxWorks the
 538     # libraries are actually on the target board, not in the file
 539     # system.
 540     AC_LIBOBJ([basename])
 541     AC_LIBOBJ([getpagesize])
 542     AC_LIBOBJ([insque])
 543     AC_LIBOBJ([random])
 544     AC_LIBOBJ([strcasecmp])
 545     AC_LIBOBJ([strncasecmp])
 546     AC_LIBOBJ([strdup])
 547     AC_LIBOBJ([vfork])
 548     AC_LIBOBJ([waitpid])
 549     AC_LIBOBJ([vasprintf])
 550     for f in $funcs; do
 551       case "$f" in
 552         basename | getpagesize | insque | random | strcasecmp)
 553           ;;
 554         strncasecmp | strdup | vfork | waitpid | vasprintf)
 555           ;;
 556         *)
 557           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 558           AC_DEFINE_UNQUOTED($n)
 559           ;;
 560       esac
 561     done
 562
 563     # VxWorks doesn't provide any of the variables in $vars, so we
 564     # don't have to check them here.
 565
 566     # Of the functions in $checkfuncs, VxWorks only has strerror.
 567     AC_DEFINE(HAVE_STRERROR)
 568
 569     setobjs=yes
 570     ;;
 571
 572   esac
 573 fi
 574
 575 if test -z "${setobjs}"; then
 576
 577   case "${host}" in
 578
 579   *-*-mingw32*)
 580     # Under mingw32, sys_nerr and sys_errlist exist, but they are
 581     # macros, so the test below won't find them.
 582     libiberty_cv_var_sys_nerr=yes
 583     libiberty_cv_var_sys_errlist=yes
 584     ;;
 585
 586   *-*-msdosdjgpp*)
 587     # vfork and fork are stubs.
 588     ac_cv_func_vfork_works=no
 589     ;;
 590
 591   *-*-uwin*)
 592     # Under some versions of uwin, vfork is notoriously buggy and the test
 593     # can hang configure; on other versions, vfork exists just as a stub.
 594     # FIXME: This should be removed once vfork in uwin's runtime is fixed.
 595     ac_cv_func_vfork_works=no
 596     # Under uwin 2.0+, sys_nerr and sys_errlist exist, but they are
 597     # macros (actually, these are imported from a DLL, but the end effect
 598     # is the same), so the test below won't find them.
 599     libiberty_cv_var_sys_nerr=yes
 600     libiberty_cv_var_sys_errlist=yes
 601     ;;
 602
 603   *-*-*vms*)
 604     # Under VMS, vfork works very different than on Unix. The standard test
 605     # won't work, and it isn't easily adaptable. It makes more sense to
 606     # just force it.
 607     ac_cv_func_vfork_works=yes
 608     ;;
 609
 610   esac
 611
 612   # We haven't set the list of objects yet.  Use the standard autoconf
 613   # tests.  This will only work if the compiler works.
 614   AC_ISC_POSIX
 615   AC_REPLACE_FUNCS($funcs)
 616   libiberty_AC_FUNC_C_ALLOCA
 617   AC_FUNC_FORK
 618   if test $ac_cv_func_vfork_works = no; then
 619     AC_LIBOBJ([vfork])
 620   fi
 621   # We only need _doprnt if we might use it to implement v*printf.
 622   if test $ac_cv_func_vprintf != yes \
 623      || test $ac_cv_func_vfprintf != yes \
 624      || test $ac_cv_func_vsprintf != yes; then
 625     AC_REPLACE_FUNCS(_doprnt)
 626   else
 627     AC_CHECK_FUNCS(_doprnt)
 628   fi
 629
 630   for v in $vars; do
 631     AC_MSG_CHECKING([for $v])
 632     AC_CACHE_VAL(libiberty_cv_var_$v,
 633       [AC_LINK_IFELSE([AC_LANG_PROGRAM([[int *p;]],[[extern int $v []; p = $v;]])],
 634                       [eval "libiberty_cv_var_$v=yes"],
 635                       [eval "libiberty_cv_var_$v=no"])])
 636     if eval "test \"`echo '$libiberty_cv_var_'$v`\" = yes"; then
 637       AC_MSG_RESULT(yes)
 638       n=HAVE_`echo $v | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 639       AC_DEFINE_UNQUOTED($n)
 640     else
 641       AC_MSG_RESULT(no)
 642     fi
 643   done
 644
 645   # special check for _system_configuration because AIX <4.3.2 do not
 646   # contain the `physmem' member.
 647   AC_MSG_CHECKING([for external symbol _system_configuration])
 648   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/systemcfg.h>]],
 649                         [[double x = _system_configuration.physmem;]])],
 650     [AC_MSG_RESULT([yes])
 651     AC_DEFINE(HAVE__SYSTEM_CONFIGURATION, 1,
 652               [Define if you have the _system_configuration variable.])],
 653     [AC_MSG_RESULT([no])])
 654
 655   AC_CHECK_FUNCS($checkfuncs)
 656   AC_CHECK_DECLS([basename(char *), ffs, asprintf, vasprintf, snprintf, vsnprintf])
 657   AC_CHECK_DECLS([calloc, getenv, getopt, malloc, realloc, sbrk])
 658   AC_CHECK_DECLS([strverscmp])
 659   libiberty_NEED_DECLARATION(canonicalize_file_name)
 660 fi
 661
 662 # Figure out which version of pexecute to use.
 663 case "${host}" in
 664      *-*-mingw* | *-*-winnt*)   pexecute=pex-win32  ;;
 665      *-*-msdosdjgpp*)           pexecute=pex-djgpp  ;;
 666      *-*-msdos*)                pexecute=pex-msdos  ;;
 667      *)                         pexecute=pex-unix   ;;
 668 esac
 669 AC_SUBST(pexecute)
 670
 671 libiberty_AC_FUNC_STRNCMP
 672
 673 # Install a library built with a cross compiler in $(tooldir) rather
 674 # than $(libdir).
 675 if test -z "${with_cross_host}"; then
 676   INSTALL_DEST=libdir
 677 else
 678   INSTALL_DEST=tooldir
 679 fi
 680 AC_SUBST(INSTALL_DEST)
 681
 682 m4_pattern_allow(LIBOBJS)
 683 L=""
 684 for l in x $LIBOBJS; do
 685   case $l in
 686     x) ;;
 687     *) L="$L ./$l" ;;
 688   esac
 689 done
 690 LIBOBJS="$L"
 691
 692 dnl Required by html and install-html
 693 AC_SUBST(datarootdir)
 694 AC_SUBST(docdir)
 695 AC_SUBST(htmldir)
 696
 697 # We need multilib support, but only if configuring for the target.
 698 AC_CONFIG_FILES([Makefile testsuite/Makefile])
 699 AC_CONFIG_COMMANDS([default],
 700   [[test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 701 if test -n "$CONFIG_FILES"; then
 702   if test -n "${with_target_subdir}"; then
 703     # FIXME: We shouldn't need to set ac_file
 704     ac_file=Makefile
 705     LD="${ORIGINAL_LD_FOR_MULTILIBS}"
 706     . ${libiberty_topdir}/config-ml.in
 707   fi
 708 fi]],
 709 [[srcdir=${srcdir}
 710 host=${host}
 711 target=${target}
 712 with_target_subdir=${with_target_subdir}
 713 with_multisubdir=${with_multisubdir}
 714 ac_configure_args="--enable-multilib ${ac_configure_args}"
 715 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 716 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
 717 libiberty_topdir=${libiberty_topdir}
 718 ]])
 719 AC_OUTPUT