configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011, 2012,
   3 #   2014, 2015, 2016 Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include([libtool.m4])
  27 m4_include([ltoptions.m4])
  28 m4_include([ltsugar.m4])
  29 m4_include([ltversion.m4])
  30 m4_include([lt~obsolete.m4])
  31 m4_include([config/isl.m4])
  32
  33 AC_INIT(move-if-change)
  34 AC_PREREQ(2.64)
  35 AC_DISABLE_OPTION_CHECKING
  36
  37 progname=$0
  38 # if PWD already has a value, it is probably wrong.
  39 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  40
  41 # Export original configure arguments for use by sub-configures.
  42 # Quote arguments with shell meta charatcers.
  43 TOPLEVEL_CONFIGURE_ARGUMENTS=
  44 set -- "$progname" "$@"
  45 for ac_arg
  46 do
  47   case "$ac_arg" in
  48   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  49     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  50     # if the argument is of the form -foo=baz, quote the baz part only
  51     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  52   *) ;;
  53   esac
  54   # Add the quoted argument to the list.
  55   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  56 done
  57 if test "$silent" = yes; then
  58   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  59 fi
  60 # Remove the initial space we just introduced and, as these will be
  61 # expanded by make, quote '$'.
  62 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  63 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  64
  65 # Find the build, host, and target systems.
  66 ACX_NONCANONICAL_BUILD
  67 ACX_NONCANONICAL_HOST
  68 ACX_NONCANONICAL_TARGET
  69
  70 dnl Autoconf 2.5x and later will set a default program prefix if
  71 dnl --target was used, even if it was the same as --host.  Disable
  72 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  73 dnl to take effect.
  74 test "$host_noncanonical" = "$target_noncanonical" &&
  75   test "$program_prefix$program_suffix$program_transform_name" = \
  76     NONENONEs,x,x, &&
  77   program_transform_name=s,y,y,
  78
  79 AC_CANONICAL_SYSTEM
  80 AC_ARG_PROGRAM
  81
  82 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  83 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  84
  85 # Get 'install' or 'install-sh' and its variants.
  86 AC_PROG_INSTALL
  87 ACX_PROG_LN
  88 AC_PROG_LN_S
  89 AC_PROG_SED
  90 AC_PROG_AWK
  91
  92 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
  93
  94 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
  95 # a relative path.
  96 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
  97   INSTALL="${srcpwd}/install-sh -c"
  98 fi
  99
 100 # Set srcdir to "." if that's what it is.
 101 # This is important for multilib support.
 102 pwd=`${PWDCMD-pwd}`
 103 if test "${pwd}" = "${srcpwd}" ; then
 104   srcdir=.
 105 fi
 106
 107 topsrcdir=$srcpwd
 108
 109 extra_host_args=
 110
 111 ### To add a new directory to the tree, first choose whether it is a target
 112 ### or a host dependent tool.  Then put it into the appropriate list
 113 ### (library or tools, host or target), doing a dependency sort.
 114
 115 # Subdirs will be configured in the order listed in build_configdirs,
 116 # configdirs, or target_configdirs; see the serialization section below.
 117
 118 # Dependency sorting is only needed when *configuration* must be done in
 119 # a particular order.  In all cases a dependency should be specified in
 120 # the Makefile, whether or not it's implicitly specified here.
 121
 122 # Double entries in build_configdirs, configdirs, or target_configdirs may
 123 # cause circular dependencies and break everything horribly.
 124
 125 # these library is used by various programs built for the build
 126 # environment
 127 #
 128 build_libs="build-libiberty build-libcpp"
 129
 130 # these tools are built for the build environment
 131 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 132
 133 # these libraries are used by various programs built for the host environment
 134 #f
 135 host_libs="intl libiberty opcodes bfd readline tcl tk itcl libgui zlib libbacktrace libcpp libdecnumber gmp mpfr mpc isl libelf libiconv"
 136
 137 # these tools are built for the host environment
 138 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 139 # know that we are building the simulator.
 140 # binutils, gas and ld appear in that order because it makes sense to run
 141 # "make check" in that particular order.
 142 # If --enable-gold is used, "gold" may replace "ld".
 143 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gprof etc expect dejagnu m4 utils guile fastjar gnattools libcc1 gotools"
 144
 145 # these libraries are built for the target environment, and are built after
 146 # the host libraries and the host tools (which may be a cross compiler)
 147 # Note that libiberty is not a target library.
 148 target_libraries="target-libgcc \
 149                 target-libbacktrace \
 150                 target-libgloss \
 151                 target-newlib \
 152                 target-libgomp \
 153                 target-libcilkrts \
 154                 target-liboffloadmic \
 155                 target-libhsail-rt \
 156                 target-libatomic \
 157                 target-libitm \
 158                 target-libstdc++-v3 \
 159                 target-libsanitizer \
 160                 target-libvtv \
 161                 target-libmpx \
 162                 target-libssp \
 163                 target-libquadmath \
 164                 target-libgfortran \
 165                 target-libffi \
 166                 target-libobjc \
 167                 target-libada \
 168                 target-libgo"
 169
 170 # these tools are built using the target libraries, and are intended to
 171 # run only in the target environment
 172 #
 173 # note: any program that *uses* libraries that are in the "target_libraries"
 174 # list belongs in this list.
 175 #
 176 target_tools="target-rda"
 177
 178 ################################################################################
 179
 180 ## All tools belong in one of the four categories, and are assigned above
 181 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 182 ## is important because configure will choke if they ever get through.
 183 ## ${configdirs} is directories we build using the host tools.
 184 ## ${target_configdirs} is directories we build using the target tools.
 185 configdirs=`echo ${host_libs} ${host_tools}`
 186 target_configdirs=`echo ${target_libraries} ${target_tools}`
 187 build_configdirs=`echo ${build_libs} ${build_tools}`
 188
 189 m4_divert_text([PARSE_ARGS],
 190 [case $srcdir in
 191   *" "*)
 192 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 193     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 194 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 195     ;;
 196 esac
 197 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 198 ])
 199
 200 ################################################################################
 201
 202 srcname="gnu development package"
 203
 204 # This gets set non-empty for some net releases of packages.
 205 appdirs=""
 206
 207 # Define is_cross_compiler to save on calls to 'test'.
 208 is_cross_compiler=
 209 if test x"${host}" = x"${target}" ; then
 210   is_cross_compiler=no
 211 else
 212   is_cross_compiler=yes
 213 fi
 214
 215 # Find the build and target subdir names.
 216 GCC_TOPLEV_SUBDIRS
 217 # Be sure to cover against remnants of an in-tree build.
 218 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 219   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 220 Use a pristine source tree when building in a separate tree])
 221 fi
 222
 223 # Skipdirs are removed silently.
 224 skipdirs=
 225 # Noconfigdirs are removed loudly.
 226 noconfigdirs=""
 227
 228 use_gnu_ld=
 229 # Make sure we don't let GNU ld be added if we didn't want it.
 230 if test x$with_gnu_ld = xno ; then
 231   use_gnu_ld=no
 232   noconfigdirs="$noconfigdirs ld gold"
 233 fi
 234
 235 use_gnu_as=
 236 # Make sure we don't let GNU as be added if we didn't want it.
 237 if test x$with_gnu_as = xno ; then
 238   use_gnu_as=no
 239   noconfigdirs="$noconfigdirs gas"
 240 fi
 241
 242 use_included_zlib=
 243 AC_ARG_WITH(system-zlib,
 244 [AS_HELP_STRING([--with-system-zlib], [use installed libz])])
 245 # Make sure we don't let ZLIB be added if we didn't want it.
 246 if test x$with_system_zlib = xyes ; then
 247   use_included_zlib=no
 248   noconfigdirs="$noconfigdirs zlib"
 249 fi
 250
 251 # some tools are so dependent upon X11 that if we're not building with X,
 252 # it's not even worth trying to configure, much less build, that tool.
 253
 254 case ${with_x} in
 255   yes | "") ;; # the default value for this tree is that X11 is available
 256   no)
 257     skipdirs="${skipdirs} tk itcl libgui"
 258     # We won't be able to build gdbtk without X.
 259     enable_gdbtk=no
 260     ;;
 261   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 262 esac
 263
 264 # Some are only suitable for cross toolchains.
 265 # Remove these if host=target.
 266 cross_only="target-libgloss target-newlib target-opcodes"
 267
 268 case $is_cross_compiler in
 269   no) skipdirs="${skipdirs} ${cross_only}" ;;
 270 esac
 271
 272 # If both --with-headers and --with-libs are specified, default to
 273 # --without-newlib.
 274 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 275    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 276   if test x"${with_newlib}" = x ; then
 277     with_newlib=no
 278   fi
 279 fi
 280
 281 # Recognize --with-newlib/--without-newlib.
 282 case ${with_newlib} in
 283   no) skipdirs="${skipdirs} target-newlib" ;;
 284   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 285 esac
 286
 287 AC_ARG_ENABLE(as-accelerator-for,
 288 [AS_HELP_STRING([--enable-as-accelerator-for=ARG],
 289                 [build as offload target compiler.
 290                 Specify offload host triple by ARG])])
 291
 292 AC_ARG_ENABLE(offload-targets,
 293 [AS_HELP_STRING([--enable-offload-targets=LIST],
 294                 [enable offloading to devices from comma-separated LIST of
 295                 TARGET[=DIR]. Use optional path to find offload target compiler
 296                 during the build])],
 297 [
 298   if test x"$enable_offload_targets" = x; then
 299     AC_MSG_ERROR([no offload targets specified])
 300   fi
 301 ], [enable_offload_targets=])
 302
 303 # Handle --enable-gold, --enable-ld.
 304 # --disable-gold [--enable-ld]
 305 #     Build only ld.  Default option.
 306 # --enable-gold [--enable-ld]
 307 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 308 #     as "ld.bfd" and "ld".
 309 # --enable-gold=default [--enable-ld]
 310 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 311 #     install ld as "ld.bfd".
 312 # --enable-gold[=default] --disable-ld
 313 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 314 # --enable-gold --enable-ld=default
 315 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 316 #     and ld.bfd).
 317 #     In other words, ld is default
 318 # --enable-gold=default --enable-ld=default
 319 #     Error.
 320
 321 default_ld=
 322 AC_ARG_ENABLE(gold,
 323 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 324                 [build gold @<:@ARG={default,yes,no}@:>@])],
 325 ENABLE_GOLD=$enableval,
 326 ENABLE_GOLD=no)
 327 case "${ENABLE_GOLD}" in
 328   yes|default)
 329     # Check for ELF target.
 330     is_elf=no
 331     case "${target}" in
 332       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 333       | *-*-linux* | *-*-gnu* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 334       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 335       | *-*-solaris2* | *-*-nto* | *-*-nacl*)
 336         case "${target}" in
 337           *-*-linux*aout* | *-*-linux*oldld*)
 338             ;;
 339           *)
 340             is_elf=yes
 341             ;;
 342         esac
 343     esac
 344
 345     if test "$is_elf" = "yes"; then
 346       # Check for target supported by gold.
 347       case "${target}" in
 348         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-* \
 349         | aarch64*-*-* | tilegx*-*-* | mips*-*-* | s390*-*-*)
 350           configdirs="$configdirs gold"
 351           if test x${ENABLE_GOLD} = xdefault; then
 352             default_ld=gold
 353           fi
 354           ENABLE_GOLD=yes
 355           ;;
 356       esac
 357     fi
 358     ;;
 359   no)
 360     ;;
 361   *)
 362     AC_MSG_ERROR([invalid --enable-gold argument])
 363     ;;
 364 esac
 365
 366 AC_ARG_ENABLE(ld,
 367 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 368                 [build ld @<:@ARG={default,yes,no}@:>@])],
 369 ENABLE_LD=$enableval,
 370 ENABLE_LD=yes)
 371
 372 case "${ENABLE_LD}" in
 373   default)
 374     if test x${default_ld} != x; then
 375       AC_MSG_ERROR([either gold or ld can be the default ld])
 376     fi
 377     ;;
 378   yes)
 379     ;;
 380   no)
 381     if test x${ENABLE_GOLD} != xyes; then
 382       AC_MSG_WARN([neither ld nor gold are enabled])
 383     fi
 384     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 385     ;;
 386   *)
 387     AC_MSG_ERROR([invalid --enable-ld argument])
 388     ;;
 389 esac
 390
 391 # PR gas/19109
 392 # Decide the default method for compressing debug sections.
 393 # Provide a configure time option to override our default.
 394 AC_ARG_ENABLE(compressed_debug_sections,
 395 [AS_HELP_STRING([--enable-compressed-debug-sections={all,gas,gold,ld,none}],
 396                 [Enable compressed debug sections for gas, gold or ld by
 397                  default])],
 398 [
 399   if test x"$enable_compressed_debug_sections" = xyes; then
 400     AC_MSG_ERROR([no program with compressed debug sections specified])
 401   fi
 402 ], [enable_compressed_debug_sections=])
 403
 404 # Configure extra directories which are host specific
 405
 406 case "${host}" in
 407   *-cygwin*)
 408     configdirs="$configdirs libtermcap" ;;
 409 esac
 410
 411 # A target can indicate whether a language isn't supported for some reason.
 412 # Only spaces may be used in this macro; not newlines or tabs.
 413 unsupported_languages=
 414
 415 # Remove more programs from consideration, based on the host or
 416 # target this usually means that a port of the program doesn't
 417 # exist yet.
 418
 419 case "${host}" in
 420   i[[3456789]]86-*-msdosdjgpp*)
 421     noconfigdirs="$noconfigdirs tcl tk itcl"
 422     ;;
 423 esac
 424
 425
 426 AC_ARG_ENABLE(libquadmath,
 427 AS_HELP_STRING([--disable-libquadmath],
 428   [do not build libquadmath directory]),
 429 ENABLE_LIBQUADMATH=$enableval,
 430 ENABLE_LIBQUADMATH=yes)
 431 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 432   noconfigdirs="$noconfigdirs target-libquadmath"
 433 fi
 434
 435
 436 AC_ARG_ENABLE(libquadmath-support,
 437 AS_HELP_STRING([--disable-libquadmath-support],
 438   [disable libquadmath support for Fortran]),
 439 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 440 ENABLE_LIBQUADMATH_SUPPORT=yes)
 441 enable_libquadmath_support=
 442 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 443   enable_libquadmath_support=no
 444 fi
 445
 446
 447 AC_ARG_ENABLE(libada,
 448 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 449 ENABLE_LIBADA=$enableval,
 450 ENABLE_LIBADA=yes)
 451 if test "${ENABLE_LIBADA}" != "yes" ; then
 452   noconfigdirs="$noconfigdirs gnattools"
 453 fi
 454
 455 AC_ARG_ENABLE(libssp,
 456 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 457 ENABLE_LIBSSP=$enableval,
 458 ENABLE_LIBSSP=yes)
 459
 460 AC_ARG_ENABLE(libstdcxx,
 461 AS_HELP_STRING([--disable-libstdcxx],
 462   [do not build libstdc++-v3 directory]),
 463 ENABLE_LIBSTDCXX=$enableval,
 464 ENABLE_LIBSTDCXX=default)
 465 [if test "${ENABLE_LIBSTDCXX}" = "no" ; then
 466   noconfigdirs="$noconfigdirs target-libstdc++-v3"
 467 fi]
 468
 469 # If this is accelerator compiler and its target is intelmic we enable
 470 # target liboffloadmic by default.  If this is compiler with offloading
 471 # for intelmic we enable host liboffloadmic by default.  Otherwise
 472 # liboffloadmic is disabled by default.
 473 AC_ARG_ENABLE([liboffloadmic],
 474 AC_HELP_STRING([[--enable-liboffloadmic[=ARG]]],
 475                [build liboffloadmic @<:@ARG={no,host,target}@:>@]),
 476 [case "$enableval" in
 477   no | host | target)
 478     enable_liboffloadmic=$enableval ;;
 479   *)
 480     AC_MSG_ERROR([--enable-liboffloadmic=no/host/target]) ;;
 481 esac],
 482 [if test x"$enable_as_accelerator_for" != x; then
 483   case "${target}" in
 484     *-intelmic-* | *-intelmicemul-*)
 485       enable_liboffloadmic=target
 486       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=target"
 487       ;;
 488     *)
 489       enable_liboffloadmic=no
 490       ;;
 491   esac
 492 else
 493   case "${enable_offload_targets}" in
 494     *-intelmic-* | *-intelmicemul-*)
 495       enable_liboffloadmic=host
 496       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=host"
 497       ;;
 498     *)
 499       enable_liboffloadmic=no
 500       ;;
 501     esac
 502 fi])
 503 AC_SUBST(extra_liboffloadmic_configure_flags)
 504
 505 # Enable libgomp by default on hosted POSIX systems, and a few others.
 506 if test x$enable_libgomp = x ; then
 507     case "${target}" in
 508     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 509         ;;
 510     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 511         ;;
 512     *-*-solaris2* | *-*-hpux11*)
 513         ;;
 514     *-*-darwin* | *-*-aix*)
 515         ;;
 516     nvptx*-*-*)
 517         ;;
 518     *)
 519         noconfigdirs="$noconfigdirs target-libgomp"
 520         ;;
 521     esac
 522 fi
 523
 524 # Disable libatomic on unsupported systems.
 525 if test -d ${srcdir}/libatomic; then
 526     if test x$enable_libatomic = x; then
 527         AC_MSG_CHECKING([for libatomic support])
 528         if (srcdir=${srcdir}/libatomic; \
 529                 . ${srcdir}/configure.tgt; \
 530                 test -n "$UNSUPPORTED")
 531         then
 532             AC_MSG_RESULT([no])
 533             noconfigdirs="$noconfigdirs target-libatomic"
 534         else
 535             AC_MSG_RESULT([yes])
 536         fi
 537     fi
 538 fi
 539
 540 # Disable libcilkrts on unsupported systems.
 541 if test -d ${srcdir}/libcilkrts; then
 542     if test x$enable_libcilkrts = x; then
 543         AC_MSG_CHECKING([for libcilkrts support])
 544         if (srcdir=${srcdir}/libcilkrts; \
 545                 . ${srcdir}/configure.tgt; \
 546                 test -n "$UNSUPPORTED")
 547         then
 548             AC_MSG_RESULT([no])
 549             noconfigdirs="$noconfigdirs target-libcilkrts"
 550         else
 551             AC_MSG_RESULT([yes])
 552         fi
 553     fi
 554 fi
 555
 556 # Disable liboffloadmic on unsupported systems.
 557 if test -d ${srcdir}/liboffloadmic; then
 558     if test x$enable_liboffloadmic != xno; then
 559         AC_MSG_CHECKING([for liboffloadmic support])
 560         if (srcdir=${srcdir}/liboffloadmic; \
 561                 . ${srcdir}/configure.tgt; \
 562                 test -n "$UNSUPPORTED")
 563         then
 564             AC_MSG_RESULT([no])
 565             noconfigdirs="$noconfigdirs target-liboffloadmic"
 566         else
 567             AC_MSG_RESULT([yes])
 568         fi
 569     fi
 570 fi
 571
 572 # Disable libitm on unsupported systems.
 573 if test -d ${srcdir}/libitm; then
 574     if test x$enable_libitm = x; then
 575         AC_MSG_CHECKING([for libitm support])
 576         if (srcdir=${srcdir}/libitm; \
 577                 . ${srcdir}/configure.tgt; \
 578                 test -n "$UNSUPPORTED")
 579         then
 580             AC_MSG_RESULT([no])
 581             noconfigdirs="$noconfigdirs target-libitm"
 582         else
 583             AC_MSG_RESULT([yes])
 584         fi
 585     fi
 586 fi
 587
 588 # Disable libsanitizer on unsupported systems.
 589 if test -d ${srcdir}/libsanitizer; then
 590     if test x$enable_libsanitizer = x; then
 591         AC_MSG_CHECKING([for libsanitizer support])
 592         if (srcdir=${srcdir}/libsanitizer; \
 593                 . ${srcdir}/configure.tgt; \
 594                 test -n "$UNSUPPORTED")
 595         then
 596             AC_MSG_RESULT([no])
 597             noconfigdirs="$noconfigdirs target-libsanitizer"
 598         else
 599             AC_MSG_RESULT([yes])
 600         fi
 601     fi
 602 fi
 603
 604 # Disable libvtv on unsupported systems.
 605 if test -d ${srcdir}/libvtv; then
 606     if test x$enable_libvtv = x; then
 607         AC_MSG_CHECKING([for libvtv support])
 608         if (srcdir=${srcdir}/libvtv; \
 609                 . ${srcdir}/configure.tgt; \
 610                 test "$VTV_SUPPORTED" != "yes")
 611         then
 612             AC_MSG_RESULT([no])
 613             noconfigdirs="$noconfigdirs target-libvtv"
 614         else
 615             AC_MSG_RESULT([yes])
 616         fi
 617     fi
 618 fi
 619
 620
 621 # Enable libmpx on supported systems by request.
 622 if test -d ${srcdir}/libmpx; then
 623     if test x$enable_libmpx = x; then
 624        AC_MSG_CHECKING([for libmpx support])
 625        if (srcdir=${srcdir}/libmpx; \
 626                . ${srcdir}/configure.tgt; \
 627                test "$LIBMPX_SUPPORTED" != "yes")
 628        then
 629            AC_MSG_RESULT([no])
 630            noconfigdirs="$noconfigdirs target-libmpx"
 631        else
 632            AC_MSG_RESULT([yes])
 633        fi
 634     fi
 635 fi
 636
 637 # Disable libhsail-rt on unsupported systems.
 638 if test -d ${srcdir}/libhsail-rt; then
 639     if test x$enable_libhsail_rt = x; then
 640         AC_MSG_CHECKING([for libhsail-rt support])
 641         if (srcdir=${srcdir}/libhsail-rt; \
 642                 . ${srcdir}/configure.tgt; \
 643                 test -n "$UNSUPPORTED")
 644         then
 645             AC_MSG_RESULT([no])
 646             unsupported_languages="$unsupported_languages brig"
 647             # This implicitly disables also target-libhsail-rt as it won't
 648             # get added to the build without BRIG FE.
 649         else
 650             AC_MSG_RESULT([yes])
 651         fi
 652     fi
 653 fi
 654
 655
 656 # Disable libquadmath for some systems.
 657 case "${target}" in
 658   avr-*-*)
 659     noconfigdirs="$noconfigdirs target-libquadmath"
 660     ;;
 661   # libquadmath is unused on AIX and libquadmath build process use of
 662   # LD_LIBRARY_PATH can break AIX bootstrap.
 663   powerpc-*-aix* | rs6000-*-aix*)
 664     noconfigdirs="$noconfigdirs target-libquadmath"
 665     ;;
 666 esac
 667
 668 # Disable libssp for some systems.
 669 case "${target}" in
 670   avr-*-*)
 671     # No hosted I/O support.
 672     noconfigdirs="$noconfigdirs target-libssp"
 673     ;;
 674   powerpc-*-aix* | rs6000-*-aix*)
 675     noconfigdirs="$noconfigdirs target-libssp"
 676     ;;
 677   rl78-*-*)
 678     # libssp uses a misaligned load to trigger a fault, but the RL78
 679     # doesn't fault for those - instead, it gives a build-time error
 680     # for explicit misaligned loads.
 681     noconfigdirs="$noconfigdirs target-libssp"
 682     ;;
 683   visium-*-*)
 684     # No hosted I/O support.
 685     noconfigdirs="$noconfigdirs target-libssp"
 686     ;;
 687 esac
 688
 689 # Disable libstdc++-v3 for some systems.
 690 # Allow user to override this if they pass --enable-libstdc++-v3
 691 if test "${ENABLE_LIBSTDCXX}" = "default" ; then
 692   case "${target}" in
 693     *-*-vxworks*)
 694       # VxWorks uses the Dinkumware C++ library.
 695       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 696       ;;
 697     arm*-wince-pe*)
 698       # the C++ libraries don't build on top of CE's C libraries
 699       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 700       ;;
 701     avr-*-*)
 702       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 703       ;;
 704     ft32-*-*)
 705       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 706       ;;
 707   esac
 708 fi
 709
 710 # Disable Fortran for some systems.
 711 case "${target}" in
 712   mmix-*-*)
 713     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 714     unsupported_languages="$unsupported_languages fortran"
 715     ;;
 716 esac
 717
 718 # Disable libffi for some systems.
 719 case "${target}" in
 720   powerpc-*-darwin*)
 721     ;;
 722   i[[3456789]]86-*-darwin*)
 723     ;;
 724   x86_64-*-darwin[[912]]*)
 725     ;;
 726   *-*-darwin*)
 727     noconfigdirs="$noconfigdirs target-libffi"
 728     ;;
 729   *-*-netware*)
 730     noconfigdirs="$noconfigdirs target-libffi"
 731     ;;
 732   *-*-phoenix*)
 733     noconfigdirs="$noconfigdirs target-libffi"
 734     ;;
 735   *-*-rtems*)
 736     noconfigdirs="$noconfigdirs target-libffi"
 737     ;;
 738   *-*-tpf*)
 739     noconfigdirs="$noconfigdirs target-libffi"
 740     ;;
 741   *-*-uclinux*)
 742     noconfigdirs="$noconfigdirs target-libffi"
 743     ;;
 744   *-*-vxworks*)
 745     noconfigdirs="$noconfigdirs target-libffi"
 746     ;;
 747   aarch64*-*-freebsd*)
 748     noconfigdirs="$noconfigdirs target-libffi"
 749     ;;
 750   alpha*-*-*vms*)
 751     noconfigdirs="$noconfigdirs target-libffi"
 752     ;;
 753   arm*-*-freebsd*)
 754     noconfigdirs="$noconfigdirs target-libffi"
 755     ;;
 756   arm-wince-pe)
 757     noconfigdirs="$noconfigdirs target-libffi"
 758     ;;
 759   arm*-*-symbianelf*)
 760     noconfigdirs="$noconfigdirs target-libffi"
 761     ;;
 762   cris-*-* | crisv32-*-*)
 763     case "${target}" in
 764       *-*-linux*)
 765         ;;
 766       *) # See PR46792 regarding target-libffi.
 767         noconfigdirs="$noconfigdirs target-libffi";;
 768     esac
 769     ;;
 770   hppa*64*-*-hpux*)
 771     noconfigdirs="$noconfigdirs target-libffi"
 772     ;;
 773   hppa*-hp-hpux11*)
 774     ;;
 775   hppa*-*-hpux*)
 776     noconfigdirs="$noconfigdirs target-libffi"
 777     ;;
 778   ia64*-*-*vms*)
 779     noconfigdirs="$noconfigdirs target-libffi"
 780     ;;
 781   i[[3456789]]86-w64-mingw*)
 782     noconfigdirs="$noconfigdirs target-libffi"
 783     ;;
 784   i[[3456789]]86-*-mingw*)
 785     noconfigdirs="$noconfigdirs target-libffi"
 786     ;;
 787   x86_64-*-mingw*)
 788     noconfigdirs="$noconfigdirs target-libffi"
 789     ;;
 790   mmix-*-*)
 791     noconfigdirs="$noconfigdirs target-libffi"
 792     ;;
 793   powerpc-*-aix*)
 794     ;;
 795   rs6000-*-aix*)
 796     ;;
 797   ft32-*-*)
 798     noconfigdirs="$noconfigdirs target-libffi"
 799     ;;
 800   *-*-lynxos*)
 801     noconfigdirs="$noconfigdirs target-libffi"
 802     ;;
 803 esac
 804
 805 # Disable the go frontend on systems where it is known to not work. Please keep
 806 # this in sync with contrib/config-list.mk.
 807 case "${target}" in
 808 *-*-darwin* | *-*-cygwin* | *-*-mingw*)
 809     unsupported_languages="$unsupported_languages go"
 810     ;;
 811 esac
 812
 813 # Disable libgo for some systems where it is known to not work.
 814 # For testing, you can easily override this with --enable-libgo.
 815 if test x$enable_libgo = x; then
 816     case "${target}" in
 817     *-*-darwin*)
 818         # PR 46986
 819         noconfigdirs="$noconfigdirs target-libgo"
 820         ;;
 821     *-*-cygwin* | *-*-mingw*)
 822         noconfigdirs="$noconfigdirs target-libgo"
 823         ;;
 824     esac
 825 fi
 826
 827 # Default libgloss CPU subdirectory.
 828 libgloss_dir="$target_cpu"
 829
 830 case "${target}" in
 831   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 832     libgloss_dir=wince
 833     ;;
 834   aarch64*-*-* )
 835     libgloss_dir=aarch64
 836     ;;
 837   arm*-*-*)
 838     libgloss_dir=arm
 839     ;;
 840   cris-*-* | crisv32-*-*)
 841     libgloss_dir=cris
 842     ;;
 843   hppa*-*-*)
 844     libgloss_dir=pa
 845     ;;
 846   i[[3456789]]86-*-*)
 847     libgloss_dir=i386
 848     ;;
 849   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 850     libgloss_dir=m68hc11
 851     ;;
 852   m68*-*-* | fido-*-*)
 853     libgloss_dir=m68k
 854     ;;
 855   mips*-*-*)
 856     libgloss_dir=mips
 857     ;;
 858   powerpc*-*-*)
 859     libgloss_dir=rs6000
 860     ;;
 861   sparc*-*-*)
 862     libgloss_dir=sparc
 863     ;;
 864 esac
 865
 866 # Disable newlib and libgloss for various target OSes.
 867 case "${target}" in
 868   alpha*-dec-osf*)
 869     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 870     ;;
 871   i[[3456789]]86-*-linux*)
 872     # This section makes it possible to build newlib natively on linux.
 873     # If we are using a cross compiler then don't configure newlib.
 874     if test x${is_cross_compiler} != xno ; then
 875       noconfigdirs="$noconfigdirs target-newlib"
 876     fi
 877     noconfigdirs="$noconfigdirs target-libgloss"
 878     # If we are not using a cross compiler, do configure newlib.
 879     # Note however, that newlib will only be configured in this situation
 880     # if the --with-newlib option has been given, because otherwise
 881     # 'target-newlib' will appear in skipdirs.
 882     ;;
 883   i[[3456789]]86-*-rdos*)
 884     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 885     ;;
 886   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 887     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 888     ;;
 889   sparc-*-sunos4*)
 890     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 891     ;;
 892   *-*-aix*)
 893     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 894     ;;
 895   *-*-beos*)
 896     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 897     ;;
 898   *-*-chorusos)
 899     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 900     ;;
 901   *-*-dragonfly*)
 902     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 903     ;;
 904   *-*-freebsd*)
 905     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 906     ;;
 907   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 908     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 909     ;;
 910   *-*-lynxos*)
 911     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 912     ;;
 913   *-*-mingw*)
 914     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 915     ;;
 916   *-*-netbsd*)
 917     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 918     ;;
 919   *-*-netware*)
 920     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 921     ;;
 922   *-*-tpf*)
 923     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 924     ;;
 925   *-*-uclinux*)
 926     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 927     ;;
 928   *-*-vxworks*)
 929     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 930     ;;
 931 esac
 932
 933 case "${target}" in
 934   *-*-chorusos)
 935     ;;
 936   aarch64-*-darwin*)
 937     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 938     noconfigdirs="$noconfigdirs sim target-rda"
 939     ;;
 940   arm-*-darwin*)
 941     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 942     noconfigdirs="$noconfigdirs sim target-rda"
 943     ;;
 944   powerpc-*-darwin*)
 945     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 946     noconfigdirs="$noconfigdirs sim target-rda"
 947     ;;
 948   i[[3456789]]86-*-darwin*)
 949     noconfigdirs="$noconfigdirs ld gprof"
 950     noconfigdirs="$noconfigdirs sim target-rda"
 951     ;;
 952   x86_64-*-darwin[[912]]*)
 953     noconfigdirs="$noconfigdirs ld gas gprof"
 954     noconfigdirs="$noconfigdirs sim target-rda"
 955     ;;
 956   *-*-darwin*)
 957     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 958     noconfigdirs="$noconfigdirs sim target-rda"
 959     ;;
 960   *-*-dragonfly*)
 961     ;;
 962   *-*-freebsd*)
 963     if test "x$with_gmp" = x && test "x$with_gmp_dir" = x \
 964         && test -f /usr/local/include/gmp.h; then
 965       with_gmp=/usr/local
 966     fi
 967     ;;
 968   *-*-kaos*)
 969     # Remove unsupported stuff on all kaOS configurations.
 970     noconfigdirs="$noconfigdirs target-libgloss"
 971     ;;
 972   *-*-netbsd*)
 973     ;;
 974   *-*-netware*)
 975     ;;
 976   *-*-phoenix*)
 977     noconfigdirs="$noconfigdirs target-libgloss"
 978     ;;
 979   *-*-rtems*)
 980     noconfigdirs="$noconfigdirs target-libgloss"
 981     # this is not caught below because this stanza matches earlier
 982     case $target in
 983       or1k*-*-*) noconfigdirs="$noconfigdirs gdb" ;;
 984     esac
 985     ;;
 986     # The tpf target doesn't support gdb yet.
 987   *-*-tpf*)
 988     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
 989     ;;
 990   *-*-uclinux*)
 991     noconfigdirs="$noconfigdirs target-rda"
 992     ;;
 993   *-*-vxworks*)
 994     ;;
 995   alpha*-dec-osf*)
 996     # ld works, but does not support shared libraries.
 997     # gas doesn't generate exception information.
 998     noconfigdirs="$noconfigdirs gas ld"
 999     ;;
