libobjc/configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 #   Copyright 1994, 1995, 1996, 1997, 1998, 1999, 2001, 2002, 2003, 2004
   3 #   Free Software Foundation, Inc.
   4 #   Originally contributed by Dave Love (d.love@dl.ac.uk).
   5 #
   6 #This file is part of GCC.
   7 #
   8 #GCC is free software; you can redistribute it and/or modify
   9 #it under the terms of the GNU General Public License as published by
  10 #the Free Software Foundation; either version 2, or (at your option)
  11 #any later version.
  12 #
  13 #GCC is distributed in the hope that it will be useful,
  14 #but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 #GNU General Public License for more details.
  17 #
  18 #You should have received a copy of the GNU General Public License
  19 #along with GCC; see the file COPYING.  If not, write to
  20 #the Free Software Foundation, 59 Temple Place - Suite 330, Boston, MA
  21 #02111-1307, USA.
  22
  23 AC_PREREQ(2.59)
  24 AC_INIT(package-unused, version-unused,, libobjc)
  25 AC_CONFIG_SRCDIR([objc/objc.h])
  26
  27 # We need the following definitions because AC_PROG_LIBTOOL relies on them
  28 PACKAGE=libobjc
  29 # Version is pulled out to make it a bit easier to change using sed.
  30 VERSION=1:0:0
  31 AC_SUBST(VERSION)
  32
  33 # This works around the fact that libtool configuration may change LD
  34 # for this particular configuration, but some shells, instead of
  35 # keeping the changes in LD private, export them just because LD is
  36 # exported.
  37 ORIGINAL_LD_FOR_MULTILIBS=$LD
  38
  39 # -------
  40 # Options
  41 # -------
  42
  43 # Default to --enable-multilib
  44 AC_ARG_ENABLE(multilib,
  45   [  --enable-multilib       build hella library versions (default)],
  46   [case "${enableval}" in
  47     yes) multilib=yes ;;
  48     no)  multilib=no ;;
  49     *)   AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
  50    esac],
  51   [multilib=yes])
  52
  53 # We use these options to decide which functions to include.
  54 AC_ARG_WITH(target-subdir,
  55 [  --with-target-subdir=SUBDIR
  56                            configuring in a subdirectory])
  57 AC_ARG_WITH(cross-host,
  58 [  --with-cross-host=HOST  configuring with a cross compiler])
  59
  60 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  61 AC_ARG_ENABLE(version-specific-runtime-libs,
  62 [  --enable-version-specific-runtime-libs    Specify that runtime libraries should be installed in a compiler-specific directory ],
  63 [case "$enableval" in
  64  yes) version_specific_libs=yes ;;
  65  no)  version_specific_libs=no ;;
  66  *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  67  esac],
  68 [version_specific_libs=no])
  69 AC_MSG_RESULT($version_specific_libs)
  70
  71 AC_ARG_ENABLE(objc-gc,
  72 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
  73                           the GNU Objective-C runtime.],
  74 [case $enable_objc_gc in
  75   no) OBJC_BOEHM_GC='' ;;
  76   *) OBJC_BOEHM_GC=libobjc_gc.la ;;
  77 esac],
  78 [OBJC_BOEHM_GC=''])
  79 AC_SUBST(OBJC_BOEHM_GC)
  80
  81 # -----------
  82 # Directories
  83 # -----------
  84
  85 # When building with srcdir == objdir, links to the source files will
  86 # be created in directories within the target_subdir.  We have to
  87 # adjust toplevel_srcdir accordingly, so that configure finds
  88 # install-sh and other auxiliary files that live in the top-level
  89 # source directory.
  90 if test "${srcdir}" = "."; then
  91   if test -z "${with_target_subdir}"; then
  92     toprel=".."
  93   else
  94     if test "${with_target_subdir}" != "."; then
  95       toprel="${with_multisrctop}../.."
  96     else
  97       toprel="${with_multisrctop}.."
  98     fi
  99   fi
 100 else
 101   toprel=".."
 102 fi
 103 AC_CONFIG_AUX_DIR(${srcdir}/$toprel)
 104 toplevel_srcdir=\${srcdir}/$toprel
 105 AC_SUBST(toplevel_srcdir)
 106
 107 AC_CANONICAL_SYSTEM
 108 ACX_NONCANONICAL_TARGET
 109
 110 # Export source directory.
 111 # These need to be absolute paths, yet at the same time need to
 112 # canonicalize only relative paths, because then amd will not unmount
 113 # drives. Thus the use of PWDCMD: set it to 'pawd' or 'amq -w' if using amd.
 114 case $srcdir in
 115   [\\/$]* | ?:[\\/]*) glibcpp_srcdir=${srcdir} ;;
 116   *) glibcpp_srcdir=`cd "$srcdir" && ${PWDCMD-pwd} || echo "$srcdir"` ;;
 117 esac
 118 AC_SUBST(glibcpp_srcdir)
 119
 120 # Process the option "--enable-version-specific-runtime-libs"
 121 gcc_version_trigger=${srcdir}/../gcc/version.c
 122 gcc_version_full=`grep version_string ${gcc_version_trigger} | sed -e 's/.*\"\([[^ \"]]*\)[[ \"]].*/\1/'`
 123 gcc_version=`echo ${gcc_version_full} | sed -e 's/\([^ ]*\) .*/\1/'`
 124 AC_SUBST(gcc_version)
 125
 126 # Calculate toolexeclibdir
 127 # Also toolexecdir, though it's only used in toolexeclibdir
 128 case ${version_specific_libs} in
 129   yes)
 130     # Need the gcc compiler version to know where to install libraries
 131     # and header files if --enable-version-specific-runtime-libs option
 132     # is selected.
 133     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
 134     toolexeclibdir='$(toolexecdir)/'${gcc_version}'$(MULTISUBDIR)'
 135     ;;
 136   no)
 137     if test -n "$with_cross_host" &&
 138        test x"$with_cross_host" != x"no"; then
 139       # Install a library built with a cross compiler in tooldir, not libdir.
 140       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
 141       toolexeclibdir='$(toolexecdir)/lib'
 142     else
 143       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
 144       toolexeclibdir='$(libdir)'
 145     fi
 146     multi_os_directory=`$CC -print-multi-os-directory`
 147     case $multi_os_directory in
 148       .) ;; # Avoid trailing /.
 149       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 150     esac
 151     ;;
 152 esac
 153 AC_SUBST(toolexecdir)
 154 AC_SUBST(toolexeclibdir)
 155
 156 # Figure out if we want to name the include directory and the
 157 #  library name changes differently.
 158 includedirname=include
 159 libext=
 160 case "${host}" in
 161   *-darwin*)
 162     # Darwin is the only target so far that needs a different include directory.
 163     includedirname=include-gnu-runtime
 164     libext=-gnu
 165     ;;
 166 esac
 167 AC_SUBST(includedirname)
 168 AC_SUBST(libext)
 169
 170 AC_CONFIG_HEADERS(config.h)
 171
 172 # --------
 173 # Programs
 174 # --------
 175
 176 GCC_NO_EXECUTABLES
 177
 178 # We must force CC to /not/ be a precious variable; otherwise
 179 # the wrong, non-multilib-adjusted value will be used in multilibs.
 180 # As a side effect, we have to subst CFLAGS ourselves.
 181 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
 182 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 183 AC_PROG_CC
 184 m4_rename([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 185
 186 AC_SUBST(CFLAGS)
 187
 188 AC_CHECK_TOOL(AS, as)
 189 AC_CHECK_TOOL(AR, ar)
 190 AC_CHECK_TOOL(RANLIB, ranlib, :)
 191 AC_PROG_INSTALL
 192
 193 AM_MAINTAINER_MODE
 194
 195 # Enable Win32 DLL on MS Windows - FIXME
 196 AC_LIBTOOL_WIN32_DLL
 197
 198 AC_PROG_LIBTOOL
 199
 200 AM_PROG_CC_C_O
 201
 202 AC_PROG_MAKE_SET
 203
 204 # -------
 205 # Headers
 206 # -------
 207
 208 # Sanity check for the cross-compilation case:
 209 AC_CHECK_HEADER(stdio.h,:,
 210   [AC_MSG_ERROR([Can't find stdio.h.
 211 You must have a usable C system for the target already installed, at least
 212 including headers and, preferably, the library, before you can configure
 213 the Objective C runtime system.  If necessary, install gcc now with
 214 \`LANGUAGES=c', then the target library, then build with \`LANGUAGES=objc'.])])
 215
 216 AC_HEADER_STDC
 217
 218 AC_CHECK_HEADERS(sched.h)
 219
 220 # -----------
 221 # Miscellanea
 222 # -----------
 223
 224 # Determine CFLAGS for gthread.
 225 # FIXME: the current implementation is dependent on the 'r' variable
 226 # passed down from the top level
 227 AC_CACHE_CHECK([for gthread cflags],objc_cv_gthread_flags,
 228 [if test -f "$r"/gcc/Makefile
 229 then
 230   objc_cv_gthread_flags=`grep \^GTHREAD_FLAGS "$r"/gcc/Makefile | awk -F= '{ print $2 }'`
 231 else
 232   AC_MSG_ERROR([not found])
 233 fi])
 234 GTHREAD_FLAGS=$objc_cv_gthread_flags
 235 AC_SUBST(GTHREAD_FLAGS)
 236
 237 AC_MSG_CHECKING([for exception model to use])
 238 AC_LANG_PUSH(C)
 239 AC_ARG_ENABLE(sjlj-exceptions,
 240   AS_HELP_STRING([--enable-sjlj-exceptions],
 241                  [force use of builtin_setjmp for exceptions]),
 242 [:],
 243 [dnl Botheration.  Now we've got to detect the exception model.
 244 dnl Link tests against libgcc.a are problematic since -- at least
 245 dnl as of this writing -- we've not been given proper -L bits for
 246 dnl single-tree newlib and libgloss.
 247 dnl
 248 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 249 dnl conftest files before we got a change to grep them first.
 250 cat > conftest.$ac_ext << EOF
 251 [#]line __oline__ "configure"
 252 @interface Frob
 253 @end
 254 @implementation Frob
 255 @end
 256 int proc();
 257 int foo()
 258 {
 259   @try {
 260    return proc();
 261   }
 262   @catch (Frob* ex) {
 263     return 0;
 264   }
 265 }
 266 EOF
 267 old_CFLAGS="$CFLAGS"
 268 dnl work around that we don't have Objective-C support in autoconf
 269 CFLAGS="-x objective-c -fgnu-runtime -fobjc-exceptions -S"
 270 if AC_TRY_EVAL(ac_compile); then
 271   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 272     enable_sjlj_exceptions=yes
 273   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 274     enable_sjlj_exceptions=no
 275   fi
 276 fi
 277 CFLAGS="$old_CFLAGS"
 278 rm -f conftest*])
 279 if test x$enable_sjlj_exceptions = xyes; then
 280   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 281         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 282   ac_exception_model_name=sjlj
 283 elif test x$enable_sjlj_exceptions = xno; then
 284   ac_exception_model_name="call frame"
 285 else
 286   AC_MSG_ERROR([unable to detect exception model])
 287 fi
 288 AC_LANG_POP(C)
 289 AC_MSG_RESULT($ac_exception_model_name)
 290
 291 # ------
 292 # Output
 293 # ------
 294
 295 AC_CONFIG_FILES([Makefile])
 296
 297 AC_CONFIG_COMMANDS([default],
 298 [[if test -n "$CONFIG_FILES"; then
 299   if test -n "${with_target_subdir}"; then
 300     # FIXME: We shouldn't need to set ac_file
 301     ac_file=Makefile
 302     LD="${ORIGINAL_LD_FOR_MULTILIBS}"
 303     . ${toplevel_srcdir}/config-ml.in
 304   fi
 305 fi]],
 306 [[srcdir=${srcdir}
 307 host=${host}
 308 target=${target}
 309 with_target_subdir=${with_target_subdir}
 310 with_multisubdir=${with_multisubdir}
 311 ac_configure_args="--enable-multilib ${ac_configure_args}"
 312 toplevel_srcdir=${toplevel_srcdir}
 313 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 314 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
 315 ]])
 316
 317 AC_OUTPUT