gcc/ada/s-memory.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUN-TIME COMPONENTS                         --
   4 --                                                                          --
   5 --                         S Y S T E M . M E M O R Y                        --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2001-2016, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  17 --                                                                          --
  18 -- As a special exception under Section 7 of GPL version 3, you are granted --
  19 -- additional permissions described in the GCC Runtime Library Exception,   --
  20 -- version 3.1, as published by the Free Software Foundation.               --
  21 --                                                                          --
  22 -- You should have received a copy of the GNU General Public License and    --
  23 -- a copy of the GCC Runtime Library Exception along with this program;     --
  24 -- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
  25 -- <http://www.gnu.org/licenses/>.                                          --
  26 --                                                                          --
  27 -- GNAT was originally developed  by the GNAT team at  New York University. --
  28 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  29 --                                                                          --
  30 ------------------------------------------------------------------------------
  31
  32 --  This is the default implementation of this package
  33
  34 --  This implementation assumes that the underlying malloc/free/realloc
  35 --  implementation is thread safe, and thus, no additional lock is required.
  36 --  Note that we still need to defer abort because on most systems, an
  37 --  asynchronous signal (as used for implementing asynchronous abort of
  38 --  task) cannot safely be handled while malloc is executing.
  39
  40 --  If you are not using Ada constructs containing the "abort" keyword, then
  41 --  you can remove the calls to Abort_Defer.all and Abort_Undefer.all from
  42 --  this unit.
  43
  44 pragma Compiler_Unit_Warning;
  45
  46 with System.CRTL;
  47 with System.Parameters;
  48 with System.Soft_Links;
  49
  50 package body System.Memory is
  51
  52    use System.Soft_Links;
  53
  54    function c_malloc (Size : System.CRTL.size_t) return System.Address
  55     renames System.CRTL.malloc;
  56
  57    procedure c_free (Ptr : System.Address)
  58      renames System.CRTL.free;
  59
  60    function c_realloc
  61      (Ptr : System.Address; Size : System.CRTL.size_t) return System.Address
  62      renames System.CRTL.realloc;
  63
  64    -----------
  65    -- Alloc --
  66    -----------
  67
  68    function Alloc (Size : size_t) return System.Address is
  69       Result : System.Address;
  70
  71    begin
  72       if Parameters.No_Abort then
  73          Result := c_malloc (System.CRTL.size_t (Size));
  74       else
  75          Abort_Defer.all;
  76          Result := c_malloc (System.CRTL.size_t (Size));
  77          Abort_Undefer.all;
  78       end if;
  79
  80       if Result = System.Null_Address then
  81
  82          --  If Size = 0, we can't allocate 0 bytes, because then two different
  83          --  allocators, one of which has Size = 0, could return pointers that
  84          --  compare equal, which is wrong. (Nonnull pointers compare equal if
  85          --  and only if they designate the same object, and two different
  86          --  allocators allocate two different objects).
  87
  88          --  malloc(0) is defined to allocate a non-zero-sized object (in which
  89          --  case we won't get here, and all is well) or NULL, in which case we
  90          --  get here. We also get here in case of error. So check for the
  91          --  zero-size case, and allocate 1 byte. Otherwise, raise
  92          --  Storage_Error.
  93
  94          --  We check for zero size here, rather than at the start, for
  95          --  efficiency.
  96
  97          if Size = 0 then
  98             return Alloc (1);
  99          end if;
 100
 101          if Size = size_t'Last then
 102             raise Storage_Error with "object too large";
 103          end if;
 104
 105          raise Storage_Error with "heap exhausted";
 106       end if;
 107
 108       return Result;
 109    end Alloc;
 110
 111    ----------
 112    -- Free --
 113    ----------
 114
 115    procedure Free (Ptr : System.Address) is
 116    begin
 117       if Parameters.No_Abort then
 118          c_free (Ptr);
 119       else
 120          Abort_Defer.all;
 121          c_free (Ptr);
 122          Abort_Undefer.all;
 123       end if;
 124    end Free;
 125
 126    -------------
 127    -- Realloc --
 128    -------------
 129
 130    function Realloc
 131      (Ptr  : System.Address;
 132       Size : size_t)
 133       return System.Address
 134    is
 135       Result      : System.Address;
 136    begin
 137       if Parameters.No_Abort then
 138          Result := c_realloc (Ptr, System.CRTL.size_t (Size));
 139       else
 140          Abort_Defer.all;
 141          Result := c_realloc (Ptr, System.CRTL.size_t (Size));
 142          Abort_Undefer.all;
 143       end if;
 144
 145       if Result = System.Null_Address then
 146          if Size = size_t'Last then
 147             raise Storage_Error with "object too large";
 148          end if;
 149
 150          raise Storage_Error with "heap exhausted";
 151       end if;
 152
 153       return Result;
 154    end Realloc;
 155
 156 end System.Memory;