libgo/configure.ac

   1 # configure.ac -- Go library configure script.
   2
   3 # Copyright 2009 The Go Authors. All rights reserved.
   4 # Use of this source code is governed by a BSD-style
   5 # license that can be found in the LICENSE file.
   6
   7 # Process this file with autoreconf to produce configure.
   8
   9 AC_PREREQ(2.64)
  10 AC_INIT(package-unused, version-unused,, libgo)
  11 AC_CONFIG_SRCDIR(Makefile.am)
  12 AC_CONFIG_HEADER(config.h)
  13
  14 libtool_VERSION=13:0:0
  15 AC_SUBST(libtool_VERSION)
  16
  17 AM_ENABLE_MULTILIB(, ..)
  18
  19 AC_CANONICAL_SYSTEM
  20 target_alias=${target_alias-$host_alias}
  21
  22 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dist -Wall -Wno-portability])
  23 AH_TEMPLATE(PACKAGE, [Name of package])
  24 AH_TEMPLATE(VERSION, [Version number of package])
  25
  26 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibgo_PRECIOUS])
  27 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  28 AC_PROG_CC
  29 AC_PROG_GO
  30 m4_rename_force([glibgo_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  31
  32 AC_SUBST(CFLAGS)
  33
  34 case ${host} in
  35   *-*-aix*)
  36     # static hash tables crashes on AIX when libgo is built with O2
  37     CFLAGS="$CFLAGS -fno-section-anchors"
  38     GOCFLAGS="$GOCFLAGS -fno-section-anchors"
  39     ;;
  40 esac
  41
  42 AM_MAINTAINER_MODE
  43
  44 AC_PROG_LD
  45 AC_PROG_RANLIB
  46 AC_CHECK_TOOL(OBJCOPY, objcopy, missing-objcopy)
  47
  48 AC_LIBTOOL_DLOPEN
  49 AM_PROG_LIBTOOL
  50 AC_SUBST(enable_shared)
  51 AC_SUBST(enable_static)
  52
  53 CC_FOR_BUILD=${CC_FOR_BUILD:-gcc}
  54 AC_SUBST(CC_FOR_BUILD)
  55
  56 AC_PROG_AWK
  57
  58 WARN_FLAGS='-Wall -Wextra -Wwrite-strings -Wcast-qual'
  59 AC_SUBST(WARN_FLAGS)
  60
  61 AC_ARG_ENABLE(werror, [AS_HELP_STRING([--enable-werror],
  62                                       [turns on -Werror @<:@default=yes@:>@])])
  63 if test "x$enable_werror" != "xno"; then
  64   WERROR="-Werror"
  65 fi
  66 AC_SUBST(WERROR)
  67
  68 glibgo_toolexecdir=no
  69 glibgo_toolexeclibdir=no
  70
  71 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  72 AC_ARG_ENABLE([version-specific-runtime-libs],
  73   AC_HELP_STRING([--enable-version-specific-runtime-libs],
  74                  [Specify that runtime libraries should be installed in a compiler-specific directory]),
  75   [case "$enableval" in
  76     yes) version_specific_libs=yes ;;
  77     no)  version_specific_libs=no ;;
  78     *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  79    esac],
  80   [version_specific_libs=no])
  81 AC_MSG_RESULT($version_specific_libs)
  82
  83 # Version-specific runtime libs processing.
  84 if test $version_specific_libs = yes; then
  85   glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
  86   glibgo_toolexeclibdir='${toolexecdir}/${gcc_version}$(MULTISUBDIR)'
  87 fi
  88
  89 # Calculate glibgo_toolexecdir, glibgo_toolexeclibdir
  90 # Install a library built with a cross compiler in tooldir, not libdir.
  91 if test -n "$with_cross_host" &&
  92    test x"$with_cross_host" != x"no"; then
  93   nover_glibgo_toolexecdir='${exec_prefix}/${host_alias}'
  94   nover_glibgo_toolexeclibdir='${toolexecdir}/lib'
  95 else
  96   nover_glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
  97   nover_glibgo_toolexeclibdir='${libdir}'
  98 fi
  99 multi_os_directory=`$GOC -print-multi-os-directory`
 100 case $multi_os_directory in
 101   .) ;; # Avoid trailing /.
 102   *) nover_glibgo_toolexeclibdir=${nover_glibgo_toolexeclibdir}/${multi_os_directory} ;;
 103 esac
 104
 105 if test x"$glibgo_toolexecdir" = x"no"; then
 106   glibgo_toolexecdir="${nover_glibgo_toolexecdir}"
 107   glibgo_toolexeclibdir="${nover_glibgo_toolexeclibdir}"
 108 fi
 109
 110 AC_SUBST(glibgo_toolexecdir)
 111 AC_SUBST(glibgo_toolexeclibdir)
 112 AC_SUBST(nover_glibgo_toolexeclibdir)
 113
 114 # See if the user wants to configure without libffi.  Some
 115 # architectures don't support it.  FIXME: We should set a default
 116 # based on the host.
 117 AC_ARG_WITH(libffi,
 118   AS_HELP_STRING([--without-libffi],
 119                  [don't use libffi]),
 120   [:],
 121   [with_libffi=${with_libffi_default-yes}])
 122
 123 LIBFFI=
 124 LIBFFIINCS=
 125 if test "$with_libffi" != no; then
 126    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 127    LIBFFI=../libffi/libffi_convenience.la
 128    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 129 fi
 130 AC_SUBST(LIBFFI)
 131 AC_SUBST(LIBFFIINCS)
 132 AM_CONDITIONAL(USE_LIBFFI, test "$with_liffi" != "no")
 133
 134 # See if the user wants to configure without libatomic. This is useful if we are
 135 # on an architecture for which libgo does not need an atomic support library and
 136 # libatomic does not support our C compiler.
 137 AC_ARG_WITH(libatomic,
 138   AS_HELP_STRING([--without-libatomic],
 139                  [don't use libatomic]),
 140   [:],
 141   [with_libatomic=${with_libatomic_default-yes}])
 142
 143 LIBATOMIC=
 144 if test "$with_libatomic" != no; then
 145    LIBATOMIC=../libatomic/libatomic_convenience.la
 146 fi
 147 AC_SUBST(LIBATOMIC)
 148
 149 # Used to tell GNU make to include a file without telling automake to
 150 # include it.
 151 go_include="-include"
 152 AC_SUBST(go_include)
 153
 154 # All known GOOS values.  This is the union of all operating systems
 155 # supported by the gofrontend and all operating systems supported by
 156 # the gc toolchain.
 157 ALLGOOS="aix android darwin dragonfly freebsd irix linux netbsd openbsd plan9 rtems solaris windows"
 158
 159 is_darwin=no
 160 is_freebsd=no
 161 is_irix=no
 162 is_linux=no
 163 is_netbsd=no
 164 is_openbsd=no
 165 is_dragonfly=no
 166 is_rtems=no
 167 is_solaris=no
 168 is_aix=no
 169 GOOS=unknown
 170 case ${host} in
 171   *-*-darwin*)   is_darwin=yes;  GOOS=darwin ;;
 172   *-*-freebsd*)  is_freebsd=yes; GOOS=freebsd ;;
 173   *-*-irix6*)    is_irix=yes;    GOOS=irix ;;
 174   *-*-linux*)    is_linux=yes;   GOOS=linux ;;
 175   *-*-netbsd*)   is_netbsd=yes;  GOOS=netbsd ;;
 176   *-*-openbsd*)  is_openbsd=yes; GOOS=openbsd ;;
 177   *-*-dragonfly*) is_dragonfly=yes; GOOS=dragonfly ;;
 178   *-*-rtems*)    is_rtems=yes;   GOOS=rtems ;;
 179   *-*-solaris2*) is_solaris=yes; GOOS=solaris ;;
 180   *-*-aix*)      is_aix=yes;     GOOS=aix ;;
 181 esac
 182 AM_CONDITIONAL(LIBGO_IS_DARWIN, test $is_darwin = yes)
 183 AM_CONDITIONAL(LIBGO_IS_FREEBSD, test $is_freebsd = yes)
 184 AM_CONDITIONAL(LIBGO_IS_IRIX, test $is_irix = yes)
 185 AM_CONDITIONAL(LIBGO_IS_LINUX, test $is_linux = yes)
 186 AM_CONDITIONAL(LIBGO_IS_NETBSD, test $is_netbsd = yes)
 187 AM_CONDITIONAL(LIBGO_IS_OPENBSD, test $is_openbsd = yes)
 188 AM_CONDITIONAL(LIBGO_IS_DRAGONFLY, test $is_dragonfly = yes)
 189 AM_CONDITIONAL(LIBGO_IS_RTEMS, test $is_rtems = yes)
 190 AM_CONDITIONAL(LIBGO_IS_SOLARIS, test $is_solaris = yes)
 191 AM_CONDITIONAL(LIBGO_IS_AIX, test $is_aix = yes)
 192 AM_CONDITIONAL(LIBGO_IS_BSD, test $is_darwin = yes -o $is_dragonfly = yes -o $is_freebsd = yes -o $is_netbsd = yes -o $is_openbsd = yes)
 193 AC_SUBST(GOOS)
 194 AC_SUBST(ALLGOOS)
 195
 196 dnl Test whether we need to use DejaGNU or whether we can use the
 197 dnl simpler gotest approach.  We can only use gotest for a native
 198 dnl build.
 199 USE_DEJAGNU=no
 200 case ${host} in
 201   *-*-rtems*) USE_DEJAGNU=yes ;;
 202   ${build}) ;;
 203   *) USE_DEJAGNU=yes ;;
 204 esac
 205 AC_SUBST(USE_DEJAGNU)
 206
 207 # All known GOARCH values.  This is the union of all architectures
 208 # supported by the gofrontend and all architectures supported by the
 209 # gc toolchain.
 210 # N.B. Keep in sync with gcc/testsuite/go.test/go-test.exp (go-set-goarch).
 211 ALLGOARCH="386 alpha amd64 amd64p32 arm armbe arm64 arm64be ia64 m68k mips mipsle mips64 mips64le mips64p32 mips64p32le ppc ppc64 ppc64le s390 s390x sh shbe sparc sparc64"
 212
 213 # All known GOARCH_FAMILY values.
 214 ALLGOARCHFAMILY="I386 ALPHA AMD64 ARM ARM64 IA64 M68K MIPS MIPS64 PPC PPC64 S390 S390X SH SPARC SPARC64"
 215
 216 GOARCH=unknown
 217 GOARCH_FAMILY=unknown
 218 GOARCH_BIGENDIAN=false
 219 GOARCH_CACHELINESIZE=64
 220 GOARCH_PHYSPAGESIZE=4096
 221 GOARCH_PCQUANTUM=1
 222 GOARCH_INT64ALIGN=8
 223 GOARCH_HUGEPAGESIZE=0
 224 GOARCH_MINFRAMESIZE=0
 225 case ${host} in
 226   alpha*-*-*)
 227     GOARCH=alpha
 228     GOARCH_FAMILY=ALPHA
 229     GOARCH_PHYSPAGESIZE=8192
 230     GOARCH_PCQUANTUM=4
 231     ;;
 232   aarch64-*-*)
 233     GOARCH=arm64
 234     GOARCH_FAMILY=ARM64
 235     GOARCH_CACHELINESIZE=32
 236     GOARCH_PHYSPAGESIZE=65536
 237     GOARCH_PCQUANTUM=4
 238     GOARCH_MINFRAMESIZE=8
 239     ;;
 240   arm*-*-* | strongarm*-*-* | ep9312*-*-* | xscale-*-*)
 241     GOARCH=arm
 242     GOARCH_FAMILY=ARM
 243     GOARCH_CACHELINESIZE=32
 244     GOARCH_PCQUANTUM=4
 245     GOARCH_MINFRAMESIZE=4
 246     case ${host} in
 247       arm*b*-*-*)
 248         GOARCH=armbe
 249         GOARCH_BIGENDIAN=true
 250         ;;
 251     esac
 252     ;;
 253 changequote(,)dnl
 254   i[34567]86-*-* | x86_64-*-*)
 255 changequote([,])dnl
 256     AC_COMPILE_IFELSE([
 257 #ifdef __x86_64__
 258 #error 64-bit
 259 #endif],
 260 [GOARCH=386
 261 GOARCH_FAMILY=I386
 262 GOARCH_INT64ALIGN=4
 263 GOARCH_HUGEPAGESIZE="1 << 21"
 264 ],
 265 [GOARCH=amd64
 266 GOARCH_FAMILY=AMD64
 267 GOARCH_HUGEPAGESIZE="1 << 21"
 268 ])
 269     ;;
 270   ia64-*-*)
 271     GOARCH=ia64
 272     GOARCH_FAMILY=IA64
 273     GOARCH_CACHELINESIZE=128
 274     GOARCH_PHYSPAGESIZE=65536
 275     ;;
 276   m68k*-*-*)
 277     GOARCH=m68k
 278     GOARCH_FAMILY=M68K
 279     GOARCH_BIGENDIAN=true
 280     GOARCH_CACHELINESIZE=16
 281     GOARCH_PCQUANTUM=4
 282     GOARCH_INT64ALIGN=2
 283     ;;
 284   mips*-*-*)
 285     AC_COMPILE_IFELSE([
 286 #if _MIPS_SIM != _ABIO32
 287 #error not o32
 288 #endif],
 289 [mips_abi="o32"],
 290         [AC_COMPILE_IFELSE([
 291 #if _MIPS_SIM != _ABIN32
 292 #error not n32
 293 #endif],
 294 [mips_abi="n32"],
 295         [AC_COMPILE_IFELSE([
 296 #if _MIPS_SIM != _ABI64
 297 #error not n64
 298 #endif],
 299 [mips_abi="n64"],
 300         [AC_MSG_ERROR([unknown MIPS ABI])
 301 [mips_abi="n32"]])])])
 302     case "$mips_abi" in
 303     "o32") GOARCH=mips ;;
 304     "n32") GOARCH=mips64p32 ;;
 305     "n64") GOARCH=mips64 ;;
 306     esac
 307     case "$mips_abi" in
 308     "o32" | "n32")
 309         GOARCH_FAMILY=MIPS
 310         GOARCH_MINFRAMESIZE=4
 311         ;;
 312     "n64")
 313         GOARCH_FAMILY=MIPS64
 314         GOARCH_MINFRAMESIZE=8
 315         ;;
 316     esac
 317     case "${host}" in
 318     mips*el-*-*)
 319         GOARCH="${GOARCH}le"
 320         ;;
 321     *)
 322         GOARCH_BIGENDIAN=true
 323         ;;
 324     esac
 325     GOARCH_CACHELINESIZE=32
 326     GOARCH_PHYSPAGESIZE=16384
 327     GOARCH_PCQUANTUM=4
 328     ;;
 329   rs6000*-*-* | powerpc*-*-*)
 330     AC_COMPILE_IFELSE([
 331 #ifdef _ARCH_PPC64
 332 #error 64-bit
 333 #endif],
 334 [GOARCH=ppc
 335 GOARCH_FAMILY=PPC
 336 GOARCH_BIGENDIAN=true
 337 ],
 338     [
 339 GOARCH_FAMILY=PPC64
 340 AC_COMPILE_IFELSE([
 341 #if defined(_BIG_ENDIAN) || defined(__BIG_ENDIAN__)
 342 #error 64be
 343 #endif],
 344 [GOARCH=ppc64le
 345 ],
 346 [GOARCH=ppc64
 347 GOARCH_BIGENDIAN=true
 348 ])])
 349     GOARCH_PHYSPAGESIZE=65536
 350     GOARCH_PCQUANTUM=4
 351     GOARCH_MINFRAMESIZE=32
 352     ;;
 353   s390*-*-*)
 354     AC_COMPILE_IFELSE([
 355 #if defined(__s390x__)
 356 #error 64-bit
 357 #endif],
 358 [GOARCH=s390
 359 GOARCH_FAMILY=S390
 360 GOARCH_MINFRAMESIZE=4
 361 ], [GOARCH=s390x
 362 GOARCH_FAMILY=S390X
 363 GOARCH_MINFRAMESIZE=8
 364 ])
 365     GOARCH_BIGENDIAN=true
 366     GOARCH_CACHELINESIZE=256
 367     GOARCH_PCQUANTUM=2
 368     ;;
 369   sh3eb*-*-*)
 370     GOARCH=shbe
 371     GOARCH_FAMILY=SH
 372     GOARCH_BIGENDIAN=true
 373     GOARCH_CACHELINESIZE=16
 374     GOARCH_PCQUANTUM=2
 375     GOARCH_MINFRAMESIZE=4
 376     ;;
 377   sh3*-*-*)
 378     GOARCH=sh
 379     GOARCH_FAMILY=SH
 380     GOARCH_CACHELINESIZE=16
 381     GOARCH_PCQUANTUM=2
 382     GOARCH_MINFRAMESIZE=4
 383     ;;
 384   sh4eb*-*-*)
 385     GOARCH=shbe
 386     GOARCH_FAMILY=SH
 387     GOARCH_BIGENDIAN=true
 388     GOARCH_CACHELINESIZE=32
 389     GOARCH_PCQUANTUM=2
 390     GOARCH_MINFRAMESIZE=4
 391     ;;
 392   sh4*-*-*)
 393     GOARCH=sh
 394     GOARCH_FAMILY=SH
 395     GOARCH_CACHELINESIZE=32
 396     GOARCH_PCQUANTUM=2
 397     GOARCH_MINFRAMESIZE=4
 398     ;;
 399   sparc*-*-*)
 400     AC_COMPILE_IFELSE([
 401 #if defined(__sparcv9) || defined(__arch64__)
 402 #error 64-bit
 403 #endif],
 404 [GOARCH=sparc
 405 GOARCH_FAMILY=SPARC
 406 ],
 407 [GOARCH=sparc64
 408 GOARCH_FAMILY=SPARC64
 409 ])
 410     GOARCH_BIGENDIAN=true
 411     GOARCH_PHYSPAGESIZE=8192
 412     GOARCH_PCQUANTUM=4
 413     ;;
 414 esac
 415 AC_SUBST(GOARCH)
 416 AC_SUBST(GOARCH_FAMILY)
 417 AC_SUBST(GOARCH_BIGENDIAN)
 418 AC_SUBST(GOARCH_CACHELINESIZE)
 419 AC_SUBST(GOARCH_PHYSPAGESIZE)
 420 AC_SUBST(GOARCH_PCQUANTUM)
 421 AC_SUBST(GOARCH_INT64ALIGN)
 422 AC_SUBST(GOARCH_HUGEPAGESIZE)
 423 AC_SUBST(GOARCH_MINFRAMESIZE)
 424 AC_SUBST(ALLGOARCH)
 425 AC_SUBST(ALLGOARCHFAMILY)
 426
 427 dnl Some files are only present when needed for specific architectures.
 428 GO_LIBCALL_OS_FILE=
 429 GO_LIBCALL_OS_ARCH_FILE=
 430 GO_SYSCALL_OS_FILE=
 431 GO_SYSCALL_OS_ARCH_FILE=
 432 if test -f "${srcdir}/go/syscall/libcall_${GOOS}.go"; then
 433   GO_LIBCALL_OS_FILE="go/syscall/libcall_${GOOS}.go"
 434 fi
 435 if test -f "${srcdir}/go/syscall/libcall_${GOOS}_${GOARCH}.go"; then
 436   GO_LIBCALL_OS_ARCH_FILE="go/syscall/libcall_${GOOS}_${GOARCH}.go"
 437 fi
 438 if test -f "${srcdir}/go/syscall/syscall_${GOOS}.go"; then
 439   GO_SYSCALL_OS_FILE="go/syscall/syscall_${GOOS}.go"
 440 fi
 441 if test -f "${srcdir}/go/syscall/syscall_${GOOS}_${GOARCH}.go"; then
 442   GO_SYSCALL_OS_ARCH_FILE="go/syscall/syscall_${GOOS}_${GOARCH}.go"
 443 fi
 444 AC_SUBST(GO_LIBCALL_OS_FILE)
 445 AC_SUBST(GO_LIBCALL_OS_ARCH_FILE)
 446 AC_SUBST(GO_SYSCALL_OS_FILE)
 447 AC_SUBST(GO_SYSCALL_OS_ARCH_FILE)
 448
 449 dnl Special flags used to generate sysinfo.go.
 450 OSCFLAGS="-D_GNU_SOURCE -D_LARGEFILE_SOURCE -D_FILE_OFFSET_BITS=64"
 451 case "$target" in
 452     mips-sgi-irix6.5*)
 453         # IRIX 6 needs _XOPEN_SOURCE=500 for the XPG5 version of struct
 454         # msghdr in <sys/socket.h>.
 455         OSCFLAGS="$OSCFLAGS -D_XOPEN_SOURCE=500"
 456         ;;
 457     *-*-solaris2.1[[01]])
 458         # Solaris 10+ needs this so struct msghdr gets the msg_control
 459         # etc. fields in <sys/socket.h> (_XPG4_2).  _XOPEN_SOURCE=600 as
 460         # above doesn't work with C99.
 461         OSCFLAGS="$OSCFLAGS -std=gnu99 -D_XOPEN_SOURCE=600 -D__EXTENSIONS__"
 462         ;;
 463 esac
 464 AC_SUBST(OSCFLAGS)
 465
 466 dnl Check if assembler supports disabling hardware capability support.
 467 GCC_CHECK_ASSEMBLER_HWCAP
 468
 469 dnl Use -fsplit-stack when compiling C code if available.
 470 AC_CACHE_CHECK([whether -fsplit-stack is supported],
 471 [libgo_cv_c_split_stack_supported],
 472 [CFLAGS_hold=$CFLAGS
 473 CFLAGS="$CFLAGS -fsplit-stack"
 474 AC_COMPILE_IFELSE([[int i;]],
 475 [libgo_cv_c_split_stack_supported=yes],
 476 [libgo_cv_c_split_stack_supported=no])
 477 CFLAGS=$CFLAGS_hold])
 478
 479 dnl Make sure the linker permits -fsplit-stack.  Old versions of gold will
 480 dnl reject split-stack code calling non-split-stack code on targets
 481 dnl they don't support.
 482 AC_CACHE_CHECK([whether linker supports split/non-split linked together],
 483 [libgo_cv_c_linker_split_non_split],
 484 [cat > conftest1.c << EOF
 485 extern void f();
 486 int main() { f(); return 0; }
 487 EOF
 488 cat > conftest2.c << EOF
 489 void f() {}
 490 EOF
 491 $CC -c -fsplit-stack $CFLAGS $CPPFLAGS conftest1.c >/dev/null 2>&1
 492 $CC -c $CFLAGS $CPPFLAGS conftest2.c > /dev/null 2>&1
 493 if $CC -o conftest conftest1.$ac_objext conftest2.$ac_objext > /dev/null 2>&1; then
 494   libgo_cv_c_linker_split_non_split=yes
 495 else
 496   libgo_cv_c_linker_split_non_split=no
 497 fi
 498 rm -f conftest1.* conftest2.* conftest])
 499
 500 if test "$libgo_cv_c_split_stack_supported" = yes -a "$libgo_cv_c_linker_split_non_split" = yes; then
 501   SPLIT_STACK=-fsplit-stack
 502   AC_DEFINE(USING_SPLIT_STACK, 1,
 503                 [Define if the compiler supports -fsplit-stack])
 504 else
 505   SPLIT_STACK=
 506 fi
 507 AC_SUBST(SPLIT_STACK)
 508 AM_CONDITIONAL(USING_SPLIT_STACK,
 509         test "$libgo_cv_c_split_stack_supported" = yes -a "$libgo_cv_c_linker_split_non_split" = yes)
 510
 511 dnl If the compiler supports split-stack but the linker does not, then
 512 dnl we need to explicitly disable split-stack for Go.
 513 if test "$libgo_cv_c_split_stack_supported" = yes -a "$libgo_cv_c_linker_split_non_split" = no; then
 514   GO_SPLIT_STACK=-fno-split-stack
 515 else
 516   GO_SPLIT_STACK=
 517 fi
 518 AC_SUBST(GO_SPLIT_STACK)
 519
 520 dnl Check whether the linker does stack munging when calling from
 521 dnl split-stack into non-split-stack code.  We check this by looking
 522 dnl at the --help output.  FIXME: This is only half right: it's
 523 dnl possible for the linker to support this for some targets but not
 524 dnl others.
 525 dnl This is slightly different from the above check, which is whether
 526 dnl the linker permits the call at all.
 527 AC_CACHE_CHECK([whether linker supports split stack],
 528 [libgo_cv_c_linker_supports_split_stack],
 529 [libgo_cv_c_linker_supports_split_stack=no
 530 if $GOC -Wl,--help 2>/dev/null | grep split-stack-adjust-size >/dev/null 2>&1; then
 531   libgo_cv_c_linker_supports_split_stack=yes
 532 fi])
 533 if test "$libgo_cv_c_linker_supports_split_stack" = yes; then
 534   AC_DEFINE(LINKER_SUPPORTS_SPLIT_STACK, 1,
 535             [Define if the linker support split stack adjustments])
 536 fi
 537
 538 AC_CACHE_CHECK([whether compiler is llgo],
 539 [libgo_cv_c_goc_is_llgo],
 540 [libgo_cv_c_goc_is_llgo=no
 541 if $GOC -dumpversion 2>/dev/null | grep llgo >/dev/null 2>&1; then
 542   libgo_cv_c_goc_is_llgo=yes
 543 fi])
 544 AM_CONDITIONAL(GOC_IS_LLGO, test "$libgo_cv_c_goc_is_llgo" = yes)
 545
 546 dnl Test for the -lm library.
 547 MATH_LIBS=
 548 AC_CHECK_LIB([m], [sqrt], MATH_LIBS=-lm)
 549 AC_SUBST(MATH_LIBS)
 550
 551 dnl Test for -lsocket and -lnsl.  Copied from libjava/configure.ac.
 552 AC_CACHE_CHECK([for socket libraries], libgo_cv_lib_sockets,
 553   [libgo_cv_lib_sockets=
 554    libgo_check_both=no
 555    AC_CHECK_FUNC(connect, libgo_check_socket=no, libgo_check_socket=yes)
 556    if test "$libgo_check_socket" = "yes"; then
 557      unset ac_cv_func_connect
 558      AC_CHECK_LIB(socket, main, libgo_cv_lib_sockets="-lsocket",
 559                   libgo_check_both=yes)
 560    fi
 561    if test "$libgo_check_both" = "yes"; then
 562      libgo_old_libs=$LIBS
 563      LIBS="$LIBS -lsocket -lnsl"
 564      unset ac_cv_func_accept
 565      AC_CHECK_FUNC(accept,
 566                    [libgo_check_nsl=no
 567                     libgo_cv_lib_sockets="-lsocket -lnsl"])
 568      unset ac_cv_func_accept
 569      LIBS=$libgo_old_libs
 570    fi
 571    unset ac_cv_func_gethostbyname
 572    libgo_old_libs="$LIBS"
 573    AC_CHECK_FUNC(gethostbyname, ,
 574                  [AC_CHECK_LIB(nsl, main,
 575                         [libgo_cv_lib_sockets="$libgo_cv_lib_sockets -lnsl"])])
 576    unset ac_cv_func_gethostbyname
 577    AC_CHECK_FUNC(sendfile, ,
 578                  [AC_CHECK_LIB(sendfile, main,
 579                         [libgo_cv_lib_sockets="$libgo_cv_lib_sockets -lsendfile"])])
 580    LIBS=$libgo_old_libs
 581 ])
 582 NET_LIBS="$libgo_cv_lib_sockets"
 583 AC_SUBST(NET_LIBS)
 584
 585 dnl Test whether the compiler supports the -pthread option.
 586 AC_CACHE_CHECK([whether -pthread is supported],
 587 [libgo_cv_lib_pthread],
 588 [CFLAGS_hold=$CFLAGS
 589 CFLAGS="$CFLAGS -pthread"
 590 AC_COMPILE_IFELSE([[int i;]],
 591 [libgo_cv_lib_pthread=yes],
 592 [libgo_cv_lib_pthread=no])
 593 CFLAGS=$CFLAGS_hold])
 594 PTHREAD_CFLAGS=
 595 if test "$libgo_cv_lib_pthread" = yes; then
 596   PTHREAD_CFLAGS=-pthread
 597 fi
 598 AC_SUBST(PTHREAD_CFLAGS)
 599
 600 dnl Test for the -lpthread library.
 601 PTHREAD_LIBS=
 602 AC_CHECK_LIB([pthread], [pthread_create], PTHREAD_LIBS=-lpthread)
 603 AC_SUBST(PTHREAD_LIBS)
 604
 605 dnl Test if -lrt is required for sched_yield or nanosleep or clock_gettime.
 606 AC_SEARCH_LIBS([sched_yield], [rt])
 607 AC_SEARCH_LIBS([nanosleep], [rt])
 608 AC_SEARCH_LIBS([clock_gettime], [rt])
 609
 610 AC_C_BIGENDIAN
 611
 612 GCC_CHECK_UNWIND_GETIPINFO
 613
 614 AC_CHECK_HEADERS(port.h sched.h semaphore.h sys/file.h sys/mman.h syscall.h sys/epoll.h sys/event.h sys/inotify.h sys/ptrace.h sys/syscall.h sys/user.h sys/utsname.h sys/select.h sys/socket.h net/if.h net/if_arp.h net/route.h netpacket/packet.h sys/prctl.h sys/mount.h sys/vfs.h sys/statfs.h sys/timex.h sys/sysinfo.h utime.h linux/ether.h linux/fs.h linux/ptrace.h linux/reboot.h netinet/in_syst.h netinet/ip.h netinet/ip_mroute.h netinet/if_ether.h)
 615
 616 AC_CHECK_HEADERS([netinet/icmp6.h], [], [],
 617 [#include <netinet/in.h>
 618 ])
 619
 620 AC_CHECK_HEADERS([linux/filter.h linux/if_addr.h linux/if_ether.h linux/if_tun.h linux/netlink.h linux/rtnetlink.h], [], [],
 621 [#ifdef HAVE_SYS_SOCKET_H
 622 #include <sys/socket.h>
 623 #endif
 624 ])
 625
 626 AC_CACHE_CHECK([whether <ustat.h> can be used],
 627 [libgo_cv_c_ustat_h],
 628 [CFLAGS_hold=$CFLAGS
 629 CFLAGS="$CFLAGS -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE $OSCFLAGS"
 630 AC_COMPILE_IFELSE(
 631 [AC_LANG_SOURCE([
 632 #include <sys/types.h>
 633 #ifdef HAVE_LINUX_FILTER_H
 634 #include <linux/filter.h>
 635 #endif
 636 #include <ustat.h>
 637 ])], [libgo_cv_c_ustat_h=yes], [libgo_cv_c_ustat_h=no])
 638 CFLAGS=$CFLAGS_hold])
 639 if test $libgo_cv_c_ustat_h = yes; then
 640   AC_DEFINE(HAVE_USTAT_H, 1,
 641     [Define to 1 if you have the <ustat.h> header file and it works.])
 642 fi
 643
 644 AM_CONDITIONAL(HAVE_SYS_MMAN_H, test "$ac_cv_header_sys_mman_h" = yes)
 645
 646 AC_CHECK_FUNCS(strerror_r strsignal wait4 mincore setenv unsetenv dl_iterate_phdr)
 647 AM_CONDITIONAL(HAVE_STRERROR_R, test "$ac_cv_func_strerror_r" = yes)
 648 AM_CONDITIONAL(HAVE_WAIT4, test "$ac_cv_func_wait4" = yes)
 649
 650 AC_CHECK_FUNCS(accept4 dup3 epoll_create1 faccessat fallocate fchmodat fchownat futimesat getxattr inotify_add_watch inotify_init inotify_init1 inotify_rm_watch listxattr mkdirat mknodat open64 openat pipe2 removexattr renameat setxattr sync_file_range splice syscall tee unlinkat unshare utimensat)
 651 AC_TYPE_OFF_T
 652 AC_CHECK_TYPES([loff_t])
 653
 654 LIBS_hold="$LIBS"
 655 LIBS="$LIBS -lm"
 656 AC_CHECK_FUNCS(cosl expl logl sinl tanl acosl asinl atanl atan2l expm1l ldexpl log10l log1pl)
 657 LIBS="$LIBS_hold"
 658
 659 CFLAGS_hold="$CFLAGS"
 660 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 661 LIBS_hold="$LIBS"
 662 LIBS="$LIBS $PTHREAD_LIBS"
 663 AC_CHECK_FUNCS(sem_timedwait)
 664 CFLAGS="$CFLAGS_hold"
 665 LIBS="$LIBS_hold"
 666
 667 LIBS_hold="$LIBS"
 668 LIBS="$LIBS $MATH_LIBS"
 669 AC_CHECK_FUNCS(matherr)
 670 LIBS="$LIBS_hold"
 671
 672 AC_CACHE_CHECK([for __sync_bool_compare_and_swap_4],
 673 [libgo_cv_func___sync_bool_compare_and_swap_4],
 674 [AC_LINK_IFELSE([
 675 typedef unsigned int uint32  __attribute__ ((mode (SI)));
 676 uint32 i;
 677 int main() { return __sync_bool_compare_and_swap (&i, 0, 1); }
 678 ],
 679 [libgo_cv_func___sync_bool_compare_and_swap_4=yes],
 680 [libgo_cv_func___sync_bool_compare_and_swap_4=no])])
 681 if test "$libgo_cv_func___sync_bool_compare_and_swap_4" = "yes"; then
 682   AC_DEFINE(HAVE_SYNC_BOOL_COMPARE_AND_SWAP_4, 1,
 683     [Define to 1 if the compiler provides the __sync_bool_compare_and_swap function for uint32])
 684 fi
 685
 686 AC_CACHE_CHECK([for __sync_bool_compare_and_swap_8],
 687 [libgo_cv_func___sync_bool_compare_and_swap_8],
 688 [AC_LINK_IFELSE([
 689 typedef unsigned int uint64  __attribute__ ((mode (DI)));
 690 uint64 i;
 691 int main() { return __sync_bool_compare_and_swap (&i, 0, 1); }
 692 ],
 693 [libgo_cv_func___sync_bool_compare_and_swap_8=yes],
 694 [libgo_cv_func___sync_bool_compare_and_swap_8=no])])
 695 if test "$libgo_cv_func___sync_bool_compare_and_swap_8" = "yes"; then
 696   AC_DEFINE(HAVE_SYNC_BOOL_COMPARE_AND_SWAP_8, 1,
 697     [Define to 1 if the compiler provides the __sync_bool_compare_and_swap function for uint64])
 698 fi
 699
 700 AC_CACHE_CHECK([for __sync_fetch_and_add_4],
 701 [libgo_cv_func___sync_fetch_and_add_4],
 702 [AC_LINK_IFELSE([
 703 typedef unsigned int uint32  __attribute__ ((mode (SI)));
 704 uint32 i;
 705 int main() { return __sync_fetch_and_add (&i, 1); }
 706 ],
 707 [libgo_cv_func___sync_fetch_and_add_4=yes],
 708 [libgo_cv_func___sync_fetch_and_add_4=no])])
 709 if test "$libgo_cv_func___sync_fetch_and_add_4" = "yes"; then
 710   AC_DEFINE(HAVE_SYNC_FETCH_AND_ADD_4, 1,
 711     [Define to 1 if the compiler provides the __sync_fetch_and_add function for uint32])
 712 fi
 713
 714 AC_CACHE_CHECK([for __sync_add_and_fetch_8],
 715 [libgo_cv_func___sync_add_and_fetch_8],
 716 [AC_LINK_IFELSE([
 717 typedef unsigned int uint64  __attribute__ ((mode (DI)));
 718 uint64 i;
 719 int main() { return __sync_add_and_fetch (&i, 1); }
 720 ],
 721 [libgo_cv_func___sync_add_and_fetch_8=yes],
 722 [libgo_cv_func___sync_add_and_fetch_8=no])])
 723 if test "$libgo_cv_func___sync_add_and_fetch_8" = "yes"; then
 724   AC_DEFINE(HAVE_SYNC_ADD_AND_FETCH_8, 1,
 725     [Define to 1 if the compiler provides the __sync_add_and_fetch function for uint64])
 726 fi
 727
 728 dnl For x86 we want to use the -minline-all-stringops option to avoid
 729 dnl forcing a stack split when calling memcpy and friends.
 730 AC_CACHE_CHECK([whether compiler supports -minline-all-stringops],
 731 [libgo_cv_c_stringops],
 732 [CFLAGS_hold=$CFLAGS
 733 CFLAGS="$CFLAGS -minline-all-stringops"
 734 AC_COMPILE_IFELSE([int i;],
 735 [libgo_cv_c_stringops=yes],
 736 [libgo_cv_c_stringops=no])
 737 CFLAGS=$CFLAGS_hold])
 738 STRINGOPS_FLAG=
 739 if test "$libgo_cv_c_stringops" = yes; then
 740   STRINGOPS_FLAG=-minline-all-stringops
 741 fi
 742 AC_SUBST(STRINGOPS_FLAG)
 743
 744 dnl For x86 we want to compile the math library with -mfancy-math-387
 745 dnl -funsafe-math-optimizations so that we can use the builtin
 746 dnl instructions directly.
 747 AC_CACHE_CHECK([whether compiler supports -mfancy-math-387],
 748 [libgo_cv_c_fancymath],
 749 [CFLAGS_hold=$CFLAGS
 750 CFLAGS="$CFLAGS -mfancy-math-387"
 751 AC_COMPILE_IFELSE([int i;],
 752 [libgo_cv_c_fancymath=yes],
 753 [libgo_cv_c_fancymath=no])
 754 CFLAGS=$CFLAGS_hold])
 755 MATH_FLAG=
 756 if test "$libgo_cv_c_fancymath" = yes; then
 757   MATH_FLAG="-mfancy-math-387 -funsafe-math-optimizations -fno-math-errno"
 758 else
 759   MATH_FLAG="-ffp-contract=off"
 760 fi
 761 AC_SUBST(MATH_FLAG)
 762
 763 CFLAGS_hold=$CFLAGS
 764 CFLAGS="$CFLAGS -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE"
 765 AC_CHECK_TYPES([off64_t])
 766 CFLAGS=$CFLAGS_hold
 767
 768 dnl Work out the size of the epoll_events struct on GNU/Linux.
 769 AC_CACHE_CHECK([epoll_event size],
 770 [libgo_cv_c_epoll_event_size],
 771 [AC_COMPUTE_INT(libgo_cv_c_epoll_event_size,
 772 [sizeof (struct epoll_event)],
 773 [#include <sys/epoll.h>],
 774 [libgo_cv_c_epoll_event_size=0])])
 775 SIZEOF_STRUCT_EPOLL_EVENT=${libgo_cv_c_epoll_event_size}
 776 AC_SUBST(SIZEOF_STRUCT_EPOLL_EVENT)
 777
 778 dnl Work out the offset of the fd field in the epoll_events struct on
 779 dnl GNU/Linux.
 780 AC_CACHE_CHECK([epoll_event data.fd offset],
 781 [libgo_cv_c_epoll_event_fd_offset],
 782 [AC_COMPUTE_INT(libgo_cv_c_epoll_event_fd_offset,
 783 [offsetof (struct epoll_event, data.fd)],
 784 [#include <stddef.h>
 785 #include <sys/epoll.h>],
 786 [libgo_cv_c_epoll_event_fd_offset=0])])
 787 STRUCT_EPOLL_EVENT_FD_OFFSET=${libgo_cv_c_epoll_event_fd_offset}
 788 AC_SUBST(STRUCT_EPOLL_EVENT_FD_OFFSET)
 789
 790 dnl Check if <sys/stat.h> uses timespec_t for st_?tim members.  Introduced
 791 dnl in Solaris 11.4 for XPG7 compatibility.
 792 AC_EGREP_HEADER([timespec_t.*st_atim], [sys/stat.h],
 793                 [have_stat_timespec=yes], [have_stat_timespec=no])
 794 AM_CONDITIONAL(HAVE_STAT_TIMESPEC, test $have_stat_timespec = yes)
 795
 796 dnl See if struct exception is defined in <math.h>.
 797 AC_CHECK_TYPE([struct exception],
 798 [libgo_has_struct_exception=yes],
 799 [libgo_has_struct_exception=no],
 800 [#include <math.h>])
 801 if test "$libgo_has_struct_exception" = "yes"; then
 802   AC_DEFINE(HAVE_STRUCT_EXCEPTION, 1,
 803             [Define to 1 if <math.h> defines struct exception])
 804 fi
 805
 806 dnl See whether setcontext changes the value of TLS variables.
 807 AC_CACHE_CHECK([whether setcontext clobbers TLS variables],
 808 [libgo_cv_lib_setcontext_clobbers_tls],
 809 [CFLAGS_hold="$CFLAGS"
 810 CFLAGS="$PTHREAD_CFLAGS"
 811 LIBS_hold="$LIBS"
 812 LIBS="$LIBS $PTHREAD_LIBS"
 813 AC_CHECK_SIZEOF([void *])
 814 AS_VAR_ARITH([ptr_type_size], [$ac_cv_sizeof_void_p \* 8])
 815 AC_RUN_IFELSE(
 816   [AC_LANG_SOURCE([
 817 #include <pthread.h>
 818 #include <stdlib.h>
 819 #include <ucontext.h>
 820 #include <unistd.h>
 821
 822 __thread int tls;
 823
 824 static char stack[[10 * 1024 * 1024]];
 825 static ucontext_t c;
 826
 827 /* Called via makecontext/setcontext.  */
 828
 829 static void
 830 cfn (void)
 831 {
 832   exit (tls);
 833 }
 834
 835 /* Called via pthread_create.  */
 836
 837 static void *
 838 tfn (void *dummy)
 839 {
 840   /* The thread should still see this value after calling
 841      setcontext.  */
 842   tls = 0;
 843
 844   setcontext (&c);
 845
 846   /* The call to setcontext should not return.  */
 847   abort ();
 848 }
 849
 850 int
 851 main ()
 852 {
 853   pthread_t tid;
 854
 855   /* The thread should not see this value.  */
 856   tls = 1;
 857
 858   if (getcontext (&c) < 0)
 859     abort ();
 860
 861   c.uc_stack.ss_sp = stack;
 862 #ifdef MAKECONTEXT_STACK_TOP
 863   c.uc_stack.ss_sp += sizeof stack;
 864 #endif
 865   c.uc_stack.ss_flags = 0;
 866   c.uc_stack.ss_size = sizeof stack;
 867   c.uc_link = NULL;
 868   makecontext (&c, cfn, 0);
 869
 870   if (pthread_create (&tid, NULL, tfn, NULL) != 0)
 871     abort ();
 872
 873   if (pthread_join (tid, NULL) != 0)
 874     abort ();
 875
 876   /* The thread should have called exit.  */
 877   abort ();
 878 }
 879 ])],
 880 [libgo_cv_lib_setcontext_clobbers_tls=no],
 881 [libgo_cv_lib_setcontext_clobbers_tls=yes],
 882 [case "$target:$ptr_type_size" in
 883   i?86-*-solaris2.1[[01]]:64 | x86_64*-*-solaris2.1[[01]]:64)
 884     libgo_cv_lib_setcontext_clobbers_tls=yes ;;
 885   *)
 886     libgo_cv_lib_setcontext_clobbers_tls=no ;;
 887  esac
 888 ])
 889 CFLAGS="$CFLAGS_hold"
 890 LIBS="$LIBS_hold"
 891 ])
 892 if test "$libgo_cv_lib_setcontext_clobbers_tls" = "yes"; then
 893   AC_DEFINE(SETCONTEXT_CLOBBERS_TLS, 1,
 894             [Define if setcontext clobbers TLS variables])
 895 fi
 896
 897 AC_CACHE_CHECK([whether .eh_frame section should be read-only],
 898 libgo_cv_ro_eh_frame, [
 899 libgo_cv_ro_eh_frame=no
 900 echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
 901 if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
 902   if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
 903     libgo_cv_ro_eh_frame=yes
 904   elif grep '.section.*eh_frame.*#alloc' conftest.c \
 905        | grep -v '#write' > /dev/null; then
 906     libgo_cv_ro_eh_frame=yes
 907   fi
 908 fi
 909 rm -f conftest.*
 910 ])
 911 if test "x$libgo_cv_ro_eh_frame" = xyes; then
 912   AC_DEFINE(EH_FRAME_FLAGS, "a",
 913             [Define to the flags needed for the .section .eh_frame directive.])
 914 else
 915   AC_DEFINE(EH_FRAME_FLAGS, "aw",
 916             [Define to the flags needed for the .section .eh_frame directive.])
 917 fi
 918
 919 AC_CACHE_CHECK([if compiler supports -Qunused-arguments],
 920 [libgo_cv_c_unused_arguments],
 921 [CFLAGS_hold=$CFLAGS
 922 CFLAGS="$CFLAGS -Qunused-arguments"
 923 AC_COMPILE_IFELSE([[int i;]],
 924 [libgo_cv_c_unused_arguments=yes],
 925 [libgo_cv_c_unused_arguments=no])
 926 CFLAGS=$CFLAGS_hold])
 927
 928 AC_CACHE_CHECK([if assembler supports GNU comdat group syntax],
 929 libgo_cv_as_comdat_gnu, [
 930 echo '.section .text,"axG",@progbits,.foo,comdat' > conftest.s
 931 CFLAGS_hold=$CFLAGS
 932 if test "$libgo_cv_c_unused_arguments" = yes; then
 933   CFLAGS="$CFLAGS -Qunused-arguments"
 934 fi
 935 if $CC $CFLAGS -c conftest.s > /dev/null 2>&1; then
 936   libgo_cv_as_comdat_gnu=yes
 937 else
 938   libgo_cv_as_comdat_gnu=no
 939 fi
 940 CFLAGS=$CFLAGS_hold
 941 ])
 942 if test "x$libgo_cv_as_comdat_gnu" = xyes; then
 943   AC_DEFINE(HAVE_AS_COMDAT_GAS, 1,
 944             [Define if your assembler supports GNU comdat group syntax.])
 945 fi
 946
 947 AC_CACHE_CHECK([assembler supports pc related relocs],
 948 libgo_cv_as_x86_pcrel, [
 949 libgo_cv_as_x86_pcrel=yes
 950 echo '.text; foo: nop; .data; .long foo-.; .text' > conftest.s
 951 CFLAGS_hold=$CFLAGS
 952 if test "$libgo_cv_c_unused_arguments" = yes; then
 953   CFLAGS="$CFLAGS -Qunused-arguments"
 954 fi
 955 if $CC $CFLAGS -c conftest.s 2>&1 | $EGREP -i 'illegal|warning' > /dev/null; then
 956     libgo_cv_as_x86_pcrel=no
 957 fi
 958 CFLAGS=$CFLAGS_hold
 959 ])
 960 if test "x$libgo_cv_as_x86_pcrel" = xyes; then
 961   AC_DEFINE(HAVE_AS_X86_PCREL, 1,
 962             [Define if your assembler supports PC relative relocs.])
 963 fi
 964
 965 AC_CACHE_CHECK([assembler supports unwind section type],
 966 libgo_cv_as_x86_64_unwind_section_type, [
 967 libgo_cv_as_x86_64_unwind_section_type=yes
 968 echo '.section .eh_frame,"a",@unwind' > conftest.s
 969 CFLAGS_hold=$CFLAGS
 970 if test "$libgo_cv_c_unused_arguments" = yes; then
 971   CFLAGS="$CFLAGS -Qunused-arguments"
 972 fi
 973 if $CC $CFLAGS -c conftest.s 2>&1 | grep -i warning > /dev/null; then
 974     libgo_cv_as_x86_64_unwind_section_type=no
 975 fi
 976 CFLAGS=$CFLAGS_hold
 977 ])
 978 if test "x$libgo_cv_as_x86_64_unwind_section_type" = xyes; then
 979   AC_DEFINE(HAVE_AS_X86_64_UNWIND_SECTION_TYPE, 1,
 980             [Define if your assembler supports unwind section type.])
 981 fi
 982
 983 AC_CACHE_CHECK([assembler supports AES instructions],
 984 libgo_cv_as_x86_aes, [
 985 libgo_cv_as_x86_aes=yes
 986 echo 'aesenc %xmm0, %xmm1' > conftest.s
 987 CFLAGS_hold=$CFLAGS
 988 if test "$libgo_cv_c_unused_arguments" = yes; then
 989   CFLAGS="$CFLAGS -Qunused-arguments"
 990 fi
 991 if $CC $CFLAGS -c conftest.s 2>&1 | grep -i error > /dev/null; then
 992     libgo_cv_as_x86_aes=no
 993 fi
 994 CFLAGS=$CFLAGS_hold
 995 ])
 996 if test "x$libgo_cv_as_x86_aes" = xyes; then
 997   AC_DEFINE(HAVE_AS_X86_AES, 1,
 998             [Define if your assembler supports AES instructions.])
 999 fi
1000
1001 AC_CACHE_SAVE
1002
1003 if test ${multilib} = yes; then
1004   multilib_arg="--enable-multilib"
1005 else
1006   multilib_arg=
1007 fi
1008
1009 AC_CONFIG_FILES(Makefile testsuite/Makefile)
1010
1011 AC_CONFIG_COMMANDS([default],
1012 [if test -n "$CONFIG_FILES"; then
1013    # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
1014    # that multilib installs will end up installed in the correct place.
1015    # The testsuite needs it for multilib-aware ABI baseline files.
1016    # To work around this not being passed down from config-ml.in ->
1017    # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
1018    # append it here.  Only modify Makefiles that have just been created.
1019    #
1020    # Also, get rid of this simulated-VPATH thing that automake does.
1021    cat > vpsed << \_EOF
1022 s!`test -f '$<' || echo '$(srcdir)/'`!!
1023 _EOF
1024    for i in $SUBDIRS; do
1025     case $CONFIG_FILES in
1026      *${i}/Makefile*)
1027        #echo "Adding MULTISUBDIR to $i/Makefile"
1028        sed -f vpsed $i/Makefile > tmp
1029        grep '^MULTISUBDIR =' Makefile >> tmp
1030        mv tmp $i/Makefile
1031        ;;
1032     esac
1033    done
1034    rm vpsed
1035  fi
1036 ],
1037 [
1038 # Variables needed in config.status (file generation) which aren't already
1039 # passed by autoconf.
1040 SUBDIRS="$SUBDIRS"
1041 ])
1042
1043 AC_OUTPUT