1000   alpha*-*-*vms*)
1001     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
1002     ;;
1003   alpha*-*-*)
1004     # newlib is not 64 bit ready
1005     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1006     ;;
1007   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
1008     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
1009     ;;
1010   arc*-*-*)
1011     noconfigdirs="$noconfigdirs sim"
1012     ;;
1013   arm-*-pe*)
1014     noconfigdirs="$noconfigdirs target-libgloss"
1015     ;;
1016   arm-*-riscix*)
1017     noconfigdirs="$noconfigdirs ld target-libgloss"
1018     ;;
1019   avr-*-*)
1020     if test x${with_avrlibc} != xno; then
1021       noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1022     fi
1023     ;;
1024   c4x-*-* | tic4x-*-*)
1025     noconfigdirs="$noconfigdirs target-libgloss"
1026     ;;
1027   tic54x-*-*)
1028     noconfigdirs="$noconfigdirs target-libgloss gdb"
1029     ;;
1030   d10v-*-*)
1031     noconfigdirs="$noconfigdirs target-libgloss"
1032     ;;
1033   d30v-*-*)
1034     noconfigdirs="$noconfigdirs gdb"
1035     ;;
1036   fr30-*-elf*)
1037     noconfigdirs="$noconfigdirs gdb"
1038     ;;
1039   ft32-*-*)
1040     noconfigdirs="$noconfigdirs target-rda gprof"
1041     ;;
1042   moxie-*-*)
1043     noconfigdirs="$noconfigdirs"
1044     ;;
1045   h8300*-*-*)
1046     noconfigdirs="$noconfigdirs target-libgloss"
1047     ;;
1048   h8500-*-*)
1049     noconfigdirs="$noconfigdirs target-libgloss"
1050     ;;
1051   hppa1.1-*-osf* | hppa1.1-*-bsd* )
1052     ;;
1053   hppa*64*-*-hpux*)
1054     noconfigdirs="$noconfigdirs gdb"
1055     ;;
1056   hppa*-*-hpux11*)
1057     noconfigdirs="$noconfigdirs gdb ld"
1058     ;;
1059   hppa*64*-*-linux*)
1060     ;;
1061   hppa*-*-linux*)
1062     ;;
1063   hppa*-*-*elf* | \
1064   hppa*-*-lites* | \
1065   hppa*-*-openbsd* | \
1066   hppa*64*-*-*)
1067     ;;
1068   hppa*-*-pro*)
1069     ;;
1070   hppa*-*-*)
1071     noconfigdirs="$noconfigdirs ld"
1072     ;;
1073   i960-*-*)
1074     noconfigdirs="$noconfigdirs gdb"
1075     ;;
1076   ia64*-*-elf*)
1077     # No gdb support yet.
1078     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
1079     ;;
1080   ia64*-**-hpux*)
1081     # No ld support yet.
1082     noconfigdirs="$noconfigdirs gdb libgui itcl ld"
1083     ;;
1084   ia64*-*-*vms*)
1085     # No ld support yet.
1086     noconfigdirs="$noconfigdirs libgui itcl ld"
1087     ;;
1088   i[[3456789]]86-w64-mingw*)
1089     ;;
1090   i[[3456789]]86-*-mingw*)
1091     target_configdirs="$target_configdirs target-winsup"
1092     ;;
1093   *-*-cygwin*)
1094     target_configdirs="$target_configdirs target-libtermcap target-winsup"
1095     noconfigdirs="$noconfigdirs target-libgloss"
1096     # always build newlib if winsup directory is present.
1097     if test -d "$srcdir/winsup/cygwin"; then
1098       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1099     elif test -d "$srcdir/newlib"; then
1100       echo "Warning: winsup/cygwin is missing so newlib can't be built."
1101     fi
1102     ;;
1103   i[[3456789]]86-*-pe)
1104     noconfigdirs="$noconfigdirs target-libgloss"
1105     ;;
1106   i[[3456789]]86-*-sco3.2v5*)
1107     # The linker does not yet know about weak symbols in COFF,
1108     # and is not configured to handle mixed ELF and COFF.
1109     noconfigdirs="$noconfigdirs ld target-libgloss"
1110     ;;
1111   i[[3456789]]86-*-sco*)
1112     noconfigdirs="$noconfigdirs gprof target-libgloss"
1113     ;;
1114   i[[3456789]]86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
1115     noconfigdirs="$noconfigdirs target-libgloss"
1116     ;;
1117   i[[3456789]]86-*-sysv4*)
1118     noconfigdirs="$noconfigdirs target-libgloss"
1119     ;;
1120   i[[3456789]]86-*-beos*)
1121     noconfigdirs="$noconfigdirs gdb"
1122     ;;
1123   i[[3456789]]86-*-rdos*)
1124     noconfigdirs="$noconfigdirs gdb"
1125     ;;
1126   mmix-*-*)
1127     noconfigdirs="$noconfigdirs gdb"
1128     ;;
1129   mt-*-*)
1130     noconfigdirs="$noconfigdirs sim"
1131     ;;
1132   powerpc-*-aix*)
1133     # copied from rs6000-*-* entry
1134     noconfigdirs="$noconfigdirs gprof"
1135     ;;
1136   powerpc*-*-winnt* | powerpc*-*-pe*)
1137     target_configdirs="$target_configdirs target-winsup"
1138     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
1139     # always build newlib.
1140     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1141     ;;
1142     # This is temporary until we can link against shared libraries
1143   powerpcle-*-solaris*)
1144     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
1145     ;;
1146   powerpc-*-beos*)
1147     noconfigdirs="$noconfigdirs gdb"
1148     ;;
1149   rs6000-*-lynxos*)
1150     noconfigdirs="$noconfigdirs gprof"
1151     ;;
1152   rs6000-*-aix*)
1153     noconfigdirs="$noconfigdirs gprof"
1154     ;;
1155   rs6000-*-*)
1156     noconfigdirs="$noconfigdirs gprof"
1157     ;;
1158   m68k-apollo-*)
1159     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
1160     ;;
1161   microblaze*)
1162     noconfigdirs="$noconfigdirs gprof"
1163     ;;
1164   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
1165     if test x$with_newlib = xyes; then
1166       noconfigdirs="$noconfigdirs gprof"
1167     fi
1168     ;;
1169   mips*-*-irix5*)
1170     noconfigdirs="$noconfigdirs gprof target-libgloss"
1171     ;;
1172   mips*-*-irix6*)
1173     noconfigdirs="$noconfigdirs gprof target-libgloss"
1174     ;;
1175   mips*-*-bsd*)
1176     noconfigdirs="$noconfigdirs ld gas gprof target-libgloss"
1177     ;;
1178   mips*-*-linux*)
1179     ;;
1180   mips*-*-ultrix* | mips*-*-osf* | mips*-*-ecoff* | mips*-*-pe* \
1181   | mips*-*-irix* | mips*-*-lnews* | mips*-*-riscos*)
1182     noconfigdirs="$noconfigdirs ld gas gprof"
1183     ;;
1184   mips*-*-*)
1185     noconfigdirs="$noconfigdirs gprof"
1186     ;;
1187   nvptx*-*-*)
1188     noconfigdirs="$noconfigdirs target-libssp target-libstdc++-v3 target-libobjc"
1189     ;;
1190   or1k*-*-*)
1191     noconfigdirs="$noconfigdirs gdb"
1192     ;;
1193   sh-*-*)
1194     case "${target}" in
1195       sh*-*-elf)
1196          ;;
1197       *)
1198          noconfigdirs="$noconfigdirs target-libgloss" ;;
1199     esac
1200     ;;
1201   sparc-*-sunos4*)
1202     if test x${is_cross_compiler} = xno ; then
1203            use_gnu_ld=no
1204     fi
1205     ;;
1206   tic6x-*-*)
1207     noconfigdirs="$noconfigdirs sim"
1208     ;;
1209   tilepro*-*-* | tilegx*-*-*)
1210     noconfigdirs="$noconfigdirs sim"
1211     ;;
1212   v810-*-*)
1213     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1214     ;;
1215   vax-*-*)
1216     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1217     ;;
1218 esac
1219
1220 # If we aren't building newlib, then don't build libgloss, since libgloss
1221 # depends upon some newlib header files.
1222 case "${noconfigdirs}" in
1223   *target-libgloss*) ;;
1224   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1225 esac
1226
1227 # Work in distributions that contain no compiler tools, like Autoconf.
1228 host_makefile_frag=/dev/null
1229 if test -d ${srcdir}/config ; then
1230 case "${host}" in
1231   i[[3456789]]86-*-msdosdjgpp*)
1232     host_makefile_frag="config/mh-djgpp"
1233     ;;
1234   *-cygwin*)
1235     ACX_CHECK_CYGWIN_CAT_WORKS
1236     host_makefile_frag="config/mh-cygwin"
1237     ;;
1238   *-mingw*)
1239     host_makefile_frag="config/mh-mingw"
1240     ;;
1241   alpha*-linux*)
1242     host_makefile_frag="config/mh-alpha-linux"
1243     ;;
1244   hppa*-hp-hpux10*)
1245     host_makefile_frag="config/mh-pa-hpux10"
1246     ;;
1247   hppa*-hp-hpux*)
1248     host_makefile_frag="config/mh-pa"
1249     ;;
1250   hppa*-*)
1251     host_makefile_frag="config/mh-pa"
1252     ;;
1253   *-*-darwin*)
1254     host_makefile_frag="config/mh-darwin"
1255     ;;
1256   powerpc-*-aix*)
1257     host_makefile_frag="config/mh-ppc-aix"
1258     ;;
1259   rs6000-*-aix*)
1260     host_makefile_frag="config/mh-ppc-aix"
1261     ;;
1262 esac
1263 fi
1264
1265 if test "${build}" != "${host}" ; then
1266   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1267   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1268   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1269   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1270   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1271   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1272   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1273   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1274   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1275   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1276   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1277   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1278 else
1279   AR_FOR_BUILD="\$(AR)"
1280   AS_FOR_BUILD="\$(AS)"
1281   CC_FOR_BUILD="\$(CC)"
1282   CXX_FOR_BUILD="\$(CXX)"
1283   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1284   GOC_FOR_BUILD="\$(GOC)"
1285   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1286   LD_FOR_BUILD="\$(LD)"
1287   NM_FOR_BUILD="\$(NM)"
1288   RANLIB_FOR_BUILD="\$(RANLIB)"
1289   WINDRES_FOR_BUILD="\$(WINDRES)"
1290   WINDMC_FOR_BUILD="\$(WINDMC)"
1291 fi
1292
1293 AC_PROG_CC
1294 AC_PROG_CXX
1295
1296 # We must set the default linker to the linker used by gcc for the correct
1297 # operation of libtool.  If LD is not defined and we are using gcc, try to
1298 # set the LD default to the ld used by gcc.
1299 if test -z "$LD"; then
1300   if test "$GCC" = yes; then
1301     case $build in
1302     *-*-mingw*)
1303       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1304     *)
1305       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1306     esac
1307     case $gcc_prog_ld in
1308     # Accept absolute paths.
1309     [[\\/]* | [A-Za-z]:[\\/]*)]
1310       LD="$gcc_prog_ld" ;;
1311     esac
1312   fi
1313 fi
1314
1315 # Check whether -static-libstdc++ -static-libgcc is supported.
1316 have_static_libs=no
1317 if test "$GCC" = yes; then
1318   saved_LDFLAGS="$LDFLAGS"
1319
1320   LDFLAGS="$LDFLAGS -static-libstdc++ -static-libgcc"
1321   AC_MSG_CHECKING([whether g++ accepts -static-libstdc++ -static-libgcc])
1322   AC_LANG_PUSH(C++)
1323   AC_LINK_IFELSE([
1324 #if (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 5)
1325 #error -static-libstdc++ not implemented
1326 #endif
1327 int main() {}],
1328     [AC_MSG_RESULT([yes]); have_static_libs=yes],
1329     [AC_MSG_RESULT([no])])
1330   AC_LANG_POP(C++)
1331
1332   LDFLAGS="$saved_LDFLAGS"
1333 fi
1334
1335 ACX_PROG_GNAT
1336 ACX_PROG_CMP_IGNORE_INITIAL
1337
1338 AC_ARG_ENABLE([bootstrap],
1339 [AS_HELP_STRING([--enable-bootstrap],
1340                 [enable bootstrapping @<:@yes if native build@:>@])],,
1341 enable_bootstrap=default)
1342
1343 # Issue errors and warnings for invalid/strange bootstrap combinations.
1344 if test -r $srcdir/gcc/configure; then
1345   have_compiler=yes
1346 else
1347   have_compiler=no
1348 fi
1349
1350 case "$have_compiler:$host:$target:$enable_bootstrap" in
1351   *:*:*:no) ;;
1352
1353   # Default behavior.  Enable bootstrap if we have a compiler
1354   # and we are in a native configuration.
1355   yes:$build:$build:default)
1356     enable_bootstrap=yes ;;
1357
1358   *:*:*:default)
1359     enable_bootstrap=no ;;
1360
1361   # We have a compiler and we are in a native configuration, bootstrap is ok
1362   yes:$build:$build:yes)
1363     ;;
1364
1365   # Other configurations, but we have a compiler.  Assume the user knows
1366   # what he's doing.
1367   yes:*:*:yes)
1368     AC_MSG_WARN([trying to bootstrap a cross compiler])
1369     ;;
1370
1371   # No compiler: if they passed --enable-bootstrap explicitly, fail
1372   no:*:*:yes)
1373     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
1374
1375   # Fail if wrong command line
1376   *)
1377     AC_MSG_ERROR([invalid option for --enable-bootstrap])
1378     ;;
1379 esac
1380
1381 # When bootstrapping with GCC, build stage 1 in C++98 mode to ensure that a
1382 # C++98 compiler can still start the bootstrap.
1383 if test "$enable_bootstrap:$GXX" = "yes:yes"; then
1384   CXX="$CXX -std=gnu++98"
1385 fi
1386
1387 # Used for setting $lt_cv_objdir
1388 _LT_CHECK_OBJDIR
1389
1390 # Check for GMP, MPFR and MPC
1391 gmplibs="-lmpc -lmpfr -lgmp"
1392 gmpinc=
1393 have_gmp=no
1394
1395 # Specify a location for mpc
1396 # check for this first so it ends up on the link line before mpfr.
1397 AC_ARG_WITH(mpc,
1398 [AS_HELP_STRING([--with-mpc=PATH],
1399                 [specify prefix directory for installed MPC package.
1400                  Equivalent to --with-mpc-include=PATH/include
1401                  plus --with-mpc-lib=PATH/lib])])
1402 AC_ARG_WITH(mpc-include,
1403 [AS_HELP_STRING([--with-mpc-include=PATH],
1404                 [specify directory for installed MPC include files])])
1405 AC_ARG_WITH(mpc-lib,
1406 [AS_HELP_STRING([--with-mpc-lib=PATH],
1407                 [specify directory for the installed MPC library])])
1408
1409 if test "x$with_mpc" != x; then
1410   gmplibs="-L$with_mpc/lib $gmplibs"
1411   gmpinc="-I$with_mpc/include $gmpinc"
1412 fi
1413 if test "x$with_mpc_include" != x; then
1414   gmpinc="-I$with_mpc_include $gmpinc"
1415 fi
1416 if test "x$with_mpc_lib" != x; then
1417   gmplibs="-L$with_mpc_lib $gmplibs"
1418 fi
1419 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1420   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1421   gmpinc='-I$$s/mpc/src '"$gmpinc"
1422   # Do not test the mpc version.  Assume that it is sufficient, since
1423   # it is in the source tree, and the library has not been built yet
1424   # but it would be included on the link line in the version check below
1425   # hence making the test fail.
1426   have_gmp=yes
1427 fi
1428
1429 # Specify a location for mpfr
1430 # check for this first so it ends up on the link line before gmp.
1431 AC_ARG_WITH(mpfr-dir,
1432 [AS_HELP_STRING([--with-mpfr-dir=PATH], [this option has been REMOVED])],
1433 [AC_MSG_ERROR([The --with-mpfr-dir=PATH option has been removed.
1434 Use --with-mpfr=PATH or --with-mpfr-include=PATH plus --with-mpfr-lib=PATH])])
1435
1436 AC_ARG_WITH(mpfr,
1437 [AS_HELP_STRING([--with-mpfr=PATH],
1438                 [specify prefix directory for installed MPFR package.
1439                  Equivalent to --with-mpfr-include=PATH/include
1440                  plus --with-mpfr-lib=PATH/lib])])
1441 AC_ARG_WITH(mpfr-include,
1442 [AS_HELP_STRING([--with-mpfr-include=PATH],
1443                 [specify directory for installed MPFR include files])])
1444 AC_ARG_WITH(mpfr-lib,
1445 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1446                 [specify directory for the installed MPFR library])])
1447
1448 if test "x$with_mpfr" != x; then
1449   gmplibs="-L$with_mpfr/lib $gmplibs"
1450   gmpinc="-I$with_mpfr/include $gmpinc"
1451 fi
1452 if test "x$with_mpfr_include" != x; then
1453   gmpinc="-I$with_mpfr_include $gmpinc"
1454 fi
1455 if test "x$with_mpfr_lib" != x; then
1456   gmplibs="-L$with_mpfr_lib $gmplibs"
1457 fi
1458 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1459   # MPFR v3.1.0 moved the sources into a src sub-directory.
1460   if ! test -d ${srcdir}/mpfr/src; then
1461     AC_MSG_ERROR([dnl
1462 Building GCC with MPFR in the source tree is only handled for MPFR 3.1.0+.])
1463   fi
1464   gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir $gmplibs"
1465   gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr/src -I$$s/mpfr/src '"$gmpinc"
1466   extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr/src --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir"
1467   # Do not test the mpfr version.  Assume that it is sufficient, since
1468   # it is in the source tree, and the library has not been built yet
1469   # but it would be included on the link line in the version check below
1470   # hence making the test fail.
1471   have_gmp=yes
1472 fi
1473
1474 # Specify a location for gmp
1475 AC_ARG_WITH(gmp-dir,
1476 [AS_HELP_STRING([--with-gmp-dir=PATH], [this option has been REMOVED])],
1477 [AC_MSG_ERROR([The --with-gmp-dir=PATH option has been removed.
1478 Use --with-gmp=PATH or --with-gmp-include=PATH plus --with-gmp-lib=PATH])])
1479
1480 AC_ARG_WITH(gmp,
1481 [AS_HELP_STRING([--with-gmp=PATH],
1482                 [specify prefix directory for the installed GMP package.
1483                  Equivalent to --with-gmp-include=PATH/include
1484                  plus --with-gmp-lib=PATH/lib])])
1485 AC_ARG_WITH(gmp-include,
1486 [AS_HELP_STRING([--with-gmp-include=PATH],
1487                 [specify directory for installed GMP include files])])
1488 AC_ARG_WITH(gmp-lib,
1489 [AS_HELP_STRING([--with-gmp-lib=PATH],
1490                 [specify directory for the installed GMP library])])
1491
1492
1493 if test "x$with_gmp" != x; then
1494   gmplibs="-L$with_gmp/lib $gmplibs"
1495   gmpinc="-I$with_gmp/include $gmpinc"
1496 fi
1497 if test "x$with_gmp_include" != x; then
1498   gmpinc="-I$with_gmp_include $gmpinc"
1499 fi
1500 if test "x$with_gmp_lib" != x; then
1501   gmplibs="-L$with_gmp_lib $gmplibs"
1502 fi
1503 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1504   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1505   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1506   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1507   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1508   extra_isl_gmp_configure_flags='--with-gmp-builddir=$$r/$(HOST_SUBDIR)/gmp'
1509   # Do not test the gmp version.  Assume that it is sufficient, since
1510   # it is in the source tree, and the library has not been built yet
1511   # but it would be included on the link line in the version check below
1512   # hence making the test fail.
1513   have_gmp=yes
1514 fi
1515
1516 if test -d ${srcdir}/gcc && test "x$have_gmp" = xno; then
1517   have_gmp=yes
1518   saved_CFLAGS="$CFLAGS"
1519   CFLAGS="$CFLAGS $gmpinc"
1520   # Check for the recommended and required versions of GMP.
1521   AC_MSG_CHECKING([for the correct version of gmp.h])
1522   AC_TRY_COMPILE([#include "gmp.h"],[
1523   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1524   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1525   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,3)
1526   choke me
1527   #endif
1528   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1529   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1530   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1531   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1532   choke me
1533   #endif
1534   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1535    [AC_MSG_RESULT([no]); have_gmp=no])
1536
1537   # If we have GMP, check the MPFR version.
1538   if test x"$have_gmp" = xyes; then
1539     # Check for the recommended and required versions of MPFR.
1540     AC_MSG_CHECKING([for the correct version of mpfr.h])
1541     AC_TRY_COMPILE([#include <gmp.h>
1542     #include <mpfr.h>],[
1543     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,0)
1544     choke me
1545     #endif
1546     ], [AC_TRY_COMPILE([#include <gmp.h>
1547     #include <mpfr.h>],[
1548     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,2)
1549     choke me
1550     #endif
1551     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1552      [AC_MSG_RESULT([no]); have_gmp=no])
1553   fi
1554
1555   # Check for the MPC header version.
1556   if test x"$have_gmp" = xyes ; then
1557     # Check for the recommended and required versions of MPC.
1558     AC_MSG_CHECKING([for the correct version of mpc.h])
1559     AC_TRY_COMPILE([#include <mpc.h>],[
1560     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1561     choke me
1562     #endif
1563     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1564     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1565     choke me
1566     #endif
1567     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1568      [AC_MSG_RESULT([no]); have_gmp=no])
1569   fi
1570
1571   # Now check the MPFR library.
1572   if test x"$have_gmp" = xyes; then
1573     saved_LIBS="$LIBS"
1574     LIBS="$LIBS $gmplibs"
1575     AC_MSG_CHECKING([for the correct version of the gmp/mpfr/mpc libraries])
1576     AC_TRY_LINK([#include <mpc.h>],[
1577     mpfr_t n;
1578     mpfr_t x;
1579     mpc_t c;
1580     int t;
1581     mpfr_init (n);
1582     mpfr_init (x);
1583     mpfr_atan2 (n, n, x, GMP_RNDN);
1584     mpfr_erfc (n, x, GMP_RNDN);
1585     mpfr_subnormalize (x, t, GMP_RNDN);
1586     mpfr_clear(n);
1587     mpfr_clear(x);
1588     mpc_init2 (c, 53);
1589     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1590     mpc_cosh (c, c, MPC_RNDNN);
1591     mpc_pow (c, c, c, MPC_RNDNN);
1592     mpc_acosh (c, c, MPC_RNDNN);
1593     mpc_clear (c);
1594     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1595     LIBS="$saved_LIBS"
1596   fi
1597
1598   CFLAGS="$saved_CFLAGS"
1599
1600 # The library versions listed in the error message below should match
1601 # the HARD-minimums enforced above.
1602   if test x$have_gmp != xyes; then
1603     AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 2.4.0+ and MPC 0.8.0+.
1604 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1605 their locations.  Source code for these libraries can be found at
1606 their respective hosting sites as well as at
1607 ftp://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1608 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1609 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1610 make sure that you have installed both the libraries and the header
1611 files.  They may be located in separate packages.])
1612   fi
1613 fi
1614
1615 # Flags needed for both GMP, MPFR and/or MPC.
1616 AC_SUBST(gmplibs)
1617 AC_SUBST(gmpinc)
1618 AC_SUBST(extra_mpfr_configure_flags)
1619 AC_SUBST(extra_mpc_gmp_configure_flags)
1620 AC_SUBST(extra_mpc_mpfr_configure_flags)
1621 AC_SUBST(extra_isl_gmp_configure_flags)
1622
1623 # Libraries to use for stage1 or when not bootstrapping.
1624 AC_ARG_WITH(stage1-libs,
1625 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1626 [if test "$withval" = "no" -o "$withval" = "yes"; then
1627    stage1_libs=
1628  else
1629    stage1_libs=$withval
1630  fi],
1631 [stage1_libs=])
1632 AC_SUBST(stage1_libs)
1633
1634 # Linker flags to use for stage1 or when not bootstrapping.
1635 AC_ARG_WITH(stage1-ldflags,
1636 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1637 [if test "$withval" = "no" -o "$withval" = "yes"; then
1638    stage1_ldflags=
1639  else
1640    stage1_ldflags=$withval
1641  fi],
1642 [stage1_ldflags=
1643  # In stage 1, default to linking libstdc++ and libgcc statically with GCC
1644  # if supported.  But if the user explicitly specified the libraries to use,
1645  # trust that they are doing what they want.
1646  if test "$stage1_libs" = "" -a "$have_static_libs" = yes; then
1647    stage1_ldflags="-static-libstdc++ -static-libgcc"
1648  fi])
1649 AC_SUBST(stage1_ldflags)
1650
1651 # Libraries to use for stage2 and later builds.
1652 AC_ARG_WITH(boot-libs,
1653 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1654 [if test "$withval" = "no" -o "$withval" = "yes"; then
1655    poststage1_libs=
1656  else
1657    poststage1_libs=$withval
1658  fi],
1659 [poststage1_libs=])
1660 AC_SUBST(poststage1_libs)
1661
1662 # Linker flags to use for stage2 and later builds.
1663 AC_ARG_WITH(boot-ldflags,
1664 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1665                 [linker flags for stage2 and later])],
1666 [if test "$withval" = "no" -o "$withval" = "yes"; then
1667    poststage1_ldflags=
1668  else
1669    poststage1_ldflags=$withval
1670  fi],
1671 [poststage1_ldflags=
1672  # In stages 2 and 3, default to linking libstdc++ and libgcc
1673  # statically.  But if the user explicitly specified the libraries to
1674  # use, trust that they are doing what they want.
1675  if test "$poststage1_libs" = ""; then
1676    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1677  fi])
1678 AC_SUBST(poststage1_ldflags)
1679
1680 # GCC GRAPHITE dependency isl.
1681 # Basic setup is inlined here, actual checks are in config/isl.m4
1682
1683 AC_ARG_WITH(isl,
1684   [AS_HELP_STRING(
1685    [--with-isl=PATH],
1686    [Specify prefix directory for the installed isl package.
1687     Equivalent to --with-isl-include=PATH/include
1688     plus --with-isl-lib=PATH/lib])])
1689
1690 # Treat --without-isl as a request to disable
1691 # GRAPHITE support and skip all following checks.
1692 if test "x$with_isl" != "xno"; then
1693   # Check for isl
1694   dnl Provide configure switches and initialize islinc & isllibs
1695   dnl with user input.
1696   ISL_INIT_FLAGS
1697   dnl The versions of isl that work for Graphite
1698   ISL_CHECK_VERSION()
1699   dnl Only execute fail-action, if isl has been requested.
1700   ISL_IF_FAILED([
1701     AC_MSG_ERROR([Unable to find a usable isl.  See config.log for details.])])
1702 fi
1703
1704 # If the isl check failed, disable builds of in-tree variant of isl
1705 if test "x$with_isl" = xno ||
1706    test "x$gcc_cv_isl" = xno; then
1707   noconfigdirs="$noconfigdirs isl"
1708   islinc=
1709 fi
1710
1711 AC_SUBST(isllibs)
1712 AC_SUBST(islinc)
1713
1714 # Check for LTO support.
1715 AC_ARG_ENABLE(lto,
1716 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1717 enable_lto=$enableval,
1718 enable_lto=yes; default_enable_lto=yes)
1719
1720 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1721   build_lto_plugin=yes
1722 ],[if test x"$default_enable_lto" = x"yes" ; then
1723     case $target in
1724       *-apple-darwin[[912]]* | *-cygwin* | *-mingw* | *djgpp*) ;;
1725       # On other non-ELF platforms, LTO has yet to be validated.
1726       *) enable_lto=no ;;
1727     esac
1728   else
1729   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1730   # It would also be nice to check the binutils support, but we don't
1731   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1732   # warn during gcc/ subconfigure; unless you're bootstrapping with
1733   # -flto it won't be needed until after installation anyway.
1734     case $target in
1735       *-cygwin* | *-mingw* | *-apple-darwin* | *djgpp*) ;;
1736       *) if test x"$enable_lto" = x"yes"; then
1737         AC_MSG_ERROR([LTO support is not enabled for this target.])
1738         fi
1739       ;;
1740     esac
1741   fi
1742   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1743   # Build it unless LTO was explicitly disabled.
1744   case $target in
1745     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1746     *) ;;
1747   esac
1748 ])
1749
1750 AC_ARG_ENABLE(linker-plugin-configure-flags,
1751   [AS_HELP_STRING([[--enable-linker-plugin-configure-flags=FLAGS]],
1752     [additional flags for configuring linker plugins @<:@none@:>@])],
1753   extra_linker_plugin_configure_flags=$enableval,
1754   extra_linker_plugin_configure_flags=)
1755 AC_SUBST(extra_linker_plugin_configure_flags)
1756 AC_ARG_ENABLE(linker-plugin-flags,
1757   [AS_HELP_STRING([[--enable-linker-plugin-flags=FLAGS]],
1758     [additional flags for configuring and building linker plugins @<:@none@:>@])],
1759   extra_linker_plugin_flags=$enableval,
1760   extra_linker_plugin_flags=)
1761 AC_SUBST(extra_linker_plugin_flags)
1762
1763 # Enable --enable-host-shared.
1764 # Checked early to determine whether jit is an 'all' language
1765 AC_ARG_ENABLE(host-shared,
1766 [AS_HELP_STRING([--enable-host-shared],
1767                 [build host code as shared libraries])],
1768 [host_shared=$enableval], [host_shared=no])
1769 AC_SUBST(host_shared)
1770
1771 # By default, C and C++ are the only stage 1 languages.
1772 stage1_languages=,c,
1773
1774 # Target libraries that we bootstrap.
1775 bootstrap_target_libs=,target-libgcc,
1776
1777 # Figure out what language subdirectories are present.
1778 # Look if the user specified --enable-languages="..."; if not, use
1779 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1780 # go away some day.
1781 # NB:  embedded tabs in this IF block -- do not untabify
1782 if test -d ${srcdir}/gcc; then
1783   if test x"${enable_languages+set}" != xset; then
1784     if test x"${LANGUAGES+set}" = xset; then
1785       enable_languages="${LANGUAGES}"
1786         echo configure.ac: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
1787     else
1788       enable_languages=default
1789     fi
1790   else
1791     if test x"${enable_languages}" = x ||
1792        test x"${enable_languages}" = xyes;
1793        then
1794       echo configure.ac: --enable-languages needs at least one language argument 1>&2
1795       exit 1
1796     fi
1797   fi
1798   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
1799
1800   # 'f95' is the old name for the 'fortran' language. We issue a warning
1801   # and make the substitution.
1802   case ,${enable_languages}, in
1803     *,f95,*)
1804       echo configure.ac: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
1805       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
1806       ;;
1807   esac
1808
1809   # If bootstrapping, C++ must be enabled.
1810   case ",$enable_languages,:$enable_bootstrap" in
1811     *,c++,*:*) ;;
1812     *:yes)
1813       if test -f ${srcdir}/gcc/cp/config-lang.in; then
1814         enable_languages="${enable_languages},c++"
1815       else
1816         AC_MSG_ERROR([bootstrapping requires c++ sources])
1817       fi
1818       ;;
1819   esac
1820
1821   # First scan to see if an enabled language requires some other language.
1822   # We assume that a given config-lang.in will list all the language
1823   # front ends it requires, even if some are required indirectly.
1824   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1825     case ${lang_frag} in
1826       ..) ;;
1827       # The odd quoting in the next line works around
1828       # an apparent bug in bash 1.12 on linux.
1829       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1830       *)
1831         # From the config-lang.in, get $language, $lang_requires, and
1832         # $lang_requires_boot_languages.
1833         language=
1834         lang_requires=
1835         lang_requires_boot_languages=
1836         # set srcdir during sourcing lang_frag to the gcc dir.
1837         # Sadly overriding srcdir on the . line doesn't work in plain sh as it
1838         # polutes this shell
1839         saved_srcdir=${srcdir}
1840         srcdir=${srcdir}/gcc . ${lang_frag}
1841         srcdir=${saved_srcdir}
1842         for other in ${lang_requires} ${lang_requires_boot_languages}; do
1843           case ,${enable_languages}, in
1844             *,$other,*) ;;
1845             *,default,*) ;;
1846             *,all,*) ;;
1847             *,$language,*)
1848               echo " \`$other' language required by \`$language'; enabling" 1>&2
1849               enable_languages="${enable_languages},${other}"
1850               ;;
1851           esac
1852         done
1853         for other in ${lang_requires_boot_languages} ; do
1854           if test "$other" != "c"; then
1855             case ,${enable_stage1_languages}, in
1856               *,$other,*) ;;
1857               *,default,*) ;;
1858               *,all,*) ;;
1859               *)
1860                 case ,${enable_languages}, in
1861                   *,$language,*)
1862                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
1863                     enable_stage1_languages="$enable_stage1_languages,${other}"
1864                     ;;
1865                 esac
1866                 ;;
1867             esac
1868           fi
1869         done
1870         ;;
1871     esac
1872   done
1873
1874   new_enable_languages=,c,
1875
1876   # If LTO is enabled, add the LTO front end.
1877   if test "$enable_lto" = "yes" ; then
1878     case ,${enable_languages}, in
1879       *,lto,*) ;;
1880       *) enable_languages="${enable_languages},lto" ;;
1881     esac
1882     if test "${build_lto_plugin}" = "yes" ; then
1883       configdirs="$configdirs lto-plugin"
1884     fi
1885   fi
1886
1887   # If we're building an offloading compiler, add the LTO front end.
1888   if test x"$enable_as_accelerator_for" != x ; then
1889     case ,${enable_languages}, in
1890       *,lto,*) ;;
1891       *) enable_languages="${enable_languages},lto" ;;
1892     esac
1893   fi
1894
1895   missing_languages=`echo ",$enable_languages," | sed -e s/,default,/,/ -e s/,all,/,/ -e s/,c,/,/ `
1896   potential_languages=,c,
1897
1898   enabled_target_libs=
1899   disabled_target_libs=
1900
1901   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1902     case ${lang_frag} in
1903       ..) ;;
1904       # The odd quoting in the next line works around
1905       # an apparent bug in bash 1.12 on linux.
1906       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1907       *)
1908         # From the config-lang.in, get $language, $target_libs,
1909         # $lang_dirs, $boot_language, and $build_by_default
1910         language=
1911         target_libs=
1912         lang_dirs=
1913         subdir_requires=
1914         boot_language=no
1915         build_by_default=yes
1916         # set srcdir during sourcing.  See above about save & restore
1917         saved_srcdir=${srcdir}
1918         srcdir=${srcdir}/gcc . ${lang_frag}
1919         srcdir=${saved_srcdir}
1920         if test x${language} = x; then
1921           echo "${lang_frag} doesn't set \$language." 1>&2
1922           exit 1
1923         fi
1924
1925         if test "$language" = "c++"; then
1926           boot_language=yes
1927         fi
1928
1929         add_this_lang=no
1930         # C is always enabled, so no need to add it again
1931         if test "$language" != "c"; then
1932           case ,${enable_languages}, in
1933             *,${language},*)
1934               # Language was explicitly selected; include it
1935               add_this_lang=yes
1936               ;;
1937             *,all,*)
1938               # All languages are enabled
1939               add_this_lang=all
1940               ;;
1941             *,default,*)
1942               # 'default' was selected, select it if it is a default language
1943               add_this_lang=${build_by_default}
1944               ;;
1945           esac
1946         fi
1947
1948         # Disable languages that need other directories if these aren't available.
1949         for i in $subdir_requires; do
1950           test -f "$srcdir/gcc/$i/config-lang.in" && continue
1951           case ${add_this_lang} in
1952             yes)
1953               # Specifically requested language; tell them.
1954               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
1955               ;;
1956             all)
1957               AC_MSG_WARN([The gcc/$i directory contains parts of $language but is missing])
1958               add_this_lang=unsupported
1959               ;;
1960             *)
1961               # Silently disable.
1962               add_this_lang=unsupported
1963               ;;
1964           esac
1965         done
1966
1967         # Disable Ada if no preexisting GNAT is available.
1968         case ${add_this_lang}:${language}:${have_gnat} in
1969           yes:ada:no)
1970             # Specifically requested language; tell them.
1971             AC_MSG_ERROR([GNAT is required to build $language])
1972             ;;
1973           all:ada:no)
1974             AC_MSG_WARN([GNAT is required to build $language])
1975             add_this_lang=unsupported
1976             ;;
1977           *:ada:no)
1978             # Silently disable.
1979             add_this_lang=unsupported
1980             ;;
1981         esac
1982
1983         # Disable jit if -enable-host-shared not specified
1984         case ${add_this_lang}:${language}:${host_shared} in
1985           yes:jit:no)
1986             # PR jit/64780: explicitly specify --enable-host-shared
1987             AC_MSG_ERROR([
1988 Enabling language "jit" requires --enable-host-shared.
1989
1990 --enable-host-shared typically slows the rest of the compiler down by
1991 a few %, so you must explicitly enable it.
1992
1993 If you want to build both the jit and the regular compiler, it is often
1994 best to do this via two separate configure/builds, in separate
1995 directories, to avoid imposing the performance cost of
1996 --enable-host-shared on the regular compiler.])
1997             ;;
1998           all:jit:no)
1999             AC_MSG_WARN([--enable-host-shared required to build $language])
2000             add_this_lang=unsupported
2001             ;;
2002           *:jit:no)
2003             # Silently disable.
2004             add_this_lang=unsupported
2005             ;;
2006         esac
2007
2008         # Disable a language that is unsupported by the target.
2009         case "${add_this_lang}: $unsupported_languages " in
2010           no:*) ;;
2011           unsupported:*) ;;
2012           *:*" $language "*)
2013             AC_MSG_WARN([${language} not supported for this target])
2014             add_this_lang=unsupported
2015             ;;
2016         esac
2017
2018         case $add_this_lang in
2019           unsupported)
2020             # Remove language-dependent dirs.
2021             disabled_target_libs="$disabled_target_libs $target_libs"
2022             noconfigdirs="$noconfigdirs $lang_dirs"
2023             ;;
2024           no)
2025             # Remove language-dependent dirs; still show language as supported.
2026             disabled_target_libs="$disabled_target_libs $target_libs"
2027             noconfigdirs="$noconfigdirs $lang_dirs"
2028             potential_languages="${potential_languages}${language},"
2029             ;;
2030           all|yes)
2031             new_enable_languages="${new_enable_languages}${language},"
2032             potential_languages="${potential_languages}${language},"
2033             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
2034             enabled_target_libs="$enabled_target_libs $target_libs"
2035             case "${boot_language}:,$enable_stage1_languages," in
2036               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
2037                 # Add to (comma-separated) list of stage 1 languages.
2038                 case ",$stage1_languages," in
2039                   *,$language,* | ,yes, | ,all,) ;;
2040                   *) stage1_languages="${stage1_languages}${language}," ;;
2041                 esac
2042                 # We need to bootstrap any supporting libraries.
2043                 bootstrap_target_libs="${bootstrap_target_libs}${target_libs},"
2044                 ;;
2045             esac
2046             ;;
2047         esac
2048         ;;
2049     esac
2050   done
2051
2052   # Add target libraries which are only needed for disabled languages
2053   # to noconfigdirs.
2054   if test -n "$disabled_target_libs"; then
2055     for dir in $disabled_target_libs; do
2056       case " $enabled_target_libs " in
2057       *" ${dir} "*) ;;
2058       *) noconfigdirs="$noconfigdirs $dir" ;;
2059       esac
2060     done
2061   fi
2062
2063   AC_ARG_ENABLE(stage1-languages,
2064   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
2065                   [choose additional languages to build during
2066                   stage1.  Mostly useful for compiler development])],
2067   [case ,${enable_stage1_languages}, in
2068     ,no,|,,)
2069       # Set it to something that will have no effect in the loop below
2070       enable_stage1_languages=c ;;
2071     ,yes,)
2072       enable_stage1_languages=`echo $new_enable_languages | \
2073         sed -e "s/^,//" -e "s/,$//" ` ;;
2074     *,all,*)
2075       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
2076         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
2077   esac
2078
2079   # Add "good" languages from enable_stage1_languages to stage1_languages,
2080   # while "bad" languages go in missing_languages.  Leave no duplicates.
2081   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
2082     case $potential_languages in
2083       *,$i,*)
2084         case $stage1_languages in
2085           *,$i,*) ;;
2086           *) stage1_languages="$stage1_languages$i," ;;
2087         esac ;;
2088       *)
2089         case $missing_languages in
2090           *,$i,*) ;;
2091           *) missing_languages="$missing_languages$i," ;;
2092         esac ;;
2093      esac
2094   done])
2095
2096   # Remove leading/trailing commas that were added for simplicity
2097   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
2098   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
2099   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
2100   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
2101
2102   if test "x$missing_languages" != x; then
2103     AC_MSG_ERROR([
2104 The following requested languages could not be built: ${missing_languages}
2105 Supported languages are: ${potential_languages}])
2106   fi
2107   if test "x$new_enable_languages" != "x$enable_languages"; then
2108     echo The following languages will be built: ${new_enable_languages}
2109     enable_languages="$new_enable_languages"
2110   fi
2111
2112   AC_SUBST(stage1_languages)
2113   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
2114 fi
2115
2116 # Handle --disable-<component> generically.
2117 for dir in $configdirs $build_configdirs $target_configdirs ; do
2118   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
2119   varname=`echo $dirname | sed -e s/+/_/g`
2120   if eval test x\${enable_${varname}} "=" xno ; then
2121     noconfigdirs="$noconfigdirs $dir"
2122   fi
2123 done
2124
2125 # Check for Boehm's garbage collector
2126 AC_ARG_ENABLE(objc-gc,
2127 [AS_HELP_STRING([--enable-objc-gc],
2128                 [enable use of Boehm's garbage collector with the
2129                  GNU Objective-C runtime])])
2130 AC_ARG_WITH([target-bdw-gc],
2131 [AS_HELP_STRING([--with-target-bdw-gc=PATHLIST],
2132                 [specify prefix directory for installed bdw-gc package.
2133                  Equivalent to --with-target-bdw-gc-include=PATH/include
2134                  plus --with-target-bdw-gc-lib=PATH/lib])])
2135 AC_ARG_WITH([target-bdw-gc-include],
2136 [AS_HELP_STRING([--with-target-bdw-gc-include=PATHLIST],
2137                 [specify directories for installed bdw-gc include files])])
2138 AC_ARG_WITH([target-bdw-gc-lib],
2139 [AS_HELP_STRING([--with-target-bdw-gc-lib=PATHLIST],
2140                 [specify directories for installed bdw-gc library])])
2141
2142 case ,${enable_languages},:${enable_objc_gc} in *,objc,*:yes|*,objc,*:auto)
2143   AC_MSG_CHECKING([for bdw garbage collector])
2144   if test "x$with_target_bdw_gc$with_target_bdw_gc_include$with_target_bdw_gc_lib" = x; then
2145     dnl no bdw-gw options, assume default locations
2146     AC_MSG_RESULT([using bdw-gc in default locations])
2147   else
2148     dnl bdw-gw options, first error checking, complete checking in libobjc
2149     if test "x$with_target_bdw_gc_include" = x && test "x$with_target_bdw_gc_lib" != x; then
2150       AC_MSG_ERROR([found --with-target-bdw-gc-lib but --with-target-bdw-gc-include missing])
2151     elif test "x$with_target_bdw_gc_include" != x && test "x$with_target_bdw_gc_lib" = x; then
2152       AC_MSG_ERROR([found --with-target-bdw-gc-include but --with-target-bdw-gc-lib missing])
2153     else
2154       AC_MSG_RESULT([using paths configured with --with-target-bdw-gc options])
2155     fi
2156   fi
2157 esac
2158
2159 # Disable libcilkrts, libitm, libsanitizer, libvtv, liboffloadmic if we're not building C++
2160 case ,${enable_languages}, in
2161   *,c++,*)
2162     # Disable libcilkrts, libitm, libsanitizer if we're not building libstdc++
2163     case "${noconfigdirs}" in
2164       *target-libstdc++-v3*)
2165         noconfigdirs="$noconfigdirs target-libcilkrts target-libitm target-libsanitizer"
2166         ;;
2167       *) ;;
2168     esac
2169     ;;
2170   *)
2171     noconfigdirs="$noconfigdirs target-libcilkrts target-liboffloadmic target-libitm target-libsanitizer target-libvtv"
2172     ;;
2173 esac
2174
2175 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
2176 # $build_configdirs and $target_configdirs.
2177 # If we have the source for $noconfigdirs entries, add them to $notsupp.
2178
2179 notsupp=""
2180 for dir in . $skipdirs $noconfigdirs ; do
2181   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
2182   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2183     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
2184     if test -r $srcdir/$dirname/configure ; then
2185       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2186         true
2187       else
2188         notsupp="$notsupp $dir"
2189       fi
2190     fi
2191   fi
2192   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2193     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
2194     if test -r $srcdir/$dirname/configure ; then
2195       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2196         true
2197       else
2198         notsupp="$notsupp $dir"
2199       fi
2200     fi
2201   fi
2202   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2203     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
2204     if test -r $srcdir/$dirname/configure ; then
2205       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2206         true
2207       else
2208         notsupp="$notsupp $dir"
2209       fi
2210     fi
2211   fi
2212 done
2213
2214 # Quietly strip out all directories which aren't configurable in this tree.
2215 # This relies on all configurable subdirectories being autoconfiscated, which
2216 # is now the case.
2217 build_configdirs_all="$build_configdirs"
2218 build_configdirs=
2219 for i in ${build_configdirs_all} ; do
2220   j=`echo $i | sed -e s/build-//g`
2221   if test -f ${srcdir}/$j/configure ; then
2222     build_configdirs="${build_configdirs} $i"
2223   fi
2224 done
2225
2226 configdirs_all="$configdirs"
2227 configdirs=
2228 for i in ${configdirs_all} ; do
2229   if test -f ${srcdir}/$i/configure ; then
2230     configdirs="${configdirs} $i"
2231   fi
2232 done
2233
2234 target_configdirs_all="$target_configdirs"
2235 target_configdirs=
2236 for i in ${target_configdirs_all} ; do
2237   j=`echo $i | sed -e s/target-//g`
2238   if test -f ${srcdir}/$j/configure ; then
2239     target_configdirs="${target_configdirs} $i"
2240   fi
2241 done
2242
2243 # libiberty-linker-plugin is special: it doesn't have its own source directory,
2244 # so we have to add it after the preceding checks.
2245 if test x"$extra_linker_plugin_flags$extra_linker_plugin_configure_flags" != x
2246 then
2247   case " $configdirs " in
2248     *" libiberty "*)
2249       # If we can build libiberty, we can also build libiberty-linker-plugin.
2250       configdirs="$configdirs libiberty-linker-plugin"
2251       extra_linker_plugin_configure_flags="$extra_linker_plugin_configure_flags \
2252         --with-libiberty=../libiberty-linker-plugin";;
2253     *)
2254       AC_MSG_ERROR([libiberty missing]);;
2255   esac
2256 fi
2257
2258 # Sometimes we have special requirements for the host libiberty.
2259 extra_host_libiberty_configure_flags=
2260 extra_host_zlib_configure_flags=
2261 case " $configdirs " in
2262   *" lto-plugin "* | *" libcc1 "*)
2263     # When these are to be built as shared libraries, the same applies to
2264     # libiberty.
2265     extra_host_libiberty_configure_flags=--enable-shared
2266     ;;
2267   *" bfd "*)
2268     # When bfd is to be built as a shared library, the same applies to
2269     # zlib.
2270     if test "$enable_shared" = "yes"; then
2271       extra_host_zlib_configure_flags=--enable-host-shared
2272     fi
2273     ;;
2274 esac
2275 AC_SUBST(extra_host_libiberty_configure_flags)
2276 AC_SUBST(extra_host_zlib_configure_flags)
2277
2278 # Produce a warning message for the subdirs we can't configure.
2279 # This isn't especially interesting in the Cygnus tree, but in the individual
2280 # FSF releases, it's important to let people know when their machine isn't
2281 # supported by the one or two programs in a package.
2282
2283 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2284   # If $appdirs is non-empty, at least one of those directories must still
2285   # be configured, or we error out.  (E.g., if the gas release supports a
2286   # specified target in some subdirs but not the gas subdir, we shouldn't
2287   # pretend that all is well.)
2288   if test -n "$appdirs" ; then
2289     for dir in $appdirs ; do
2290       if test -r $dir/Makefile.in ; then
2291         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2292           appdirs=""
2293           break
2294         fi
2295         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2296           appdirs=""
2297           break
2298         fi
2299       fi
2300     done
2301     if test -n "$appdirs" ; then
2302       echo "*** This configuration is not supported by this package." 1>&2
2303       exit 1
2304     fi
2305   fi
2306   # Okay, some application will build, or we don't care to check.  Still
2307   # notify of subdirs not getting built.
2308   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2309   echo "    ${notsupp}" 1>&2
2310   echo "    (Any other directories should still work fine.)" 1>&2
2311 fi
2312
2313 case "$host" in
2314   *msdosdjgpp*)
2315     enable_gdbtk=no ;;
2316 esac
2317
2318 # To find our prefix, in gcc_cv_tool_prefix.
2319 ACX_TOOL_DIRS
2320
2321 copy_dirs=
2322
2323 AC_ARG_WITH([build-sysroot],
2324   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2325                   [use sysroot as the system root during the build])],
2326   [if test x"$withval" != x ; then
2327      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2328    fi],
2329   [SYSROOT_CFLAGS_FOR_TARGET=])
2330 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2331
2332 AC_ARG_WITH([debug-prefix-map],
2333   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2334                   [map A to B, C to D ... in debug information])],
2335   [if test x"$withval" != x; then
2336      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2337      for debug_map in $withval; do
2338        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2339      done
2340    fi],
2341   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2342 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2343
2344 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2345 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2346 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2347 # We want to ensure that TARGET libraries (which we know are built with
2348 # gcc) are built with "-O2 -g", so include those options when setting
2349 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2350 if test "x$CFLAGS_FOR_TARGET" = x; then
2351   if test "x${is_cross_compiler}" = xyes; then
2352     CFLAGS_FOR_TARGET="-g -O2"
2353   else
2354     CFLAGS_FOR_TARGET=$CFLAGS
2355     case " $CFLAGS " in
2356       *" -O2 "*) ;;
2357       *) CFLAGS_FOR_TARGET="-O2 $CFLAGS_FOR_TARGET" ;;
2358     esac
2359     case " $CFLAGS " in
2360       *" -g "* | *" -g3 "*) ;;
2361       *) CFLAGS_FOR_TARGET="-g $CFLAGS_FOR_TARGET" ;;
2362     esac
2363   fi
2364 fi
2365 AC_SUBST(CFLAGS_FOR_TARGET)
2366
2367 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2368   if test "x${is_cross_compiler}" = xyes; then
2369     CXXFLAGS_FOR_TARGET="-g -O2"
2370   else
2371     CXXFLAGS_FOR_TARGET=$CXXFLAGS
2372     case " $CXXFLAGS " in
2373       *" -O2 "*) ;;
2374       *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS_FOR_TARGET" ;;
2375     esac
2376     case " $CXXFLAGS " in
2377       *" -g "* | *" -g3 "*) ;;
2378       *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS_FOR_TARGET" ;;
2379     esac
2380   fi
2381 fi
2382 AC_SUBST(CXXFLAGS_FOR_TARGET)
2383
2384 AC_SUBST(LDFLAGS_FOR_TARGET)
2385
2386 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2387 # the named directory are copied to $(tooldir)/sys-include.
2388 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2389   if test x${is_cross_compiler} = xno ; then
2390     echo 1>&2 '***' --with-headers is only supported when cross compiling
2391     exit 1
2392   fi
2393   if test x"${with_headers}" != xyes ; then
2394     x=${gcc_cv_tool_prefix}
2395     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2396   fi
2397 fi
2398
2399 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2400 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2401 # are permitted.
2402 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2403   if test x${is_cross_compiler} = xno ; then
2404     echo 1>&2 '***' --with-libs is only supported when cross compiling
2405     exit 1
2406   fi
2407   if test x"${with_libs}" != xyes ; then
2408     # Copy the libraries in reverse order, so that files in the first named
2409     # library override files in subsequent libraries.
2410     x=${gcc_cv_tool_prefix}
2411     for l in ${with_libs}; do
2412       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2413     done
2414   fi
2415 fi
2416
2417 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2418 #
2419 # This is done by determining whether or not the appropriate directory
2420 # is available, and by checking whether or not specific configurations
2421 # have requested that this magic not happen.
2422 #
2423 # The command line options always override the explicit settings in
2424 # configure.ac, and the settings in configure.ac override this magic.
2425 #
2426 # If the default for a toolchain is to use GNU as and ld, and you don't
2427 # want to do that, then you should use the --without-gnu-as and
2428 # --without-gnu-ld options for the configure script.  Similarly, if
2429 # the default is to use the included zlib and you don't want to do that,
2430 # you should use the --with-system-zlib option for the configure script.
2431
2432 if test x${use_gnu_as} = x &&
2433    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2434   with_gnu_as=yes
2435   extra_host_args="$extra_host_args --with-gnu-as"
2436 fi
2437
2438 if test x${use_gnu_ld} = x &&
2439    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2440   with_gnu_ld=yes
2441   extra_host_args="$extra_host_args --with-gnu-ld"
2442 fi
2443
2444 if test x${use_included_zlib} = x &&
2445    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2446   :
2447 else
2448   with_system_zlib=yes
2449   extra_host_args="$extra_host_args --with-system-zlib"
2450 fi
2451
2452 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2453 # can detect this case.
2454
2455 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2456   with_newlib=yes
2457   extra_host_args="$extra_host_args --with-newlib"
2458 fi
2459
2460 # Handle ${copy_dirs}
2461 set fnord ${copy_dirs}
2462 shift
2463 while test $# != 0 ; do
2464   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2465     :
2466   else
2467     echo Copying $1 to $2
2468
2469     # Use the install script to create the directory and all required
2470     # parent directories.
2471     if test -d $2 ; then
2472       :
2473     else
2474       echo >config.temp
2475       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2476     fi
2477
2478     # Copy the directory, assuming we have tar.
2479     # FIXME: Should we use B in the second tar?  Not all systems support it.
2480     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2481
2482     # It is the responsibility of the user to correctly adjust all
2483     # symlinks.  If somebody can figure out how to handle them correctly
2484     # here, feel free to add the code.
2485
2486     echo $1 > $2/COPIED
2487   fi
2488   shift; shift
2489 done
2490
2491 # Determine a target-dependent exec_prefix that the installed
2492 # gcc will search in.  Keep this list sorted by triplet, with
2493 # the *-*-osname triplets last.
2494 md_exec_prefix=
2495 case "${target}" in
2496   i[[34567]]86-pc-msdosdjgpp*)
2497     md_exec_prefix=/dev/env/DJDIR/bin
2498     ;;
2499   *-*-hpux* | \
2500   *-*-nto-qnx* | \
2501   *-*-solaris2*)
2502     md_exec_prefix=/usr/ccs/bin
2503     ;;
2504 esac
2505
2506 extra_arflags_for_target=
2507 extra_nmflags_for_target=
2508 extra_ranlibflags_for_target=
2509 target_makefile_frag=/dev/null
2510 case "${target}" in
2511   spu-*-*)
2512     target_makefile_frag="config/mt-spu"
2513     ;;
2514   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
2515     target_makefile_frag="config/mt-sde"
2516     ;;
2517   mipsisa*-*-elfoabi*)
2518     target_makefile_frag="config/mt-mips-elfoabi"
2519     ;;
2520   mips*-*-*linux* | mips*-*-gnu*)
2521     target_makefile_frag="config/mt-mips-gnu"
2522     ;;
2523   nios2-*-elf*)
2524     target_makefile_frag="config/mt-nios2-elf"
2525     ;;
2526   *-*-linux-android*)
2527     target_makefile_frag="config/mt-android"
2528     ;;
2529   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2530     target_makefile_frag="config/mt-gnu"
2531     ;;
2532   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2533     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2534     # commands to handle both 32-bit and 64-bit objects.  These flags are
2535     # harmless if we're using GNU nm or ar.
2536     extra_arflags_for_target=" -X32_64"
2537     extra_nmflags_for_target=" -B -X32_64"
2538     ;;
2539 esac
2540
2541 alphaieee_frag=/dev/null
2542 case $target in
2543   alpha*-*-*)
2544     # This just makes sure to use the -mieee option to build target libs.
2545     # This should probably be set individually by each library.
2546     alphaieee_frag="config/mt-alphaieee"
2547     ;;
2548 esac
2549
2550 # If --enable-target-optspace always use -Os instead of -O2 to build
2551 # the target libraries, similarly if it is not specified, use -Os
2552 # on selected platforms.
2553 ospace_frag=/dev/null
2554 case "${enable_target_optspace}:${target}" in
2555   yes:*)
2556     ospace_frag="config/mt-ospace"
2557     ;;
2558   :d30v-*)
2559     ospace_frag="config/mt-d30v"
2560     ;;
2561   :m32r-* | :d10v-* | :fr30-* | :i?86*-*-elfiamcu)
2562     ospace_frag="config/mt-ospace"
2563     ;;
2564   no:* | :*)
2565     ;;
2566   *)
2567     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2568     ;;
2569 esac
2570
2571 # Some systems (e.g., one of the i386-aix systems the gas testers are
2572 # using) don't handle "\$" correctly, so don't use it here.
2573 tooldir='${exec_prefix}'/${target_noncanonical}
2574 build_tooldir=${tooldir}
2575
2576 # Create a .gdbinit file which runs the one in srcdir
2577 # and tells GDB to look there for source files.
2578
2579 if test -r ${srcdir}/.gdbinit ; then
2580   case ${srcdir} in
2581     .) ;;
2582     *) cat > ./.gdbinit <<EOF
2583 # ${NO_EDIT}
2584 dir ${srcdir}
2585 dir .
2586 source ${srcdir}/.gdbinit
2587 EOF
2588     ;;
2589   esac
2590 fi
2591
2592 # Make sure that the compiler is able to generate an executable.  If it
2593 # can't, we are probably in trouble.  We don't care whether we can run the
2594 # executable--we might be using a cross compiler--we only care whether it
2595 # can be created.  At this point the main configure script has set CC.
2596 we_are_ok=no
2597 echo "int main () { return 0; }" > conftest.c
2598 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2599 if test $? = 0 ; then
2600   if test -s conftest || test -s conftest.exe ; then
2601     we_are_ok=yes
2602   fi
2603 fi
2604 case $we_are_ok in
2605   no)
2606     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2607     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2608     rm -f conftest*
2609     exit 1
2610     ;;
2611 esac
2612 rm -f conftest*
2613
2614 # Decide which environment variable is used to find dynamic libraries.
2615 case "${host}" in
2616   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2617   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2618   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2619   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2620 esac
2621
2622 # On systems where the dynamic library environment variable is PATH,
2623 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2624 # built executables to PATH.
2625 if test "$RPATH_ENVVAR" = PATH; then
2626   GCC_SHLIB_SUBDIR=/shlib
2627 else
2628   GCC_SHLIB_SUBDIR=
2629 fi
2630
2631 # Adjust the toplevel makefile according to whether bootstrap was selected.
2632 case $enable_bootstrap in
2633   yes)
2634     bootstrap_suffix=bootstrap
2635     BUILD_CONFIG=bootstrap-debug
2636     ;;
2637   no)
2638     bootstrap_suffix=no-bootstrap
2639     BUILD_CONFIG=
2640     ;;
2641 esac
2642
2643 AC_MSG_CHECKING(for default BUILD_CONFIG)
2644
2645 AC_ARG_WITH([build-config],
2646   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2647                   [use config/NAME.mk build configuration])],
2648   [case $with_build_config in
2649    yes) with_build_config= ;;
2650    no) with_build_config= BUILD_CONFIG= ;;
2651    esac])
2652
2653 if test "x${with_build_config}" != x; then
2654   BUILD_CONFIG=$with_build_config
2655 else
2656   case $BUILD_CONFIG in
2657   bootstrap-debug)
2658     if echo "int f (void) { return 0; }" > conftest.c &&
2659        ${CC} -c conftest.c &&
2660        mv conftest.o conftest.o.g0 &&
2661        ${CC} -c -g conftest.c &&
2662        mv conftest.o conftest.o.g &&
2663        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2664       :
2665     else
2666       BUILD_CONFIG=
2667     fi
2668     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2669     ;;
2670   esac
2671 fi
2672 AC_MSG_RESULT($BUILD_CONFIG)
2673 AC_SUBST(BUILD_CONFIG)
2674
2675 # Use same top-level configure hooks in libgcc/libstdc++/libvtv.
2676 AC_MSG_CHECKING([for --enable-vtable-verify])
2677 AC_ARG_ENABLE(vtable-verify,
2678 [AS_HELP_STRING([--enable-vtable-verify],
2679                 [Enable vtable verification feature])],
2680 [case "$enableval" in
2681  yes) enable_vtable_verify=yes ;;
2682  no)  enable_vtable_verify=no ;;
2683  *)   enable_vtable_verify=no;;
2684  esac],
2685 [enable_vtable_verify=no])
2686 AC_MSG_RESULT($enable_vtable_verify)
2687
2688 # Record target_configdirs and the configure arguments for target and
2689 # build configuration in Makefile.
2690 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2691 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2692 bootstrap_fixincludes=no
2693
2694 # If we are building libgomp, bootstrap it.
2695 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
2696   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
2697 fi
2698
2699 # If we are building libsanitizer and $BUILD_CONFIG contains bootstrap-asan
2700 # or bootstrap-ubsan, bootstrap it.
2701 if echo " ${target_configdirs} " | grep " libsanitizer " > /dev/null 2>&1; then
2702   case "$BUILD_CONFIG" in
2703     *bootstrap-asan* | *bootstrap-ubsan* )
2704       bootstrap_target_libs=${bootstrap_target_libs}target-libsanitizer,
2705       bootstrap_fixincludes=yes
2706       ;;
2707   esac
2708 fi
2709
2710 # If we are building libvtv and --enable-vtable-verify, bootstrap it.
2711 if echo " ${target_configdirs} " | grep " libvtv " > /dev/null 2>&1 &&
2712    test "$enable_vtable_verify" != no; then
2713   bootstrap_target_libs=${bootstrap_target_libs}target-libvtv,
2714 fi
2715
2716 # If we are building libmpx and $BUILD_CONFIG contains bootstrap-mpx,
2717 # bootstrap it.
2718 if echo " ${target_configdirs} " | grep " libmpx " > /dev/null 2>&1; then
2719   case "$BUILD_CONFIG" in
2720     *bootstrap-mpx* )
2721       bootstrap_target_libs=${bootstrap_target_libs}target-libmpx,
2722       ;;
2723   esac
2724 fi
2725
2726 # Determine whether gdb needs tk/tcl or not.
2727 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
2728 # and in that case we want gdb to be built without tk.  Ugh!
2729 # In fact I believe gdb is the *only* package directly dependent on tk,
2730 # so we should be able to put the 'maybe's in unconditionally and
2731 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
2732 # 100% sure that that's safe though.
2733
2734 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
2735 case "$enable_gdbtk" in
2736   no)
2737     GDB_TK="" ;;
2738   yes)
2739     GDB_TK="${gdb_tk}" ;;
2740   *)
2741     # Only add the dependency on gdbtk when GDBtk is part of the gdb
2742     # distro.  Eventually someone will fix this and move Insight, nee
2743     # gdbtk to a separate directory.
2744     if test -d ${srcdir}/gdb/gdbtk ; then
2745       GDB_TK="${gdb_tk}"
2746     else
2747       GDB_TK=""
2748     fi
2749     ;;
2750 esac
2751 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
2752 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
2753
2754 # Strip out unwanted targets.
2755
2756 # While at that, we remove Makefiles if we were started for recursive
2757 # configuration, so that the top-level Makefile reconfigures them,
2758 # like we used to do when configure itself was recursive.
2759
2760 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
2761 # but now we're fixing up the Makefile ourselves with the additional
2762 # commands passed to AC_CONFIG_FILES.  Use separate variables
2763 # extrasub-{build,host,target} not because there is any reason to split
2764 # the substitutions up that way, but only to remain below the limit of
2765 # 99 commands in a script, for HP-UX sed.
2766 # Do not nest @if/@endif pairs, because configure will not warn you at all.
2767
2768 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
2769   yes:yes:*\ gold\ *:*,c++,*) ;;
2770   yes:yes:*\ gold\ *:*)
2771     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
2772     ;;
2773 esac
2774
2775 extrasub_build=
2776 for module in ${build_configdirs} ; do
2777   if test -z "${no_recursion}" \
2778      && test -f ${build_subdir}/${module}/Makefile; then
2779     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
2780     rm -f ${build_subdir}/${module}/Makefile
2781   fi
2782   extrasub_build="$extrasub_build
2783 /^@if build-$module\$/d
2784 /^@endif build-$module\$/d
2785 /^@if build-$module-$bootstrap_suffix\$/d
2786 /^@endif build-$module-$bootstrap_suffix\$/d"
2787 done
2788 extrasub_host=
2789 for module in ${configdirs} ; do
2790   if test -z "${no_recursion}"; then
2791     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
2792       if test -f ${file}; then
2793         echo 1>&2 "*** removing ${file} to force reconfigure"
2794         rm -f ${file}
2795       fi
2796     done
2797   fi
2798   case ${module},${bootstrap_fixincludes} in
2799     fixincludes,no) host_bootstrap_suffix=no-bootstrap ;;
2800     *) host_bootstrap_suffix=$bootstrap_suffix ;;
2801   esac
2802   extrasub_host="$extrasub_host
2803 /^@if $module\$/d
2804 /^@endif $module\$/d
2805 /^@if $module-$host_bootstrap_suffix\$/d
2806 /^@endif $module-$host_bootstrap_suffix\$/d"
2807 done
2808 extrasub_target=
2809 for module in ${target_configdirs} ; do
2810   if test -z "${no_recursion}" \
2811      && test -f ${target_subdir}/${module}/Makefile; then
2812     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
2813     rm -f ${target_subdir}/${module}/Makefile
2814   fi
2815
2816   # We only bootstrap target libraries listed in bootstrap_target_libs.
2817   case $bootstrap_target_libs in
2818     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
2819     *) target_bootstrap_suffix=no-bootstrap ;;
2820   esac
2821
2822   extrasub_target="$extrasub_target
2823 /^@if target-$module\$/d
2824 /^@endif target-$module\$/d
2825 /^@if target-$module-$target_bootstrap_suffix\$/d
2826 /^@endif target-$module-$target_bootstrap_suffix\$/d"
2827 done
2828
2829 # Do the final fixup along with target modules.
2830 extrasub_target="$extrasub_target
2831 /^@if /,/^@endif /d"
2832
2833 # Create the serialization dependencies.  This uses a temporary file.
2834
2835 AC_ARG_ENABLE([serial-configure],
2836 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
2837                 [force sequential configuration of
2838                  sub-packages for the host, target or build
2839                  machine, or all sub-packages])])
2840
2841 case ${enable_serial_configure} in
2842   yes)
2843     enable_serial_build_configure=yes
2844     enable_serial_host_configure=yes
2845     enable_serial_target_configure=yes
2846     ;;
2847 esac
2848
2849 # These force 'configure's to be done one at a time, to avoid problems
2850 # with contention over a shared config.cache.
2851 rm -f serdep.tmp
2852 echo '# serdep.tmp' > serdep.tmp
2853 olditem=
2854 test "x${enable_serial_build_configure}" = xyes &&
2855 for item in ${build_configdirs} ; do
2856   case ${olditem} in
2857     "") ;;
2858     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
2859   esac
2860   olditem=${item}
2861 done
2862 olditem=
2863 test "x${enable_serial_host_configure}" = xyes &&
2864 for item in ${configdirs} ; do
2865   case ${olditem} in
2866     "") ;;
2867     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
2868   esac
2869   olditem=${item}
2870 done
2871 olditem=
2872 test "x${enable_serial_target_configure}" = xyes &&
2873 for item in ${target_configdirs} ; do
2874   case ${olditem} in
2875     "") ;;
2876     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
2877   esac
2878   olditem=${item}
2879 done
2880 serialization_dependencies=serdep.tmp
2881 AC_SUBST_FILE(serialization_dependencies)
2882
2883 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
2884 # target, nonopt, and variable assignments.  These are the ones we
2885 # might not want to pass down to subconfigures.  The exception being
2886 # --cache-file=/dev/null, which is used to turn off the use of cache
2887 # files altogether, and which should be passed on to subconfigures.
2888 # Also strip program-prefix, program-suffix, and program-transform-name,
2889 # so that we can pass down a consistent program-transform-name.
2890 baseargs=
2891 tbaseargs=
2892 keep_next=no
2893 skip_next=no
2894 eval "set -- $ac_configure_args"
2895 for ac_arg
2896 do
2897   if test X"$skip_next" = X"yes"; then
2898     skip_next=no
2899     continue
2900   fi
2901   if test X"$keep_next" = X"yes"; then
2902     case $ac_arg in
2903       *\'*)
2904         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2905     esac
2906     baseargs="$baseargs '$ac_arg'"
2907     tbaseargs="$tbaseargs '$ac_arg'"
2908     keep_next=no
2909     continue
2910   fi
2911
2912   # Handle separated arguments.  Based on the logic generated by
2913   # autoconf 2.59.
2914   case $ac_arg in
2915     *=* | --config-cache | -C | -disable-* | --disable-* \
2916       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
2917       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
2918       | -with-* | --with-* | -without-* | --without-* | --x)
2919       separate_arg=no
2920       ;;
2921     -*)
2922       separate_arg=yes
2923       ;;
2924     *)
2925       separate_arg=no
2926       ;;
2927   esac
2928
2929   skip_targ=no
2930   case $ac_arg in
2931 changequote(,)
2932   --with-* | --without-*)
2933     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
2934
2935     case $libopt in
2936     *[-_]include)
2937       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
2938       ;;
2939     *[-_]lib)
2940       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
2941       ;;
2942     *)
2943       lib=$libopt
2944       ;;
2945     esac
2946 changequote([,])
2947
2948     case $lib in
2949     mpc | mpfr | gmp | isl)
2950       # If we're processing --with-$lib, --with-$lib-include or
2951       # --with-$lib-lib, for one of the libs above, and target is
2952       # different from host, don't pass the current argument to any
2953       # target library's configure.
2954       if test x$is_cross_compiler = xyes; then
2955         skip_targ=yes
2956       fi
2957       ;;
2958     esac
2959     ;;
2960   esac
2961
2962   case "$ac_arg" in
2963     --cache-file=/dev/null | \
2964     -cache-file=/dev/null )
2965       # Handled here to avoid the test to skip args below.
2966       baseargs="$baseargs '$ac_arg'"
2967       tbaseargs="$tbaseargs '$ac_arg'"
2968       # Assert: $separate_arg should always be no.
2969       keep_next=$separate_arg
2970       ;;
2971     --no*)
2972       continue
2973       ;;
2974     --c* | \
2975     --sr* | \
2976     --ho* | \
2977     --bu* | \
2978     --t* | \
2979     --program-* | \
2980     -cache_file* | \
2981     -srcdir* | \
2982     -host* | \
2983     -build* | \
2984     -target* | \
2985     -program-prefix* | \
2986     -program-suffix* | \
2987     -program-transform-name* )
2988       skip_next=$separate_arg
2989       continue
2990       ;;
2991     -*)
2992       # An option.  Add it.
2993       case $ac_arg in
2994         *\'*)
2995           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2996       esac
2997       baseargs="$baseargs '$ac_arg'"
2998       if test X"$skip_targ" = Xno; then
2999         tbaseargs="$tbaseargs '$ac_arg'"
3000       fi
3001       keep_next=$separate_arg
3002       ;;
3003     *)
3004       # Either a variable assignment, or a nonopt (triplet).  Don't
3005       # pass it down; let the Makefile handle this.
3006       continue
3007       ;;
3008   esac
3009 done
3010 # Remove the initial space we just introduced and, as these will be
3011 # expanded by make, quote '$'.
3012 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
3013
3014 # Add in --program-transform-name, after --program-prefix and
3015 # --program-suffix have been applied to it.  Autoconf has already
3016 # doubled dollar signs and backslashes in program_transform_name; we want
3017 # the backslashes un-doubled, and then the entire thing wrapped in single
3018 # quotes, because this will be expanded first by make and then by the shell.
3019 # Also, because we want to override the logic in subdir configure scripts to
3020 # choose program_transform_name, replace any s,x,x, with s,y,y,.
3021 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
3022 ${program_transform_name}
3023 EOF_SED
3024 gcc_transform_name=`cat conftestsed.out`
3025 rm -f conftestsed.out
3026 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
3027 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
3028 if test "$silent" = yes; then
3029   baseargs="$baseargs --silent"
3030   tbaseargs="$tbaseargs --silent"
3031 fi
3032 baseargs="$baseargs --disable-option-checking"
3033 tbaseargs="$tbaseargs --disable-option-checking"
3034
3035 # Record and document user additions to sub configure arguments.
3036 AC_ARG_VAR([build_configargs],
3037            [additional configure arguments for build directories])
3038 AC_ARG_VAR([host_configargs],
3039            [additional configure arguments for host directories])
3040 AC_ARG_VAR([target_configargs],
3041            [additional configure arguments for target directories])
3042
3043 # For the build-side libraries, we just need to pretend we're native,
3044 # and not use the same cache file.  Multilibs are neither needed nor
3045 # desired.  We can't even use the same cache file for all build-side
3046 # libraries, as they're compiled differently; some with C, some with
3047 # C++ or with different feature-enabling options.
3048 build_configargs="$build_configargs --cache-file=./config.cache ${baseargs}"
3049
3050 # For host modules, accept cache file option, or specification as blank.
3051 case "${cache_file}" in
3052 "") # empty
3053   cache_file_option="" ;;
3054 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
3055   cache_file_option="--cache-file=${cache_file}" ;;
3056 *) # relative path
3057   cache_file_option="--cache-file=../${cache_file}" ;;
3058 esac
3059
3060 # Host dirs don't like to share a cache file either, horribly enough.
3061 # This seems to be due to autoconf 2.5x stupidity.
3062 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
3063
3064 target_configargs="$target_configargs ${tbaseargs}"
3065
3066 # Passing a --with-cross-host argument lets the target libraries know
3067 # whether they are being built with a cross-compiler or being built
3068 # native.  However, it would be better to use other mechanisms to make the
3069 # sorts of decisions they want to make on this basis.  Please consider
3070 # this option to be deprecated.  FIXME.
3071 if test x${is_cross_compiler} = xyes ; then
3072   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
3073 fi
3074
3075 # Special user-friendly check for native x86_64-linux build, if
3076 # multilib is not explicitly enabled.
3077 case "$target:$have_compiler:$host:$target:$enable_multilib" in
3078   x86_64-*linux*:yes:$build:$build:)
3079     # Make sure we have a development environment that handles 32-bit
3080     dev64=no
3081     echo "int main () { return 0; }" > conftest.c
3082     ${CC} -m32 -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
3083     if test $? = 0 ; then
3084       if test -s conftest || test -s conftest.exe ; then
3085         dev64=yes
3086       fi
3087     fi
3088     rm -f conftest*
3089     if test x${dev64} != xyes ; then
3090       AC_MSG_ERROR([I suspect your system does not have 32-bit development libraries (libc and headers). If you have them, rerun configure with --enable-multilib. If you do not have them, and want to build a 64-bit-only compiler, rerun configure with --disable-multilib.])
3091     fi
3092     ;;
3093 esac
3094
3095 # Default to --enable-multilib.
3096 if test x${enable_multilib} = x ; then
3097   target_configargs="--enable-multilib ${target_configargs}"
3098 fi
3099
3100 # Pass --with-newlib if appropriate.  Note that target_configdirs has
3101 # changed from the earlier setting of with_newlib.
3102 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
3103   target_configargs="--with-newlib ${target_configargs}"
3104 fi
3105
3106 # Different target subdirs use different values of certain variables
3107 # (notably CXX).  Worse, multilibs use *lots* of different values.
3108 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
3109 # it doesn't automatically accept command-line overrides of them.
3110 # This means it's not safe for target subdirs to share a cache file,
3111 # which is disgusting, but there you have it.  Hopefully this can be
3112 # fixed in future.  It's still worthwhile to use a cache file for each
3113 # directory.  I think.
3114
3115 # Pass the appropriate --build, --host, --target and --cache-file arguments.
3116 # We need to pass --target, as newer autoconf's requires consistency
3117 # for target_alias and gcc doesn't manage it consistently.
3118 target_configargs="--cache-file=./config.cache ${target_configargs}"
3119
3120 FLAGS_FOR_TARGET=
3121 case " $target_configdirs " in
3122  *" newlib "*)
3123   case " $target_configargs " in
3124   *" --with-newlib "*)
3125    case "$target" in
3126     *-cygwin*)
3127       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -isystem $$s/winsup/cygwin/include'
3128       ;;
3129    esac
3130
3131    # If we're not building GCC, don't discard standard headers.
3132    if test -d ${srcdir}/gcc; then
3133      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
3134
3135      if test "${build}" != "${host}"; then
3136        # On Canadian crosses, CC_FOR_TARGET will have already been set
3137        # by `configure', so we won't have an opportunity to add -Bgcc/
3138        # to it.  This is right: we don't want to search that directory
3139        # for binaries, but we want the header files in there, so add
3140        # them explicitly.
3141        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
3142
3143        # Someone might think of using the pre-installed headers on
3144        # Canadian crosses, in case the installed compiler is not fully
3145        # compatible with the compiler being built.  In this case, it
3146        # would be better to flag an error than risking having
3147        # incompatible object files being constructed.  We can't
3148        # guarantee that an error will be flagged, but let's hope the
3149        # compiler will do it, when presented with incompatible header
3150        # files.
3151      fi
3152    fi
3153
3154    case "${target}-${is_cross_compiler}" in
3155    i[[3456789]]86-*-linux*-no)
3156       # Here host == target, so we don't need to build gcc,
3157       # so we don't want to discard standard headers.
3158       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
3159       ;;
3160    *)
3161       # If we're building newlib, use its generic headers last, but search
3162       # for any libc-related directories first (so make it the last -B
3163       # switch).
3164       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
3165
3166       # If we're building libgloss, find the startup file, simulator library
3167       # and linker script.
3168       case " $target_configdirs " in
3169         *" libgloss "*)
3170         # Look for startup file, simulator library and maybe linker script.
3171         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
3172         # Look for libnosys.a in case the target needs it.
3173         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
3174         # Most targets have the linker script in the source directory.
3175         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
3176         ;;
3177       esac
3178       ;;
3179    esac
3180    ;;
3181   esac
3182   ;;
3183 esac
3184
3185 case "$target" in
3186   x86_64-*mingw* | *-w64-mingw*)
3187   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
3188   # however, use a symlink named 'mingw' in ${prefix} .
3189     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
3190     ;;
3191   *-mingw*)
3192   # MinGW can't be handled as Cygwin above since it does not use newlib.
3193     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
3194     ;;
3195 esac
3196
3197 # Allow the user to override the flags for
3198 # our build compiler if desired.
3199 if test x"${build}" = x"${host}" ; then
3200   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
3201   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
3202   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
3203 fi
3204
3205 # On Canadian crosses, we'll be searching the right directories for
3206 # the previously-installed cross compiler, so don't bother to add
3207 # flags for directories within the install tree of the compiler
3208 # being built; programs in there won't even run.
3209 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
3210   # Search for pre-installed headers if nothing else fits.
3211   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
3212 fi
3213
3214 if test "x${use_gnu_ld}" = x &&
3215    echo " ${configdirs} " | grep " ld " > /dev/null ; then
3216   # Arrange for us to find uninstalled linker scripts.
3217   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
3218 fi
3219
3220 # Search for other target-specific linker scripts and such.
3221 case "${target}" in
3222   mep*)
3223     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
3224     ;;
3225 esac
3226
3227 # Makefile fragments.
3228 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
3229 do
3230   eval fragval=\$$frag
3231   if test $fragval != /dev/null; then
3232     eval $frag=${srcdir}/$fragval
3233   fi
3234 done
3235 AC_SUBST_FILE(host_makefile_frag)
3236 AC_SUBST_FILE(target_makefile_frag)
3237 AC_SUBST_FILE(alphaieee_frag)
3238 AC_SUBST_FILE(ospace_frag)
3239
3240 # Miscellanea: directories, flags, etc.
3241 AC_SUBST(RPATH_ENVVAR)
3242 AC_SUBST(GCC_SHLIB_SUBDIR)
3243 AC_SUBST(tooldir)
3244 AC_SUBST(build_tooldir)
3245 AC_SUBST(CONFIGURE_GDB_TK)
3246 AC_SUBST(GDB_TK)
3247 AC_SUBST(INSTALL_GDB_TK)
3248
3249 # Build module lists & subconfigure args.
3250 AC_SUBST(build_configargs)
3251 AC_SUBST(build_configdirs)
3252
3253 # Host module lists & subconfigure args.
3254 AC_SUBST(host_configargs)
3255 AC_SUBST(configdirs)
3256 AC_SUBST(target_configdirs)
3257
3258 # Target module lists & subconfigure args.
3259 AC_SUBST(target_configargs)
3260
3261
3262 # Build tools.
3263 AC_SUBST(AR_FOR_BUILD)
3264 AC_SUBST(AS_FOR_BUILD)
3265 AC_SUBST(CC_FOR_BUILD)
3266 AC_SUBST(CFLAGS_FOR_BUILD)
3267 AC_SUBST(CXXFLAGS_FOR_BUILD)
3268 AC_SUBST(CXX_FOR_BUILD)
3269 AC_SUBST(DLLTOOL_FOR_BUILD)
3270 AC_SUBST(GFORTRAN_FOR_BUILD)
3271 AC_SUBST(GOC_FOR_BUILD)
3272 AC_SUBST(LDFLAGS_FOR_BUILD)
3273 AC_SUBST(LD_FOR_BUILD)
3274 AC_SUBST(NM_FOR_BUILD)
3275 AC_SUBST(RANLIB_FOR_BUILD)
3276 AC_SUBST(WINDMC_FOR_BUILD)
3277 AC_SUBST(WINDRES_FOR_BUILD)
3278
3279 # Generate default definitions for YACC, M4, LEX and other programs that run
3280 # on the build machine.  These are used if the Makefile can't locate these
3281 # programs in objdir.
3282 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
3283
3284 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
3285 case " $build_configdirs " in
3286   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
3287 esac
3288
3289 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
3290 case " $build_configdirs " in
3291   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
3292 esac
3293
3294 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
3295 case " $build_configdirs " in
3296   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
3297 esac
3298
3299 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3300 case " $build_configdirs " in
3301   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3302   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3303 esac
3304
3305 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3306 case " $build_configdirs " in
3307   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3308 esac
3309
3310 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3311 case " $build_configdirs " in
3312   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3313   *)
3314 changequote(,)
3315     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3316     # higher, else we use the "missing" dummy.
3317     if ${MAKEINFO} --version \
3318        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3319       :
3320     else
3321       MAKEINFO="$MISSING makeinfo"
3322     fi
3323     ;;
3324 changequote([,])
3325 esac
3326
3327 # FIXME: expect and dejagnu may become build tools?
3328
3329 AC_CHECK_PROGS(EXPECT, expect, expect)
3330 case " $configdirs " in
3331   *" expect "*)
3332     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3333     ;;
3334 esac
3335
3336 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3337 case " $configdirs " in
3338   *" dejagnu "*)
3339     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3340     ;;
3341 esac
3342
3343
3344 # Host tools.
3345 NCN_STRICT_CHECK_TOOLS(AR, ar)
3346 NCN_STRICT_CHECK_TOOLS(AS, as)
3347 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3348 NCN_STRICT_CHECK_TOOLS(LD, ld)
3349 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3350 NCN_STRICT_CHECK_TOOLS(NM, nm)
3351 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3352 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3353 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3354 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3355 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3356 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3357 NCN_STRICT_CHECK_TOOLS(READELF, readelf)
3358 AC_SUBST(CC)
3359 AC_SUBST(CXX)
3360 AC_SUBST(CFLAGS)
3361 AC_SUBST(CXXFLAGS)
3362
3363 # Target tools.
3364 AC_ARG_WITH([build-time-tools],
3365   [AS_HELP_STRING([--with-build-time-tools=PATH],
3366                   [use given path to find target tools during the build])],
3367   [case x"$withval" in
3368      x/*) ;;
3369      *)
3370        with_build_time_tools=
3371        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3372        ;;
3373    esac],
3374   [with_build_time_tools=])
3375
3376 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3377 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3378 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3379 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3380 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3381
3382 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3383 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3384 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3385 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3386 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3387 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3388 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJCOPY_FOR_TARGET, objcopy)
3389 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3390 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3391 ACX_CHECK_INSTALLED_TARGET_TOOL(READELF_FOR_TARGET, readelf)
3392 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3393 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3394 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3395
3396 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3397
3398 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3399 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3400 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3401 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3402 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3403                 [gcc/xg++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3404                 c++)
3405 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3406                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3407                 c++)
3408 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3409 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3410 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3411                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3412 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3413                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3414 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3415 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3416 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3417 GCC_TARGET_TOOL(objcopy, OBJCOPY_FOR_TARGET, OBJCOPY, [binutils/objcopy])
3418 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3419 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3420 GCC_TARGET_TOOL(readelf, READELF_FOR_TARGET, READELF, [binutils/readelf])
3421 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3422 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3423 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3424
3425 AC_SUBST(FLAGS_FOR_TARGET)
3426 AC_SUBST(RAW_CXX_FOR_TARGET)
3427
3428 # Certain tools may need extra flags.
3429 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3430 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3431 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3432
3433 # When building target libraries, except in a Canadian cross, we use
3434 # the same toolchain as the compiler we just built.
3435 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3436 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3437 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3438 if test $host = $build; then
3439   case " $configdirs " in
3440     *" gcc "*)
3441       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3442       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3443       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3444       ;;
3445   esac
3446 fi
3447
3448 AC_SUBST(COMPILER_AS_FOR_TARGET)
3449 AC_SUBST(COMPILER_LD_FOR_TARGET)
3450 AC_SUBST(COMPILER_NM_FOR_TARGET)
3451
3452 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3453 AC_ARG_ENABLE(maintainer-mode,
3454 [AS_HELP_STRING([--enable-maintainer-mode],
3455                 [enable make rules and dependencies not useful
3456                  (and sometimes confusing) to the casual installer])],
3457       USE_MAINTAINER_MODE=$enableval,
3458       USE_MAINTAINER_MODE=no)
3459 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3460 AC_SUBST(MAINTAINER_MODE_TRUE)
3461 AC_SUBST(MAINTAINER_MODE_FALSE)
3462 if test "$USE_MAINTAINER_MODE" = yes; then
3463   MAINTAINER_MODE_TRUE=
3464   MAINTAINER_MODE_FALSE='#'
3465 else
3466   MAINTAINER_MODE_TRUE='#'
3467   MAINTAINER_MODE_FALSE=
3468 fi
3469 MAINT=$MAINTAINER_MODE_TRUE
3470 AC_SUBST(MAINT)dnl
3471
3472 # ---------------------
3473 # GCC bootstrap support
3474 # ---------------------
3475
3476 # Stage specific cflags for build.
3477 stage1_cflags="-g"
3478 case $build in
3479   vax-*-*)
3480     case ${GCC} in
3481       yes) stage1_cflags="-g -Wa,-J" ;;
3482       *) stage1_cflags="-g -J" ;;
3483     esac ;;
3484 esac
3485
3486 AC_SUBST(stage1_cflags)
3487
3488 # Enable --enable-checking in stage1 of the compiler.
3489 AC_ARG_ENABLE(stage1-checking,
3490 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3491                 [choose additional checking for stage1 of the compiler])],
3492 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3493 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3494   # For --disable-checking or implicit --enable-checking=release, avoid
3495   # setting --enable-checking=gc in the default stage1 checking for LTO
3496   # bootstraps.  See PR62077.
3497   case $BUILD_CONFIG in
3498     *lto*)
3499       stage1_checking=--enable-checking=release,misc,gimple,rtlflag,tree,types;;
3500     *)
3501       stage1_checking=--enable-checking=yes,types;;
3502   esac
3503   if test "x$enable_checking" = x && \
3504      test -d ${srcdir}/gcc && \
3505      test x"`cat ${srcdir}/gcc/DEV-PHASE`" = xexperimental; then
3506     stage1_checking=--enable-checking=yes,types,extra
3507   fi
3508 else
3509   stage1_checking=--enable-checking=$enable_checking,types
3510 fi])
3511 AC_SUBST(stage1_checking)
3512
3513 # Enable -Werror in bootstrap stage2 and later.
3514 AC_ARG_ENABLE(werror,
3515 [AS_HELP_STRING([--enable-werror],
3516                 [enable -Werror in bootstrap stage2 and later])],
3517 [
3518 case ${enable_werror} in
3519   yes) stage2_werror_flag="--enable-werror-always" ;;
3520   *) stage2_werror_flag="" ;;
3521 esac
3522 ],
3523 [
3524 if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3525   case $BUILD_CONFIG in
3526   bootstrap-debug)
3527       stage2_werror_flag="--enable-werror-always" ;;
3528   "")
3529       stage2_werror_flag="--enable-werror-always" ;;
3530   esac
3531 fi
3532 ])
3533
3534 AC_SUBST(stage2_werror_flag)
3535
3536 # Specify what files to not compare during bootstrap.
3537
3538 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3539 case "$target" in
3540   hppa*64*-*-hpux*) ;;
3541   hppa*-*-hpux*) compare_exclusions="gcc/cc*-checksum\$(objext) | */libgcc/lib2funcs* | gcc/ada/*tools/* | gcc/function-tests.o" ;;
3542   powerpc*-ibm-aix*) compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/* | *libgomp*\$(objext)" ;;
3543 esac
3544 AC_SUBST(compare_exclusions)
3545
3546 AC_CONFIG_FILES([Makefile],
3547   [sed "$extrasub_build" Makefile |
3548    sed "$extrasub_host" |
3549    sed "$extrasub_target" > mf$$
3550    mv -f mf$$ Makefile],
3551   [extrasub_build="$extrasub_build"
3552    extrasub_host="$extrasub_host"
3553    extrasub_target="$extrasub_target"])
3554 AC_OUTPUT