gcc/ada/a-nudira.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUNTIME COMPONENTS                          --
   4 --                                                                          --
   5 --         A D A . N U M E R I C S . D I S C R E T E _ R A N D O M          --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2003 Free Software Foundation, Inc.          --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  20 -- MA 02111-1307, USA.                                                      --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 with Ada.Calendar;
  35 with Interfaces; use Interfaces;
  36
  37 package body Ada.Numerics.Discrete_Random is
  38
  39    -------------------------
  40    -- Implementation Note --
  41    -------------------------
  42
  43    --  The design of this spec is very awkward, as a result of Ada 95 not
  44    --  permitting in-out parameters for function formals (most naturally
  45    --  Generator values would be passed this way). In pure Ada 95, the only
  46    --  solution is to use the heap and pointers, and, to avoid memory leaks,
  47    --  controlled types.
  48
  49    --  This is awfully heavy, so what we do is to use Unrestricted_Access to
  50    --  get a pointer to the state in the passed Generator. This works because
  51    --  Generator is a limited type and will thus always be passed by reference.
  52
  53    type Pointer is access all State;
  54
  55    Need_64 : constant Boolean := Rst'Pos (Rst'Last) > Int'Last;
  56    --  Set if we need more than 32 bits in the result. In practice we will
  57    --  only use the meaningful 48 bits of any 64 bit number generated, since
  58    --  if more than 48 bits are required, we split the computation into two
  59    --  separate parts, since the algorithm does not behave above 48 bits.
  60
  61    -----------------------
  62    -- Local Subprograms --
  63    -----------------------
  64
  65    function Square_Mod_N (X, N : Int) return Int;
  66    pragma Inline (Square_Mod_N);
  67    --  Computes X**2 mod N avoiding intermediate overflow
  68
  69    -----------
  70    -- Image --
  71    -----------
  72
  73    function Image (Of_State : State) return String is
  74    begin
  75       return Int'Image (Of_State.X1) &
  76              ','                            &
  77              Int'Image (Of_State.X2) &
  78              ','                            &
  79              Int'Image (Of_State.Q);
  80    end Image;
  81
  82    ------------
  83    -- Random --
  84    ------------
  85
  86    function Random (Gen : Generator) return Rst is
  87       Genp : constant Pointer := Gen.Gen_State'Unrestricted_Access;
  88       Temp : Int;
  89       TF   : Flt;
  90
  91    begin
  92       --  Check for flat range here, since we are typically run with checks
  93       --  off, note that in practice, this condition will usually be static
  94       --  so we will not actually generate any code for the normal case.
  95
  96       if Rst'Last < Rst'First then
  97          raise Constraint_Error;
  98       end if;
  99
 100       --  Continue with computation if non-flat range
 101
 102       Genp.X1 := Square_Mod_N (Genp.X1, Genp.P);
 103       Genp.X2 := Square_Mod_N (Genp.X2, Genp.Q);
 104       Temp := Genp.X2 - Genp.X1;
 105
 106       --  Following duplication is not an error, it is a loop unwinding!
 107
 108       if Temp < 0 then
 109          Temp := Temp + Genp.Q;
 110       end if;
 111
 112       if Temp < 0 then
 113          Temp := Temp + Genp.Q;
 114       end if;
 115
 116       TF := Offs + (Flt (Temp) * Flt (Genp.P) + Flt (Genp.X1)) * Genp.Scl;
 117
 118       --  Pathological, but there do exist cases where the rounding implicit
 119       --  in calculating the scale factor will cause rounding to 'Last + 1.
 120       --  In those cases, returning 'First results in the least bias.
 121
 122       if TF >= Flt (Rst'Pos (Rst'Last)) + 0.5 then
 123          return Rst'First;
 124
 125       elsif Need_64 then
 126          return Rst'Val (Interfaces.Integer_64 (TF));
 127
 128       else
 129          return Rst'Val (Int (TF));
 130       end if;
 131    end Random;
 132
 133    -----------
 134    -- Reset --
 135    -----------
 136
 137    procedure Reset (Gen : Generator; Initiator : Integer) is
 138       Genp   : constant Pointer := Gen.Gen_State'Unrestricted_Access;
 139       X1, X2 : Int;
 140
 141    begin
 142       X1 := 2 + Int (Initiator) mod (K1 - 3);
 143       X2 := 2 + Int (Initiator) mod (K2 - 3);
 144
 145       for J in 1 .. 5 loop
 146          X1 := Square_Mod_N (X1, K1);
 147          X2 := Square_Mod_N (X2, K2);
 148       end loop;
 149
 150       --  Eliminate effects of small Initiators
 151
 152       Genp.all :=
 153         (X1  => X1,
 154          X2  => X2,
 155          P   => K1,
 156          Q   => K2,
 157          FP  => K1F,
 158          Scl => Scal);
 159    end Reset;
 160
 161    -----------
 162    -- Reset --
 163    -----------
 164
 165    procedure Reset (Gen : Generator) is
 166       Genp : constant Pointer       := Gen.Gen_State'Unrestricted_Access;
 167       Now  : constant Calendar.Time := Calendar.Clock;
 168       X1   : Int;
 169       X2   : Int;
 170
 171    begin
 172       X1 := Int (Calendar.Year    (Now)) * 12 * 31 +
 173             Int (Calendar.Month   (Now) * 31)     +
 174             Int (Calendar.Day     (Now));
 175
 176       X2 := Int (Calendar.Seconds (Now) * Duration (1000.0));
 177
 178       X1 := 2 + X1 mod (K1 - 3);
 179       X2 := 2 + X2 mod (K2 - 3);
 180
 181       --  Eliminate visible effects of same day starts
 182
 183       for J in 1 .. 5 loop
 184          X1 := Square_Mod_N (X1, K1);
 185          X2 := Square_Mod_N (X2, K2);
 186       end loop;
 187
 188       Genp.all :=
 189         (X1  => X1,
 190          X2  => X2,
 191          P   => K1,
 192          Q   => K2,
 193          FP  => K1F,
 194          Scl => Scal);
 195
 196    end Reset;
 197
 198    -----------
 199    -- Reset --
 200    -----------
 201
 202    procedure Reset (Gen : Generator; From_State : State) is
 203       Genp : constant Pointer := Gen.Gen_State'Unrestricted_Access;
 204
 205    begin
 206       Genp.all := From_State;
 207    end Reset;
 208
 209    ----------
 210    -- Save --
 211    ----------
 212
 213    procedure Save (Gen : Generator; To_State : out State) is
 214    begin
 215       To_State := Gen.Gen_State;
 216    end Save;
 217
 218    ------------------
 219    -- Square_Mod_N --
 220    ------------------
 221
 222    function Square_Mod_N (X, N : Int) return Int is
 223    begin
 224       return Int ((Integer_64 (X) ** 2) mod (Integer_64 (N)));
 225    end Square_Mod_N;
 226
 227    -----------
 228    -- Value --
 229    -----------
 230
 231    function Value (Coded_State : String) return State is
 232       Start : Positive := Coded_State'First;
 233       Stop  : Positive := Coded_State'First;
 234       Outs  : State;
 235
 236    begin
 237       while Coded_State (Stop) /= ',' loop
 238          Stop := Stop + 1;
 239       end loop;
 240
 241       Outs.X1 := Int'Value (Coded_State (Start .. Stop - 1));
 242       Start := Stop + 1;
 243
 244       loop
 245          Stop := Stop + 1;
 246          exit when Coded_State (Stop) = ',';
 247       end loop;
 248
 249       Outs.X2  := Int'Value (Coded_State (Start .. Stop - 1));
 250       Outs.Q   := Int'Value (Coded_State (Stop + 1 .. Coded_State'Last));
 251       Outs.P   := Outs.Q * 2 + 1;
 252       Outs.FP  := Flt (Outs.P);
 253       Outs.Scl := (RstL - RstF + 1.0) / (Flt (Outs.P) * Flt (Outs.Q));
 254
 255       --  Now do *some* sanity checks.
 256
 257       if Outs.Q < 31
 258         or else Outs.X1 not in 2 .. Outs.P - 1
 259         or else Outs.X2 not in 2 .. Outs.Q - 1
 260       then
 261          raise Constraint_Error;
 262       end if;
 263
 264       return Outs;
 265    end Value;
 266
 267 end Ada.Numerics.Discrete_Random;