libobjc/configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 #   Copyright (C) 1995, 1997, 1998, 1999, 2002, 2003
   3 #   Free Software Foundation, Inc.
   4 #   Contributed by Dave Love (d.love@dl.ac.uk).
   5 #
   6 #This file is part of GNU Objective C.
   7 #
   8 #GNU Objective C is free software; you can redistribute it and/or modify
   9 #it under the terms of the GNU General Public License as published by
  10 #the Free Software Foundation; either version 2, or (at your option)
  11 #any later version.
  12 #
  13 #GNU Objective C is distributed in the hope that it will be useful,
  14 #but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 #GNU General Public License for more details.
  17 #
  18 #You should have received a copy of the GNU General Public License
  19 #along with GNU Objective C; see the file COPYING.  If not, write to
  20 #the Free Software Foundation, 59 Temple Place - Suite 330, Boston, MA
  21 #02111-1307, USA.
  22
  23 AC_PREREQ(2.13)
  24 AC_INIT(objc/objc.h)
  25 AC_CONFIG_HEADER(config.h)
  26
  27 # This works around the fact that libtool configuration may change LD
  28 # for this particular configuration, but some shells, instead of
  29 # keeping the changes in LD private, export them just because LD is
  30 # exported.
  31 ORIGINAL_LD_FOR_MULTILIBS=$LD
  32
  33 GLIBCPP_TOPREL_CONFIGURE
  34
  35 AC_CANONICAL_SYSTEM
  36 target_alias=${target_alias-$target}
  37 AC_SUBST(target_alias)
  38
  39 GLIBCPP_CONFIGURE(.)
  40 GLIBCPP_EXPORT_INSTALL_INFO
  41
  42 dnl Checks for programs.
  43
  44 # Disable shared libs by default
  45 AC_DISABLE_SHARED
  46 # Enable Win32 DLL on MS Windows - FIXME
  47 AC_LIBTOOL_WIN32_DLL
  48
  49 AC_PROG_LIBTOOL
  50
  51 dnl These should be inherited in the recursive make, but ensure they are
  52 dnl defined:
  53 test "$AR" || AR=ar
  54 AC_SUBST(AR)
  55 if test "$RANLIB"; then :
  56   AC_SUBST(RANLIB)
  57 else
  58   AC_PROG_RANLIB
  59 fi
  60 AC_PROG_INSTALL
  61 AC_PROG_MAKE_SET
  62
  63 dnl Checks for header files.
  64 # Sanity check for the cross-compilation case:
  65 AC_CHECK_HEADER(stdio.h,:,
  66   [AC_MSG_ERROR([Can't find stdio.h.
  67 You must have a usable C system for the target already installed, at least
  68 including headers and, preferably, the library, before you can configure
  69 the Objective C runtime system.  If necessary, install gcc now with
  70 \`LANGUAGES=c', then the target library, then build with \`LANGUAGES=objc'.])])
  71
  72 AC_HEADER_STDC
  73
  74 AC_CHECK_HEADERS(sched.h)
  75
  76 # Determine CFLAGS for gthread.
  77
  78 AC_CACHE_CHECK([for gthread cflags],objc_cv_gthread_flags,
  79 [if test -f "$r"/gcc/Makefile
  80 then
  81   objc_cv_gthread_flags=`grep \^GTHREAD_FLAGS "$r"/gcc/Makefile | awk -F= '{ print $2 }'`
  82 else
  83   AC_MSG_ERROR([not found])
  84 fi])
  85 GTHREAD_FLAGS=$objc_cv_gthread_flags
  86 AC_SUBST(GTHREAD_FLAGS)
  87
  88 AC_ARG_ENABLE(objc-gc,
  89 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
  90                           the GNU Objective-C runtime.],
  91 if [[[ x$enable_objc_gc = xno ]]]; then
  92         OBJC_BOEHM_GC=''
  93 else
  94         OBJC_BOEHM_GC=libobjc_gc.la
  95 fi,
  96 OBJC_BOEHM_GC='')
  97 AC_SUBST(OBJC_BOEHM_GC)
  98
  99
 100 # We need multilib support, but only if configuring for the target.
 101 AC_OUTPUT(Makefile,
 102  [test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 103 if test -n "$CONFIG_FILES"; then
 104   if test -n "${with_target_subdir}"; then
 105     # FIXME: We shouldn't need to set ac_file
 106     ac_file=Makefile
 107     LD="${ORIGINAL_LD_FOR_MULTILIBS}"
 108     . ${toplevel_srcdir}/config-ml.in
 109   fi
 110 fi],
 111 srcdir=${srcdir}
 112 host=${host}
 113 target=${target}
 114 with_target_subdir=${with_target_subdir}
 115 with_multisubdir=${with_multisubdir}
 116 ac_configure_args="--enable-multilib ${ac_configure_args}"
 117 toplevel_srcdir=${toplevel_srcdir}
 118 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 119 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
 120 )
 121
 122
 123 dnl Local Variables:
 124 dnl comment-start: "dnl "
 125 dnl comment-end: ""
 126 dnl comment-start-skip: "\\bdnl\\b\\s *"
 127 dnl End: