gcc/ada/sem_case.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             S E M _ C A S E                              --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --         Copyright (C) 1996-2002 Free Software Foundation, Inc.           --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  20 -- MA 02111-1307, USA.                                                      --
  21 --                                                                          --
  22 -- GNAT was originally developed  by the GNAT team at  New York University. --
  23 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  24 --                                                                          --
  25 ------------------------------------------------------------------------------
  26
  27 with Types; use Types;
  28
  29 --  Package containing the routines to process a list of discrete choices.
  30 --  Such lists can occur in two different constructs: case statements and
  31 --  record variants. We have factorized what used to be two very similar
  32 --  sets of routines in one place. These are not currently used for the
  33 --  aggregate case, since issues with nested aggregates make that case
  34 --  substantially different.
  35
  36 package Sem_Case is
  37
  38    type Choice_Bounds is record
  39      Lo   : Node_Id;
  40      Hi   : Node_Id;
  41      Node : Node_Id;
  42    end record;
  43
  44    type Choice_Table_Type is array (Pos range <>) of Choice_Bounds;
  45    --  Table type used to sort the choices present in a case statement,
  46    --  array aggregate or record variant.
  47
  48    procedure No_OP (C : Node_Id);
  49    --  The no-operation routine. Does absolutely nothing. Can be used
  50    --  in the following generic for the parameter Proces_Empty_Choice.
  51
  52    generic
  53       with function Get_Alternatives (N : Node_Id) return List_Id;
  54       --  Function needed to get to the actual list of case statement
  55       --  alternatives, or array aggregate component associations or
  56       --  record variants from which we can then access the actual lists
  57       --  of discrete choices. N is the node for the original construct
  58       --  ie a case statement, an array aggregate or a record variant.
  59
  60       with function Get_Choices (A : Node_Id) return List_Id;
  61       --  Given a case statement alternative, array aggregate component
  62       --  association or record variant A we need different access functions
  63       --  to get to the actual list of discrete choices.
  64
  65       with procedure Process_Empty_Choice (Choice : Node_Id);
  66       --  Processing to carry out for an empty Choice.
  67
  68       with procedure Process_Non_Static_Choice (Choice : Node_Id);
  69       --  Processing to carry out for a non static Choice.
  70
  71       with procedure Process_Associated_Node (A : Node_Id);
  72       --  Associated to each case alternative, aggregate component
  73       --  association or record variant A there is a node or list of nodes
  74       --  that need semantic processing. This routine implements that
  75       --  processing.
  76
  77    package Generic_Choices_Processing is
  78
  79       function Number_Of_Choices (N : Node_Id) return Nat;
  80       --  Iterates through the choices of N, (N can be a case statement,
  81       --  array aggregate or record variant), counting all the Choice nodes
  82       --  except for the Others choice.
  83
  84       procedure Analyze_Choices
  85         (N              : Node_Id;
  86          Subtyp         : Entity_Id;
  87          Choice_Table   : out Choice_Table_Type;
  88          Last_Choice    : out Nat;
  89          Raises_CE      : out Boolean;
  90          Others_Present : out Boolean);
  91       --  From a case statement, array aggregate or record variant N, this
  92       --  routine analyzes the corresponding list of discrete choices.
  93       --  Subtyp is the subtype of the discrete choices. The type against
  94       --  which the discrete choices must be resolved is its base type.
  95       --
  96       --  On entry Choice_Table must be big enough to contain all the
  97       --  discrete choices encountered.
  98       --
  99       --  On exit Choice_Table contains all the static and non empty
 100       --  discrete choices in sorted order. Last_Choice gives the position
 101       --  of the last valid choice in Choice_Table, Choice_Table'First
 102       --  contains the first. We can have Last_Choice < Choice_Table'Last
 103       --  for one (or several) of the following reasons:
 104       --
 105       --    (a) The list of choices contained a non static choice
 106       --
 107       --    (b) The list of choices contained an empty choice
 108       --        (something like "1 .. 0 => ")
 109       --
 110       --    (c) One of the bounds of a discrete choice contains an
 111       --        error or raises constraint error.
 112       --
 113       --  In one of the bounds of a discrete choice raises a constraint
 114       --  error the flag Raise_CE is set.
 115       --
 116       --  Finally Others_Present is set to True if an Others choice is
 117       --  present in the list of choices, and in this case the call also
 118       --  sets Others_Discrete_Choices in the N_Others_Choice node.
 119
 120    end Generic_Choices_Processing;
 121
 122 end Sem_Case;