libgo/configure.ac

   1 # configure.ac -- Go library configure script.
   2
   3 # Copyright 2009 The Go Authors. All rights reserved.
   4 # Use of this source code is governed by a BSD-style
   5 # license that can be found in the LICENSE file.
   6
   7 # Process this file with autoreconf to produce configure.
   8
   9 AC_PREREQ(2.64)
  10 AC_INIT(package-unused, version-unused,, libgo)
  11 AC_CONFIG_SRCDIR(Makefile.am)
  12 AC_CONFIG_HEADER(config.h)
  13
  14 libtool_VERSION=5:0:0
  15 AC_SUBST(libtool_VERSION)
  16
  17 AM_ENABLE_MULTILIB(, ..)
  18
  19 AC_CANONICAL_SYSTEM
  20 target_alias=${target_alias-$host_alias}
  21
  22 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dist -Wall -Wno-portability])
  23 AH_TEMPLATE(PACKAGE, [Name of package])
  24 AH_TEMPLATE(VERSION, [Version number of package])
  25
  26 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibgo_PRECIOUS])
  27 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  28 AC_PROG_CC
  29 AC_PROG_GO
  30 m4_rename_force([glibgo_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  31
  32 AC_SUBST(CFLAGS)
  33
  34 AM_MAINTAINER_MODE
  35
  36 AC_PROG_LD
  37 AC_PROG_RANLIB
  38 AC_CHECK_TOOL(OBJCOPY, objcopy, missing-objcopy)
  39
  40 AC_LIBTOOL_DLOPEN
  41 AM_PROG_LIBTOOL
  42 AC_SUBST(enable_shared)
  43 AC_SUBST(enable_static)
  44
  45 CC_FOR_BUILD=${CC_FOR_BUILD:-gcc}
  46 AC_SUBST(CC_FOR_BUILD)
  47
  48 AC_PROG_AWK
  49
  50 WARN_FLAGS='-Wall -Wextra -Wwrite-strings -Wcast-qual'
  51 AC_SUBST(WARN_FLAGS)
  52
  53 AC_ARG_ENABLE(werror, [AS_HELP_STRING([--enable-werror],
  54                                       [turns on -Werror @<:@default=yes@:>@])])
  55 if test "x$enable_werror" != "xno"; then
  56   WERROR="-Werror"
  57 fi
  58 AC_SUBST(WERROR)
  59
  60 glibgo_toolexecdir=no
  61 glibgo_toolexeclibdir=no
  62
  63 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  64 AC_ARG_ENABLE([version-specific-runtime-libs],
  65   AC_HELP_STRING([--enable-version-specific-runtime-libs],
  66                  [Specify that runtime libraries should be installed in a compiler-specific directory]),
  67   [case "$enableval" in
  68     yes) version_specific_libs=yes ;;
  69     no)  version_specific_libs=no ;;
  70     *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  71    esac],
  72   [version_specific_libs=no])
  73 AC_MSG_RESULT($version_specific_libs)
  74
  75 # Version-specific runtime libs processing.
  76 if test $version_specific_libs = yes; then
  77   glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
  78   glibgo_toolexeclibdir='${toolexecdir}/${gcc_version}$(MULTISUBDIR)'
  79 fi
  80
  81 # Calculate glibgo_toolexecdir, glibgo_toolexeclibdir
  82 # Install a library built with a cross compiler in tooldir, not libdir.
  83 if test -n "$with_cross_host" &&
  84    test x"$with_cross_host" != x"no"; then
  85   nover_glibgo_toolexecdir='${exec_prefix}/${host_alias}'
  86   nover_glibgo_toolexeclibdir='${toolexecdir}/lib'
  87 else
  88   nover_glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
  89   nover_glibgo_toolexeclibdir='${libdir}'
  90 fi
  91 multi_os_directory=`$CC -print-multi-os-directory`
  92 case $multi_os_directory in
  93   .) ;; # Avoid trailing /.
  94   *) nover_glibgo_toolexeclibdir=${nover_glibgo_toolexeclibdir}/${multi_os_directory} ;;
  95 esac
  96
  97 if test x"$glibgo_toolexecdir" = x"no"; then
  98   glibgo_toolexecdir="${nover_glibgo_toolexecdir}"
  99   glibgo_toolexeclibdir="${nover_glibgo_toolexeclibdir}"
 100 fi
 101
 102 AC_SUBST(glibgo_toolexecdir)
 103 AC_SUBST(glibgo_toolexeclibdir)
 104 AC_SUBST(nover_glibgo_toolexeclibdir)
 105
 106 # See if the user wants to configure without libffi.  Some
 107 # architectures don't support it.  FIXME: We should set a default
 108 # based on the host.
 109 AC_ARG_WITH(libffi,
 110   AS_HELP_STRING([--without-libffi],
 111                  [don't use libffi]),
 112   [:],
 113   [with_libffi=${with_libffi_default-yes}])
 114
 115 LIBFFI=
 116 LIBFFIINCS=
 117 if test "$with_libffi" != no; then
 118    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 119    LIBFFI=../libffi/libffi_convenience.la
 120    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 121 fi
 122 AC_SUBST(LIBFFI)
 123 AC_SUBST(LIBFFIINCS)
 124
 125 # Used to tell GNU make to include a file without telling automake to
 126 # include it.
 127 go_include="-include"
 128 AC_SUBST(go_include)
 129
 130 is_darwin=no
 131 is_freebsd=no
 132 is_irix=no
 133 is_linux=no
 134 is_netbsd=no
 135 is_openbsd=no
 136 is_dragonfly=no
 137 is_rtems=no
 138 is_solaris=no
 139 GOOS=unknown
 140 case ${host} in
 141   *-*-darwin*)   is_darwin=yes;  GOOS=darwin ;;
 142   *-*-freebsd*)  is_freebsd=yes; GOOS=freebsd ;;
 143   *-*-irix6*)    is_irix=yes;    GOOS=irix ;;
 144   *-*-linux*)    is_linux=yes;   GOOS=linux ;;
 145   *-*-netbsd*)   is_netbsd=yes;  GOOS=netbsd ;;
 146   *-*-openbsd*)  is_openbsd=yes; GOOS=openbsd ;;
 147   *-*-dragonfly*) is_dragonfly=yes; GOOS=dragonfly ;;
 148   *-*-rtems*)    is_rtems=yes;   GOOS=rtems ;;
 149   *-*-solaris2*) is_solaris=yes; GOOS=solaris ;;
 150 esac
 151 AM_CONDITIONAL(LIBGO_IS_DARWIN, test $is_darwin = yes)
 152 AM_CONDITIONAL(LIBGO_IS_FREEBSD, test $is_freebsd = yes)
 153 AM_CONDITIONAL(LIBGO_IS_IRIX, test $is_irix = yes)
 154 AM_CONDITIONAL(LIBGO_IS_LINUX, test $is_linux = yes)
 155 AM_CONDITIONAL(LIBGO_IS_NETBSD, test $is_netbsd = yes)
 156 AM_CONDITIONAL(LIBGO_IS_OPENBSD, test $is_openbsd = yes)
 157 AM_CONDITIONAL(LIBGO_IS_DRAGONFLY, test $is_dragonfly = yes)
 158 AM_CONDITIONAL(LIBGO_IS_RTEMS, test $is_rtems = yes)
 159 AM_CONDITIONAL(LIBGO_IS_SOLARIS, test $is_solaris = yes)
 160 AC_SUBST(GOOS)
 161
 162 dnl Test whether we need to use DejaGNU or whether we can use the
 163 dnl simpler gotest approach.  We can only use gotest for a native
 164 dnl build.
 165 USE_DEJAGNU=no
 166 case ${host} in
 167   *-*-rtems*) USE_DEJAGNU=yes ;;
 168   ${build}) ;;
 169   *) USE_DEJAGNU=yes ;;
 170 esac
 171 AC_SUBST(USE_DEJAGNU)
 172
 173 dnl N.B. Keep in sync with gcc/testsuite/go.test/go-test.exp (go-set-goarch).
 174 is_386=no
 175 is_alpha=no
 176 is_arm=no
 177 is_m68k=no
 178 mips_abi=unknown
 179 is_ppc=no
 180 is_ppc64=no
 181 is_sparc=no
 182 is_sparc64=no
 183 is_x86_64=no
 184 GOARCH=unknown
 185 case ${host} in
 186   alpha*-*-*)
 187     is_alpha=yes
 188     GOARCH=alpha
 189     ;;
 190   arm*-*-* | strongarm*-*-* | ep9312*-*-* | xscale-*-*)
 191     is_arm=yes
 192     GOARCH=arm
 193     ;;
 194 changequote(,)dnl
 195   i[34567]86-*-* | x86_64-*-*)
 196 changequote([,])dnl
 197     AC_COMPILE_IFELSE([
 198 #ifdef __x86_64__
 199 #error 64-bit
 200 #endif],
 201 [is_386=yes], [is_x86_64=yes])
 202     if test "$is_386" = "yes"; then
 203       GOARCH=386
 204     else
 205       GOARCH=amd64
 206     fi
 207     ;;
 208   m68k*-*-*)
 209     is_m68k=yes
 210     GOARCH=m68k
 211     ;;
 212   mips*-*-*)
 213     AC_COMPILE_IFELSE([
 214 #if _MIPS_SIM != _ABIO32
 215 #error not o32
 216 #endif],
 217 [mips_abi="o32"],
 218         [AC_COMPILE_IFELSE([
 219 #if _MIPS_SIM != _ABIN32
 220 #error not n32
 221 #endif],
 222 [mips_abi="n32"],
 223         [AC_COMPILE_IFELSE([
 224 #if _MIPS_SIM != _ABI64
 225 #error not n64
 226 #endif],
 227 [mips_abi="n64"],
 228         [AC_COMPILE_IFELSE([
 229 #if _MIPS_SIM != _ABIO64
 230 #error not o64
 231 #endif],
 232 [mips_abi="o64"],
 233         [AC_MSG_ERROR([unknown MIPS ABI])
 234 [mips_abi="n32"]])])])])
 235     case "$mips_abi" in
 236     "o32") GOARCH=mipso32 ;;
 237     "n32") GOARCH=mipsn32 ;;
 238     "n64") GOARCH=mipsn64 ;;
 239     "o64") GOARCH=mipso64 ;;
 240     esac
 241     ;;
 242   rs6000*-*-* | powerpc*-*-*)
 243     AC_COMPILE_IFELSE([
 244 #ifdef _ARCH_PPC64
 245 #error 64-bit
 246 #endif],
 247 [is_ppc=yes], [is_ppc64=yes])
 248     if test "$is_ppc" = "yes"; then
 249       GOARCH=ppc
 250     else
 251       GOARCH=ppc64
 252     fi
 253     ;;
 254   sparc*-*-*)
 255     AC_COMPILE_IFELSE([
 256 #if defined(__sparcv9) || defined(__arch64__)
 257 #error 64-bit
 258 #endif],
 259 [is_sparc=yes], [is_sparc64=yes])
 260     if test "$is_sparc" = "yes"; then
 261       GOARCH=sparc
 262     else
 263       GOARCH=sparc64
 264     fi
 265     ;;
 266 esac
 267 AM_CONDITIONAL(LIBGO_IS_386, test $is_386 = yes)
 268 AM_CONDITIONAL(LIBGO_IS_ALPHA, test $is_alpha = yes)
 269 AM_CONDITIONAL(LIBGO_IS_ARM, test $is_arm = yes)
 270 AM_CONDITIONAL(LIBGO_IS_M68K, test $is_m68k = yes)
 271 AM_CONDITIONAL(LIBGO_IS_MIPS, test $mips_abi != unknown)
 272 AM_CONDITIONAL(LIBGO_IS_MIPSO32, test $mips_abi = o32)
 273 AM_CONDITIONAL(LIBGO_IS_MIPSN32, test $mips_abi = n32)
 274 AM_CONDITIONAL(LIBGO_IS_MIPSN64, test $mips_abi = n64)
 275 AM_CONDITIONAL(LIBGO_IS_MIPSO64, test $mips_abi = o64)
 276 AM_CONDITIONAL(LIBGO_IS_PPC, test $is_ppc = yes)
 277 AM_CONDITIONAL(LIBGO_IS_PPC64, test $is_ppc64 = yes)
 278 AM_CONDITIONAL(LIBGO_IS_SPARC, test $is_sparc = yes)
 279 AM_CONDITIONAL(LIBGO_IS_SPARC64, test $is_sparc64 = yes)
 280 AM_CONDITIONAL(LIBGO_IS_X86_64, test $is_x86_64 = yes)
 281 AC_SUBST(GOARCH)
 282
 283 dnl Some files are only present when needed for specific architectures.
 284 GO_LIBCALL_OS_FILE=
 285 GO_LIBCALL_OS_ARCH_FILE=
 286 GO_SYSCALL_OS_FILE=
 287 GO_SYSCALL_OS_ARCH_FILE=
 288 if test -f ${srcdir}/go/syscall/libcall_${GOOS}.go; then
 289   GO_LIBCALL_OS_FILE=go/syscall/libcall_${GOOS}.go
 290 fi
 291 if test -f ${srcdir}/go/syscall/libcall_${GOOS}_${GOARCH}.go; then
 292   GO_LIBCALL_OS_ARCH_FILE=go/syscall/libcall_${GOOS}_${GOARCH}.go
 293 fi
 294 if test -f ${srcdir}/go/syscall/syscall_${GOOS}.go; then
 295   GO_SYSCALL_OS_FILE=go/syscall/syscall_${GOOS}.go
 296 fi
 297 if test -f ${srcdir}/go/syscall/syscall_${GOOS}_${GOARCH}.go; then
 298   GO_SYSCALL_OS_ARCH_FILE=go/syscall/syscall_${GOOS}_${GOARCH}.go
 299 fi
 300 AC_SUBST(GO_LIBCALL_OS_FILE)
 301 AC_SUBST(GO_LIBCALL_OS_ARCH_FILE)
 302 AC_SUBST(GO_SYSCALL_OS_FILE)
 303 AC_SUBST(GO_SYSCALL_OS_ARCH_FILE)
 304
 305 dnl Special flags used to generate sysinfo.go.
 306 OSCFLAGS="-D_GNU_SOURCE -D_LARGEFILE_SOURCE -D_FILE_OFFSET_BITS=64"
 307 case "$target" in
 308     mips-sgi-irix6.5*)
 309         # IRIX 6 needs _XOPEN_SOURCE=500 for the XPG5 version of struct
 310         # msghdr in <sys/socket.h>.
 311         OSCFLAGS="$OSCFLAGS -D_XOPEN_SOURCE=500"
 312         ;;
 313     *-*-solaris2.[[89]])
 314         # Solaris 8/9 need this so struct msghdr gets the msg_control
 315         # etc. fields in <sys/socket.h> (_XPG4_2).
 316         OSCFLAGS="$OSCFLAGS -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D__EXTENSIONS__"
 317         ;;
 318     *-*-solaris2.1[[01]])
 319         # Solaris 10+ needs this so struct msghdr gets the msg_control
 320         # etc. fields in <sys/socket.h> (_XPG4_2).  _XOPEN_SOURCE=600 as
 321         # above doesn't work with C99.
 322         OSCFLAGS="$OSCFLAGS -std=gnu99 -D_XOPEN_SOURCE=600 -D__EXTENSIONS__"
 323         ;;
 324 esac
 325 AC_SUBST(OSCFLAGS)
 326
 327 dnl Use -fsplit-stack when compiling C code if available.
 328 AC_CACHE_CHECK([whether -fsplit-stack is supported],
 329 [libgo_cv_c_split_stack_supported],
 330 [CFLAGS_hold=$CFLAGS
 331 CFLAGS="$CFLAGS -fsplit-stack"
 332 AC_COMPILE_IFELSE([[int i;]],
 333 [libgo_cv_c_split_stack_supported=yes],
 334 [libgo_cv_c_split_stack_supported=no])
 335 CFLAGS=$CFLAGS_hold])
 336 if test "$libgo_cv_c_split_stack_supported" = yes; then
 337   SPLIT_STACK=-fsplit-stack
 338   AC_DEFINE(USING_SPLIT_STACK, 1,
 339                 [Define if the compiler supports -fsplit-stack])
 340 else
 341   SPLIT_STACK=
 342 fi
 343 AC_SUBST(SPLIT_STACK)
 344 AM_CONDITIONAL(USING_SPLIT_STACK,
 345         test "$libgo_cv_c_split_stack_supported" = yes)
 346
 347 dnl Check whether the linker does stack munging when calling from
 348 dnl split-stack into non-split-stack code.  We check this by looking
 349 dnl at the --help output.  FIXME: This is only half right: it's
 350 dnl possible for the linker to support this for some targets but not
 351 dnl others.
 352 AC_CACHE_CHECK([whether linker supports split stack],
 353 [libgo_cv_c_linker_supports_split_stack],
 354 libgo_cv_c_linker_supports_split_stack=no
 355 if $LD --help 2>/dev/null | grep split-stack-adjust-size >/dev/null 2>&1; then
 356   libgo_cv_c_linker_supports_split_stack=yes
 357 fi)
 358 if test "$libgo_cv_c_linker_supports_split_stack" = yes; then
 359   AC_DEFINE(LINKER_SUPPORTS_SPLIT_STACK, 1,
 360             [Define if the linker support split stack adjustments])
 361 fi
 362
 363 dnl Test for the -lm library.
 364 MATH_LIBS=
 365 AC_CHECK_LIB([m], [sqrt], MATH_LIBS=-lm)
 366 AC_SUBST(MATH_LIBS)
 367
 368 dnl Test for -lsocket and -lnsl.  Copied from libjava/configure.ac.
 369 AC_CACHE_CHECK([for socket libraries], libgo_cv_lib_sockets,
 370   [libgo_cv_lib_sockets=
 371    libgo_check_both=no
 372    AC_CHECK_FUNC(connect, libgo_check_socket=no, libgo_check_socket=yes)
 373    if test "$libgo_check_socket" = "yes"; then
 374      unset ac_cv_func_connect
 375      AC_CHECK_LIB(socket, main, libgo_cv_lib_sockets="-lsocket",
 376                   libgo_check_both=yes)
 377    fi
 378    if test "$libgo_check_both" = "yes"; then
 379      libgo_old_libs=$LIBS
 380      LIBS="$LIBS -lsocket -lnsl"
 381      unset ac_cv_func_accept
 382      AC_CHECK_FUNC(accept,
 383                    [libgo_check_nsl=no
 384                     libgo_cv_lib_sockets="-lsocket -lnsl"])
 385      unset ac_cv_func_accept
 386      LIBS=$libgo_old_libs
 387    fi
 388    unset ac_cv_func_gethostbyname
 389    libgo_old_libs="$LIBS"
 390    AC_CHECK_FUNC(gethostbyname, ,
 391                  [AC_CHECK_LIB(nsl, main,
 392                         [libgo_cv_lib_sockets="$libgo_cv_lib_sockets -lnsl"])])
 393    unset ac_cv_func_gethostbyname
 394    LIBS=$libgo_old_libs
 395 ])
 396 NET_LIBS="$libgo_cv_lib_sockets"
 397 AC_SUBST(NET_LIBS)
 398
 399 dnl Test whether the compiler supports the -pthread option.
 400 AC_CACHE_CHECK([whether -pthread is supported],
 401 [libgo_cv_lib_pthread],
 402 [CFLAGS_hold=$CFLAGS
 403 CFLAGS="$CFLAGS -pthread"
 404 AC_COMPILE_IFELSE([[int i;]],
 405 [libgo_cv_lib_pthread=yes],
 406 [libgo_cv_lib_pthread=no])
 407 CFLAGS=$CFLAGS_hold])
 408 PTHREAD_CFLAGS=
 409 if test "$libgo_cv_lib_pthread" = yes; then
 410   PTHREAD_CFLAGS=-pthread
 411 fi
 412 AC_SUBST(PTHREAD_CFLAGS)
 413
 414 dnl Test for the -lpthread library.
 415 PTHREAD_LIBS=
 416 AC_CHECK_LIB([pthread], [pthread_create], PTHREAD_LIBS=-lpthread)
 417 AC_SUBST(PTHREAD_LIBS)
 418
 419 dnl Test if -lrt is required for sched_yield and/or nanosleep.
 420 AC_SEARCH_LIBS([sched_yield], [rt])
 421 AC_SEARCH_LIBS([nanosleep], [rt])
 422
 423 AC_C_BIGENDIAN
 424
 425 GCC_CHECK_UNWIND_GETIPINFO
 426
 427 AC_ARG_ENABLE(sjlj-exceptions,
 428   AC_HELP_STRING([--enable-sjlj-exceptions],
 429                  [force use of builtin_setjmp for exceptions]),
 430   [case "$enableval" in
 431    yes|no|auto) ;;
 432    *) AC_MSG_ERROR([unknown argument to --enable-sjlj-exceptions]) ;;
 433    esac],
 434   [enable_sjlj_exceptions=auto])
 435
 436 AC_CACHE_CHECK([whether to use setjmp/longjmp exceptions],
 437 [libgo_cv_lib_sjlj_exceptions],
 438 [AC_LANG_CONFTEST(
 439   [AC_LANG_SOURCE([
 440 void bar ();
 441 void clean (int *);
 442 void foo ()
 443 {
 444   int i __attribute__ ((cleanup (clean)));
 445   bar();
 446 }
 447 ])])
 448 CFLAGS_hold=$CFLAGS
 449 CFLAGS="--save-temps -fexceptions"
 450 libgo_cv_lib_sjlj_exceptions=unknown
 451 AS_IF([ac_fn_c_try_compile],
 452   [if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1; then
 453     libgo_cv_lib_sjlj_exceptions=yes
 454   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1; then
 455     libgo_cv_lib_sjlj_exceptions=no
 456   fi])
 457 CFLAGS=$CFLAGS_hold
 458 rm -f conftest*
 459 ])
 460
 461 if test "$enable_sjlj_exceptions" = "auto"; then
 462   enable_sjlj_exceptions=$libgo_cv_lib_sjlj_exceptions
 463 fi
 464
 465 case $enable_sjlj_exceptions in
 466 yes)
 467   AC_DEFINE(LIBGO_SJLJ_EXCEPTIONS, 1,
 468         [Define if the C++ compiler is configured for setjmp/longjmp exceptions.])
 469   ;;
 470 no)
 471   ;;
 472 *)
 473   AC_MSG_ERROR([unable to detect exception model])
 474   ;;
 475 esac
 476
 477 AC_CHECK_HEADERS(sys/file.h sys/mman.h syscall.h sys/epoll.h sys/inotify.h sys/ptrace.h sys/syscall.h sys/user.h sys/utsname.h sys/select.h sys/socket.h net/if.h net/if_arp.h net/route.h netpacket/packet.h sys/prctl.h sys/mount.h sys/vfs.h sys/statfs.h sys/timex.h sys/sysinfo.h utime.h linux/ether.h linux/fs.h linux/reboot.h netinet/icmp6.h netinet/in_syst.h netinet/ip.h netinet/ip_mroute.h netinet/if_ether.h)
 478
 479 AC_CHECK_HEADERS([linux/filter.h linux/if_addr.h linux/if_ether.h linux/if_tun.h linux/netlink.h linux/rtnetlink.h], [], [],
 480 [#ifdef HAVE_SYS_SOCKET_H
 481 #include <sys/socket.h>
 482 #endif
 483 ])
 484
 485 AC_CACHE_CHECK([whether <ustat.h> can be used],
 486 [libgo_cv_c_ustat_h],
 487 [CFLAGS_hold=$CFLAGS
 488 CFLAGS="$CFLAGS -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE $OSCFLAGS"
 489 AC_COMPILE_IFELSE(
 490 [AC_LANG_SOURCE([
 491 #include <sys/types.h>
 492 #ifdef HAVE_LINUX_FILTER_H
 493 #include <linux/filter.h>
 494 #endif
 495 #include <ustat.h>
 496 ])], [libgo_cv_c_ustat_h=yes], [libgo_cv_c_ustat_h=no])
 497 CFLAGS=$CFLAGS_hold])
 498 if test $libgo_cv_c_ustat_h = yes; then
 499   AC_DEFINE(HAVE_USTAT_H, 1,
 500     [Define to 1 if you have the <ustat.h> header file and it works.])
 501 fi
 502
 503 AM_CONDITIONAL(HAVE_SYS_MMAN_H, test "$ac_cv_header_sys_mman_h" = yes)
 504
 505 AC_CHECK_FUNCS(strerror_r strsignal wait4 mincore setenv dl_iterate_phdr)
 506 AM_CONDITIONAL(HAVE_STRERROR_R, test "$ac_cv_func_strerror_r" = yes)
 507 AM_CONDITIONAL(HAVE_WAIT4, test "$ac_cv_func_wait4" = yes)
 508
 509 AC_CHECK_FUNCS(accept4 dup3 epoll_create1 faccessat fallocate fchmodat fchownat futimesat getxattr inotify_add_watch inotify_init inotify_init1 inotify_rm_watch listxattr mkdirat mknodat open64 openat pipe2 removexattr renameat setxattr sync_file_range splice tee unlinkat unshare utimensat)
 510 AC_TYPE_OFF_T
 511 AC_CHECK_TYPES([loff_t])
 512
 513 LIBS_hold="$LIBS"
 514 LIBS="$LIBS -lm"
 515 AC_CHECK_FUNCS(cosl expl logl sinl tanl acosl asinl atanl atan2l expm1l ldexpl log10l log1pl)
 516 LIBS="$LIBS_hold"
 517
 518 CFLAGS_hold="$CFLAGS"
 519 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 520 LIBS_hold="$LIBS"
 521 LIBS="$LIBS $PTHREAD_LIBS"
 522 AC_CHECK_FUNCS(sem_timedwait)
 523 CFLAGS="$CFLAGS_hold"
 524 LIBS="$LIBS_hold"
 525
 526 LIBS_hold="$LIBS"
 527 LIBS="$LIBS $MATH_LIBS"
 528 AC_CHECK_FUNCS(matherr)
 529 LIBS="$LIBS_hold"
 530
 531 AC_CACHE_CHECK([for __sync_bool_compare_and_swap_4],
 532 [libgo_cv_func___sync_bool_compare_and_swap_4],
 533 [AC_LINK_IFELSE([
 534 typedef unsigned int uint32  __attribute__ ((mode (SI)));
 535 uint32 i;
 536 int main() { return __sync_bool_compare_and_swap (&i, 0, 1); }
 537 ],
 538 [libgo_cv_func___sync_bool_compare_and_swap_4=yes],
 539 [libgo_cv_func___sync_bool_compare_and_swap_4=no])])
 540 if test "$libgo_cv_func___sync_bool_compare_and_swap_4" = "yes"; then
 541   AC_DEFINE(HAVE_SYNC_BOOL_COMPARE_AND_SWAP_4, 1,
 542     [Define to 1 if the compiler provides the __sync_bool_compare_and_swap function for uint32])
 543 fi
 544
 545 AC_CACHE_CHECK([for __sync_bool_compare_and_swap_8],
 546 [libgo_cv_func___sync_bool_compare_and_swap_8],
 547 [AC_LINK_IFELSE([
 548 typedef unsigned int uint64  __attribute__ ((mode (DI)));
 549 uint64 i;
 550 int main() { return __sync_bool_compare_and_swap (&i, 0, 1); }
 551 ],
 552 [libgo_cv_func___sync_bool_compare_and_swap_8=yes],
 553 [libgo_cv_func___sync_bool_compare_and_swap_8=no])])
 554 if test "$libgo_cv_func___sync_bool_compare_and_swap_8" = "yes"; then
 555   AC_DEFINE(HAVE_SYNC_BOOL_COMPARE_AND_SWAP_8, 1,
 556     [Define to 1 if the compiler provides the __sync_bool_compare_and_swap function for uint64])
 557 fi
 558
 559 AC_CACHE_CHECK([for __sync_fetch_and_add_4],
 560 [libgo_cv_func___sync_fetch_and_add_4],
 561 [AC_LINK_IFELSE([
 562 typedef unsigned int uint32  __attribute__ ((mode (SI)));
 563 uint32 i;
 564 int main() { return __sync_fetch_and_add (&i, 1); }
 565 ],
 566 [libgo_cv_func___sync_fetch_and_add_4=yes],
 567 [libgo_cv_func___sync_fetch_and_add_4=no])])
 568 if test "$libgo_cv_func___sync_fetch_and_add_4" = "yes"; then
 569   AC_DEFINE(HAVE_SYNC_FETCH_AND_ADD_4, 1,
 570     [Define to 1 if the compiler provides the __sync_fetch_and_add function for uint32])
 571 fi
 572
 573 AC_CACHE_CHECK([for __sync_add_and_fetch_8],
 574 [libgo_cv_func___sync_add_and_fetch_8],
 575 [AC_LINK_IFELSE([
 576 typedef unsigned int uint64  __attribute__ ((mode (DI)));
 577 uint64 i;
 578 int main() { return __sync_add_and_fetch (&i, 1); }
 579 ],
 580 [libgo_cv_func___sync_add_and_fetch_8=yes],
 581 [libgo_cv_func___sync_add_and_fetch_8=no])])
 582 if test "$libgo_cv_func___sync_add_and_fetch_8" = "yes"; then
 583   AC_DEFINE(HAVE_SYNC_ADD_AND_FETCH_8, 1,
 584     [Define to 1 if the compiler provides the __sync_add_and_fetch function for uint64])
 585 fi
 586
 587 dnl For x86 we want to use the -minline-all-stringops option to avoid
 588 dnl forcing a stack split when calling memcpy and friends.
 589 AC_CACHE_CHECK([whether compiler supports -minline-all-stringops],
 590 [libgo_cv_c_stringops],
 591 [CFLAGS_hold=$CFLAGS
 592 CFLAGS="$CFLAGS -minline-all-stringops"
 593 AC_COMPILE_IFELSE([int i;],
 594 [libgo_cv_c_stringops=yes],
 595 [libgo_cv_c_stringops=no])
 596 CFLAGS=$CFLAGS_hold])
 597 STRINGOPS_FLAG=
 598 if test "$libgo_cv_c_stringops" = yes; then
 599   STRINGOPS_FLAG=-minline-all-stringops
 600 fi
 601 AC_SUBST(STRINGOPS_FLAG)
 602
 603 dnl For x86 we want to compile the math library with -mfancy-math-387
 604 dnl -funsafe-math-optimizations so that we can use the builtin
 605 dnl instructions directly.
 606 AC_CACHE_CHECK([whether compiler supports -mfancy-math-387],
 607 [libgo_cv_c_fancymath],
 608 [CFLAGS_hold=$CFLAGS
 609 CFLAGS="$CFLAGS -mfancy-math-387"
 610 AC_COMPILE_IFELSE([int i;],
 611 [libgo_cv_c_fancymath=yes],
 612 [libgo_cv_c_fancymath=no])
 613 CFLAGS=$CFLAGS_hold])
 614 MATH_FLAG=
 615 if test "$libgo_cv_c_fancymath" = yes; then
 616   MATH_FLAG="-mfancy-math-387 -funsafe-math-optimizations"
 617 fi
 618 AC_SUBST(MATH_FLAG)
 619
 620 CFLAGS_hold=$CFLAGS
 621 CFLAGS="$CFLAGS -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE"
 622 AC_CHECK_TYPES([off64_t])
 623 CFLAGS=$CFLAGS_hold
 624
 625 dnl Work out the size of the epoll_events struct on GNU/Linux.
 626 AC_CACHE_CHECK([epoll_event size],
 627 [libgo_cv_c_epoll_event_size],
 628 [AC_COMPUTE_INT(libgo_cv_c_epoll_event_size,
 629 [sizeof (struct epoll_event)],
 630 [#include <sys/epoll.h>],
 631 [libgo_cv_c_epoll_event_size=0])])
 632 SIZEOF_STRUCT_EPOLL_EVENT=${libgo_cv_c_epoll_event_size}
 633 AC_SUBST(SIZEOF_STRUCT_EPOLL_EVENT)
 634
 635 dnl Work out the offset of the fd field in the epoll_events struct on
 636 dnl GNU/Linux.
 637 AC_CACHE_CHECK([epoll_event data.fd offset],
 638 [libgo_cv_c_epoll_event_fd_offset],
 639 [AC_COMPUTE_INT(libgo_cv_c_epoll_event_fd_offset,
 640 [offsetof (struct epoll_event, data.fd)],
 641 [#include <stddef.h>
 642 #include <sys/epoll.h>],
 643 [libgo_cv_c_epoll_event_fd_offset=0])])
 644 STRUCT_EPOLL_EVENT_FD_OFFSET=${libgo_cv_c_epoll_event_fd_offset}
 645 AC_SUBST(STRUCT_EPOLL_EVENT_FD_OFFSET)
 646
 647 dnl See if struct exception is defined in <math.h>.
 648 AC_CHECK_TYPE([struct exception],
 649 [libgo_has_struct_exception=yes],
 650 [libgo_has_struct_exception=no],
 651 [#include <math.h>])
 652 if test "$libgo_has_struct_exception" = "yes"; then
 653   AC_DEFINE(HAVE_STRUCT_EXCEPTION, 1,
 654             [Define to 1 if <math.h> defines struct exception])
 655 fi
 656
 657 dnl Check if makecontext expects the uc_stack member of ucontext to point
 658 dnl to the top of the stack.
 659 case "$target" in
 660   sparc*-*-solaris2.[[89]]*)
 661     libgo_cv_lib_makecontext_stack_top=yes
 662     ;;
 663   *)
 664     libgo_cv_lib_makecontext_stack_top=no
 665     ;;
 666 esac
 667 if test "$libgo_cv_lib_makecontext_stack_top" = "yes"; then
 668   AC_DEFINE(MAKECONTEXT_STACK_TOP, 1,
 669             [Define if makecontext expects top of stack in uc_stack.])
 670 fi
 671
 672 dnl See whether setcontext changes the value of TLS variables.
 673 AC_CACHE_CHECK([whether setcontext clobbers TLS variables],
 674 [libgo_cv_lib_setcontext_clobbers_tls],
 675 [CFLAGS_hold="$CFLAGS"
 676 CFLAGS="$PTHREAD_CFLAGS"
 677 LIBS_hold="$LIBS"
 678 LIBS="$LIBS $PTHREAD_LIBS"
 679 AC_CHECK_SIZEOF([void *])
 680 AS_VAR_ARITH([ptr_type_size], [$ac_cv_sizeof_void_p \* 8])
 681 AC_RUN_IFELSE(
 682   [AC_LANG_SOURCE([
 683 #include <pthread.h>
 684 #include <stdlib.h>
 685 #include <ucontext.h>
 686 #include <unistd.h>
 687
 688 __thread int tls;
 689
 690 static char stack[[10 * 1024 * 1024]];
 691 static ucontext_t c;
 692
 693 /* Called via makecontext/setcontext.  */
 694
 695 static void
 696 cfn (void)
 697 {
 698   exit (tls);
 699 }
 700
 701 /* Called via pthread_create.  */
 702
 703 static void *
 704 tfn (void *dummy)
 705 {
 706   /* The thread should still see this value after calling
 707      setcontext.  */
 708   tls = 0;
 709
 710   setcontext (&c);
 711
 712   /* The call to setcontext should not return.  */
 713   abort ();
 714 }
 715
 716 int
 717 main ()
 718 {
 719   pthread_t tid;
 720
 721   /* The thread should not see this value.  */
 722   tls = 1;
 723
 724   if (getcontext (&c) < 0)
 725     abort ();
 726
 727   c.uc_stack.ss_sp = stack;
 728 #ifdef MAKECONTEXT_STACK_TOP
 729   c.uc_stack.ss_sp += sizeof stack;
 730 #endif
 731   c.uc_stack.ss_flags = 0;
 732   c.uc_stack.ss_size = sizeof stack;
 733   c.uc_link = NULL;
 734   makecontext (&c, cfn, 0);
 735
 736   if (pthread_create (&tid, NULL, tfn, NULL) != 0)
 737     abort ();
 738
 739   if (pthread_join (tid, NULL) != 0)
 740     abort ();
 741
 742   /* The thread should have called exit.  */
 743   abort ();
 744 }
 745 ])],
 746 [libgo_cv_lib_setcontext_clobbers_tls=no],
 747 [libgo_cv_lib_setcontext_clobbers_tls=yes],
 748 [case "$target:$ptr_type_size" in
 749   i?86-*-solaris2.1[[01]]:64 | x86_64*-*-solaris2.1[[01]]:64)
 750     libgo_cv_lib_setcontext_clobbers_tls=yes ;;
 751   *)
 752     libgo_cv_lib_setcontext_clobbers_tls=no ;;
 753  esac
 754 ])
 755 CFLAGS="$CFLAGS_hold"
 756 LIBS="$LIBS_hold"
 757 ])
 758 if test "$libgo_cv_lib_setcontext_clobbers_tls" = "yes"; then
 759   AC_DEFINE(SETCONTEXT_CLOBBERS_TLS, 1,
 760             [Define if setcontext clobbers TLS variables])
 761 fi
 762
 763 AC_CACHE_CHECK([whether .eh_frame section should be read-only],
 764 libgo_cv_ro_eh_frame, [
 765 libgo_cv_ro_eh_frame=no
 766 echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
 767 if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
 768   if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
 769     libgo_cv_ro_eh_frame=yes
 770   elif grep '.section.*eh_frame.*#alloc' conftest.c \
 771        | grep -v '#write' > /dev/null; then
 772     libgo_cv_ro_eh_frame=yes
 773   fi
 774 fi
 775 rm -f conftest.*
 776 ])
 777 if test "x$libgo_cv_ro_eh_frame" = xyes; then
 778   AC_DEFINE(EH_FRAME_FLAGS, "a",
 779             [Define to the flags needed for the .section .eh_frame directive.])
 780 else
 781   AC_DEFINE(EH_FRAME_FLAGS, "aw",
 782             [Define to the flags needed for the .section .eh_frame directive.])
 783 fi
 784
 785 AC_CACHE_CHECK([if assembler supports GNU comdat group syntax],
 786 libgo_cv_as_comdat_gnu, [
 787 echo '.section .text,"axG",@progbits,.foo,comdat' > conftest.s
 788 if $CC $CFLAGS -c conftest.s > /dev/null 2>&1; then
 789   libgo_cv_as_comdat_gnu=yes
 790 else
 791   libgo_cv_as_comdat_gnu=no
 792 fi
 793 ])
 794 if test "x$libgo_cv_as_comdat_gnu" = xyes; then
 795   AC_DEFINE(HAVE_AS_COMDAT_GAS, 1,
 796             [Define if your assembler supports GNU comdat group syntax.])
 797 fi
 798
 799 AC_CACHE_CHECK([assembler supports pc related relocs],
 800 libgo_cv_as_x86_pcrel, [
 801 libgo_cv_as_x86_pcrel=yes
 802 echo '.text; foo: nop; .data; .long foo-.; .text' > conftest.s
 803 if $CC $CFLAGS -c conftest.s 2>&1 | $EGREP -i 'illegal|warning' > /dev/null; then
 804     libgo_cv_as_x86_pcrel=no
 805 fi
 806 ])
 807 if test "x$libgo_cv_as_x86_pcrel" = xyes; then
 808   AC_DEFINE(HAVE_AS_X86_PCREL, 1,
 809             [Define if your assembler supports PC relative relocs.])
 810 fi
 811
 812 AC_CACHE_CHECK([assembler supports unwind section type],
 813 libgo_cv_as_x86_64_unwind_section_type, [
 814 libgo_cv_as_x86_64_unwind_section_type=yes
 815 echo '.section .eh_frame,"a",@unwind' > conftest.s
 816 if $CC $CFLAGS -c conftest.s 2>&1 | grep -i warning > /dev/null; then
 817     libgo_cv_as_x86_64_unwind_section_type=no
 818 fi
 819 ])
 820 if test "x$libgo_cv_as_x86_64_unwind_section_type" = xyes; then
 821   AC_DEFINE(HAVE_AS_X86_64_UNWIND_SECTION_TYPE, 1,
 822             [Define if your assembler supports unwind section type.])
 823 fi
 824
 825 AC_CACHE_SAVE
 826
 827 if test ${multilib} = yes; then
 828   multilib_arg="--enable-multilib"
 829 else
 830   multilib_arg=
 831 fi
 832
 833 AC_CONFIG_FILES(Makefile testsuite/Makefile)
 834
 835 AC_CONFIG_COMMANDS([default],
 836 [if test -n "$CONFIG_FILES"; then
 837    # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 838    # that multilib installs will end up installed in the correct place.
 839    # The testsuite needs it for multilib-aware ABI baseline files.
 840    # To work around this not being passed down from config-ml.in ->
 841    # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 842    # append it here.  Only modify Makefiles that have just been created.
 843    #
 844    # Also, get rid of this simulated-VPATH thing that automake does.
 845    cat > vpsed << \_EOF
 846 s!`test -f '$<' || echo '$(srcdir)/'`!!
 847 _EOF
 848    for i in $SUBDIRS; do
 849     case $CONFIG_FILES in
 850      *${i}/Makefile*)
 851        #echo "Adding MULTISUBDIR to $i/Makefile"
 852        sed -f vpsed $i/Makefile > tmp
 853        grep '^MULTISUBDIR =' Makefile >> tmp
 854        mv tmp $i/Makefile
 855        ;;
 856     esac
 857    done
 858    rm vpsed
 859  fi
 860 ],
 861 [
 862 # Variables needed in config.status (file generation) which aren't already
 863 # passed by autoconf.
 864 SUBDIRS="$SUBDIRS"
 865 ])
 866
 867 AC_OUTPUT