gcc/ada/gprep.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                                G P R E P                                 --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2002-2005, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- GNAT was originally developed  by the GNAT team at  New York University. --
  23 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  24 --                                                                          --
  25 ------------------------------------------------------------------------------
  26
  27 with Csets;
  28 with Err_Vars; use Err_Vars;
  29 with Errutil;
  30 with Gnatvsn;
  31 with Namet;    use Namet;
  32 with Opt;
  33 with Osint;    use Osint;
  34 with Output;   use Output;
  35 with Prep;     use Prep;
  36 with Scng;
  37 with Sinput.C;
  38 with Snames;
  39 with Stringt;  use Stringt;
  40 with Types;    use Types;
  41
  42 with Ada.Text_IO;               use Ada.Text_IO;
  43 with GNAT.Case_Util;            use GNAT.Case_Util;
  44 with GNAT.Command_Line;
  45 with GNAT.Directory_Operations; use GNAT.Directory_Operations;
  46 with GNAT.OS_Lib;               use GNAT.OS_Lib;
  47
  48 package body GPrep is
  49
  50    Copyright_Displayed : Boolean := False;
  51    --  Used to prevent multiple displays of the copyright notice
  52
  53    ------------------------
  54    -- Argument Line Data --
  55    ------------------------
  56
  57    Infile_Name  : Name_Id := No_Name;
  58    Outfile_Name : Name_Id := No_Name;
  59    Deffile_Name : Name_Id := No_Name;
  60
  61    Output_Directory : Name_Id := No_Name;
  62    --  Used when the specified output is an existing directory
  63
  64    Input_Directory : Name_Id := No_Name;
  65    --  Used when the specified input and output are existing directories
  66
  67    Source_Ref_Pragma : Boolean := False;
  68    --  Record command line options (set if -r switch set)
  69
  70    Text_Outfile : aliased Ada.Text_IO.File_Type;
  71    Outfile      : constant File_Access := Text_Outfile'Access;
  72
  73    File_Name_Buffer_Initial_Size : constant := 50;
  74    File_Name_Buffer : String_Access :=
  75                         new String (1 .. File_Name_Buffer_Initial_Size);
  76    --  A buffer to build output file names from input file names
  77
  78    -----------------
  79    -- Subprograms --
  80    -----------------
  81
  82    procedure Display_Copyright;
  83    --  Display the copyright notice
  84
  85    procedure Obsolescent_Check (S : Source_Ptr);
  86    --  Null procedure, needed by instantiation of Scng below
  87
  88    procedure Post_Scan;
  89    --  Null procedure, needed by instantiation of Scng below
  90
  91    package Scanner is new Scng
  92      (Post_Scan,
  93       Errutil.Error_Msg,
  94       Errutil.Error_Msg_S,
  95       Errutil.Error_Msg_SC,
  96       Errutil.Error_Msg_SP,
  97       Obsolescent_Check,
  98       Errutil.Style);
  99    --  The scanner for the preprocessor
 100
 101    function Is_ASCII_Letter (C : Character) return Boolean;
 102    --  True if C is in 'a' .. 'z' or in 'A' .. 'Z'
 103
 104    procedure Double_File_Name_Buffer;
 105    --  Double the size of the file name buffer
 106
 107    procedure Preprocess_Infile_Name;
 108    --  When the specified output is a directory, preprocess the infile name
 109    --  for symbol substitution, to get the output file name.
 110
 111    procedure Process_Files;
 112    --  Process the single input file or all the files in the directory tree
 113    --  rooted at the input directory.
 114
 115    procedure Process_Command_Line_Symbol_Definition (S : String);
 116    --  Process a -D switch on the command line
 117
 118    procedure Put_Char_To_Outfile (C : Character);
 119    --  Output one character to the output file. Used to initialize the
 120    --  preprocessor.
 121
 122    procedure New_EOL_To_Outfile;
 123    --  Output a new line to the output file. Used to initialize the
 124    --  preprocessor.
 125
 126    procedure Scan_Command_Line;
 127    --  Scan the switches and the file names
 128
 129    procedure Usage;
 130    --  Display the usage
 131
 132    -----------------------
 133    -- Display_Copyright --
 134    -----------------------
 135
 136    procedure Display_Copyright is
 137    begin
 138       if not Copyright_Displayed then
 139          Write_Line ("GNAT Preprocessor " & Gnatvsn.Gnat_Version_String);
 140          Write_Line ("Copyright 1996-2005, Free Software Foundation, Inc.");
 141          Copyright_Displayed := True;
 142       end if;
 143    end Display_Copyright;
 144
 145    -----------------------------
 146    -- Double_File_Name_Buffer --
 147    -----------------------------
 148
 149    procedure Double_File_Name_Buffer is
 150       New_Buffer : constant String_Access :=
 151                      new String (1 .. 2 * File_Name_Buffer'Length);
 152    begin
 153       New_Buffer (File_Name_Buffer'Range) := File_Name_Buffer.all;
 154       Free (File_Name_Buffer);
 155       File_Name_Buffer := New_Buffer;
 156    end Double_File_Name_Buffer;
 157
 158    --------------
 159    -- Gnatprep --
 160    --------------
 161
 162    procedure Gnatprep is
 163    begin
 164       --  Do some initializations (order is important here!)
 165
 166       Csets.Initialize;
 167       Namet.Initialize;
 168       Snames.Initialize;
 169       Stringt.Initialize;
 170
 171       --  Initialize the preprocessor
 172
 173       Prep.Initialize
 174         (Error_Msg         => Errutil.Error_Msg'Access,
 175          Scan              => Scanner.Scan'Access,
 176          Set_Ignore_Errors => Errutil.Set_Ignore_Errors'Access,
 177          Put_Char          => Put_Char_To_Outfile'Access,
 178          New_EOL           => New_EOL_To_Outfile'Access);
 179
 180       --  Set the scanner characteristics for the preprocessor
 181
 182       Scanner.Set_Special_Character ('#');
 183       Scanner.Set_Special_Character ('$');
 184       Scanner.Set_End_Of_Line_As_Token (True);
 185
 186       --  Initialize the mapping table of symbols to values
 187
 188       Prep.Symbol_Table.Init (Prep.Mapping);
 189
 190       --  Parse the switches and arguments
 191
 192       Scan_Command_Line;
 193
 194       if Opt.Verbose_Mode then
 195          Display_Copyright;
 196       end if;
 197
 198       --  Test we had all the arguments needed
 199
 200       if Infile_Name = No_Name then
 201
 202          --  No input file specified, just output the usage and exit
 203
 204          Usage;
 205          return;
 206
 207       elsif Outfile_Name = No_Name then
 208
 209          --  No output file specified, just output the usage and exit
 210
 211          Usage;
 212          return;
 213       end if;
 214
 215       --  If a pragma Source_File_Name, we need to keep line numbers. So, if
 216       --  the deleted lines are not put as comment, we must output them as
 217       --  blank lines.
 218
 219       if Source_Ref_Pragma and (not Opt.Comment_Deleted_Lines) then
 220          Opt.Blank_Deleted_Lines := True;
 221       end if;
 222
 223       --  If we have a definition file, parse it
 224
 225       if Deffile_Name /= No_Name then
 226          declare
 227             Deffile : Source_File_Index;
 228
 229          begin
 230             Errutil.Initialize;
 231             Deffile := Sinput.C.Load_File (Get_Name_String (Deffile_Name));
 232
 233             --  Set Main_Source_File to the definition file for the benefit of
 234             --  Errutil.Finalize.
 235
 236             Sinput.Main_Source_File := Deffile;
 237
 238             if Deffile = No_Source_File then
 239                Fail ("unable to find definition file """,
 240                      Get_Name_String (Deffile_Name),
 241                      """");
 242             end if;
 243
 244             Scanner.Initialize_Scanner (No_Unit, Deffile);
 245
 246             Prep.Parse_Def_File;
 247          end;
 248       end if;
 249
 250       --  If there are errors in the definition file, output them and exit
 251
 252       if Total_Errors_Detected > 0 then
 253          Errutil.Finalize (Source_Type => "definition");
 254          Fail ("errors in definition file """,
 255                Get_Name_String (Deffile_Name), """");
 256       end if;
 257
 258       --  If -s switch was specified, print a sorted list of symbol names and
 259       --  values, if any.
 260
 261       if Opt.List_Preprocessing_Symbols then
 262          Prep.List_Symbols (Foreword => "");
 263       end if;
 264
 265       Output_Directory := No_Name;
 266       Input_Directory  := No_Name;
 267
 268       --  Check if the specified output is an existing directory
 269
 270       if Is_Directory (Get_Name_String (Outfile_Name)) then
 271          Output_Directory := Outfile_Name;
 272
 273          --  As the output is an existing directory, check if the input too
 274          --  is a directory.
 275
 276          if Is_Directory (Get_Name_String (Infile_Name)) then
 277             Input_Directory := Infile_Name;
 278          end if;
 279       end if;
 280
 281       --  And process the single input or the files in the directory tree
 282       --  rooted at the input directory.
 283
 284       Process_Files;
 285    end Gnatprep;
 286
 287    ---------------------
 288    -- Is_ASCII_Letter --
 289    ---------------------
 290
 291    function Is_ASCII_Letter (C : Character) return Boolean is
 292    begin
 293       return C in 'A' .. 'Z' or else C in 'a' .. 'z';
 294    end Is_ASCII_Letter;
 295
 296    ------------------------
 297    -- New_EOL_To_Outfile --
 298    ------------------------
 299
 300    procedure New_EOL_To_Outfile is
 301    begin
 302       New_Line (Outfile.all);
 303    end New_EOL_To_Outfile;
 304
 305    -----------------------
 306    -- Obsolescent_Check --
 307    -----------------------
 308
 309    procedure Obsolescent_Check (S : Source_Ptr) is
 310       pragma Warnings (Off, S);
 311    begin
 312       null;
 313    end Obsolescent_Check;
 314
 315    ---------------
 316    -- Post_Scan --
 317    ---------------
 318
 319    procedure Post_Scan is
 320    begin
 321       null;
 322    end Post_Scan;
 323
 324    ----------------------------
 325    -- Preprocess_Infile_Name --
 326    ----------------------------
 327
 328    procedure Preprocess_Infile_Name is
 329       Len    : Natural;
 330       First  : Positive;
 331       Last   : Natural;
 332       Symbol : Name_Id;
 333       Data   : Symbol_Data;
 334
 335    begin
 336       --  Initialize the buffer with the name of the input file
 337
 338       Get_Name_String (Infile_Name);
 339       Len := Name_Len;
 340
 341       while File_Name_Buffer'Length < Len loop
 342          Double_File_Name_Buffer;
 343       end loop;
 344
 345       File_Name_Buffer (1 .. Len) := Name_Buffer (1 .. Len);
 346
 347       --  Look for possible symbols in the file name
 348
 349       First := 1;
 350       while First < Len loop
 351
 352          --  A symbol starts with a dollar sign followed by a letter
 353
 354          if File_Name_Buffer (First) = '$' and then
 355            Is_ASCII_Letter (File_Name_Buffer (First + 1))
 356          then
 357             Last := First + 1;
 358
 359             --  Find the last letter of the symbol
 360
 361             while Last < Len and then
 362                Is_ASCII_Letter (File_Name_Buffer (Last + 1))
 363             loop
 364                Last := Last + 1;
 365             end loop;
 366
 367             --  Get the symbol name id
 368
 369             Name_Len := Last - First;
 370             Name_Buffer (1 .. Name_Len) :=
 371               File_Name_Buffer (First + 1 .. Last);
 372             To_Lower (Name_Buffer (1 .. Name_Len));
 373             Symbol := Name_Find;
 374
 375             --  And look for this symbol name in the symbol table
 376
 377             for Index in 1 .. Symbol_Table.Last (Mapping) loop
 378                Data := Mapping.Table (Index);
 379
 380                if Data.Symbol = Symbol then
 381
 382                   --  We found the symbol. If its value is not a string,
 383                   --  replace the symbol in the file name with the value of
 384                   --  the symbol.
 385
 386                   if not Data.Is_A_String then
 387                      String_To_Name_Buffer (Data.Value);
 388
 389                      declare
 390                         Sym_Len : constant Positive := Last - First + 1;
 391                         Offset  : constant Integer := Name_Len - Sym_Len;
 392                         New_Len : constant Natural := Len + Offset;
 393
 394                      begin
 395                         while New_Len > File_Name_Buffer'Length loop
 396                            Double_File_Name_Buffer;
 397                         end loop;
 398
 399                         File_Name_Buffer (Last + 1 + Offset .. New_Len) :=
 400                           File_Name_Buffer (Last + 1 .. Len);
 401                         Len := New_Len;
 402                         Last := Last + Offset;
 403                         File_Name_Buffer (First .. Last) :=
 404                           Name_Buffer (1 .. Name_Len);
 405                      end;
 406                   end if;
 407
 408                   exit;
 409                end if;
 410             end loop;
 411
 412             --  Skip over the symbol name or its value: we are not checking
 413             --  for another symbol name in the value.
 414
 415             First := Last + 1;
 416
 417          else
 418             First := First + 1;
 419          end if;
 420       end loop;
 421
 422       --  We now have the output file name in the buffer. Get the output
 423       --  path and put it in Outfile_Name.
 424
 425       Get_Name_String (Output_Directory);
 426       Add_Char_To_Name_Buffer (Directory_Separator);
 427       Add_Str_To_Name_Buffer (File_Name_Buffer (1 .. Len));
 428       Outfile_Name := Name_Find;
 429    end Preprocess_Infile_Name;
 430
 431    --------------------------------------------
 432    -- Process_Command_Line_Symbol_Definition --
 433    --------------------------------------------
 434
 435    procedure Process_Command_Line_Symbol_Definition (S : String) is
 436       Data   : Symbol_Data;
 437       Symbol : Symbol_Id;
 438
 439    begin
 440       --  Check the symbol definition and get the symbol and its value.
 441       --  Fail if symbol definition is illegal.
 442
 443       Check_Command_Line_Symbol_Definition (S, Data);
 444
 445       Symbol := Index_Of (Data.Symbol);
 446
 447       --  If symbol does not alrady exist, create a new entry in the mapping
 448       --  table.
 449
 450       if Symbol = No_Symbol then
 451          Symbol_Table.Increment_Last (Mapping);
 452          Symbol := Symbol_Table.Last (Mapping);
 453       end if;
 454
 455       Mapping.Table (Symbol) := Data;
 456    end Process_Command_Line_Symbol_Definition;
 457
 458    -------------------
 459    -- Process_Files --
 460    -------------------
 461
 462    procedure Process_Files is
 463
 464       procedure Process_One_File;
 465       --  Process input file Infile_Name and put the result in file
 466       --  Outfile_Name.
 467
 468       procedure Recursive_Process (In_Dir : String; Out_Dir : String);
 469       --  Process recursively files in In_Dir. Results go to Out_Dir
 470
 471       ----------------------
 472       -- Process_One_File --
 473       ----------------------
 474
 475       procedure Process_One_File is
 476          Infile : Source_File_Index;
 477
 478       begin
 479          --  Create the output file (fails if this does not work)
 480
 481          begin
 482             Create (Text_Outfile, Out_File, Get_Name_String (Outfile_Name));
 483
 484          exception
 485             when others =>
 486                Fail
 487                  ("unable to create output file """,
 488                   Get_Name_String (Outfile_Name), """");
 489          end;
 490
 491          --  Load the input file
 492
 493          Infile := Sinput.C.Load_File (Get_Name_String (Infile_Name));
 494
 495          if Infile = No_Source_File then
 496             Fail ("unable to find input file """,
 497                   Get_Name_String (Infile_Name), """");
 498          end if;
 499
 500          --  Set Main_Source_File to the input file for the benefit of
 501          --  Errutil.Finalize.
 502
 503          Sinput.Main_Source_File := Infile;
 504
 505          Scanner.Initialize_Scanner (No_Unit, Infile);
 506
 507          --  Output the SFN pragma if asked to
 508
 509          if Source_Ref_Pragma then
 510             Put_Line (Outfile.all, "pragma Source_Reference (1, """ &
 511                       Get_Name_String (Sinput.File_Name (Infile)) &
 512                       """);");
 513          end if;
 514
 515          --  Preprocess the input file
 516
 517          Prep.Preprocess;
 518
 519          --  In verbose mode, if there is no error, report it
 520
 521          if Opt.Verbose_Mode and then Err_Vars.Total_Errors_Detected = 0 then
 522             Errutil.Finalize (Source_Type => "input");
 523          end if;
 524
 525          --  If we had some errors, delete the output file, and report them
 526
 527          if Err_Vars.Total_Errors_Detected > 0 then
 528             if Outfile /= Standard_Output then
 529                Delete (Text_Outfile);
 530             end if;
 531
 532             Errutil.Finalize (Source_Type => "input");
 533
 534             OS_Exit (0);
 535
 536          --  Otherwise, close the output file, and we are done
 537
 538          elsif Outfile /= Standard_Output then
 539             Close (Text_Outfile);
 540          end if;
 541       end Process_One_File;
 542
 543       -----------------------
 544       -- Recursive_Process --
 545       -----------------------
 546
 547       procedure Recursive_Process (In_Dir : String; Out_Dir : String) is
 548          Dir_In : Dir_Type;
 549          Name : String (1 .. 255);
 550          Last : Natural;
 551          In_Dir_Name  : Name_Id;
 552          Out_Dir_Name : Name_Id;
 553
 554          procedure Set_Directory_Names;
 555          --  Establish or reestablish the current input and output directories
 556
 557          -------------------------
 558          -- Set_Directory_Names --
 559          -------------------------
 560
 561          procedure Set_Directory_Names is
 562          begin
 563             Input_Directory := In_Dir_Name;
 564             Output_Directory := Out_Dir_Name;
 565          end Set_Directory_Names;
 566
 567       --  Start of processing for Recursive_Process
 568
 569       begin
 570          --  Open the current input directory
 571
 572          begin
 573             Open (Dir_In, In_Dir);
 574
 575          exception
 576             when Directory_Error =>
 577                Fail ("could not read directory " & In_Dir);
 578          end;
 579
 580          --  Set the new input and output directory names
 581
 582          Name_Len := In_Dir'Length;
 583          Name_Buffer (1 .. Name_Len) := In_Dir;
 584          In_Dir_Name := Name_Find;
 585          Name_Len := Out_Dir'Length;
 586          Name_Buffer (1 .. Name_Len) := Out_Dir;
 587          Out_Dir_Name := Name_Find;
 588
 589          Set_Directory_Names;
 590
 591          --  Traverse the input directory
 592          loop
 593             Read (Dir_In, Name, Last);
 594             exit when Last = 0;
 595
 596             if Name (1 .. Last) /= "." and then Name (1 .. Last) /= ".." then
 597                declare
 598                   Input : constant String :=
 599                             In_Dir & Directory_Separator & Name (1 .. Last);
 600                   Output : constant String :=
 601                              Out_Dir & Directory_Separator & Name (1 .. Last);
 602
 603                begin
 604                   --  If input is an ordinary file, process it
 605
 606                   if Is_Regular_File (Input) then
 607                      --  First get the output file name
 608
 609                      Name_Len := Last;
 610                      Name_Buffer (1 .. Name_Len) := Name (1 .. Last);
 611                      Infile_Name := Name_Find;
 612                      Preprocess_Infile_Name;
 613
 614                      --  Set the input file name and process the file
 615
 616                      Name_Len := Input'Length;
 617                      Name_Buffer (1 .. Name_Len) := Input;
 618                      Infile_Name := Name_Find;
 619                      Process_One_File;
 620
 621                   elsif Is_Directory (Input) then
 622                      --  Input is a directory. If the corresponding output
 623                      --  directory does not already exist, create it.
 624
 625                      if not Is_Directory (Output) then
 626                         begin
 627                            Make_Dir (Dir_Name => Output);
 628
 629                         exception
 630                            when Directory_Error =>
 631                               Fail ("could not create directory """,
 632                                     Output, """");
 633                         end;
 634                      end if;
 635
 636                      --  And process this new input directory
 637
 638                      Recursive_Process (Input, Output);
 639
 640                      --  Reestablish the input and output directory names
 641                      --  that have been modified by the recursive call.
 642
 643                      Set_Directory_Names;
 644                   end if;
 645                end;
 646             end if;
 647          end loop;
 648       end Recursive_Process;
 649
 650    --  Start of processing for Process_Files
 651
 652    begin
 653       if Output_Directory = No_Name then
 654
 655          --  If the output is not a directory, fail if the input is
 656          --  an existing directory, to avoid possible problems.
 657
 658          if Is_Directory (Get_Name_String (Infile_Name)) then
 659             Fail ("input file """ & Get_Name_String (Infile_Name) &
 660                   """ is a directory");
 661          end if;
 662
 663          --  Just process the single input file
 664
 665          Process_One_File;
 666
 667       elsif Input_Directory = No_Name then
 668
 669          --  Get the output file name from the input file name, and process
 670          --  the single input file.
 671
 672          Preprocess_Infile_Name;
 673          Process_One_File;
 674
 675       else
 676          --  Recursively process files in the directory tree rooted at the
 677          --  input directory.
 678
 679          Recursive_Process
 680            (In_Dir => Get_Name_String (Input_Directory),
 681             Out_Dir => Get_Name_String (Output_Directory));
 682       end if;
 683    end Process_Files;
 684
 685    -------------------------
 686    -- Put_Char_To_Outfile --
 687    -------------------------
 688
 689    procedure Put_Char_To_Outfile (C : Character) is
 690    begin
 691       Put (Outfile.all, C);
 692    end Put_Char_To_Outfile;
 693
 694    -----------------------
 695    -- Scan_Command_Line --
 696    -----------------------
 697
 698    procedure Scan_Command_Line is
 699       Switch : Character;
 700
 701    begin
 702       --  Parse the switches
 703
 704       loop
 705          begin
 706             Switch := GNAT.Command_Line.Getopt ("D: b c C r s u v");
 707
 708             case Switch is
 709
 710                when ASCII.NUL =>
 711                   exit;
 712
 713                when 'D' =>
 714                   Process_Command_Line_Symbol_Definition
 715                     (S => GNAT.Command_Line.Parameter);
 716
 717                when 'b' =>
 718                   Opt.Blank_Deleted_Lines := True;
 719
 720                when 'c' =>
 721                   Opt.Comment_Deleted_Lines := True;
 722
 723                when 'C' =>
 724                   Opt.Replace_In_Comments := True;
 725
 726                when 'r' =>
 727                   Source_Ref_Pragma := True;
 728
 729                when 's' =>
 730                   Opt.List_Preprocessing_Symbols := True;
 731
 732                when 'u' =>
 733                   Opt.Undefined_Symbols_Are_False := True;
 734
 735                when 'v' =>
 736                   Opt.Verbose_Mode := True;
 737
 738                when others =>
 739                   Fail ("Invalid Switch: -" & Switch);
 740             end case;
 741
 742          exception
 743             when GNAT.Command_Line.Invalid_Switch =>
 744                Write_Str ("Invalid Switch: -");
 745                Write_Line (GNAT.Command_Line.Full_Switch);
 746                Usage;
 747                OS_Exit (1);
 748          end;
 749       end loop;
 750
 751       --  Get the file names
 752
 753       loop
 754          declare
 755             S : constant String := GNAT.Command_Line.Get_Argument;
 756
 757          begin
 758             exit when S'Length = 0;
 759
 760             Name_Len := S'Length;
 761             Name_Buffer (1 .. Name_Len) := S;
 762
 763             if Infile_Name = No_Name then
 764                Infile_Name := Name_Find;
 765             elsif Outfile_Name = No_Name then
 766                Outfile_Name := Name_Find;
 767             elsif Deffile_Name = No_Name then
 768                Deffile_Name := Name_Find;
 769             else
 770                Fail ("too many arguments specifed");
 771             end if;
 772          end;
 773       end loop;
 774    end Scan_Command_Line;
 775
 776    -----------
 777    -- Usage --
 778    -----------
 779
 780    procedure Usage is
 781    begin
 782       Display_Copyright;
 783       Write_Line ("Usage: gnatprep [-bcrsuv] [-Dsymbol=value] " &
 784                     "infile outfile [deffile]");
 785       Write_Eol;
 786       Write_Line ("  infile     Name of the input file");
 787       Write_Line ("  outfile    Name of the output file");
 788       Write_Line ("  deffile    Name of the definition file");
 789       Write_Eol;
 790       Write_Line ("gnatprep switches:");
 791       Write_Line ("   -b  Replace preprocessor lines by blank lines");
 792       Write_Line ("   -c  Keep preprocessor lines as comments");
 793       Write_Line ("   -C  Do symbol replacements within comments");
 794       Write_Line ("   -D  Associate symbol with value");
 795       Write_Line ("   -r  Generate Source_Reference pragma");
 796       Write_Line ("   -s  Print a sorted list of symbol names and values");
 797       Write_Line ("   -u  Treat undefined symbols as FALSE");
 798       Write_Line ("   -v  Verbose mode");
 799       Write_Eol;
 800    end Usage;
 801
 802 end GPrep;