| blob | b9aa5c746e56c00020f89c9e9db7fd7486efe6dd |
1 dnl
2 dnl GLIBCXX_CONDITIONAL (NAME, SHELL-TEST)
3 dnl
4 dnl Exactly like AM_CONDITIONAL, but delays evaluation of the test until the
5 dnl end of configure. This lets tested variables be reassigned, and the
6 dnl conditional will depend on the final state of the variable. For a simple
7 dnl example of why this is needed, see GLIBCXX_ENABLE_HOSTED.
8 dnl
9 m4_define([_m4_divert(glibcxx_diversion)], 8000)dnl
10 AC_DEFUN([GLIBCXX_CONDITIONAL], [dnl
11 m4_divert_text([glibcxx_diversion],dnl
12 AM_CONDITIONAL([$1],[$2])
13 )dnl
14 ])dnl
15 AC_DEFUN([GLIBCXX_EVALUATE_CONDITIONALS], [m4_undivert([glibcxx_diversion])])dnl
18 dnl
19 dnl Check to see what architecture and operating system we are compiling
20 dnl for. Also, if architecture- or OS-specific flags are required for
21 dnl compilation, pick them up here.
22 dnl
23 AC_DEFUN([GLIBCXX_CHECK_HOST], [
24 . $glibcxx_srcdir/configure.host
25 AC_MSG_NOTICE([CPU config directory is $cpu_include_dir])
26 AC_MSG_NOTICE([OS config directory is $os_include_dir])
27 ])
29 dnl
30 dnl Initialize the rest of the library configury. At this point we have
31 dnl variables like $host.
32 dnl
33 dnl Sets:
34 dnl SUBDIRS
35 dnl Substs:
36 dnl glibcxx_builddir (absolute path)
37 dnl glibcxx_srcdir (absolute path)
38 dnl toplevel_builddir (absolute path)
39 dnl toplevel_srcdir (absolute path)
40 dnl with_cross_host
41 dnl with_newlib
42 dnl with_target_subdir
43 dnl plus
44 dnl - the variables in GLIBCXX_CHECK_HOST / configure.host
45 dnl - default settings for all AM_CONFITIONAL test variables
46 dnl - lots of tools, like CC and CXX
47 dnl
48 AC_DEFUN([GLIBCXX_CONFIGURE], [
49 # Keep these sync'd with the list in Makefile.am. The first provides an
50 # expandable list at autoconf time; the second provides an expandable list
51 # (i.e., shell variable) at configure time.
52 m4_define([glibcxx_SUBDIRS],[include libsupc++ python src src/c++98 src/c++11 doc po testsuite])
53 SUBDIRS='glibcxx_SUBDIRS'
55 # These need to be absolute paths, yet at the same time need to
56 # canonicalize only relative paths, because then amd will not unmount
57 # drives. Thus the use of PWDCMD: set it to 'pawd' or 'amq -w' if using amd.
58 glibcxx_builddir=`${PWDCMD-pwd}`
59 case $srcdir in
60 [\\/$]* | ?:[\\/]*) glibcxx_srcdir=${srcdir} ;;
61 *) glibcxx_srcdir=`cd "$srcdir" && ${PWDCMD-pwd} || echo "$srcdir"` ;;
62 esac
63 toplevel_builddir=${glibcxx_builddir}/..
64 toplevel_srcdir=${glibcxx_srcdir}/..
65 AC_SUBST(glibcxx_builddir)
66 AC_SUBST(glibcxx_srcdir)
67 AC_SUBST(toplevel_builddir)
68 AC_SUBST(toplevel_srcdir)
70 # We use these options to decide which functions to include. They are
71 # set from the top level.
72 AC_ARG_WITH([target-subdir],
73 AC_HELP_STRING([--with-target-subdir=SUBDIR],
74 [configuring in a subdirectory]))
76 AC_ARG_WITH([cross-host],
77 AC_HELP_STRING([--with-cross-host=HOST],
78 [configuring with a cross compiler]))
80 AC_ARG_WITH([newlib],
81 AC_HELP_STRING([--with-newlib],
82 [assume newlib as a system C library]))
84 # Will set LN_S to either 'ln -s', 'ln', or 'cp -p' (if linking isn't
85 # available). Uncomment the next line to force a particular method.
86 AC_PROG_LN_S
87 #LN_S='cp -p'
89 AC_CHECK_TOOL(AS, as)
90 AC_CHECK_TOOL(AR, ar)
91 AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
93 AM_MAINTAINER_MODE
95 # Set up safe default values for all subsequent AM_CONDITIONAL tests
96 # which are themselves conditionally expanded.
97 ## (Right now, this only matters for enable_wchar_t, but nothing prevents
98 ## other macros from doing the same. This should be automated.) -pme
100 # Check for C library flavor since GNU/Linux platforms use different
101 # configuration directories depending on the C library in use.
102 AC_EGREP_CPP([_using_uclibc], [
103 #include <stdio.h>
104 #if __UCLIBC__
105 _using_uclibc
106 #endif
107 ], uclibc=yes, uclibc=no)
109 AC_EGREP_CPP([_using_bionic], [
110 #include <stdio.h>
111 #if __BIONIC__
112 _using_bionic
113 #endif
114 ], bionic=yes, bionic=no)
116 # Find platform-specific directories containing configuration info.
117 # Also possibly modify flags used elsewhere, as needed by the platform.
118 GLIBCXX_CHECK_HOST
119 ])
122 dnl
123 dnl Tests for newer compiler features, or features that are present in newer
124 dnl compiler versions but not older compiler versions still in use, should
125 dnl be placed here.
126 dnl
127 dnl Defines:
128 dnl WERROR='-Werror' if requested and possible; g++'s that lack the
129 dnl new inlining code or the new system_header pragma will die on -Werror.
130 dnl Leave it out by default and use maint-mode to use it.
131 dnl SECTION_FLAGS='-ffunction-sections -fdata-sections' if
132 dnl compiler supports it and the user has not requested debug mode.
133 dnl
134 AC_DEFUN([GLIBCXX_CHECK_COMPILER_FEATURES], [
135 # All these tests are for C++; save the language and the compiler flags.
136 # The CXXFLAGS thing is suspicious, but based on similar bits previously
137 # found in GLIBCXX_CONFIGURE.
138 AC_LANG_SAVE
139 AC_LANG_CPLUSPLUS
140 ac_test_CXXFLAGS="${CXXFLAGS+set}"
141 ac_save_CXXFLAGS="$CXXFLAGS"
143 # Check for maintainer-mode bits.
144 if test x"$USE_MAINTAINER_MODE" = xno; then
145 WERROR=''
146 else
147 WERROR='-Werror'
148 fi
150 # Check for -ffunction-sections -fdata-sections
151 AC_MSG_CHECKING([for g++ that supports -ffunction-sections -fdata-sections])
152 CXXFLAGS='-g -Werror -ffunction-sections -fdata-sections'
153 AC_TRY_COMPILE([int foo; void bar() { };],, [ac_fdsections=yes], [ac_fdsections=no])
154 if test "$ac_test_CXXFLAGS" = set; then
155 CXXFLAGS="$ac_save_CXXFLAGS"
156 else
157 # this is the suspicious part
158 CXXFLAGS=''
159 fi
160 if test x"$ac_fdsections" = x"yes"; then
161 SECTION_FLAGS='-ffunction-sections -fdata-sections'
162 fi
163 AC_MSG_RESULT($ac_fdsections)
165 AC_LANG_RESTORE
166 AC_SUBST(WERROR)
167 AC_SUBST(SECTION_FLAGS)
168 ])
171 dnl
172 dnl Check if the assembler used supports disabling generation of hardware
173 dnl capabilities. This is only supported by Sun as at the moment.
174 dnl
175 dnl Defines:
176 dnl HWCAP_FLAGS='-Wa,-nH' if possible.
177 dnl
178 AC_DEFUN([GLIBCXX_CHECK_ASSEMBLER_HWCAP], [
179 test -z "$HWCAP_FLAGS" && HWCAP_FLAGS=''
181 ac_save_CFLAGS="$CFLAGS"
182 CFLAGS="$CFLAGS -Wa,-nH"
184 AC_MSG_CHECKING([for as that supports -Wa,-nH])
185 AC_TRY_COMPILE([], [return 0;], [ac_hwcap_flags=yes],[ac_hwcap_flags=no])
186 if test "$ac_hwcap_flags" = "yes"; then
187 HWCAP_FLAGS="-Wa,-nH $HWCAP_FLAGS"
188 fi
189 AC_MSG_RESULT($ac_hwcap_flags)
191 CFLAGS="$ac_save_CFLAGS"
193 AC_SUBST(HWCAP_FLAGS)
194 ])
197 dnl
198 dnl If GNU ld is in use, check to see if tricky linker opts can be used. If
199 dnl the native linker is in use, all variables will be defined to something
200 dnl safe (like an empty string).
201 dnl
202 dnl Defines:
203 dnl SECTION_LDFLAGS='-Wl,--gc-sections' if possible
204 dnl OPT_LDFLAGS='-Wl,-O1' and '-z,relro' if possible
205 dnl LD (as a side effect of testing)
206 dnl Sets:
207 dnl with_gnu_ld
208 dnl glibcxx_ld_is_gold (set to "no" or "yes")
209 dnl glibcxx_gnu_ld_version (possibly)
210 dnl
211 dnl The last will be a single integer, e.g., version 1.23.45.0.67.89 will
212 dnl set glibcxx_gnu_ld_version to 12345. Zeros cause problems.
213 dnl
214 AC_DEFUN([GLIBCXX_CHECK_LINKER_FEATURES], [
215 # If we're not using GNU ld, then there's no point in even trying these
216 # tests. Check for that first. We should have already tested for gld
217 # by now (in libtool), but require it now just to be safe...
218 test -z "$SECTION_LDFLAGS" && SECTION_LDFLAGS=''
219 test -z "$OPT_LDFLAGS" && OPT_LDFLAGS=''
220 AC_REQUIRE([AC_PROG_LD])
221 AC_REQUIRE([AC_PROG_AWK])
223 # The name set by libtool depends on the version of libtool. Shame on us
224 # for depending on an impl detail, but c'est la vie. Older versions used
225 # ac_cv_prog_gnu_ld, but now it's lt_cv_prog_gnu_ld, and is copied back on
226 # top of with_gnu_ld (which is also set by --with-gnu-ld, so that actually
227 # makes sense). We'll test with_gnu_ld everywhere else, so if that isn't
228 # set (hence we're using an older libtool), then set it.
229 if test x${with_gnu_ld+set} != xset; then
230 if test x${ac_cv_prog_gnu_ld+set} != xset; then
231 # We got through "ac_require(ac_prog_ld)" and still not set? Huh?
232 with_gnu_ld=no
233 else
234 with_gnu_ld=$ac_cv_prog_gnu_ld
235 fi
236 fi
238 # Start by getting the version number. I think the libtool test already
239 # does some of this, but throws away the result.
240 glibcxx_ld_is_gold=no
241 if test x"$with_gnu_ld" = x"yes"; then
242 AC_MSG_CHECKING([for ld version])
243 changequote(,)
244 if $LD --version 2>/dev/null | grep 'GNU gold' >/dev/null 2>&1; then
245 glibcxx_ld_is_gold=yes
246 fi
247 ldver=`$LD --version 2>/dev/null |
248 sed -e 's/GNU gold /GNU ld /;s/GNU ld version /GNU ld /;s/GNU ld ([^)]*) /GNU ld /;s/GNU ld \([0-9.][0-9.]*\).*/\1/; q'`
249 changequote([,])
250 glibcxx_gnu_ld_version=`echo $ldver | \
251 $AWK -F. '{ if (NF<3) [$]3=0; print ([$]1*100+[$]2)*100+[$]3 }'`
252 AC_MSG_RESULT($glibcxx_gnu_ld_version)
253 fi
255 # Set --gc-sections.
256 glibcxx_have_gc_sections=no
257 if test "$glibcxx_ld_is_gold" = "yes"; then
258 if $LD --help 2>/dev/null | grep gc-sections >/dev/null 2>&1; then
259 glibcxx_have_gc_sections=yes
260 fi
261 else
262 glibcxx_gcsections_min_ld=21602
263 if test x"$with_gnu_ld" = x"yes" &&
264 test $glibcxx_gnu_ld_version -gt $glibcxx_gcsections_min_ld ; then
265 glibcxx_have_gc_sections=yes
266 fi
267 fi
268 if test "$glibcxx_have_gc_sections" = "yes"; then
269 # Sufficiently young GNU ld it is! Joy and bunny rabbits!
270 # NB: This flag only works reliably after 2.16.1. Configure tests
271 # for this are difficult, so hard wire a value that should work.
273 ac_test_CFLAGS="${CFLAGS+set}"
274 ac_save_CFLAGS="$CFLAGS"
275 CFLAGS='-Wl,--gc-sections'
277 # Check for -Wl,--gc-sections
278 AC_MSG_CHECKING([for ld that supports -Wl,--gc-sections])
279 AC_TRY_LINK([ int one(void) { return 1; }
280 int two(void) { return 2; }
281 ], [ two(); ] , [ac_gcsections=yes], [ac_gcsections=no])
282 if test "$ac_gcsections" = "yes"; then
283 rm -f conftest.c
284 touch conftest.c
285 if $CC -c conftest.c; then
286 if $LD --gc-sections -o conftest conftest.o 2>&1 | \
287 grep "Warning: gc-sections option ignored" > /dev/null; then
288 ac_gcsections=no
289 fi
290 fi
291 rm -f conftest.c conftest.o conftest
292 fi
293 if test "$ac_gcsections" = "yes"; then
294 SECTION_LDFLAGS="-Wl,--gc-sections $SECTION_LDFLAGS"
295 fi
296 AC_MSG_RESULT($ac_gcsections)
298 if test "$ac_test_CFLAGS" = set; then
299 CFLAGS="$ac_save_CFLAGS"
300 else
301 # this is the suspicious part
302 CFLAGS=''
303 fi
304 fi
306 # Set -z,relro.
307 # Note this is only for shared objects.
308 ac_ld_relro=no
309 if test x"$with_gnu_ld" = x"yes"; then
310 AC_MSG_CHECKING([for ld that supports -Wl,-z,relro])
311 cxx_z_relo=`$LD -v --help 2>/dev/null | grep "z relro"`
312 if test -n "$cxx_z_relo"; then
313 OPT_LDFLAGS="-Wl,-z,relro"
314 ac_ld_relro=yes
315 fi
316 AC_MSG_RESULT($ac_ld_relro)
317 fi
319 # Set linker optimization flags.
320 if test x"$with_gnu_ld" = x"yes"; then
321 OPT_LDFLAGS="-Wl,-O1 $OPT_LDFLAGS"
322 fi
324 AC_SUBST(SECTION_LDFLAGS)
325 AC_SUBST(OPT_LDFLAGS)
326 ])
329 dnl
330 dnl Check for headers for, and arguments to, the setrlimit() function.
331 dnl Used only in testsuite_hooks.h. Called from GLIBCXX_CONFIGURE_TESTSUITE.
332 dnl
333 dnl Defines:
334 dnl _GLIBCXX_RES_LIMITS if we can set artificial resource limits
335 dnl various HAVE_LIMIT_* for individual limit names
336 dnl
337 AC_DEFUN([GLIBCXX_CHECK_SETRLIMIT_ancilliary], [
338 AC_MSG_CHECKING([for RLIMIT_$1])
339 AC_TRY_COMPILE(
340 [#include <unistd.h>
341 #include <sys/time.h>
342 #include <sys/resource.h>
343 ],
344 [ int f = RLIMIT_$1 ; ],
345 [glibcxx_mresult=1], [glibcxx_mresult=0])
346 AC_DEFINE_UNQUOTED(HAVE_LIMIT_$1, $glibcxx_mresult,
347 [Only used in build directory testsuite_hooks.h.])
348 if test $glibcxx_mresult = 1 ; then res=yes ; else res=no ; fi
349 AC_MSG_RESULT($res)
350 ])
352 AC_DEFUN([GLIBCXX_CHECK_SETRLIMIT], [
353 setrlimit_have_headers=yes
354 AC_CHECK_HEADERS(unistd.h sys/time.h sys/resource.h,
355 [],
356 [setrlimit_have_headers=no])
357 # If don't have the headers, then we can't run the tests now, and we
358 # won't be seeing any of these during testsuite compilation.
359 if test $setrlimit_have_headers = yes; then
360 # Can't do these in a loop, else the resulting syntax is wrong.
361 GLIBCXX_CHECK_SETRLIMIT_ancilliary(DATA)
362 GLIBCXX_CHECK_SETRLIMIT_ancilliary(RSS)
363 GLIBCXX_CHECK_SETRLIMIT_ancilliary(VMEM)
364 GLIBCXX_CHECK_SETRLIMIT_ancilliary(AS)
365 GLIBCXX_CHECK_SETRLIMIT_ancilliary(FSIZE)
367 # Check for rlimit, setrlimit.
368 AC_CACHE_VAL(glibcxx_cv_setrlimit, [
369 AC_TRY_COMPILE(
370 [#include <unistd.h>
371 #include <sys/time.h>
372 #include <sys/resource.h>
373 ],
374 [struct rlimit r;
375 setrlimit(0, &r);],
376 [glibcxx_cv_setrlimit=yes], [glibcxx_cv_setrlimit=no])
377 ])
378 fi
380 AC_MSG_CHECKING([for testsuite resource limits support])
381 if test $setrlimit_have_headers = yes && test $glibcxx_cv_setrlimit = yes; then
382 ac_res_limits=yes
383 AC_DEFINE(_GLIBCXX_RES_LIMITS, 1,
384 [Define if using setrlimit to set resource limits during
385 "make check"])
386 else
387 ac_res_limits=no
388 fi
389 AC_MSG_RESULT($ac_res_limits)
390 ])
393 dnl
394 dnl Check whether S_ISREG (Posix) or S_IFREG is available in <sys/stat.h>.
395 dnl Define HAVE_S_ISREG / HAVE_S_IFREG appropriately.
396 dnl
397 AC_DEFUN([GLIBCXX_CHECK_S_ISREG_OR_S_IFREG], [
399 AC_LANG_SAVE
400 AC_LANG_CPLUSPLUS
401 ac_save_CXXFLAGS="$CXXFLAGS"
402 CXXFLAGS="$CXXFLAGS -fno-exceptions"
404 AC_MSG_CHECKING([for S_ISREG or S_IFREG])
405 AC_CACHE_VAL(glibcxx_cv_S_ISREG, [
406 GCC_TRY_COMPILE_OR_LINK(
407 [#include <sys/stat.h>],
408 [struct stat buffer;
409 fstat(0, &buffer);
410 S_ISREG(buffer.st_mode);],
411 [glibcxx_cv_S_ISREG=yes],
412 [glibcxx_cv_S_ISREG=no])
413 ])
414 AC_CACHE_VAL(glibcxx_cv_S_IFREG, [
415 GCC_TRY_COMPILE_OR_LINK(
416 [#include <sys/stat.h>],
417 [struct stat buffer;
418 fstat(0, &buffer);
419 S_IFREG & buffer.st_mode;],
420 [glibcxx_cv_S_IFREG=yes],
421 [glibcxx_cv_S_IFREG=no])
422 ])
423 res=no
424 if test $glibcxx_cv_S_ISREG = yes; then
425 AC_DEFINE(HAVE_S_ISREG, 1,
426 [Define if S_IFREG is available in <sys/stat.h>.])
427 res=S_ISREG
428 elif test $glibcxx_cv_S_IFREG = yes; then
429 AC_DEFINE(HAVE_S_IFREG, 1,
430 [Define if S_IFREG is available in <sys/stat.h>.])
431 res=S_IFREG
432 fi
433 AC_MSG_RESULT($res)
435 CXXFLAGS="$ac_save_CXXFLAGS"
436 AC_LANG_RESTORE
437 ])
440 dnl
441 dnl Check whether poll is available in <poll.h>, and define HAVE_POLL.
442 dnl
443 AC_DEFUN([GLIBCXX_CHECK_POLL], [
445 AC_LANG_SAVE
446 AC_LANG_CPLUSPLUS
447 ac_save_CXXFLAGS="$CXXFLAGS"
448 CXXFLAGS="$CXXFLAGS -fno-exceptions"
450 AC_MSG_CHECKING([for poll])
451 AC_CACHE_VAL(glibcxx_cv_POLL, [
452 GCC_TRY_COMPILE_OR_LINK(
453 [#include <poll.h>],
454 [struct pollfd pfd[1];
455 pfd[0].events = POLLIN;
456 poll(pfd, 1, 0);],
457 [glibcxx_cv_POLL=yes],
458 [glibcxx_cv_POLL=no])
459 ])
460 if test $glibcxx_cv_POLL = yes; then
461 AC_DEFINE(HAVE_POLL, 1, [Define if poll is available in <poll.h>.])
462 fi
463 AC_MSG_RESULT($glibcxx_cv_POLL)
465 CXXFLAGS="$ac_save_CXXFLAGS"
466 AC_LANG_RESTORE
467 ])
470 dnl
471 dnl Check whether writev is available in <sys/uio.h>, and define HAVE_WRITEV.
472 dnl
473 AC_DEFUN([GLIBCXX_CHECK_WRITEV], [
475 AC_LANG_SAVE
476 AC_LANG_CPLUSPLUS
477 ac_save_CXXFLAGS="$CXXFLAGS"
478 CXXFLAGS="$CXXFLAGS -fno-exceptions"
480 AC_MSG_CHECKING([for writev])
481 AC_CACHE_VAL(glibcxx_cv_WRITEV, [
482 GCC_TRY_COMPILE_OR_LINK(
483 [#include <sys/uio.h>],
484 [struct iovec iov[2];
485 writev(0, iov, 0);],
486 [glibcxx_cv_WRITEV=yes],
487 [glibcxx_cv_WRITEV=no])
488 ])
489 if test $glibcxx_cv_WRITEV = yes; then
490 AC_DEFINE(HAVE_WRITEV, 1, [Define if writev is available in <sys/uio.h>.])
491 fi
492 AC_MSG_RESULT($glibcxx_cv_WRITEV)
494 CXXFLAGS="$ac_save_CXXFLAGS"
495 AC_LANG_RESTORE
496 ])
499 dnl
500 dnl Check whether int64_t is available in <stdint.h>, and define HAVE_INT64_T.
501 dnl Also check whether int64_t is actually a typedef to long or long long.
502 dnl
503 AC_DEFUN([GLIBCXX_CHECK_INT64_T], [
505 AC_LANG_SAVE
506 AC_LANG_CPLUSPLUS
508 AC_MSG_CHECKING([for int64_t])
509 AC_CACHE_VAL(glibcxx_cv_INT64_T, [
510 AC_TRY_COMPILE(
511 [#include <stdint.h>],
512 [int64_t var;],
513 [glibcxx_cv_INT64_T=yes],
514 [glibcxx_cv_INT64_T=no])
515 ])
517 if test $glibcxx_cv_INT64_T = yes; then
518 AC_DEFINE(HAVE_INT64_T, 1, [Define if int64_t is available in <stdint.h>.])
519 AC_MSG_RESULT($glibcxx_cv_INT64_T)
521 AC_MSG_CHECKING([for int64_t as long])
522 AC_CACHE_VAL(glibcxx_cv_int64_t_long, [
523 AC_TRY_COMPILE(
524 [#include <stdint.h>
525 template<typename, typename> struct same { enum { value = -1 }; };
526 template<typename Tp> struct same<Tp, Tp> { enum { value = 1 }; };
527 int array[same<int64_t, long>::value];], [],
528 [glibcxx_cv_int64_t_long=yes], [glibcxx_cv_int64_t_long=no])
529 ])
531 if test $glibcxx_cv_int64_t_long = yes; then
532 AC_DEFINE(HAVE_INT64_T_LONG, 1, [Define if int64_t is a long.])
533 AC_MSG_RESULT($glibcxx_cv_int64_t_long)
534 fi
536 AC_MSG_CHECKING([for int64_t as long long])
537 AC_CACHE_VAL(glibcxx_cv_int64_t_long_long, [
538 AC_TRY_COMPILE(
539 [#include <stdint.h>
540 template<typename, typename> struct same { enum { value = -1 }; };
541 template<typename Tp> struct same<Tp, Tp> { enum { value = 1 }; };
542 int array[same<int64_t, long long>::value];], [],
543 [glibcxx_cv_int64_t_long_long=yes], [glibcxx_cv_int64_t_long_long=no])
544 ])
546 if test $glibcxx_cv_int64_t_long_long = yes; then
547 AC_DEFINE(HAVE_INT64_T_LONG_LONG, 1, [Define if int64_t is a long long.])
548 AC_MSG_RESULT($glibcxx_cv_int64_t_long_long)
549 fi
550 fi
552 AC_LANG_RESTORE
553 ])
556 dnl
557 dnl Check whether LFS support is available.
558 dnl
559 AC_DEFUN([GLIBCXX_CHECK_LFS], [
560 AC_LANG_SAVE
561 AC_LANG_CPLUSPLUS
562 ac_save_CXXFLAGS="$CXXFLAGS"
563 CXXFLAGS="$CXXFLAGS -fno-exceptions"
564 AC_MSG_CHECKING([for LFS support])
565 AC_CACHE_VAL(glibcxx_cv_LFS, [
566 GCC_TRY_COMPILE_OR_LINK(
567 [#include <unistd.h>
568 #include <stdio.h>
569 #include <sys/stat.h>
570 ],
571 [FILE* fp;
572 fopen64("t", "w");
573 fseeko64(fp, 0, SEEK_CUR);
574 ftello64(fp);
575 lseek64(1, 0, SEEK_CUR);
576 struct stat64 buf;
577 fstat64(1, &buf);],
578 [glibcxx_cv_LFS=yes],
579 [glibcxx_cv_LFS=no])
580 ])
581 if test $glibcxx_cv_LFS = yes; then
582 AC_DEFINE(_GLIBCXX_USE_LFS, 1, [Define if LFS support is available.])
583 fi
584 AC_MSG_RESULT($glibcxx_cv_LFS)
585 CXXFLAGS="$ac_save_CXXFLAGS"
586 AC_LANG_RESTORE
587 ])
590 dnl
591 dnl Check for whether a fully dynamic basic_string implementation should
592 dnl be turned on, that does not put empty objects in per-process static
593 dnl memory (mostly useful together with shared memory allocators, see PR
594 dnl libstdc++/16612 for details).
595 dnl
596 dnl --enable-fully-dynamic-string defines _GLIBCXX_FULLY_DYNAMIC_STRING to 1
597 dnl --disable-fully-dynamic-string defines _GLIBCXX_FULLY_DYNAMIC_STRING to 0
598 dnl otherwise undefined
599 dnl + Usage: GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING[(DEFAULT)]
600 dnl Where DEFAULT is either `yes' or `no'.
601 dnl
602 AC_DEFUN([GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING], [
603 GLIBCXX_ENABLE(fully-dynamic-string,$1,,[do not put empty strings in per-process static memory])
604 if test $enable_fully_dynamic_string = yes; then
605 enable_fully_dynamic_string_def=1
606 else
607 enable_fully_dynamic_string_def=0
608 fi
609 AC_DEFINE_UNQUOTED([_GLIBCXX_FULLY_DYNAMIC_STRING], [${enable_fully_dynamic_string_def}],
610 [Define to 1 if a fully dynamic basic_string is wanted, 0 to disable, undefined for platform defaults])
611 ])
614 dnl
615 dnl Does any necessary configuration of the testsuite directory. Generates
616 dnl the testsuite_hooks.h header.
617 dnl
618 dnl GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE must be done before this.
619 dnl
620 dnl Sets:
621 dnl enable_abi_check
622 dnl GLIBCXX_TEST_WCHAR_T
623 dnl GLIBCXX_TEST_THREAD
624 dnl Substs:
625 dnl baseline_dir
626 dnl baseline_subdir_switch
627 dnl
628 AC_DEFUN([GLIBCXX_CONFIGURE_TESTSUITE], [
629 if $GLIBCXX_IS_NATIVE ; then
630 # Do checks for resource limit functions.
631 GLIBCXX_CHECK_SETRLIMIT
633 # Look for setenv, so that extended locale tests can be performed.
634 GLIBCXX_CHECK_STDLIB_DECL_AND_LINKAGE_3(setenv)
635 fi
637 if $GLIBCXX_IS_NATIVE && test $is_hosted = yes &&
638 test $enable_symvers != no; then
639 case "$host" in
640 *-*-cygwin*)
641 enable_abi_check=no ;;
642 *)
643 enable_abi_check=yes ;;
644 esac
645 else
646 # Only build this as native, since automake does not understand
647 # CXX_FOR_BUILD.
648 enable_abi_check=no
649 fi
651 # Export file names for ABI checking.
652 baseline_dir="$glibcxx_srcdir/config/abi/post/${abi_baseline_pair}"
653 AC_SUBST(baseline_dir)
654 baseline_subdir_switch="$abi_baseline_subdir_switch"
655 AC_SUBST(baseline_subdir_switch)
656 ])
659 dnl
660 dnl Does any necessary configuration for docbook in the docs directory.
661 dnl
662 dnl XSLTPROC must be set before this
663 dnl
664 dnl Sets:
665 dnl glibcxx_stylesheets
666 dnl Substs:
667 dnl XSL_STYLE_DIR
668 dnl
669 AC_DEFUN([GLIBCXX_CONFIGURE_DOCBOOK], [
671 AC_MSG_CHECKING([for docbook stylesheets for documentation creation])
672 glibcxx_stylesheets=no
673 if test x${XSLTPROC} = xyes && echo '<title/>' | xsltproc --noout --nonet --xinclude http://docbook.sourceforge.net/release/xsl-ns/current/xhtml-1_1/docbook.xsl - 2>/dev/null; then
674 glibcxx_stylesheets=yes
675 fi
676 AC_MSG_RESULT($glibcxx_stylesheets)
678 AC_MSG_CHECKING([for local stylesheet directory])
679 glibcxx_local_stylesheets=no
680 if test x"$glibcxx_stylesheets" = x"yes"; then
681 if test -d /usr/share/sgml/docbook/xsl-ns-stylesheets; then
682 glibcxx_local_stylesheets=yes
683 XSL_STYLE_DIR=/usr/share/sgml/docbook/xsl-ns-stylesheets
684 fi
685 if test -d /usr/share/xml/docbook/stylesheet/docbook-xsl-ns; then
686 glibcxx_local_stylesheets=yes
687 XSL_STYLE_DIR=/usr/share/xml/docbook/stylesheet/docbook-xsl-ns
688 fi
689 fi
690 AC_MSG_RESULT($glibcxx_local_stylesheets)
692 if test x"$glibcxx_local_stylesheets" = x"yes"; then
693 AC_SUBST(XSL_STYLE_DIR)
694 AC_MSG_NOTICE($XSL_STYLE_DIR)
695 else
696 glibcxx_stylesheets=no
697 fi
699 # Check for epub3 dependencies.
700 AC_MSG_CHECKING([for epub3 stylesheets for documentation creation])
701 glibcxx_epub_stylesheets=no
702 if test x"$glibcxx_local_stylesheets" = x"yes"; then
703 if test -f "$XSL_STYLE_DIR/epub3/chunk.xsl"; then
704 glibcxx_epub_stylesheets=yes
705 fi
706 fi
707 AC_MSG_RESULT($glibcxx_epub_stylesheets)
708 AM_CONDITIONAL(BUILD_EPUB, test x"$glibcxx_epub_stylesheets" = x"yes")
710 ])
713 dnl
714 dnl Set up *_INCLUDES variables for all sundry Makefile.am's.
715 dnl
716 dnl Substs:
717 dnl GLIBCXX_INCLUDES
718 dnl TOPLEVEL_INCLUDES
719 dnl
720 AC_DEFUN([GLIBCXX_EXPORT_INCLUDES], [
721 # Used for every C++ compile we perform.
722 GLIBCXX_INCLUDES="\
723 -I$glibcxx_builddir/include/$host_alias \
724 -I$glibcxx_builddir/include \
725 -I$glibcxx_srcdir/libsupc++"
727 # For Canadian crosses, pick this up too.
728 if test $CANADIAN = yes; then
729 GLIBCXX_INCLUDES="$GLIBCXX_INCLUDES -I\${includedir}"
730 fi
732 # Stuff in the actual top level. Currently only used by libsupc++ to
733 # get unwind* headers from the libgcc dir.
734 #TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/libgcc -I$(toplevel_srcdir)/include'
735 TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/libgcc'
737 # Now, export this to all the little Makefiles....
738 AC_SUBST(GLIBCXX_INCLUDES)
739 AC_SUBST(TOPLEVEL_INCLUDES)
740 ])
743 dnl
744 dnl Set up *_FLAGS and *FLAGS variables for all sundry Makefile.am's.
745 dnl (SECTION_FLAGS is done under CHECK_COMPILER_FEATURES.)
746 dnl
747 dnl Substs:
748 dnl OPTIMIZE_CXXFLAGS
749 dnl WARN_FLAGS
750 dnl
751 AC_DEFUN([GLIBCXX_EXPORT_FLAGS], [
752 # Optimization flags that are probably a good idea for thrill-seekers. Just
753 # uncomment the lines below and make, everything else is ready to go...
754 # Alternatively OPTIMIZE_CXXFLAGS can be set in configure.host.
755 # OPTIMIZE_CXXFLAGS = -O3 -fstrict-aliasing -fvtable-gc
756 AC_SUBST(OPTIMIZE_CXXFLAGS)
758 WARN_FLAGS='-Wall -Wextra -Wwrite-strings -Wcast-qual -Wabi'
759 AC_SUBST(WARN_FLAGS)
760 ])
763 dnl
764 dnl All installation directory information is determined here.
765 dnl
766 dnl Substs:
767 dnl gxx_install_dir
768 dnl glibcxx_prefixdir
769 dnl glibcxx_toolexecdir
770 dnl glibcxx_toolexeclibdir
771 dnl
772 dnl Assumes cross_compiling bits already done, and with_cross_host in
773 dnl particular.
774 dnl
775 dnl This logic must match gcc/configure.ac's setting of gcc_gxx_include_dir.
776 dnl config/gxx-include-dir.m4 must be kept consistant with this as well.
777 AC_DEFUN([GLIBCXX_EXPORT_INSTALL_INFO], [
778 glibcxx_toolexecdir=no
779 glibcxx_toolexeclibdir=no
780 glibcxx_prefixdir=$prefix
782 AC_MSG_CHECKING([for gxx-include-dir])
783 AC_ARG_WITH([gxx-include-dir],
784 AC_HELP_STRING([--with-gxx-include-dir=DIR],
785 [installation directory for include files]),
786 [case "$withval" in
787 yes) AC_MSG_ERROR([Missing directory for --with-gxx-include-dir]) ;;
788 no) gxx_include_dir=no ;;
789 *) gxx_include_dir=$withval ;;
790 esac],
791 [gxx_include_dir=no])
792 AC_MSG_RESULT($gxx_include_dir)
794 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
795 AC_ARG_ENABLE([version-specific-runtime-libs],
796 AC_HELP_STRING([--enable-version-specific-runtime-libs],
797 [Specify that runtime libraries should be installed in a compiler-specific directory]),
798 [case "$enableval" in
799 yes) version_specific_libs=yes ;;
800 no) version_specific_libs=no ;;
801 *) AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
802 esac],
803 [version_specific_libs=no])
804 AC_MSG_RESULT($version_specific_libs)
806 # Default case for install directory for include files.
807 if test $version_specific_libs = no && test $gxx_include_dir = no; then
808 gxx_include_dir='include/c++/${gcc_version}'
809 if test -n "$with_cross_host" &&
810 test x"$with_cross_host" != x"no"; then
811 gxx_include_dir='${prefix}/${target_alias}/'"$gxx_include_dir"
812 else
813 gxx_include_dir='${prefix}/'"$gxx_include_dir"
814 fi
815 fi
817 # Version-specific runtime libs processing.
818 if test $version_specific_libs = yes; then
819 # Need the gcc compiler version to know where to install libraries
820 # and header files if --enable-version-specific-runtime-libs option
821 # is selected. FIXME: these variables are misnamed, there are
822 # no executables installed in _toolexecdir or _toolexeclibdir.
823 if test x"$gxx_include_dir" = x"no"; then
824 gxx_include_dir='${libdir}/gcc/${host_alias}/${gcc_version}/include/c++'
825 fi
826 glibcxx_toolexecdir='${libdir}/gcc/${host_alias}'
827 glibcxx_toolexeclibdir='${toolexecdir}/${gcc_version}$(MULTISUBDIR)'
828 fi
830 # Calculate glibcxx_toolexecdir, glibcxx_toolexeclibdir
831 # Install a library built with a cross compiler in tooldir, not libdir.
832 if test x"$glibcxx_toolexecdir" = x"no"; then
833 if test -n "$with_cross_host" &&
834 test x"$with_cross_host" != x"no"; then
835 glibcxx_toolexecdir='${exec_prefix}/${host_alias}'
836 glibcxx_toolexeclibdir='${toolexecdir}/lib'
837 else
838 glibcxx_toolexecdir='${libdir}/gcc/${host_alias}'
839 glibcxx_toolexeclibdir='${libdir}'
840 fi
841 multi_os_directory=`$CXX -print-multi-os-directory`
842 case $multi_os_directory in
843 .) ;; # Avoid trailing /.
844 *) glibcxx_toolexeclibdir=$glibcxx_toolexeclibdir/$multi_os_directory ;;
845 esac
846 fi
848 AC_MSG_CHECKING([for install location])
849 AC_MSG_RESULT($gxx_include_dir)
851 AC_SUBST(glibcxx_prefixdir)
852 AC_SUBST(gxx_include_dir)
853 AC_SUBST(glibcxx_toolexecdir)
854 AC_SUBST(glibcxx_toolexeclibdir)
855 ])
858 dnl
859 dnl GLIBCXX_ENABLE
860 dnl (FEATURE, DEFAULT, HELP-ARG, HELP-STRING)
861 dnl (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, permit a|b|c)
862 dnl (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, SHELL-CODE-HANDLER)
863 dnl
864 dnl See docs/html/17_intro/configury.html#enable for documentation.
865 dnl
866 m4_define([GLIBCXX_ENABLE],[dnl
867 m4_define([_g_switch],[--enable-$1])dnl
868 m4_define([_g_help],[AC_HELP_STRING([_g_switch$3],[$4 @<:@default=$2@:>@])])dnl
869 AC_ARG_ENABLE([$1],m4_dquote(_g_help),
870 m4_bmatch([$5],
871 [^permit ],
872 [[
873 case "$enableval" in
874 m4_bpatsubst([$5],[permit ])) ;;
875 *) AC_MSG_ERROR(Unknown argument to enable/disable $1) ;;
876 dnl Idea for future: generate a URL pointing to
877 dnl "onlinedocs/configopts.html#whatever"
878 esac
879 ]],
880 [^$],
881 [[
882 case "$enableval" in
883 yes|no) ;;
884 *) AC_MSG_ERROR(Argument to enable/disable $1 must be yes or no) ;;
885 esac
886 ]],
887 [[$5]]),
888 [enable_]m4_bpatsubst([$1],-,_)[=][$2])
889 m4_undefine([_g_switch])dnl
890 m4_undefine([_g_help])dnl
891 ])
894 dnl
895 dnl Check for ISO/IEC 9899:1999 "C99" support.
896 dnl
897 dnl --enable-c99 defines _GLIBCXX_USE_C99
898 dnl --disable-c99 leaves _GLIBCXX_USE_C99 undefined
899 dnl + Usage: GLIBCXX_ENABLE_C99[(DEFAULT)]
900 dnl Where DEFAULT is either `yes' or `no'.
901 dnl + If 'C99' stuff is not available, ignores DEFAULT and sets `no'.
902 dnl
903 AC_DEFUN([GLIBCXX_ENABLE_C99], [
904 GLIBCXX_ENABLE(c99,$1,,[turns on ISO/IEC 9899:1999 support])
906 if test x"$enable_c99" = x"yes"; then
908 AC_LANG_SAVE
909 AC_LANG_CPLUSPLUS
911 # Use -std=c++98 because the default (-std=gnu++98) leaves __STRICT_ANSI__
912 # undefined and fake C99 facilities - like pre-standard snprintf - may be
913 # spuriously enabled.
914 # Long term, -std=c++0x could be even better, could manage to explicitely
915 # request C99 facilities to the underlying C headers.
916 ac_save_CXXFLAGS="$CXXFLAGS"
917 CXXFLAGS="$CXXFLAGS -std=c++98"
918 ac_save_LIBS="$LIBS"
919 ac_save_gcc_no_link="$gcc_no_link"
921 if test x$gcc_no_link != xyes; then
922 # Use -fno-exceptions to that the C driver can link these tests without
923 # hitting undefined references to personality routines.
924 CXXFLAGS="$CXXFLAGS -fno-exceptions"
925 AC_CHECK_LIB(m, sin, [
926 LIBS="$LIBS -lm"
927 ], [
928 # Use the default compile-only tests in GCC_TRY_COMPILE_OR_LINK
929 gcc_no_link=yes
930 ])
931 fi
933 # Check for the existence of <math.h> functions used if C99 is enabled.
934 AC_MSG_CHECKING([for ISO C99 support in <math.h>])
935 AC_CACHE_VAL(glibcxx_cv_c99_math, [
936 GCC_TRY_COMPILE_OR_LINK(
937 [#include <math.h>
938 volatile double d1, d2;
939 volatile int i;],
940 [i = fpclassify(d1);
941 i = isfinite(d1);
942 i = isinf(d1);
943 i = isnan(d1);
944 i = isnormal(d1);
945 i = signbit(d1);
946 i = isgreater(d1, d2);
947 i = isgreaterequal(d1, d2);
948 i = isless(d1, d2);
949 i = islessequal(d1, d2);
950 i = islessgreater(d1, d2);
951 i = islessgreater(d1, d2);
952 i = isunordered(d1, d2);
953 ],[glibcxx_cv_c99_math=yes], [glibcxx_cv_c99_math=no])
954 ])
955 AC_MSG_RESULT($glibcxx_cv_c99_math)
956 if test x"$glibcxx_cv_c99_math" = x"yes"; then
957 AC_DEFINE(_GLIBCXX_USE_C99_MATH, 1,
958 [Define if C99 functions or macros in <math.h> should be imported
959 in <cmath> in namespace std.])
960 fi
962 # Check for the existence of <complex.h> complex math functions.
963 # This is necessary even though libstdc++ uses the builtin versions
964 # of these functions, because if the builtin cannot be used, a reference
965 # to the library function is emitted.
966 AC_CHECK_HEADERS(tgmath.h, ac_has_tgmath_h=yes, ac_has_tgmath_h=no)
967 AC_CHECK_HEADERS(complex.h, ac_has_complex_h=yes, ac_has_complex_h=no)
968 glibcxx_cv_c99_complex=no;
969 if test x"$ac_has_complex_h" = x"yes"; then
970 AC_MSG_CHECKING([for ISO C99 support in <complex.h>])
971 GCC_TRY_COMPILE_OR_LINK(
972 [#include <complex.h>
973 typedef __complex__ float float_type;
974 typedef __complex__ double double_type;
975 typedef __complex__ long double ld_type;
976 volatile float_type tmpf;
977 volatile double_type tmpd;
978 volatile ld_type tmpld;
979 volatile float f;
980 volatile double d;
981 volatile long double ld;],
982 [f = cabsf(tmpf);
983 f = cargf(tmpf);
984 tmpf = ccosf(tmpf);
985 tmpf = ccoshf(tmpf);
986 tmpf = cexpf(tmpf);
987 tmpf = clogf(tmpf);
988 tmpf = csinf(tmpf);
989 tmpf = csinhf(tmpf);
990 tmpf = csqrtf(tmpf);
991 tmpf = ctanf(tmpf);
992 tmpf = ctanhf(tmpf);
993 tmpf = cpowf(tmpf, tmpf);
994 tmpf = cprojf(tmpf);
995 d = cabs(tmpd);
996 d = carg(tmpd);
997 tmpd = ccos(tmpd);
998 tmpd = ccosh(tmpd);
999 tmpd = cexp(tmpd);
1000 tmpd = clog(tmpd);
1001 tmpd = csin(tmpd);
1002 tmpd = csinh(tmpd);
1003 tmpd = csqrt(tmpd);
1004 tmpd = ctan(tmpd);
1005 tmpd = ctanh(tmpd);
1006 tmpd = cpow(tmpd, tmpd);
1007 tmpd = cproj(tmpd);
1008 ld = cabsl(tmpld);
1009 ld = cargl(tmpld);
1010 tmpld = ccosl(tmpld);
1011 tmpld = ccoshl(tmpld);
1012 tmpld = cexpl(tmpld);
1013 tmpld = clogl(tmpld);
1014 tmpld = csinl(tmpld);
1015 tmpld = csinhl(tmpld);
1016 tmpld = csqrtl(tmpld);
1017 tmpld = ctanl(tmpld);
1018 tmpld = ctanhl(tmpld);
1019 tmpld = cpowl(tmpld, tmpld);
1020 tmpld = cprojl(tmpld);
1021 ],[glibcxx_cv_c99_complex=yes], [glibcxx_cv_c99_complex=no])
1022 fi
1023 AC_MSG_RESULT($glibcxx_cv_c99_complex)
1024 if test x"$glibcxx_cv_c99_complex" = x"yes"; then
1025 AC_DEFINE(_GLIBCXX_USE_C99_COMPLEX, 1,
1026 [Define if C99 functions in <complex.h> should be used in
1027 <complex>. Using compiler builtins for these functions requires
1028 corresponding C99 library functions to be present.])
1029 fi
1031 # Check for the existence in <stdio.h> of vscanf, et. al.
1032 AC_MSG_CHECKING([for ISO C99 support in <stdio.h>])
1033 AC_CACHE_VAL(glibcxx_cv_c99_stdio, [
1034 GCC_TRY_COMPILE_OR_LINK(
1035 [#include <stdio.h>
1036 #include <stdarg.h>
1037 void foo(char* fmt, ...)
1038 {
1039 va_list args; va_start(args, fmt);
1040 vfscanf(stderr, "%i", args);
1041 vscanf("%i", args);
1042 vsnprintf(fmt, 0, "%i", args);
1043 vsscanf(fmt, "%i", args);
1044 }],
1045 [snprintf("12", 0, "%i");],
1046 [glibcxx_cv_c99_stdio=yes], [glibcxx_cv_c99_stdio=no])
1047 ])
1048 AC_MSG_RESULT($glibcxx_cv_c99_stdio)
1050 # Check for the existence in <stdlib.h> of lldiv_t, et. al.
1051 AC_MSG_CHECKING([for ISO C99 support in <stdlib.h>])
1052 AC_CACHE_VAL(glibcxx_cv_c99_stdlib, [
1053 GCC_TRY_COMPILE_OR_LINK(
1054 [#include <stdlib.h>
1055 volatile float f;
1056 volatile long double ld;
1057 volatile unsigned long long ll;
1058 lldiv_t mydivt;],
1059 [char* tmp;
1060 f = strtof("gnu", &tmp);
1061 ld = strtold("gnu", &tmp);
1062 ll = strtoll("gnu", &tmp, 10);
1063 ll = strtoull("gnu", &tmp, 10);
1064 ll = llabs(10);
1065 mydivt = lldiv(10,1);
1066 ll = mydivt.quot;
1067 ll = mydivt.rem;
1068 ll = atoll("10");
1069 _Exit(0);
1070 ],[glibcxx_cv_c99_stdlib=yes], [glibcxx_cv_c99_stdlib=no])
1071 ])
1072 AC_MSG_RESULT($glibcxx_cv_c99_stdlib)
1074 # Check for the existence in <wchar.h> of wcstold, etc.
1075 glibcxx_cv_c99_wchar=no;
1076 if test x"$ac_has_wchar_h" = xyes &&
1077 test x"$ac_has_wctype_h" = xyes; then
1078 AC_MSG_CHECKING([for ISO C99 support in <wchar.h>])
1079 AC_TRY_COMPILE([#include <wchar.h>
1080 namespace test
1081 {
1082 using ::wcstold;
1083 using ::wcstoll;
1084 using ::wcstoull;
1085 }
1086 ],[],[glibcxx_cv_c99_wchar=yes], [glibcxx_cv_c99_wchar=no])
1088 # Checks for wide character functions that may not be present.
1089 # Injection of these is wrapped with guard macros.
1090 # NB: only put functions here, instead of immediately above, if
1091 # absolutely necessary.
1092 AC_TRY_COMPILE([#include <wchar.h>
1093 namespace test { using ::vfwscanf; } ], [],
1094 [AC_DEFINE(HAVE_VFWSCANF,1,
1095 [Defined if vfwscanf exists.])],[])
1097 AC_TRY_COMPILE([#include <wchar.h>
1098 namespace test { using ::vswscanf; } ], [],
1099 [AC_DEFINE(HAVE_VSWSCANF,1,
1100 [Defined if vswscanf exists.])],[])
1102 AC_TRY_COMPILE([#include <wchar.h>
1103 namespace test { using ::vwscanf; } ], [],
1104 [AC_DEFINE(HAVE_VWSCANF,1,[Defined if vwscanf exists.])],[])
1106 AC_TRY_COMPILE([#include <wchar.h>
1107 namespace test { using ::wcstof; } ], [],
1108 [AC_DEFINE(HAVE_WCSTOF,1,[Defined if wcstof exists.])],[])
1110 AC_TRY_COMPILE([#include <wctype.h>],
1111 [ wint_t t; int i = iswblank(t);],
1112 [AC_DEFINE(HAVE_ISWBLANK,1,
1113 [Defined if iswblank exists.])],[])
1115 AC_MSG_RESULT($glibcxx_cv_c99_wchar)
1116 fi
1118 # Option parsed, now set things appropriately.
1119 if test x"$glibcxx_cv_c99_math" = x"no" ||
1120 test x"$glibcxx_cv_c99_complex" = x"no" ||
1121 test x"$glibcxx_cv_c99_stdio" = x"no" ||
1122 test x"$glibcxx_cv_c99_stdlib" = x"no" ||
1123 test x"$glibcxx_cv_c99_wchar" = x"no"; then
1124 enable_c99=no;
1125 else
1126 AC_DEFINE(_GLIBCXX_USE_C99, 1,
1127 [Define if C99 functions or macros from <wchar.h>, <math.h>,
1128 <complex.h>, <stdio.h>, and <stdlib.h> can be used or exposed.])
1129 fi
1131 gcc_no_link="$ac_save_gcc_no_link"
1132 LIBS="$ac_save_LIBS"
1133 CXXFLAGS="$ac_save_CXXFLAGS"
1134 AC_LANG_RESTORE
1135 fi
1137 AC_MSG_CHECKING([for fully enabled ISO C99 support])
1138 AC_MSG_RESULT($enable_c99)
1139 ])
1142 dnl
1143 dnl Check for clock_gettime, nanosleep and sched_yield, used in the
1144 dnl implementation of 20.11.7 [time.clock], and 30.3.2 [thread.thread.this]
1145 dnl in the C++11 standard.
1146 dnl
1147 dnl --enable-libstdcxx-time
1148 dnl --enable-libstdcxx-time=yes
1149 dnl checks for the availability of monotonic and realtime clocks,
1150 dnl nanosleep and sched_yield in libc and libposix4 and, if needed,
1151 dnl links in the latter.
1152 dnl --enable-libstdcxx-time=rt
1153 dnl also searches (and, if needed, links) librt. Note that this is
1154 dnl not always desirable because, in glibc, for example, in turn it
1155 dnl triggers the linking of libpthread too, which activates locking,
1156 dnl a large overhead for single-thread programs.
1157 dnl --enable-libstdcxx-time=no
1158 dnl --disable-libstdcxx-time
1159 dnl disables the checks completely
1160 dnl
1161 AC_DEFUN([GLIBCXX_ENABLE_LIBSTDCXX_TIME], [
1163 AC_MSG_CHECKING([for clock_gettime, nanosleep and sched_yield])
1164 GLIBCXX_ENABLE(libstdcxx-time,$1,[[[=KIND]]],
1165 [use KIND for check type],
1166 [permit yes|no|rt])
1168 AC_LANG_SAVE
1169 AC_LANG_CPLUSPLUS
1170 ac_save_CXXFLAGS="$CXXFLAGS"
1171 CXXFLAGS="$CXXFLAGS -fno-exceptions"
1172 ac_save_LIBS="$LIBS"
1174 ac_has_clock_monotonic=no
1175 ac_has_clock_realtime=no
1176 AC_MSG_RESULT($enable_libstdcxx_time)
1178 if test x"$enable_libstdcxx_time" != x"no"; then
1180 if test x"$enable_libstdcxx_time" = x"rt"; then
1181 AC_SEARCH_LIBS(clock_gettime, [rt posix4])
1182 AC_SEARCH_LIBS(nanosleep, [rt posix4])
1183 else
1184 AC_SEARCH_LIBS(clock_gettime, [posix4])
1185 AC_SEARCH_LIBS(nanosleep, [posix4])
1186 fi
1188 case "$ac_cv_search_clock_gettime" in
1189 -l*) GLIBCXX_LIBS=$ac_cv_search_clock_gettime
1190 ;;
1191 esac
1192 case "$ac_cv_search_nanosleep" in
1193 -l*) GLIBCXX_LIBS="$GLIBCXX_LIBS $ac_cv_search_nanosleep"
1194 ;;
1195 esac
1197 AC_SEARCH_LIBS(sched_yield, [rt posix4])
1199 case "$ac_cv_search_sched_yield" in
1200 -lposix4*)
1201 GLIBCXX_LIBS="$GLIBCXX_LIBS $ac_cv_search_sched_yield"
1202 AC_DEFINE(_GLIBCXX_USE_SCHED_YIELD, 1,
1203 [ Defined if sched_yield is available. ])
1204 ;;
1205 -lrt*)
1206 if test x"$enable_libstdcxx_time" = x"rt"; then
1207 GLIBCXX_LIBS="$GLIBCXX_LIBS $ac_cv_search_sched_yield"
1208 AC_DEFINE(_GLIBCXX_USE_SCHED_YIELD, 1,
1209 [ Defined if sched_yield is available. ])
1210 fi
1211 ;;
1212 *)
1213 AC_DEFINE(_GLIBCXX_USE_SCHED_YIELD, 1,
1214 [ Defined if sched_yield is available. ])
1215 ;;
1216 esac
1218 AC_CHECK_HEADERS(unistd.h, ac_has_unistd_h=yes, ac_has_unistd_h=no)
1220 if test x"$ac_has_unistd_h" = x"yes"; then
1221 AC_MSG_CHECKING([for monotonic clock])
1222 AC_TRY_LINK(
1223 [#include <unistd.h>
1224 #include <time.h>
1225 ],
1226 [#if _POSIX_TIMERS > 0 && defined(_POSIX_MONOTONIC_CLOCK)
1227 timespec tp;
1228 #endif
1229 clock_gettime(CLOCK_MONOTONIC, &tp);
1230 ], [ac_has_clock_monotonic=yes], [ac_has_clock_monotonic=no])
1232 AC_MSG_RESULT($ac_has_clock_monotonic)
1234 AC_MSG_CHECKING([for realtime clock])
1235 AC_TRY_LINK(
1236 [#include <unistd.h>
1237 #include <time.h>
1238 ],
1239 [#if _POSIX_TIMERS > 0
1240 timespec tp;
1241 #endif
1242 clock_gettime(CLOCK_REALTIME, &tp);
1243 ], [ac_has_clock_realtime=yes], [ac_has_clock_realtime=no])
1245 AC_MSG_RESULT($ac_has_clock_realtime)
1247 AC_MSG_CHECKING([for nanosleep])
1248 AC_TRY_LINK(
1249 [#include <unistd.h>
1250 #include <time.h>
1251 ],
1252 [#if _POSIX_TIMERS > 0
1253 timespec tp;
1254 #endif
1255 nanosleep(&tp, 0);
1256 ], [ac_has_nanosleep=yes], [ac_has_nanosleep=no])
1258 AC_MSG_RESULT($ac_has_nanosleep)
1259 fi
1260 fi
1262 if test x"$ac_has_clock_monotonic" = x"yes"; then
1263 AC_DEFINE(_GLIBCXX_USE_CLOCK_MONOTONIC, 1,
1264 [ Defined if clock_gettime has monotonic clock support. ])
1265 fi
1267 if test x"$ac_has_clock_realtime" = x"yes"; then
1268 AC_DEFINE(_GLIBCXX_USE_CLOCK_REALTIME, 1,
1269 [ Defined if clock_gettime has realtime clock support. ])
1270 fi
1272 if test x"$ac_has_nanosleep" = x"yes"; then
1273 AC_DEFINE(_GLIBCXX_USE_NANOSLEEP, 1,
1274 [ Defined if nanosleep is available. ])
1275 fi
1277 AC_SUBST(GLIBCXX_LIBS)
1279 CXXFLAGS="$ac_save_CXXFLAGS"
1280 LIBS="$ac_save_LIBS"
1281 AC_LANG_RESTORE
1282 ])
1284 dnl
1285 dnl Check for gettimeofday, used in the implementation of 20.11.7
1286 dnl [time.clock] in the C++11 standard.
1287 dnl
1288 AC_DEFUN([GLIBCXX_CHECK_GETTIMEOFDAY], [
1290 AC_MSG_CHECKING([for gettimeofday])
1292 AC_LANG_SAVE
1293 AC_LANG_CPLUSPLUS
1294 ac_save_CXXFLAGS="$CXXFLAGS"
1295 CXXFLAGS="$CXXFLAGS -fno-exceptions"
1297 ac_has_gettimeofday=no;
1298 AC_CHECK_HEADERS(sys/time.h, ac_has_sys_time_h=yes, ac_has_sys_time_h=no)
1299 if test x"$ac_has_sys_time_h" = x"yes"; then
1300 AC_MSG_CHECKING([for gettimeofday])
1301 GCC_TRY_COMPILE_OR_LINK([#include <sys/time.h>],
1302 [timeval tv; gettimeofday(&tv, 0);],
1303 [ac_has_gettimeofday=yes], [ac_has_gettimeofday=no])
1305 AC_MSG_RESULT($ac_has_gettimeofday)
1306 fi
1308 if test x"$ac_has_gettimeofday" = x"yes"; then
1309 AC_DEFINE(_GLIBCXX_USE_GETTIMEOFDAY, 1,
1310 [ Defined if gettimeofday is available. ])
1311 fi
1313 CXXFLAGS="$ac_save_CXXFLAGS"
1314 AC_LANG_RESTORE
1315 ])
1317 dnl
1318 dnl Check for ISO/IEC 9899:1999 "C99" support to ISO/IEC DTR 19768 "TR1"
1319 dnl facilities in Chapter 8, "C compatibility".
1320 dnl
1321 AC_DEFUN([GLIBCXX_CHECK_C99_TR1], [
1323 AC_LANG_SAVE
1324 AC_LANG_CPLUSPLUS
1326 # Use -std=c++98 because the default (-std=gnu++98) leaves __STRICT_ANSI__
1327 # undefined and fake C99 facilities may be spuriously enabled.
1328 ac_save_CXXFLAGS="$CXXFLAGS"
1329 CXXFLAGS="$CXXFLAGS -std=c++98"
1331 # Check for the existence of <complex.h> complex math functions used
1332 # by tr1/complex.
1333 AC_CHECK_HEADERS(complex.h, ac_has_complex_h=yes, ac_has_complex_h=no)
1334 ac_c99_complex_tr1=no;
1335 if test x"$ac_has_complex_h" = x"yes"; then
1336 AC_MSG_CHECKING([for ISO C99 support to TR1 in <complex.h>])
1337 AC_TRY_COMPILE([#include <complex.h>],
1338 [typedef __complex__ float float_type; float_type tmpf;
1339 cacosf(tmpf);
1340 casinf(tmpf);
1341 catanf(tmpf);
1342 cacoshf(tmpf);
1343 casinhf(tmpf);
1344 catanhf(tmpf);
1345 typedef __complex__ double double_type; double_type tmpd;
1346 cacos(tmpd);
1347 casin(tmpd);
1348 catan(tmpd);
1349 cacosh(tmpd);
1350 casinh(tmpd);
1351 catanh(tmpd);
1352 typedef __complex__ long double ld_type; ld_type tmpld;
1353 cacosl(tmpld);
1354 casinl(tmpld);
1355 catanl(tmpld);
1356 cacoshl(tmpld);
1357 casinhl(tmpld);
1358 catanhl(tmpld);
1359 ],[ac_c99_complex_tr1=yes], [ac_c99_complex_tr1=no])
1360 fi
1361 AC_MSG_RESULT($ac_c99_complex_tr1)
1362 if test x"$ac_c99_complex_tr1" = x"yes"; then
1363 AC_DEFINE(_GLIBCXX_USE_C99_COMPLEX_TR1, 1,
1364 [Define if C99 functions in <complex.h> should be used in
1365 <tr1/complex>. Using compiler builtins for these functions
1366 requires corresponding C99 library functions to be present.])
1367 fi
1369 # Check for the existence of <ctype.h> functions.
1370 AC_MSG_CHECKING([for ISO C99 support to TR1 in <ctype.h>])
1371 AC_CACHE_VAL(glibcxx_cv_c99_ctype_tr1, [
1372 AC_TRY_COMPILE([#include <ctype.h>],
1373 [int ch;
1374 int ret;
1375 ret = isblank(ch);
1376 ],[glibcxx_cv_c99_ctype_tr1=yes],
1377 [glibcxx_cv_c99_ctype_tr1=no])
1378 ])
1379 AC_MSG_RESULT($glibcxx_cv_c99_ctype_tr1)
1380 if test x"$glibcxx_cv_c99_ctype_tr1" = x"yes"; then
1381 AC_DEFINE(_GLIBCXX_USE_C99_CTYPE_TR1, 1,
1382 [Define if C99 functions in <ctype.h> should be imported in
1383 <tr1/cctype> in namespace std::tr1.])
1384 fi
1386 # Check for the existence of <fenv.h> functions.
1387 AC_CHECK_HEADERS(fenv.h, ac_has_fenv_h=yes, ac_has_fenv_h=no)
1388 ac_c99_fenv_tr1=no;
1389 if test x"$ac_has_fenv_h" = x"yes"; then
1390 AC_MSG_CHECKING([for ISO C99 support to TR1 in <fenv.h>])
1391 AC_TRY_COMPILE([#include <fenv.h>],
1392 [int except, mode;
1393 fexcept_t* pflag;
1394 fenv_t* penv;
1395 int ret;
1396 ret = feclearexcept(except);
1397 ret = fegetexceptflag(pflag, except);
1398 ret = feraiseexcept(except);
1399 ret = fesetexceptflag(pflag, except);
1400 ret = fetestexcept(except);
1401 ret = fegetround();
1402 ret = fesetround(mode);
1403 ret = fegetenv(penv);
1404 ret = feholdexcept(penv);
1405 ret = fesetenv(penv);
1406 ret = feupdateenv(penv);
1407 ],[ac_c99_fenv_tr1=yes], [ac_c99_fenv_tr1=no])
1408 fi
1409 AC_MSG_RESULT($ac_c99_fenv_tr1)
1410 if test x"$ac_c99_fenv_tr1" = x"yes"; then
1411 AC_DEFINE(_GLIBCXX_USE_C99_FENV_TR1, 1,
1412 [Define if C99 functions in <fenv.h> should be imported in
1413 <tr1/cfenv> in namespace std::tr1.])
1414 fi
1416 # Check for the existence of <stdint.h> types.
1417 AC_MSG_CHECKING([for ISO C99 support to TR1 in <stdint.h>])
1418 AC_CACHE_VAL(glibcxx_cv_c99_stdint_tr1, [
1419 AC_TRY_COMPILE([#define __STDC_LIMIT_MACROS
1420 #define __STDC_CONSTANT_MACROS
1421 #include <stdint.h>],
1422 [typedef int8_t my_int8_t;
1423 my_int8_t i8 = INT8_MIN;
1424 i8 = INT8_MAX;
1425 typedef int16_t my_int16_t;
1426 my_int16_t i16 = INT16_MIN;
1427 i16 = INT16_MAX;
1428 typedef int32_t my_int32_t;
1429 my_int32_t i32 = INT32_MIN;
1430 i32 = INT32_MAX;
1431 typedef int64_t my_int64_t;
1432 my_int64_t i64 = INT64_MIN;
1433 i64 = INT64_MAX;
1434 typedef int_fast8_t my_int_fast8_t;
1435 my_int_fast8_t if8 = INT_FAST8_MIN;
1436 if8 = INT_FAST8_MAX;
1437 typedef int_fast16_t my_int_fast16_t;
1438 my_int_fast16_t if16 = INT_FAST16_MIN;
1439 if16 = INT_FAST16_MAX;
1440 typedef int_fast32_t my_int_fast32_t;
1441 my_int_fast32_t if32 = INT_FAST32_MIN;
1442 if32 = INT_FAST32_MAX;
1443 typedef int_fast64_t my_int_fast64_t;
1444 my_int_fast64_t if64 = INT_FAST64_MIN;
1445 if64 = INT_FAST64_MAX;
1446 typedef int_least8_t my_int_least8_t;
1447 my_int_least8_t il8 = INT_LEAST8_MIN;
1448 il8 = INT_LEAST8_MAX;
1449 typedef int_least16_t my_int_least16_t;
1450 my_int_least16_t il16 = INT_LEAST16_MIN;
1451 il16 = INT_LEAST16_MAX;
1452 typedef int_least32_t my_int_least32_t;
1453 my_int_least32_t il32 = INT_LEAST32_MIN;
1454 il32 = INT_LEAST32_MAX;
1455 typedef int_least64_t my_int_least64_t;
1456 my_int_least64_t il64 = INT_LEAST64_MIN;
1457 il64 = INT_LEAST64_MAX;
1458 typedef intmax_t my_intmax_t;
1459 my_intmax_t im = INTMAX_MAX;
1460 im = INTMAX_MIN;
1461 typedef intptr_t my_intptr_t;
1462 my_intptr_t ip = INTPTR_MAX;
1463 ip = INTPTR_MIN;
1464 typedef uint8_t my_uint8_t;
1465 my_uint8_t ui8 = UINT8_MAX;
1466 ui8 = UINT8_MAX;
1467 typedef uint16_t my_uint16_t;
1468 my_uint16_t ui16 = UINT16_MAX;
1469 ui16 = UINT16_MAX;
1470 typedef uint32_t my_uint32_t;
1471 my_uint32_t ui32 = UINT32_MAX;
1472 ui32 = UINT32_MAX;
1473 typedef uint64_t my_uint64_t;
1474 my_uint64_t ui64 = UINT64_MAX;
1475 ui64 = UINT64_MAX;
1476 typedef uint_fast8_t my_uint_fast8_t;
1477 my_uint_fast8_t uif8 = UINT_FAST8_MAX;
1478 uif8 = UINT_FAST8_MAX;
1479 typedef uint_fast16_t my_uint_fast16_t;
1480 my_uint_fast16_t uif16 = UINT_FAST16_MAX;
1481 uif16 = UINT_FAST16_MAX;
1482 typedef uint_fast32_t my_uint_fast32_t;
1483 my_uint_fast32_t uif32 = UINT_FAST32_MAX;
1484 uif32 = UINT_FAST32_MAX;
1485 typedef uint_fast64_t my_uint_fast64_t;
1486 my_uint_fast64_t uif64 = UINT_FAST64_MAX;
1487 uif64 = UINT_FAST64_MAX;
1488 typedef uint_least8_t my_uint_least8_t;
1489 my_uint_least8_t uil8 = UINT_LEAST8_MAX;
1490 uil8 = UINT_LEAST8_MAX;
1491 typedef uint_least16_t my_uint_least16_t;
1492 my_uint_least16_t uil16 = UINT_LEAST16_MAX;
1493 uil16 = UINT_LEAST16_MAX;
1494 typedef uint_least32_t my_uint_least32_t;
1495 my_uint_least32_t uil32 = UINT_LEAST32_MAX;
1496 uil32 = UINT_LEAST32_MAX;
1497 typedef uint_least64_t my_uint_least64_t;
1498 my_uint_least64_t uil64 = UINT_LEAST64_MAX;
1499 uil64 = UINT_LEAST64_MAX;
1500 typedef uintmax_t my_uintmax_t;
1501 my_uintmax_t uim = UINTMAX_MAX;
1502 uim = UINTMAX_MAX;
1503 typedef uintptr_t my_uintptr_t;
1504 my_uintptr_t uip = UINTPTR_MAX;
1505 uip = UINTPTR_MAX;
1506 ],[glibcxx_cv_c99_stdint_tr1=yes],
1507 [glibcxx_cv_c99_stdint_tr1=no])
1508 ])
1509 AC_MSG_RESULT($glibcxx_cv_c99_stdint_tr1)
1510 if test x"$glibcxx_cv_c99_stdint_tr1" = x"yes"; then
1511 AC_DEFINE(_GLIBCXX_USE_C99_STDINT_TR1, 1,
1512 [Define if C99 types in <stdint.h> should be imported in
1513 <tr1/cstdint> in namespace std::tr1.])
1514 fi
1516 # Check for the existence of <math.h> functions.
1517 AC_MSG_CHECKING([for ISO C99 support to TR1 in <math.h>])
1518 AC_CACHE_VAL(glibcxx_cv_c99_math_tr1, [
1519 AC_TRY_COMPILE([#include <math.h>],
1520 [typedef double_t my_double_t;
1521 typedef float_t my_float_t;
1522 acosh(0.0);
1523 acoshf(0.0f);
1524 acoshl(0.0l);
1525 asinh(0.0);
1526 asinhf(0.0f);
1527 asinhl(0.0l);
1528 atanh(0.0);
1529 atanhf(0.0f);
1530 atanhl(0.0l);
1531 cbrt(0.0);
1532 cbrtf(0.0f);
1533 cbrtl(0.0l);
1534 copysign(0.0, 0.0);
1535 copysignf(0.0f, 0.0f);
1536 copysignl(0.0l, 0.0l);
1537 erf(0.0);
1538 erff(0.0f);
1539 erfl(0.0l);
1540 erfc(0.0);
1541 erfcf(0.0f);
1542 erfcl(0.0l);
1543 exp2(0.0);
1544 exp2f(0.0f);
1545 exp2l(0.0l);
1546 expm1(0.0);
1547 expm1f(0.0f);
1548 expm1l(0.0l);
1549 fdim(0.0, 0.0);
1550 fdimf(0.0f, 0.0f);
1551 fdiml(0.0l, 0.0l);
1552 fma(0.0, 0.0, 0.0);
1553 fmaf(0.0f, 0.0f, 0.0f);
1554 fmal(0.0l, 0.0l, 0.0l);
1555 fmax(0.0, 0.0);
1556 fmaxf(0.0f, 0.0f);
1557 fmaxl(0.0l, 0.0l);
1558 fmin(0.0, 0.0);
1559 fminf(0.0f, 0.0f);
1560 fminl(0.0l, 0.0l);
1561 hypot(0.0, 0.0);
1562 hypotf(0.0f, 0.0f);
1563 hypotl(0.0l, 0.0l);
1564 ilogb(0.0);
1565 ilogbf(0.0f);
1566 ilogbl(0.0l);
1567 lgamma(0.0);
1568 lgammaf(0.0f);
1569 lgammal(0.0l);
1570 llrint(0.0);
1571 llrintf(0.0f);
1572 llrintl(0.0l);
1573 llround(0.0);
1574 llroundf(0.0f);
1575 llroundl(0.0l);
1576 log1p(0.0);
1577 log1pf(0.0f);
1578 log1pl(0.0l);
1579 log2(0.0);
1580 log2f(0.0f);
1581 log2l(0.0l);
1582 logb(0.0);
1583 logbf(0.0f);
1584 logbl(0.0l);
1585 lrint(0.0);
1586 lrintf(0.0f);
1587 lrintl(0.0l);
1588 lround(0.0);
1589 lroundf(0.0f);
1590 lroundl(0.0l);
1591 nan(0);
1592 nanf(0);
1593 nanl(0);
1594 nearbyint(0.0);
1595 nearbyintf(0.0f);
1596 nearbyintl(0.0l);
1597 nextafter(0.0, 0.0);
1598 nextafterf(0.0f, 0.0f);
1599 nextafterl(0.0l, 0.0l);
1600 nexttoward(0.0, 0.0);
1601 nexttowardf(0.0f, 0.0f);
1602 nexttowardl(0.0l, 0.0l);
1603 remainder(0.0, 0.0);
1604 remainderf(0.0f, 0.0f);
1605 remainderl(0.0l, 0.0l);
1606 remquo(0.0, 0.0, 0);
1607 remquof(0.0f, 0.0f, 0);
1608 remquol(0.0l, 0.0l, 0);
1609 rint(0.0);
1610 rintf(0.0f);
1611 rintl(0.0l);
1612 round(0.0);
1613 roundf(0.0f);
1614 roundl(0.0l);
1615 scalbln(0.0, 0l);
1616 scalblnf(0.0f, 0l);
1617 scalblnl(0.0l, 0l);
1618 scalbn(0.0, 0);
1619 scalbnf(0.0f, 0);
1620 scalbnl(0.0l, 0);
1621 tgamma(0.0);
1622 tgammaf(0.0f);
1623 tgammal(0.0l);
1624 trunc(0.0);
1625 truncf(0.0f);
1626 truncl(0.0l);
1627 ],[glibcxx_cv_c99_math_tr1=yes], [glibcxx_cv_c99_math_tr1=no])
1628 ])
1629 AC_MSG_RESULT($glibcxx_cv_c99_math_tr1)
1630 if test x"$glibcxx_cv_c99_math_tr1" = x"yes"; then
1631 AC_DEFINE(_GLIBCXX_USE_C99_MATH_TR1, 1,
1632 [Define if C99 functions or macros in <math.h> should be imported
1633 in <tr1/cmath> in namespace std::tr1.])
1634 fi
1636 # Check for the existence of <inttypes.h> functions (NB: doesn't make
1637 # sense if the glibcxx_cv_c99_stdint_tr1 check fails, per C99, 7.8/1).
1638 ac_c99_inttypes_tr1=no;
1639 if test x"$glibcxx_cv_c99_stdint_tr1" = x"yes"; then
1640 AC_MSG_CHECKING([for ISO C99 support to TR1 in <inttypes.h>])
1641 AC_TRY_COMPILE([#include <inttypes.h>],
1642 [intmax_t i, numer, denom, base;
1643 const char* s;
1644 char** endptr;
1645 intmax_t ret = imaxabs(i);
1646 imaxdiv_t dret = imaxdiv(numer, denom);
1647 ret = strtoimax(s, endptr, base);
1648 uintmax_t uret = strtoumax(s, endptr, base);
1649 ],[ac_c99_inttypes_tr1=yes], [ac_c99_inttypes_tr1=no])
1650 fi
1651 AC_MSG_RESULT($ac_c99_inttypes_tr1)
1652 if test x"$ac_c99_inttypes_tr1" = x"yes"; then
1653 AC_DEFINE(_GLIBCXX_USE_C99_INTTYPES_TR1, 1,
1654 [Define if C99 functions in <inttypes.h> should be imported in
1655 <tr1/cinttypes> in namespace std::tr1.])
1656 fi
1658 # Check for the existence of whcar_t <inttypes.h> functions (NB: doesn't
1659 # make sense if the glibcxx_cv_c99_stdint_tr1 check fails, per C99, 7.8/1).
1660 ac_c99_inttypes_wchar_t_tr1=no;
1661 if test x"$glibcxx_cv_c99_stdint_tr1" = x"yes"; then
1662 AC_MSG_CHECKING([for wchar_t ISO C99 support to TR1 in <inttypes.h>])
1663 AC_TRY_COMPILE([#include <inttypes.h>],
1664 [intmax_t base;
1665 const wchar_t* s;
1666 wchar_t** endptr;
1667 intmax_t ret = wcstoimax(s, endptr, base);
1668 uintmax_t uret = wcstoumax(s, endptr, base);
1669 ],[ac_c99_inttypes_wchar_t_tr1=yes],
1670 [ac_c99_inttypes_wchar_t_tr1=no])
1671 fi
1672 AC_MSG_RESULT($ac_c99_inttypes_wchar_t_tr1)
1673 if test x"$ac_c99_inttypes_wchar_t_tr1" = x"yes"; then
1674 AC_DEFINE(_GLIBCXX_USE_C99_INTTYPES_WCHAR_T_TR1, 1,
1675 [Define if wchar_t C99 functions in <inttypes.h> should be
1676 imported in <tr1/cinttypes> in namespace std::tr1.])
1677 fi
1679 # Check for the existence of the <stdbool.h> header.
1680 AC_CHECK_HEADERS(stdbool.h)
1682 # Check for the existence of the <stdalign.h> header.
1683 AC_CHECK_HEADERS(stdalign.h)
1685 CXXFLAGS="$ac_save_CXXFLAGS"
1686 AC_LANG_RESTORE
1687 ])
1689 dnl
1690 dnl Check whether "/dev/random" and "/dev/urandom" are available for the
1691 dnl random_device of "TR1" (Chapter 5.1, "Random number generation").
1692 dnl
1693 AC_DEFUN([GLIBCXX_CHECK_RANDOM_TR1], [
1695 AC_MSG_CHECKING([for "/dev/random" and "/dev/urandom" for TR1 random_device])
1696 AC_CACHE_VAL(glibcxx_cv_random_tr1, [
1697 if test -r /dev/random && test -r /dev/urandom; then
1698 glibcxx_cv_random_tr1=yes;
1699 else
1700 glibcxx_cv_random_tr1=no;
1701 fi
1702 ])
1703 AC_MSG_RESULT($glibcxx_cv_random_tr1)
1705 if test x"$glibcxx_cv_random_tr1" = x"yes"; then
1706 AC_DEFINE(_GLIBCXX_USE_RANDOM_TR1, 1,
1707 [Define if /dev/random and /dev/urandom are available for
1708 the random_device of TR1 (Chapter 5.1).])
1709 fi
1711 ])
1713 dnl
1714 dnl Compute the EOF, SEEK_CUR, and SEEK_END integer constants.
1715 dnl
1716 AC_DEFUN([GLIBCXX_COMPUTE_STDIO_INTEGER_CONSTANTS], [
1718 AC_CACHE_CHECK([for the value of EOF], glibcxx_cv_stdio_eof, [
1719 AC_COMPUTE_INT([glibcxx_cv_stdio_eof], [[EOF]],
1720 [#include <stdio.h>],
1721 [AC_MSG_ERROR([computing EOF failed])])
1722 ])
1723 AC_DEFINE_UNQUOTED(_GLIBCXX_STDIO_EOF, $glibcxx_cv_stdio_eof,
1724 [Define to the value of the EOF integer constant.])
1726 AC_CACHE_CHECK([for the value of SEEK_CUR], glibcxx_cv_stdio_seek_cur, [
1727 AC_COMPUTE_INT([glibcxx_cv_stdio_seek_cur], [[SEEK_CUR]],
1728 [#include <stdio.h>],
1729 [AC_MSG_ERROR([computing SEEK_CUR failed])])
1730 ])
1731 AC_DEFINE_UNQUOTED(_GLIBCXX_STDIO_SEEK_CUR, $glibcxx_cv_stdio_seek_cur,
1732 [Define to the value of the SEEK_CUR integer constant.])
1734 AC_CACHE_CHECK([for the value of SEEK_END], glibcxx_cv_stdio_seek_end, [
1735 AC_COMPUTE_INT([glibcxx_cv_stdio_seek_end], [[SEEK_END]],
1736 [#include <stdio.h>],
1737 [AC_MSG_ERROR([computing SEEK_END failed])])
1738 ])
1739 AC_DEFINE_UNQUOTED(_GLIBCXX_STDIO_SEEK_END, $glibcxx_cv_stdio_seek_end,
1740 [Define to the value of the SEEK_END integer constant.])
1741 ])
1743 dnl
1744 dnl Check whether required C++ overloads are present in <stdio.h>.
1745 dnl
1746 AC_DEFUN([GLIBCXX_CHECK_STDIO_PROTO], [
1748 AC_LANG_SAVE
1749 AC_LANG_CPLUSPLUS
1751 AC_MSG_CHECKING([for gets declaration])
1752 AC_CACHE_VAL(glibcxx_cv_gets, [
1753 AC_COMPILE_IFELSE([AC_LANG_SOURCE(
1754 [#include <stdio.h>
1755 namespace test
1756 {
1757 using ::gets;
1758 }
1759 ])],
1760 [glibcxx_cv_gets=yes],
1761 [glibcxx_cv_gets=no]
1762 )])
1764 if test $glibcxx_cv_gets = yes; then
1765 AC_DEFINE(HAVE_GETS, 1, [Define if gets is available in <stdio.h>.])
1766 fi
1767 AC_MSG_RESULT($glibcxx_cv_gets)
1769 AC_LANG_RESTORE
1770 ])
1772 dnl
1773 dnl Check whether macros, etc are present for <system_error>
1774 dnl
1775 AC_DEFUN([GLIBCXX_CHECK_SYSTEM_ERROR], [
1777 m4_pushdef([n_syserr], [1])dnl
1778 m4_foreach([syserr], [EOWNERDEAD, ENOTRECOVERABLE, ENOLINK, EPROTO, ENODATA,
1779 ENOSR, ENOSTR, ETIME, EBADMSG, ECANCELED,
1780 EOVERFLOW, ENOTSUP, EIDRM, ETXTBSY,
1781 ECHILD, ENOSPC, EPERM,
1782 ETIMEDOUT, EWOULDBLOCK],
1783 [m4_pushdef([SYSERR], m4_toupper(syserr))dnl
1784 AC_MSG_CHECKING([for syserr])
1785 AC_CACHE_VAL([glibcxx_cv_system_error[]n_syserr], [
1786 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <errno.h>]],
1787 [int i = syserr;])],
1788 [glibcxx_cv_system_error[]n_syserr=yes],
1789 [glibcxx_cv_system_error[]n_syserr=no])
1790 ])
1791 AC_MSG_RESULT([$glibcxx_cv_system_error[]n_syserr])
1792 if test x"$glibcxx_cv_system_error[]n_syserr" = x"yes"; then
1793 AC_DEFINE([HAVE_]SYSERR, 1, [Define if ]syserr[ exists.])
1794 fi
1795 m4_define([n_syserr], m4_incr(n_syserr))dnl
1796 m4_popdef([SYSERR])dnl
1797 ])
1798 m4_popdef([n_syserr])dnl
1799 ])
1801 dnl
1802 dnl Check for what type of C headers to use.
1803 dnl
1804 dnl --enable-cheaders= [does stuff].
1805 dnl --disable-cheaders [does not do anything, really].
1806 dnl + Usage: GLIBCXX_ENABLE_CHEADERS[(DEFAULT)]
1807 dnl Where DEFAULT is either 'c' or 'c_std' or 'c_global'.
1808 dnl
1809 AC_DEFUN([GLIBCXX_ENABLE_CHEADERS], [
1810 GLIBCXX_ENABLE(cheaders,$1,[[[=KIND]]],
1811 [construct "C" headers for g++], [permit c|c_std|c_global])
1812 AC_MSG_NOTICE("C" header strategy set to $enable_cheaders)
1814 C_INCLUDE_DIR='${glibcxx_srcdir}/include/'$enable_cheaders
1816 # Allow overrides to configure.host here.
1817 if test $enable_cheaders = c_global; then
1818 c_compatibility=yes
1819 fi
1821 AC_SUBST(C_INCLUDE_DIR)
1822 GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C, test $enable_cheaders = c)
1823 GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C_STD, test $enable_cheaders = c_std)
1824 GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C_GLOBAL, test $enable_cheaders = c_global)
1825 GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_COMPATIBILITY, test $c_compatibility = yes)
1826 ])
1829 dnl
1830 dnl Check for which locale library to use. The choice is mapped to
1831 dnl a subdirectory of config/locale.
1832 dnl
1833 dnl Default is generic.
1834 dnl
1835 AC_DEFUN([GLIBCXX_ENABLE_CLOCALE], [
1836 GLIBCXX_ENABLE(clocale,auto,[[[=MODEL]]],
1837 [use MODEL for target locale package],
1838 [permit generic|gnu|ieee_1003.1-2001|newlib|yes|no|auto])
1840 # Deal with gettext issues. Default to not using it (=no) until we detect
1841 # support for it later. Let the user turn it off via --e/d, but let that
1842 # default to on for easier handling.
1843 USE_NLS=no
1844 AC_ARG_ENABLE(nls,
1845 AC_HELP_STRING([--enable-nls],[use Native Language Support (default)]),
1846 [],
1847 [enable_nls=yes])
1849 # Either a known package, or "auto"
1850 if test $enable_clocale = no || test $enable_clocale = yes; then
1851 enable_clocale=auto
1852 fi
1853 enable_clocale_flag=$enable_clocale
1855 # Probe for locale model to use if none specified.
1856 # Default to "generic".
1857 if test $enable_clocale_flag = auto; then
1858 case ${target_os} in
1859 linux* | gnu* | kfreebsd*-gnu | knetbsd*-gnu)
1860 enable_clocale_flag=gnu
1861 ;;
1862 darwin* | freebsd*)
1863 enable_clocale_flag=darwin
1864 ;;
1865 *)
1866 if test x"$with_newlib" = x"yes"; then
1867 enable_clocale_flag=newlib
1868 else
1869 enable_clocale_flag=generic
1870 fi
1871 ;;
1872 esac
1873 fi
1875 # Sanity check model, and test for special functionality.
1876 if test $enable_clocale_flag = gnu; then
1877 AC_EGREP_CPP([_GLIBCXX_ok], [
1878 #include <features.h>
1879 #if (__GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 3)) && !defined(__UCLIBC__)
1880 _GLIBCXX_ok
1881 #endif
1882 ], enable_clocale_flag=gnu, enable_clocale_flag=generic)
1884 # Set it to scream when it hurts.
1885 ac_save_CFLAGS="$CFLAGS"
1886 CFLAGS="-Wimplicit-function-declaration -Werror"
1888 # Use strxfrm_l if available.
1889 AC_TRY_COMPILE([#define _GNU_SOURCE 1
1890 #include <string.h>
1891 #include <locale.h>],
1892 [char s[128]; __locale_t loc; strxfrm_l(s, "C", 5, loc);],
1893 AC_DEFINE(HAVE_STRXFRM_L, 1,
1894 [Define if strxfrm_l is available in <string.h>.]),)
1896 # Use strerror_l if available.
1897 AC_TRY_COMPILE([#define _GNU_SOURCE 1
1898 #include <string.h>
1899 #include <locale.h>],
1900 [__locale_t loc; strerror_l(5, loc);],
1901 AC_DEFINE(HAVE_STRERROR_L, 1,
1902 [Define if strerror_l is available in <string.h>.]),)
1904 CFLAGS="$ac_save_CFLAGS"
1905 fi
1907 # Perhaps use strerror_r if available, and strerror_l isn't.
1908 ac_save_CFLAGS="$CFLAGS"
1909 CFLAGS="-Wimplicit-function-declaration -Werror"
1910 AC_TRY_COMPILE([#define _GNU_SOURCE 1
1911 #include <string.h>
1912 #include <locale.h>],
1913 [char s[128]; strerror_r(5, s, 128);],
1914 AC_DEFINE(HAVE_STRERROR_R, 1,
1915 [Define if strerror_r is available in <string.h>.]),)
1916 CFLAGS="$ac_save_CFLAGS"
1918 # Set configure bits for specified locale package
1919 AC_MSG_CHECKING([for C locale to use])
1920 case ${enable_clocale_flag} in
1921 generic)
1922 AC_MSG_RESULT(generic)
1924 CLOCALE_H=config/locale/generic/c_locale.h
1925 CLOCALE_CC=config/locale/generic/c_locale.cc
1926 CCODECVT_CC=config/locale/generic/codecvt_members.cc
1927 CCOLLATE_CC=config/locale/generic/collate_members.cc
1928 CCTYPE_CC=config/locale/generic/ctype_members.cc
1929 CMESSAGES_H=config/locale/generic/messages_members.h
1930 CMESSAGES_CC=config/locale/generic/messages_members.cc
1931 CMONEY_CC=config/locale/generic/monetary_members.cc
1932 CNUMERIC_CC=config/locale/generic/numeric_members.cc
1933 CTIME_H=config/locale/generic/time_members.h
1934 CTIME_CC=config/locale/generic/time_members.cc
1935 CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1936 ;;
1937 darwin)
1938 AC_MSG_RESULT(darwin or freebsd)
1940 CLOCALE_H=config/locale/generic/c_locale.h
1941 CLOCALE_CC=config/locale/generic/c_locale.cc
1942 CCODECVT_CC=config/locale/generic/codecvt_members.cc
1943 CCOLLATE_CC=config/locale/generic/collate_members.cc
1944 CCTYPE_CC=config/locale/darwin/ctype_members.cc
1945 CMESSAGES_H=config/locale/generic/messages_members.h
1946 CMESSAGES_CC=config/locale/generic/messages_members.cc
1947 CMONEY_CC=config/locale/generic/monetary_members.cc
1948 CNUMERIC_CC=config/locale/generic/numeric_members.cc
1949 CTIME_H=config/locale/generic/time_members.h
1950 CTIME_CC=config/locale/generic/time_members.cc
1951 CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1952 ;;
1954 gnu)
1955 AC_MSG_RESULT(gnu)
1957 # Declare intention to use gettext, and add support for specific
1958 # languages.
1959 # For some reason, ALL_LINGUAS has to be before AM-GNU-GETTEXT
1960 ALL_LINGUAS="de fr"
1962 # Don't call AM-GNU-GETTEXT here. Instead, assume glibc.
1963 AC_CHECK_PROG(check_msgfmt, msgfmt, yes, no)
1964 if test x"$check_msgfmt" = x"yes" && test x"$enable_nls" = x"yes"; then
1965 USE_NLS=yes
1966 fi
1967 # Export the build objects.
1968 for ling in $ALL_LINGUAS; do \
1969 glibcxx_MOFILES="$glibcxx_MOFILES $ling.mo"; \
1970 glibcxx_POFILES="$glibcxx_POFILES $ling.po"; \
1971 done
1972 AC_SUBST(glibcxx_MOFILES)
1973 AC_SUBST(glibcxx_POFILES)
1975 CLOCALE_H=config/locale/gnu/c_locale.h
1976 CLOCALE_CC=config/locale/gnu/c_locale.cc
1977 CCODECVT_CC=config/locale/gnu/codecvt_members.cc
1978 CCOLLATE_CC=config/locale/gnu/collate_members.cc
1979 CCTYPE_CC=config/locale/gnu/ctype_members.cc
1980 CMESSAGES_H=config/locale/gnu/messages_members.h
1981 CMESSAGES_CC=config/locale/gnu/messages_members.cc
1982 CMONEY_CC=config/locale/gnu/monetary_members.cc
1983 CNUMERIC_CC=config/locale/gnu/numeric_members.cc
1984 CTIME_H=config/locale/gnu/time_members.h
1985 CTIME_CC=config/locale/gnu/time_members.cc
1986 CLOCALE_INTERNAL_H=config/locale/gnu/c++locale_internal.h
1987 ;;
1988 ieee_1003.1-2001)
1989 AC_MSG_RESULT(IEEE 1003.1)
1991 CLOCALE_H=config/locale/ieee_1003.1-2001/c_locale.h
1992 CLOCALE_CC=config/locale/ieee_1003.1-2001/c_locale.cc
1993 CCODECVT_CC=config/locale/generic/codecvt_members.cc
1994 CCOLLATE_CC=config/locale/generic/collate_members.cc
1995 CCTYPE_CC=config/locale/generic/ctype_members.cc
1996 CMESSAGES_H=config/locale/ieee_1003.1-2001/messages_members.h
1997 CMESSAGES_CC=config/locale/ieee_1003.1-2001/messages_members.cc
1998 CMONEY_CC=config/locale/generic/monetary_members.cc
1999 CNUMERIC_CC=config/locale/generic/numeric_members.cc
2000 CTIME_H=config/locale/generic/time_members.h
2001 CTIME_CC=config/locale/generic/time_members.cc
2002 CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
2003 ;;
2004 newlib)
2005 AC_MSG_RESULT(newlib)
2007 CLOCALE_H=config/locale/generic/c_locale.h
2008 CLOCALE_CC=config/locale/generic/c_locale.cc
2009 CCODECVT_CC=config/locale/generic/codecvt_members.cc
2010 CCOLLATE_CC=config/locale/generic/collate_members.cc
2011 CCTYPE_CC=config/locale/newlib/ctype_members.cc
2012 CMESSAGES_H=config/locale/generic/messages_members.h
2013 CMESSAGES_CC=config/locale/generic/messages_members.cc
2014 CMONEY_CC=config/locale/generic/monetary_members.cc
2015 CNUMERIC_CC=config/locale/generic/numeric_members.cc
2016 CTIME_H=config/locale/generic/time_members.h
2017 CTIME_CC=config/locale/generic/time_members.cc
2018 CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
2019 ;;
2020 esac
2022 # This is where the testsuite looks for locale catalogs, using the
2023 # -DLOCALEDIR define during testsuite compilation.
2024 glibcxx_localedir=${glibcxx_builddir}/po/share/locale
2025 AC_SUBST(glibcxx_localedir)
2027 # A standalone libintl (e.g., GNU libintl) may be in use.
2028 if test $USE_NLS = yes; then
2029 AC_CHECK_HEADERS([libintl.h], [], USE_NLS=no)
2030 AC_SEARCH_LIBS(gettext, intl, [], USE_NLS=no)
2031 fi
2032 if test $USE_NLS = yes; then
2033 AC_DEFINE(_GLIBCXX_USE_NLS, 1,
2034 [Define if NLS translations are to be used.])
2035 fi
2037 AC_SUBST(USE_NLS)
2038 AC_SUBST(CLOCALE_H)
2039 AC_SUBST(CMESSAGES_H)
2040 AC_SUBST(CCODECVT_CC)
2041 AC_SUBST(CCOLLATE_CC)
2042 AC_SUBST(CCTYPE_CC)
2043 AC_SUBST(CMESSAGES_CC)
2044 AC_SUBST(CMONEY_CC)
2045 AC_SUBST(CNUMERIC_CC)
2046 AC_SUBST(CTIME_H)
2047 AC_SUBST(CTIME_CC)
2048 AC_SUBST(CLOCALE_CC)
2049 AC_SUBST(CLOCALE_INTERNAL_H)
2050 ])
2053 dnl
2054 dnl Check for which std::allocator base class to use. The choice is
2055 dnl mapped from a subdirectory of include/ext.
2056 dnl
2057 dnl Default is new.
2058 dnl
2059 AC_DEFUN([GLIBCXX_ENABLE_ALLOCATOR], [
2060 AC_MSG_CHECKING([for std::allocator base class])
2061 GLIBCXX_ENABLE(libstdcxx-allocator,auto,[[[=KIND]]],
2062 [use KIND for target std::allocator base],
2063 [permit new|malloc|mt|bitmap|pool|yes|no|auto])
2065 # If they didn't use this option switch, or if they specified --enable
2066 # with no specific model, we'll have to look for one. If they
2067 # specified --disable (???), do likewise.
2068 if test $enable_libstdcxx_allocator = no ||
2069 test $enable_libstdcxx_allocator = yes;
2070 then
2071 enable_libstdcxx_allocator=auto
2072 fi
2074 # Either a known package, or "auto". Auto implies the default choice
2075 # for a particular platform.
2076 enable_libstdcxx_allocator_flag=$enable_libstdcxx_allocator
2078 # Probe for host-specific support if no specific model is specified.
2079 # Default to "new".
2080 if test $enable_libstdcxx_allocator_flag = auto; then
2081 case ${target_os} in
2082 linux* | gnu* | kfreebsd*-gnu | knetbsd*-gnu)
2083 enable_libstdcxx_allocator_flag=new
2084 ;;
2085 *)
2086 enable_libstdcxx_allocator_flag=new
2087 ;;
2088 esac
2089 fi
2090 AC_MSG_RESULT($enable_libstdcxx_allocator_flag)
2093 # Set configure bits for specified locale package
2094 case ${enable_libstdcxx_allocator_flag} in
2095 bitmap)
2096 ALLOCATOR_H=config/allocator/bitmap_allocator_base.h
2097 ALLOCATOR_NAME=__gnu_cxx::bitmap_allocator
2098 ;;
2099 malloc)
2100 ALLOCATOR_H=config/allocator/malloc_allocator_base.h
2101 ALLOCATOR_NAME=__gnu_cxx::malloc_allocator
2102 ;;
2103 mt)
2104 ALLOCATOR_H=config/allocator/mt_allocator_base.h
2105 ALLOCATOR_NAME=__gnu_cxx::__mt_alloc
2106 ;;
2107 new)
2108 ALLOCATOR_H=config/allocator/new_allocator_base.h
2109 ALLOCATOR_NAME=__gnu_cxx::new_allocator
2110 ;;
2111 pool)
2112 ALLOCATOR_H=config/allocator/pool_allocator_base.h
2113 ALLOCATOR_NAME=__gnu_cxx::__pool_alloc
2114 ;;
2115 esac
2117 AC_SUBST(ALLOCATOR_H)
2118 AC_SUBST(ALLOCATOR_NAME)
2119 ])
2122 dnl
2123 dnl Check for whether the Boost-derived checks should be turned on.
2124 dnl
2125 dnl --enable-concept-checks turns them on.
2126 dnl --disable-concept-checks leaves them off.
2127 dnl + Usage: GLIBCXX_ENABLE_CONCEPT_CHECKS[(DEFAULT)]
2128 dnl Where DEFAULT is either `yes' or `no'.
2129 dnl
2130 AC_DEFUN([GLIBCXX_ENABLE_CONCEPT_CHECKS], [
2131 GLIBCXX_ENABLE(concept-checks,$1,,[use Boost-derived template checks])
2132 if test $enable_concept_checks = yes; then
2133 AC_DEFINE(_GLIBCXX_CONCEPT_CHECKS, 1,
2134 [Define to use concept checking code from the boost libraries.])
2135 fi
2136 ])
2138 dnl
2139 dnl Use extern templates.
2140 dnl
2141 dnl --enable-extern-template defines _GLIBCXX_EXTERN_TEMPLATE to 1
2142 dnl --disable-extern-template defines _GLIBCXX_EXTERN_TEMPLATE to 0
2144 dnl + Usage: GLIBCXX_ENABLE_TEMPLATE[(DEFAULT)]
2145 dnl Where DEFAULT is `yes' or `no'.
2146 dnl
2147 AC_DEFUN([GLIBCXX_ENABLE_EXTERN_TEMPLATE], [
2149 GLIBCXX_ENABLE(extern-template,$1,,[enable extern template])
2151 AC_MSG_CHECKING([for extern template support])
2152 AC_MSG_RESULT([$enable_extern_template])
2154 GLIBCXX_CONDITIONAL(ENABLE_EXTERN_TEMPLATE, test $enable_extern_template = yes)
2155 ])
2157 dnl
2158 dnl Check for parallel mode pre-requisites, including OpenMP support.
2159 dnl
2160 dnl + Usage: GLIBCXX_ENABLE_PARALLEL
2161 dnl
2162 AC_DEFUN([GLIBCXX_ENABLE_PARALLEL], [
2164 enable_parallel=no;
2166 # See if configured libgomp/omp.h exists. (libgomp may be in
2167 # noconfigdirs but not explicitly disabled.)
2168 if echo " ${TARGET_CONFIGDIRS} " | grep " libgomp " > /dev/null 2>&1 ; then
2169 enable_parallel=yes;
2170 else
2171 AC_MSG_NOTICE([target-libgomp not built])
2172 fi
2174 AC_MSG_CHECKING([for parallel mode support])
2175 AC_MSG_RESULT([$enable_parallel])
2176 ])
2179 dnl
2180 dnl Check for which I/O library to use: stdio, or something specific.
2181 dnl
2182 dnl Default is stdio.
2183 dnl
2184 AC_DEFUN([GLIBCXX_ENABLE_CSTDIO], [
2185 AC_MSG_CHECKING([for underlying I/O to use])
2186 GLIBCXX_ENABLE(cstdio,stdio,[[[=PACKAGE]]],
2187 [use target-specific I/O package], [permit stdio])
2189 # Now that libio has been removed, you can have any color you want as long
2190 # as it's black. This is one big no-op until other packages are added, but
2191 # showing the framework never hurts.
2192 case ${enable_cstdio} in
2193 stdio)
2194 CSTDIO_H=config/io/c_io_stdio.h
2195 BASIC_FILE_H=config/io/basic_file_stdio.h
2196 BASIC_FILE_CC=config/io/basic_file_stdio.cc
2197 AC_MSG_RESULT(stdio)
2198 ;;
2199 esac
2201 AC_SUBST(CSTDIO_H)
2202 AC_SUBST(BASIC_FILE_H)
2203 AC_SUBST(BASIC_FILE_CC)
2204 ])
2207 dnl
2208 dnl Check for "unusual" flags to pass to the compiler while building.
2209 dnl
2210 dnl --enable-cxx-flags='-foo -bar -baz' is a general method for passing
2211 dnl experimental flags such as -fpch, -fIMI, -Dfloat=char, etc.
2212 dnl --disable-cxx-flags passes nothing.
2213 dnl + See http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00131.html
2214 dnl http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00284.html
2215 dnl http://gcc.gnu.org/ml/libstdc++/2000-q1/msg00035.html
2216 dnl + Usage: GLIBCXX_ENABLE_CXX_FLAGS(default flags)
2217 dnl If "default flags" is an empty string, the effect is the same
2218 dnl as --disable or --enable=no.
2219 dnl
2220 AC_DEFUN([GLIBCXX_ENABLE_CXX_FLAGS], [dnl
2221 AC_MSG_CHECKING([for extra compiler flags for building])
2222 GLIBCXX_ENABLE(cxx-flags,$1,[=FLAGS],
2223 [pass compiler FLAGS when building library],
2224 [case "x$enable_cxx_flags" in
2225 xno | x) enable_cxx_flags= ;;
2226 x-*) ;;
2227 *) AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
2228 esac])
2230 # Run through flags (either default or command-line) and set anything
2231 # extra (e.g., #defines) that must accompany particular g++ options.
2232 if test -n "$enable_cxx_flags"; then
2233 for f in $enable_cxx_flags; do
2234 case "$f" in
2235 -fhonor-std) ;;
2236 -*) ;;
2237 *) # and we're trying to pass /what/ exactly?
2238 AC_MSG_ERROR([compiler flags start with a -]) ;;
2239 esac
2240 done
2241 fi
2243 EXTRA_CXX_FLAGS="$enable_cxx_flags"
2244 AC_MSG_RESULT($EXTRA_CXX_FLAGS)
2245 AC_SUBST(EXTRA_CXX_FLAGS)
2246 ])
2249 dnl
2250 dnl Check to see if debugging libraries are to be built.
2251 dnl
2252 dnl --enable-libstdcxx-debug
2253 dnl builds a separate set of debugging libraries in addition to the
2254 dnl normal (shared, static) libstdc++ binaries.
2255 dnl
2256 dnl --disable-libstdcxx-debug
2257 dnl builds only one (non-debug) version of libstdc++.
2258 dnl
2259 dnl --enable-libstdcxx-debug-flags=FLAGS
2260 dnl iff --enable-debug == yes, then use FLAGS to build the debug library.
2261 dnl
2262 dnl + Usage: GLIBCXX_ENABLE_DEBUG[(DEFAULT)]
2263 dnl Where DEFAULT is either `yes' or `no'.
2264 dnl
2265 AC_DEFUN([GLIBCXX_ENABLE_DEBUG], [
2266 AC_MSG_CHECKING([for additional debug build])
2267 GLIBCXX_ENABLE(libstdcxx-debug,$1,,[build extra debug library])
2268 AC_MSG_RESULT($enable_libstdcxx_debug)
2269 GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_DEBUG, test $enable_libstdcxx_debug = yes)
2270 ])
2273 dnl
2274 dnl Check for explicit debug flags.
2275 dnl
2276 dnl --enable-libstdcxx-debug-flags='-O1'
2277 dnl is a general method for passing flags to be used when
2278 dnl building debug libraries with --enable-debug.
2279 dnl
2280 dnl --disable-libstdcxx-debug-flags does nothing.
2281 dnl + Usage: GLIBCXX_ENABLE_DEBUG_FLAGS(default flags)
2282 dnl If "default flags" is an empty string, the effect is the same
2283 dnl as --disable or --enable=no.
2284 dnl
2285 AC_DEFUN([GLIBCXX_ENABLE_DEBUG_FLAGS], [
2286 GLIBCXX_ENABLE(libstdcxx-debug-flags,[$1],[=FLAGS],
2287 [pass compiler FLAGS when building debug library],
2288 [case "x$enable_libstdcxx_debug_flags" in
2289 xno | x) enable_libstdcxx_debug_flags= ;;
2290 x-*) ;;
2291 *) AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
2292 esac])
2294 # Option parsed, now set things appropriately
2295 DEBUG_FLAGS="$enable_libstdcxx_debug_flags"
2296 AC_SUBST(DEBUG_FLAGS)
2298 AC_MSG_NOTICE([Debug build flags set to $DEBUG_FLAGS])
2299 ])
2302 dnl
2303 dnl Check if the user only wants a freestanding library implementation.
2304 dnl
2305 dnl --disable-hosted-libstdcxx will turn off most of the library build,
2306 dnl installing only the headers required by [17.4.1.3] and the language
2307 dnl support library. More than that will be built (to keep the Makefiles
2308 dnl conveniently clean), but not installed.
2309 dnl
2310 dnl Sets:
2311 dnl is_hosted (yes/no)
2312 dnl
2313 dnl Defines:
2314 dnl _GLIBCXX_HOSTED (always defined, either to 1 or 0)
2315 dnl
2316 AC_DEFUN([GLIBCXX_ENABLE_HOSTED], [
2317 AC_ARG_ENABLE([hosted-libstdcxx],
2318 AC_HELP_STRING([--disable-hosted-libstdcxx],
2319 [only build freestanding C++ runtime support]),,
2320 [case "$host" in
2321 arm*-*-symbianelf*)
2322 enable_hosted_libstdcxx=no
2323 ;;
2324 *)
2325 enable_hosted_libstdcxx=yes
2326 ;;
2327 esac])
2328 if test "$enable_hosted_libstdcxx" = no; then
2329 AC_MSG_NOTICE([Only freestanding libraries will be built])
2330 is_hosted=no
2331 hosted_define=0
2332 enable_abi_check=no
2333 enable_libstdcxx_pch=no
2334 else
2335 is_hosted=yes
2336 hosted_define=1
2337 fi
2338 GLIBCXX_CONDITIONAL(GLIBCXX_HOSTED, test $is_hosted = yes)
2339 AC_DEFINE_UNQUOTED(_GLIBCXX_HOSTED, $hosted_define,
2340 [Define to 1 if a full hosted library is built, or 0 if freestanding.])
2341 ])
2344 dnl
2345 dnl Check if the user wants a non-verbose library implementation.
2346 dnl
2347 dnl --disable-libstdcxx-verbose will turn off descriptive messages to
2348 dnl standard error on termination.
2349 dnl
2350 dnl Defines:
2351 dnl _GLIBCXX_VERBOSE (always defined, either to 1 or 0)
2352 dnl
2353 AC_DEFUN([GLIBCXX_ENABLE_VERBOSE], [
2354 AC_ARG_ENABLE([libstdcxx-verbose],
2355 AC_HELP_STRING([--disable-libstdcxx-verbose],
2356 [disable termination messages to standard error]),,
2357 [enable_libstdcxx_verbose=yes])
2358 if test x"$enable_libstdcxx_verbose" = xyes; then
2359 verbose_define=1
2360 else
2361 AC_MSG_NOTICE([verbose termination messages are disabled])
2362 verbose_define=0
2363 fi
2364 AC_DEFINE_UNQUOTED(_GLIBCXX_VERBOSE, $verbose_define,
2365 [Define to 1 if a verbose library is built, or 0 otherwise.])
2366 ])
2369 dnl
2370 dnl Check for template specializations for the 'long long' type.
2371 dnl The result determines only whether 'long long' I/O is enabled; things
2372 dnl like numeric_limits<> specializations are always available.
2373 dnl
2374 dnl --enable-long-long defines _GLIBCXX_USE_LONG_LONG
2375 dnl --disable-long-long leaves _GLIBCXX_USE_LONG_LONG undefined
2376 dnl + Usage: GLIBCXX_ENABLE_LONG_LONG[(DEFAULT)]
2377 dnl Where DEFAULT is either `yes' or `no'.
2378 dnl
2379 AC_DEFUN([GLIBCXX_ENABLE_LONG_LONG], [
2380 GLIBCXX_ENABLE(long-long,$1,,[enable template specializations for 'long long'])
2381 if test $enable_long_long = yes; then
2382 AC_DEFINE(_GLIBCXX_USE_LONG_LONG, 1,
2383 [Define if code specialized for long long should be used.])
2384 fi
2385 AC_MSG_CHECKING([for enabled long long specializations])
2386 AC_MSG_RESULT([$enable_long_long])
2387 ])
2390 dnl
2391 dnl Check for decimal floating point.
2392 dnl See:
2393 dnl http://gcc.gnu.org/onlinedocs/gcc/Decimal-Float.html#Decimal-Float
2394 dnl
2395 dnl This checks to see if the host supports decimal floating point types.
2396 dnl
2397 dnl Defines:
2398 dnl _GLIBCXX_USE_DECIMAL_FLOAT
2399 dnl
2400 AC_DEFUN([GLIBCXX_ENABLE_DECIMAL_FLOAT], [
2402 # Fake what AC_TRY_COMPILE does, without linking as this is
2403 # unnecessary for this test.
2405 cat > conftest.$ac_ext << EOF
2406 [#]line __oline__ "configure"
2407 int main()
2408 {
2409 _Decimal32 d1;
2410 _Decimal64 d2;
2411 _Decimal128 d3;
2412 return 0;
2413 }
2414 EOF
2416 AC_MSG_CHECKING([for ISO/IEC TR 24733 ])
2417 if AC_TRY_EVAL(ac_compile); then
2418 AC_DEFINE(_GLIBCXX_USE_DECIMAL_FLOAT, 1,
2419 [Define if ISO/IEC TR 24733 decimal floating point types are supported on this host.])
2420 enable_dfp=yes
2421 else
2422 enable_dfp=no
2423 fi
2424 AC_MSG_RESULT($enable_dfp)
2425 rm -f conftest*
2426 ])
2428 dnl
2429 dnl Check for GNU 128-bit integer and floating point types.
2430 dnl
2431 dnl Note: also checks that the types aren't standard types.
2432 dnl
2433 dnl Defines:
2434 dnl _GLIBCXX_USE_INT128
2435 dnl _GLIBCXX_USE_FLOAT128
2436 dnl
2437 AC_DEFUN([GLIBCXX_ENABLE_INT128_FLOAT128], [
2439 AC_LANG_SAVE
2440 AC_LANG_CPLUSPLUS
2442 # Fake what AC_TRY_COMPILE does, without linking as this is
2443 # unnecessary for this test.
2445 cat > conftest.$ac_ext << EOF
2446 [#]line __oline__ "configure"
2447 template<typename T1, typename T2>
2448 struct same
2449 { typedef T2 type; };
2451 template<typename T>
2452 struct same<T, T>;
2454 int main()
2455 {
2456 typename same<long, __int128>::type i1;
2457 typename same<long long, __int128>::type i2;
2458 }
2459 EOF
2461 AC_MSG_CHECKING([for __int128])
2462 if AC_TRY_EVAL(ac_compile); then
2463 AC_DEFINE(_GLIBCXX_USE_INT128, 1,
2464 [Define if __int128 is supported on this host.])
2465 enable_int128=yes
2466 else
2467 enable_int128=no
2468 fi
2469 AC_MSG_RESULT($enable_int128)
2470 rm -f conftest*
2472 cat > conftest.$ac_ext << EOF
2473 [#]line __oline__ "configure"
2474 template<typename T1, typename T2>
2475 struct same
2476 { typedef T2 type; };
2478 template<typename T>
2479 struct same<T, T>;
2481 int main()
2482 {
2483 typename same<double, __float128>::type f1;
2484 typename same<long double, __float128>::type f2;
2485 }
2486 EOF
2488 AC_MSG_CHECKING([for __float128])
2489 if AC_TRY_EVAL(ac_compile); then
2490 AC_DEFINE(_GLIBCXX_USE_FLOAT128, 1,
2491 [Define if __float128 is supported on this host.])
2492 enable_float128=yes
2493 else
2494 enable_float128=no
2495 fi
2496 AC_MSG_RESULT($enable_float128)
2497 rm -f conftest*
2499 AC_LANG_RESTORE
2500 ])
2502 dnl
2503 dnl Check for template specializations for the 'wchar_t' type.
2504 dnl
2505 dnl --enable-wchar_t defines _GLIBCXX_USE_WCHAR_T
2506 dnl --disable-wchar_t leaves _GLIBCXX_USE_WCHAR_T undefined
2507 dnl + Usage: GLIBCXX_ENABLE_WCHAR_T[(DEFAULT)]
2508 dnl Where DEFAULT is either `yes' or `no'.
2509 dnl
2510 dnl Necessary support must also be present.
2511 dnl
2512 AC_DEFUN([GLIBCXX_ENABLE_WCHAR_T], [
2513 GLIBCXX_ENABLE(wchar_t,$1,,[enable template specializations for 'wchar_t'])
2515 # Test wchar.h for mbstate_t, which is needed for char_traits and fpos.
2516 AC_CHECK_HEADERS(wchar.h, ac_has_wchar_h=yes, ac_has_wchar_h=no)
2517 AC_MSG_CHECKING([for mbstate_t])
2518 AC_TRY_COMPILE([#include <wchar.h>],
2519 [mbstate_t teststate;],
2520 have_mbstate_t=yes, have_mbstate_t=no)
2521 AC_MSG_RESULT($have_mbstate_t)
2522 if test x"$have_mbstate_t" = xyes; then
2523 AC_DEFINE(HAVE_MBSTATE_T,1,[Define if mbstate_t exists in wchar.h.])
2524 fi
2526 # Test it always, for use in GLIBCXX_ENABLE_C99, together with
2527 # ac_has_wchar_h.
2528 AC_CHECK_HEADERS(wctype.h, ac_has_wctype_h=yes, ac_has_wctype_h=no)
2530 if test x"$enable_wchar_t" = x"yes"; then
2532 AC_LANG_SAVE
2533 AC_LANG_CPLUSPLUS
2535 if test x"$ac_has_wchar_h" = xyes &&
2536 test x"$ac_has_wctype_h" = xyes; then
2537 AC_TRY_COMPILE([#include <wchar.h>
2538 #include <stddef.h>
2539 wint_t i;
2540 long l = WEOF;
2541 long j = WCHAR_MIN;
2542 long k = WCHAR_MAX;
2543 namespace test
2544 {
2545 using ::btowc;
2546 using ::fgetwc;
2547 using ::fgetws;
2548 using ::fputwc;
2549 using ::fputws;
2550 using ::fwide;
2551 using ::fwprintf;
2552 using ::fwscanf;
2553 using ::getwc;
2554 using ::getwchar;
2555 using ::mbrlen;
2556 using ::mbrtowc;
2557 using ::mbsinit;
2558 using ::mbsrtowcs;
2559 using ::putwc;
2560 using ::putwchar;
2561 using ::swprintf;
2562 using ::swscanf;
2563 using ::ungetwc;
2564 using ::vfwprintf;
2565 using ::vswprintf;
2566 using ::vwprintf;
2567 using ::wcrtomb;
2568 using ::wcscat;
2569 using ::wcschr;
2570 using ::wcscmp;
2571 using ::wcscoll;
2572 using ::wcscpy;
2573 using ::wcscspn;
2574 using ::wcsftime;
2575 using ::wcslen;
2576 using ::wcsncat;
2577 using ::wcsncmp;
2578 using ::wcsncpy;
2579 using ::wcspbrk;
2580 using ::wcsrchr;
2581 using ::wcsrtombs;
2582 using ::wcsspn;
2583 using ::wcsstr;
2584 using ::wcstod;
2585 using ::wcstok;
2586 using ::wcstol;
2587 using ::wcstoul;
2588 using ::wcsxfrm;
2589 using ::wctob;
2590 using ::wmemchr;
2591 using ::wmemcmp;
2592 using ::wmemcpy;
2593 using ::wmemmove;
2594 using ::wmemset;
2595 using ::wprintf;
2596 using ::wscanf;
2597 }
2598 ],[],[], [enable_wchar_t=no])
2599 else
2600 enable_wchar_t=no
2601 fi
2603 AC_LANG_RESTORE
2604 fi
2606 if test x"$enable_wchar_t" = x"yes"; then
2607 AC_DEFINE(_GLIBCXX_USE_WCHAR_T, 1,
2608 [Define if code specialized for wchar_t should be used.])
2609 fi
2611 AC_MSG_CHECKING([for enabled wchar_t specializations])
2612 AC_MSG_RESULT([$enable_wchar_t])
2613 ])
2616 dnl
2617 dnl Check to see if building and using a C++ precompiled header can be done.
2618 dnl
2619 dnl --enable-libstdcxx-pch=yes
2620 dnl default, this shows intent to use stdc++.h.gch If it looks like it
2621 dnl may work, after some light-hearted attempts to puzzle out compiler
2622 dnl support, flip bits on in include/Makefile.am
2623 dnl
2624 dnl --disable-libstdcxx-pch
2625 dnl turns off attempts to use or build stdc++.h.gch.
2626 dnl
2627 dnl Substs:
2628 dnl glibcxx_PCHFLAGS
2629 dnl
2630 AC_DEFUN([GLIBCXX_ENABLE_PCH], [
2631 GLIBCXX_ENABLE(libstdcxx-pch,$1,,[build pre-compiled libstdc++ headers])
2632 if test $enable_libstdcxx_pch = yes; then
2633 AC_CACHE_CHECK([for compiler with PCH support],
2634 [glibcxx_cv_prog_CXX_pch],
2635 [ac_save_CXXFLAGS="$CXXFLAGS"
2636 CXXFLAGS="$CXXFLAGS -Werror -Winvalid-pch -Wno-deprecated"
2637 AC_LANG_SAVE
2638 AC_LANG_CPLUSPLUS
2639 echo '#include <math.h>' > conftest.h
2640 if $CXX $CXXFLAGS $CPPFLAGS -x c++-header conftest.h \
2641 -o conftest.h.gch 1>&5 2>&1 &&
2642 echo '#error "pch failed"' > conftest.h &&
2643 echo '#include "conftest.h"' > conftest.cc &&
2644 $CXX -c $CXXFLAGS $CPPFLAGS conftest.cc 1>&5 2>&1 ;
2645 then
2646 glibcxx_cv_prog_CXX_pch=yes
2647 else
2648 glibcxx_cv_prog_CXX_pch=no
2649 fi
2650 rm -f conftest*
2651 CXXFLAGS=$ac_save_CXXFLAGS
2652 AC_LANG_RESTORE
2653 ])
2654 enable_libstdcxx_pch=$glibcxx_cv_prog_CXX_pch
2655 fi
2657 AC_MSG_CHECKING([for enabled PCH])
2658 AC_MSG_RESULT([$enable_libstdcxx_pch])
2660 GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_PCH, test $enable_libstdcxx_pch = yes)
2661 if test $enable_libstdcxx_pch = yes; then
2662 glibcxx_PCHFLAGS="-include bits/stdc++.h"
2663 else
2664 glibcxx_PCHFLAGS=""
2665 fi
2666 AC_SUBST(glibcxx_PCHFLAGS)
2667 ])
2670 dnl
2671 dnl Check for atomic builtins.
2672 dnl See:
2673 dnl http://gcc.gnu.org/onlinedocs/gcc/_005f_005fatomic-Builtins.html
2674 dnl
2675 dnl This checks to see if the host supports the compiler-generated
2676 dnl builtins for atomic operations for various integral sizes. Note, this
2677 dnl is intended to be an all-or-nothing switch, so all the atomic operations
2678 dnl that are used should be checked.
2679 dnl
2680 dnl Note:
2681 dnl libgomp and libgfortran use a link test, see CHECK_SYNC_FETCH_AND_ADD.
2682 dnl
2683 AC_DEFUN([GLIBCXX_ENABLE_ATOMIC_BUILTINS], [
2684 AC_LANG_SAVE
2685 AC_LANG_CPLUSPLUS
2686 old_CXXFLAGS="$CXXFLAGS"
2688 # Do link tests if possible, instead asm tests, limited to some platforms
2689 # see discussion in PR target/40134, PR libstdc++/40133 and the thread
2690 # starting at http://gcc.gnu.org/ml/gcc-patches/2009-07/msg00322.html
2691 atomic_builtins_link_tests=no
2692 if test x$gcc_no_link != xyes; then
2693 # Can do link tests. Limit to some tested platforms
2694 case "$host" in
2695 *-*-linux* | *-*-uclinux* | *-*-kfreebsd*-gnu | *-*-gnu*)
2696 atomic_builtins_link_tests=yes
2697 ;;
2698 esac
2699 fi
2701 if test x$atomic_builtins_link_tests = xyes; then
2703 # Do link tests.
2705 CXXFLAGS="$CXXFLAGS -fno-exceptions"
2707 AC_MSG_CHECKING([for atomic builtins for bool])
2708 AC_CACHE_VAL(glibcxx_cv_atomic_bool, [
2709 AC_TRY_LINK(
2710 [ ],
2711 [typedef bool atomic_type;
2712 atomic_type c1;
2713 atomic_type c2;
2714 atomic_type c3(0);
2715 __atomic_fetch_add(&c1, c2, __ATOMIC_RELAXED);
2716 __atomic_compare_exchange_n(&c1, &c2, c3, true, __ATOMIC_ACQ_REL,
2717 __ATOMIC_RELAXED);
2718 __atomic_test_and_set(&c1, __ATOMIC_RELAXED);
2719 __atomic_load_n(&c1, __ATOMIC_RELAXED);
2720 ],
2721 [glibcxx_cv_atomic_bool=yes],
2722 [glibcxx_cv_atomic_bool=no])
2723 ])
2724 AC_MSG_RESULT($glibcxx_cv_atomic_bool)
2726 AC_MSG_CHECKING([for atomic builtins for short])
2727 AC_CACHE_VAL(glibcxx_cv_atomic_short, [
2728 AC_TRY_LINK(
2729 [ ],
2730 [typedef short atomic_type;
2731 atomic_type c1;
2732 atomic_type c2;
2733 atomic_type c3(0);
2734 __atomic_fetch_add(&c1, c2, __ATOMIC_RELAXED);
2735 __atomic_compare_exchange_n(&c1, &c2, c3, true, __ATOMIC_ACQ_REL,
2736 __ATOMIC_RELAXED);
2737 __atomic_test_and_set(&c1, __ATOMIC_RELAXED);
2738 __atomic_load_n(&c1, __ATOMIC_RELAXED);
2739 ],
2740 [glibcxx_cv_atomic_short=yes],
2741 [glibcxx_cv_atomic_short=no])
2742 ])
2743 AC_MSG_RESULT($glibcxx_cv_atomic_short)
2745 AC_MSG_CHECKING([for atomic builtins for int])
2746 AC_CACHE_VAL(glibcxx_cv_atomic_int, [
2747 AC_TRY_LINK(
2748 [ ],
2749 [typedef int atomic_type;
2750 atomic_type c1;
2751 atomic_type c2;
2752 atomic_type c3(0);
2753 __atomic_fetch_add(&c1, c2, __ATOMIC_RELAXED);
2754 __atomic_compare_exchange_n(&c1, &c2, c3, true, __ATOMIC_ACQ_REL,
2755 __ATOMIC_RELAXED);
2756 __atomic_test_and_set(&c1, __ATOMIC_RELAXED);
2757 __atomic_load_n(&c1, __ATOMIC_RELAXED);
2758 ],
2759 [glibcxx_cv_atomic_int=yes],
2760 [glibcxx_cv_atomic_int=no])
2761 ])
2762 AC_MSG_RESULT($glibcxx_cv_atomic_int)
2764 AC_MSG_CHECKING([for atomic builtins for long long])
2765 AC_CACHE_VAL(glibcxx_cv_atomic_long_long, [
2766 AC_TRY_LINK(
2767 [ ],
2768 [typedef long long atomic_type;
2769 atomic_type c1;
2770 atomic_type c2;
2771 atomic_type c3(0);
2772 __atomic_fetch_add(&c1, c2, __ATOMIC_RELAXED);
2773 __atomic_compare_exchange_n(&c1, &c2, c3, true, __ATOMIC_ACQ_REL,
2774 __ATOMIC_RELAXED);
2775 __atomic_test_and_set(&c1, __ATOMIC_RELAXED);
2776 __atomic_load_n(&c1, __ATOMIC_RELAXED);
2777 ],
2778 [glibcxx_cv_atomic_long_long=yes],
2779 [glibcxx_cv_atomic_long_long=no])
2780 ])
2781 AC_MSG_RESULT($glibcxx_cv_atomic_long_long)
2783 else
2785 # Do asm tests.
2787 # Compile unoptimized.
2788 CXXFLAGS='-O0 -S'
2790 # Fake what AC_TRY_COMPILE does.
2792 cat > conftest.$ac_ext << EOF
2793 [#]line __oline__ "configure"
2794 int main()
2795 {
2796 typedef bool atomic_type;
2797 atomic_type c1;
2798 atomic_type c2;
2799 atomic_type c3(0);
2800 __atomic_fetch_add(&c1, c2, __ATOMIC_RELAXED);
2801 __atomic_compare_exchange_n(&c1, &c2, c3, true, __ATOMIC_ACQ_REL,
2802 __ATOMIC_RELAXED);
2803 __atomic_test_and_set(&c1, __ATOMIC_RELAXED);
2804 __atomic_load_n(&c1, __ATOMIC_RELAXED);
2806 return 0;
2807 }
2808 EOF
2810 AC_MSG_CHECKING([for atomic builtins for bool])
2811 if AC_TRY_EVAL(ac_compile); then
2812 if grep __atomic_ conftest.s >/dev/null 2>&1 ; then
2813 glibcxx_cv_atomic_bool=no
2814 else
2815 glibcxx_cv_atomic_bool=yes
2816 fi
2817 fi
2818 AC_MSG_RESULT($glibcxx_cv_atomic_bool)
2819 rm -f conftest*
2821 cat > conftest.$ac_ext << EOF
2822 [#]line __oline__ "configure"
2823 int main()
2824 {
2825 typedef short atomic_type;
2826 atomic_type c1;
2827 atomic_type c2;
2828 atomic_type c3(0);
2829 __atomic_fetch_add(&c1, c2, __ATOMIC_RELAXED);
2830 __atomic_compare_exchange_n(&c1, &c2, c3, true, __ATOMIC_ACQ_REL,
2831 __ATOMIC_RELAXED);
2832 __atomic_test_and_set(&c1, __ATOMIC_RELAXED);
2833 __atomic_load_n(&c1, __ATOMIC_RELAXED);
2835 return 0;
2836 }
2837 EOF
2839 AC_MSG_CHECKING([for atomic builtins for short])
2840 if AC_TRY_EVAL(ac_compile); then
2841 if grep __atomic_ conftest.s >/dev/null 2>&1 ; then
2842 glibcxx_cv_atomic_short=no
2843 else
2844 glibcxx_cv_atomic_short=yes
2845 fi
2846 fi
2847 AC_MSG_RESULT($glibcxx_cv_atomic_short)
2848 rm -f conftest*
2850 cat > conftest.$ac_ext << EOF
2851 [#]line __oline__ "configure"
2852 int main()
2853 {
2854 // NB: _Atomic_word not necessarily int.
2855 typedef int atomic_type;
2856 atomic_type c1;
2857 atomic_type c2;
2858 atomic_type c3(0);
2859 __atomic_fetch_add(&c1, c2, __ATOMIC_RELAXED);
2860 __atomic_compare_exchange_n(&c1, &c2, c3, true, __ATOMIC_ACQ_REL,
2861 __ATOMIC_RELAXED);
2862 __atomic_test_and_set(&c1, __ATOMIC_RELAXED);
2863 __atomic_load_n(&c1, __ATOMIC_RELAXED);
2865 return 0;
2866 }
2867 EOF
2869 AC_MSG_CHECKING([for atomic builtins for int])
2870 if AC_TRY_EVAL(ac_compile); then
2871 if grep __atomic_ conftest.s >/dev/null 2>&1 ; then
2872 glibcxx_cv_atomic_int=no
2873 else
2874 glibcxx_cv_atomic_int=yes
2875 fi
2876 fi
2877 AC_MSG_RESULT($glibcxx_cv_atomic_int)
2878 rm -f conftest*
2880 cat > conftest.$ac_ext << EOF
2881 [#]line __oline__ "configure"
2882 int main()
2883 {
2884 typedef long long atomic_type;
2885 atomic_type c1;
2886 atomic_type c2;
2887 atomic_type c3(0);
2888 __atomic_fetch_add(&c1, c2, __ATOMIC_RELAXED);
2889 __atomic_compare_exchange_n(&c1, &c2, c3, true, __ATOMIC_ACQ_REL,
2890 __ATOMIC_RELAXED);
2891 __atomic_test_and_set(&c1, __ATOMIC_RELAXED);
2892 __atomic_load_n(&c1, __ATOMIC_RELAXED);
2894 return 0;
2895 }
2896 EOF
2898 AC_MSG_CHECKING([for atomic builtins for long long])
2899 if AC_TRY_EVAL(ac_compile); then
2900 if grep __atomic_ conftest.s >/dev/null 2>&1 ; then
2901 glibcxx_cv_atomic_long_long=no
2902 else
2903 glibcxx_cv_atomic_long_long=yes
2904 fi
2905 fi
2906 AC_MSG_RESULT($glibcxx_cv_atomic_long_long)
2907 rm -f conftest*
2909 fi
2911 CXXFLAGS="$old_CXXFLAGS"
2912 AC_LANG_RESTORE
2914 # Set atomicity_dir to builtins if all but the long long test above passes.
2915 if test $glibcxx_cv_atomic_bool = yes \
2916 && test $glibcxx_cv_atomic_short = yes \
2917 && test $glibcxx_cv_atomic_int = yes; then
2918 AC_DEFINE(_GLIBCXX_ATOMIC_BUILTINS, 1,
2919 [Define if the compiler supports C++11 atomics.])
2920 atomicity_dir=cpu/generic/atomicity_builtins
2921 fi
2923 # If still generic, set to mutex.
2924 if test $atomicity_dir = "cpu/generic" ; then
2925 atomicity_dir=cpu/generic/atomicity_mutex
2926 AC_MSG_WARN([No native atomic operations are provided for this platform.])
2927 if test "x$target_thread_file" = xsingle; then
2928 AC_MSG_WARN([They cannot be faked when thread support is disabled.])
2929 AC_MSG_WARN([Thread-safety of certain classes is not guaranteed.])
2930 else
2931 AC_MSG_WARN([They will be faked using a mutex.])
2932 AC_MSG_WARN([Performance of certain classes will degrade as a result.])
2933 fi
2934 fi
2936 ])
2939 dnl
2940 dnl Check for exception handling support. If an explicit enable/disable
2941 dnl sjlj exceptions is given, we don't have to detect. Otherwise the
2942 dnl target may or may not support call frame exceptions.
2943 dnl
2944 dnl --enable-sjlj-exceptions forces the use of builtin setjmp.
2945 dnl --disable-sjlj-exceptions forces the use of call frame unwinding.
2946 dnl Neither one forces an attempt at detection.
2947 dnl
2948 dnl Defines:
2949 dnl _GLIBCXX_SJLJ_EXCEPTIONS if the compiler is configured for it
2950 dnl
2951 AC_DEFUN([GLIBCXX_ENABLE_SJLJ_EXCEPTIONS], [
2952 AC_MSG_CHECKING([for exception model to use])
2953 AC_LANG_SAVE
2954 AC_LANG_CPLUSPLUS
2955 GLIBCXX_ENABLE(sjlj-exceptions,auto,,
2956 [force use of builtin_setjmp for exceptions],
2957 [permit yes|no|auto])
2959 if test $enable_sjlj_exceptions = auto; then
2960 # Botheration. Now we've got to detect the exception model. Link tests
2961 # against libgcc.a are problematic since we've not been given proper -L
2962 # bits for single-tree newlib and libgloss.
2963 #
2964 # Fake what AC_TRY_COMPILE does. XXX Look at redoing this new-style.
2965 cat > conftest.$ac_ext << EOF
2966 [#]line __oline__ "configure"
2967 struct S { ~S(); };
2968 void bar();
2969 void foo()
2970 {
2971 S s;
2972 bar();
2973 }
2974 EOF
2975 old_CXXFLAGS="$CXXFLAGS"
2976 CXXFLAGS=-S
2977 if AC_TRY_EVAL(ac_compile); then
2978 if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
2979 enable_sjlj_exceptions=yes
2980 elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
2981 enable_sjlj_exceptions=no
2982 elif grep __cxa_end_cleanup conftest.s >/dev/null 2>&1 ; then
2983 enable_sjlj_exceptions=no
2984 fi
2985 fi
2986 CXXFLAGS="$old_CXXFLAGS"
2987 rm -f conftest*
2988 fi
2990 # This is a tad weird, for hysterical raisins. We have to map
2991 # enable/disable to two different models.
2992 case $enable_sjlj_exceptions in
2993 yes)
2994 AC_DEFINE(_GLIBCXX_SJLJ_EXCEPTIONS, 1,
2995 [Define if the compiler is configured for setjmp/longjmp exceptions.])
2996 ac_exception_model_name=sjlj
2997 ;;
2998 no)
2999 ac_exception_model_name="call frame"
3000 ;;
3001 *)
3002 AC_MSG_ERROR([unable to detect exception model])
3003 ;;
3004 esac
3005 AC_LANG_RESTORE
3006 AC_MSG_RESULT($ac_exception_model_name)
3007 ])
3010 dnl
3011 dnl Allow visibility attributes to be used on namespaces, objects, etc.
3012 dnl
3013 dnl --enable-libstdcxx-visibility enables attempt to use visibility attributes.
3014 dnl --disable-libstdcxx-visibility turns off all use of visibility attributes.
3015 dnl + Usage: GLIBCXX_ENABLE_LIBSTDCXX_VISIBILITY[(DEFAULT)]
3016 dnl Where DEFAULT is 'yes'.
3017 dnl
3018 AC_DEFUN([GLIBCXX_ENABLE_LIBSTDCXX_VISIBILITY], [
3019 GLIBCXX_ENABLE(libstdcxx-visibility,$1,,[enables visibility safe usage])
3021 if test x$enable_libstdcxx_visibility = xyes ; then
3022 dnl all hail libgfortran
3023 dnl Check whether the target supports hidden visibility.
3024 AC_CACHE_CHECK([whether the target supports hidden visibility],
3025 glibcxx_cv_have_attribute_visibility, [
3026 save_CFLAGS="$CFLAGS"
3027 CFLAGS="$CFLAGS -Werror"
3028 AC_TRY_COMPILE([void __attribute__((visibility("hidden"))) foo(void) { }],
3029 [], glibcxx_cv_have_attribute_visibility=yes,
3030 glibcxx_cv_have_attribute_visibility=no)
3031 CFLAGS="$save_CFLAGS"])
3032 if test $glibcxx_cv_have_attribute_visibility = no; then
3033 enable_libstdcxx_visibility=no
3034 fi
3035 fi
3037 GLIBCXX_CONDITIONAL(ENABLE_VISIBILITY, test $enable_libstdcxx_visibility = yes)
3038 AC_MSG_NOTICE([visibility supported: $enable_libstdcxx_visibility])
3039 ])
3042 dnl
3043 dnl Add version tags to symbols in shared library (or not), additionally
3044 dnl marking other symbols as private/local (or not).
3045 dnl
3046 dnl Sets libtool_VERSION, and determines shared library SONAME.
3047 dnl
3048 dnl This depends on GLIBCXX CHECK_LINKER_FEATURES, but without it assumes no.
3049 dnl
3050 dnl --enable-symvers=style adds a version script to the linker call when
3051 dnl creating the shared library. The choice of version script is
3052 dnl controlled by 'style'.
3053 dnl --disable-symvers does not.
3054 dnl
3055 dnl + Usage: GLIBCXX_ENABLE_SYMVERS[(DEFAULT)]
3056 dnl Where DEFAULT is either 'yes' or 'no'. Passing `yes' tries to
3057 dnl choose a default style based on linker characteristics. Passing
3058 dnl 'no' disables versioning.
3059 dnl
3060 AC_DEFUN([GLIBCXX_ENABLE_SYMVERS], [
3062 GLIBCXX_ENABLE(symvers,$1,[[[=STYLE]]],
3063 [enables symbol versioning of the shared library],
3064 [permit yes|no|gnu|gnu-versioned-namespace|darwin|darwin-export|sun])
3066 # If we never went through the GLIBCXX_CHECK_LINKER_FEATURES macro, then we
3067 # don't know enough about $LD to do tricks...
3068 AC_REQUIRE([GLIBCXX_CHECK_LINKER_FEATURES])
3069 # Sun style symbol versions needs GNU c++filt for make_sunver.pl to work
3070 # with extern "C++" in version scripts.
3071 AC_REQUIRE([GCC_PROG_GNU_CXXFILT])
3073 # Turn a 'yes' into a suitable default.
3074 if test x$enable_symvers = xyes ; then
3075 if test $enable_shared = no || test "x$LD" = x || test x$gcc_no_link = xyes; then
3076 enable_symvers=no
3077 else
3078 if test $with_gnu_ld = yes ; then
3079 case ${target_os} in
3080 hpux*)
3081 enable_symvers=no ;;
3082 *)
3083 enable_symvers=gnu ;;
3084 esac
3085 else
3086 case ${target_os} in
3087 darwin*)
3088 enable_symvers=darwin ;;
3089 # Sun symbol versioning exists since Solaris 2.5.
3090 solaris2.[[5-9]]* | solaris2.1[[0-9]]*)
3091 # make_sunver.pl needs GNU c++filt to support extern "C++" in
3092 # version scripts, so disable symbol versioning if none can be
3093 # found.
3094 if test -z "$ac_cv_path_CXXFILT"; then
3095 AC_MSG_WARN([=== You have requested Sun symbol versioning, but])
3096 AC_MSG_WARN([=== no GNU c++filt could be found.])
3097 AC_MSG_WARN([=== Symbol versioning will be disabled.])
3098 enable_symvers=no
3099 else
3100 enable_symvers=sun
3101 fi
3102 ;;
3103 *)
3104 enable_symvers=no ;;
3105 esac
3106 fi
3107 fi
3108 fi
3110 # Check to see if 'darwin' or 'darwin-export' can win.
3111 if test x$enable_symvers = xdarwin-export ; then
3112 enable_symvers=darwin
3113 fi
3115 # Check if 'sun' was requested on non-Solaris 2 platforms.
3116 if test x$enable_symvers = xsun ; then
3117 case ${target_os} in
3118 solaris2*)
3119 # All fine.
3120 ;;
3121 *)
3122 # Unlikely to work.
3123 AC_MSG_WARN([=== You have requested Sun symbol versioning, but])
3124 AC_MSG_WARN([=== you are not targetting Solaris 2.])
3125 AC_MSG_WARN([=== Symbol versioning will be disabled.])
3126 enable_symvers=no
3127 ;;
3128 esac
3129 fi
3131 # Check to see if 'gnu' can win.
3132 if test $enable_symvers = gnu ||
3133 test $enable_symvers = gnu-versioned-namespace ||
3134 test $enable_symvers = sun; then
3135 # Check to see if libgcc_s exists, indicating that shared libgcc is possible.
3136 AC_MSG_CHECKING([for shared libgcc])
3137 ac_save_CFLAGS="$CFLAGS"
3138 CFLAGS=' -lgcc_s'
3139 AC_TRY_LINK(, [return 0;], glibcxx_shared_libgcc=yes, glibcxx_shared_libgcc=no)
3140 CFLAGS="$ac_save_CFLAGS"
3141 if test $glibcxx_shared_libgcc = no; then
3142 cat > conftest.c <<EOF
3143 int main (void) { return 0; }
3144 EOF
3145 changequote(,)dnl
3146 glibcxx_libgcc_s_suffix=`${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
3147 -shared -shared-libgcc -o conftest.so \
3148 conftest.c -v 2>&1 >/dev/null \
3149 | sed -n 's/^.* -lgcc_s\([^ ]*\) .*$/\1/p'`
3150 changequote([,])dnl
3151 rm -f conftest.c conftest.so
3152 if test x${glibcxx_libgcc_s_suffix+set} = xset; then
3153 CFLAGS=" -lgcc_s$glibcxx_libgcc_s_suffix"
3154 AC_TRY_LINK(, [return 0;], glibcxx_shared_libgcc=yes)
3155 CFLAGS="$ac_save_CFLAGS"
3156 fi
3157 fi
3158 AC_MSG_RESULT($glibcxx_shared_libgcc)
3160 # For GNU ld, we need at least this version. The format is described in
3161 # GLIBCXX_CHECK_LINKER_FEATURES above.
3162 glibcxx_min_gnu_ld_version=21400
3164 # If no shared libgcc, can't win.
3165 if test $glibcxx_shared_libgcc != yes; then
3166 AC_MSG_WARN([=== You have requested GNU symbol versioning, but])
3167 AC_MSG_WARN([=== you are not building a shared libgcc_s.])
3168 AC_MSG_WARN([=== Symbol versioning will be disabled.])
3169 enable_symvers=no
3170 elif test $with_gnu_ld != yes && test $enable_symvers = sun; then
3171 : All interesting versions of Sun ld support sun style symbol versioning.
3172 elif test $with_gnu_ld != yes ; then
3173 # just fail for now
3174 AC_MSG_WARN([=== You have requested GNU symbol versioning, but])
3175 AC_MSG_WARN([=== you are not using the GNU linker.])
3176 AC_MSG_WARN([=== Symbol versioning will be disabled.])
3177 enable_symvers=no
3178 elif test $glibcxx_ld_is_gold = yes ; then
3179 : All versions of gold support symbol versioning.
3180 elif test $glibcxx_gnu_ld_version -lt $glibcxx_min_gnu_ld_version ; then
3181 # The right tools, the right setup, but too old. Fallbacks?
3182 AC_MSG_WARN(=== Linker version $glibcxx_gnu_ld_version is too old for)
3183 AC_MSG_WARN(=== full symbol versioning support in this release of GCC.)
3184 AC_MSG_WARN(=== You would need to upgrade your binutils to version)
3185 AC_MSG_WARN(=== $glibcxx_min_gnu_ld_version or later and rebuild GCC.)
3186 AC_MSG_WARN([=== Symbol versioning will be disabled.])
3187 enable_symvers=no
3188 fi
3189 fi
3191 # For libtool versioning info, format is CURRENT:REVISION:AGE
3192 libtool_VERSION=6:17:0
3194 # Everything parsed; figure out what files and settings to use.
3195 case $enable_symvers in
3196 no)
3197 SYMVER_FILE=config/abi/pre/none.ver
3198 ;;
3199 gnu)
3200 SYMVER_FILE=config/abi/pre/gnu.ver
3201 AC_DEFINE(_GLIBCXX_SYMVER_GNU, 1,
3202 [Define to use GNU versioning in the shared library.])
3203 ;;
3204 gnu-versioned-namespace)
3205 libtool_VERSION=7:0:0
3206 SYMVER_FILE=config/abi/pre/gnu-versioned-namespace.ver
3207 AC_DEFINE(_GLIBCXX_SYMVER_GNU_NAMESPACE, 1,
3208 [Define to use GNU namespace versioning in the shared library.])
3209 ;;
3210 darwin)
3211 SYMVER_FILE=config/abi/pre/gnu.ver
3212 AC_DEFINE(_GLIBCXX_SYMVER_DARWIN, 1,
3213 [Define to use darwin versioning in the shared library.])
3214 ;;
3215 sun)
3216 SYMVER_FILE=config/abi/pre/gnu.ver
3217 AC_DEFINE(_GLIBCXX_SYMVER_SUN, 1,
3218 [Define to use Sun versioning in the shared library.])
3219 ;;
3220 esac
3222 if test x$enable_symvers != xno ; then
3223 AC_DEFINE(_GLIBCXX_SYMVER, 1,
3224 [Define to use symbol versioning in the shared library.])
3225 fi
3227 AC_CACHE_CHECK([whether the target supports .symver directive],
3228 glibcxx_cv_have_as_symver_directive, [
3229 AC_TRY_COMPILE([void foo (void); __asm (".symver foo, bar@SYMVER");],
3230 [], glibcxx_cv_have_as_symver_directive=yes,
3231 glibcxx_cv_have_as_symver_directive=no)])
3232 if test $glibcxx_cv_have_as_symver_directive = yes; then
3233 AC_DEFINE(HAVE_AS_SYMVER_DIRECTIVE, 1,
3234 [Define to 1 if the target assembler supports .symver directive.])
3235 fi
3237 AC_SUBST(SYMVER_FILE)
3238 AC_SUBST(port_specific_symbol_files)
3239 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS, test $enable_symvers != no)
3240 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS_GNU, test $enable_symvers = gnu)
3241 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS_GNU_NAMESPACE, test $enable_symvers = gnu-versioned-namespace)
3242 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS_DARWIN, test $enable_symvers = darwin)
3243 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS_SUN, test $enable_symvers = sun)
3244 AC_MSG_NOTICE(versioning on shared library symbols is $enable_symvers)
3246 if test $enable_symvers != no ; then
3247 case ${target_os} in
3248 # The Solaris 2 runtime linker doesn't support the GNU extension of
3249 # binding the same symbol to different versions
3250 solaris2*)
3251 ;;
3252 # Other platforms with GNU symbol versioning (GNU/Linux, more?) do.
3253 *)
3254 AC_DEFINE(HAVE_SYMVER_SYMBOL_RENAMING_RUNTIME_SUPPORT, 1,
3255 [Define to 1 if the target runtime linker supports binding the same symbol to different versions.])
3256 ;;
3257 esac
3258 fi
3260 # Now, set up compatibility support, if any.
3261 # In addition, need this to deal with std::size_t mangling in
3262 # src/compatibility.cc. In a perfect world, could use
3263 # typeid(std::size_t).name()[0] to do direct substitution.
3264 AC_MSG_CHECKING([for size_t as unsigned int])
3265 ac_save_CFLAGS="$CFLAGS"
3266 CFLAGS="-Werror"
3267 AC_TRY_COMPILE(, [__SIZE_TYPE__* stp; unsigned int* uip; stp = uip;],
3268 [glibcxx_size_t_is_i=yes], [glibcxx_size_t_is_i=no])
3269 CFLAGS=$ac_save_CFLAGS
3270 if test "$glibcxx_size_t_is_i" = yes; then
3271 AC_DEFINE(_GLIBCXX_SIZE_T_IS_UINT, 1, [Define if size_t is unsigned int.])
3272 fi
3273 AC_MSG_RESULT([$glibcxx_size_t_is_i])
3275 AC_MSG_CHECKING([for ptrdiff_t as int])
3276 ac_save_CFLAGS="$CFLAGS"
3277 CFLAGS="-Werror"
3278 AC_TRY_COMPILE(, [__PTRDIFF_TYPE__* ptp; int* ip; ptp = ip;],
3279 [glibcxx_ptrdiff_t_is_i=yes], [glibcxx_ptrdiff_t_is_i=no])
3280 CFLAGS=$ac_save_CFLAGS
3281 if test "$glibcxx_ptrdiff_t_is_i" = yes; then
3282 AC_DEFINE(_GLIBCXX_PTRDIFF_T_IS_INT, 1, [Define if ptrdiff_t is int.])
3283 fi
3284 AC_MSG_RESULT([$glibcxx_ptrdiff_t_is_i])
3285 ])
3288 dnl
3289 dnl Setup to use the gcc gthr.h thread-specific memory and mutex model.
3290 dnl We must stage the required headers so that they will be installed
3291 dnl with the library (unlike libgcc, the STL implementation is provided
3292 dnl solely within headers). Since we must not inject random user-space
3293 dnl macro names into user-provided C++ code, we first stage into <file>-in
3294 dnl and process to <file> with an output command. The reason for a two-
3295 dnl stage process here is to correctly handle $srcdir!=$objdir without
3296 dnl having to write complex code (the sed commands to clean the macro
3297 dnl namespace are complex and fragile enough as it is). We must also
3298 dnl add a relative path so that -I- is supported properly.
3299 dnl
3300 AC_DEFUN([GLIBCXX_ENABLE_THREADS], [
3301 AC_MSG_CHECKING([for thread model used by GCC])
3302 target_thread_file=`$CXX -v 2>&1 | sed -n 's/^Thread model: //p'`
3303 AC_MSG_RESULT([$target_thread_file])
3304 ])
3307 dnl
3308 dnl Check if gthread implementation defines the types and functions
3309 dnl required by the c++0x thread library. Conforming gthread
3310 dnl implementations can define __GTHREADS_CXX0X to enable use with c++0x.
3311 dnl
3312 dnl GLIBCXX_ENABLE_SYMVERS must be done before this.
3313 dnl
3314 AC_DEFUN([GLIBCXX_CHECK_GTHREADS], [
3315 GLIBCXX_ENABLE(libstdcxx-threads,auto,,[enable C++11 threads support])
3317 if test x$enable_libstdcxx_threads = xauto ||
3318 test x$enable_libstdcxx_threads = xyes; then
3320 AC_LANG_SAVE
3321 AC_LANG_CPLUSPLUS
3323 ac_save_CXXFLAGS="$CXXFLAGS"
3324 CXXFLAGS="$CXXFLAGS -fno-exceptions \
3325 -I${toplevel_srcdir}/libgcc -I${toplevel_builddir}/libgcc"
3327 target_thread_file=`$CXX -v 2>&1 | sed -n 's/^Thread model: //p'`
3328 case $target_thread_file in
3329 posix)
3330 CXXFLAGS="$CXXFLAGS -DSUPPORTS_WEAK -DGTHREAD_USE_WEAK -D_PTHREADS"
3331 esac
3333 AC_MSG_CHECKING([whether it can be safely assumed that mutex_timedlock is available])
3335 AC_TRY_COMPILE([#include <unistd.h>],
3336 [
3337 // In case of POSIX threads check _POSIX_TIMEOUTS.
3338 #if (defined(_PTHREADS) \
3339 && (!defined(_POSIX_TIMEOUTS) || _POSIX_TIMEOUTS <= 0))
3340 #error
3341 #endif
3342 ], [ac_gthread_use_mutex_timedlock=1], [ac_gthread_use_mutex_timedlock=0])
3344 AC_DEFINE_UNQUOTED(_GTHREAD_USE_MUTEX_TIMEDLOCK, $ac_gthread_use_mutex_timedlock,
3345 [Define to 1 if mutex_timedlock is available.])
3347 if test $ac_gthread_use_mutex_timedlock = 1 ; then res_mutex_timedlock=yes ;
3348 else res_mutex_timedlock=no ; fi
3349 AC_MSG_RESULT([$res_mutex_timedlock])
3351 AC_MSG_CHECKING([for gthreads library])
3353 AC_TRY_COMPILE([#include "gthr.h"],
3354 [
3355 #ifndef __GTHREADS_CXX0X
3356 #error
3357 #endif
3358 ], [case $target_os in
3359 # gthreads support breaks symbol versioning on Solaris 9 (PR
3360 # libstdc++/52189).
3361 solaris2.9*)
3362 if test x$enable_symvers = xno; then
3363 ac_has_gthreads=yes
3364 elif test x$enable_libstdcxx_threads = xyes; then
3365 AC_MSG_WARN([You have requested C++11 threads support, but])
3366 AC_MSG_WARN([this breaks symbol versioning.])
3367 ac_has_gthreads=yes
3368 else
3369 ac_has_gthreads=no
3370 fi
3371 ;;
3372 *)
3373 ac_has_gthreads=yes
3374 ;;
3375 esac],
3376 [ac_has_gthreads=no])
3377 else
3378 ac_has_gthreads=no
3379 fi
3381 AC_MSG_RESULT([$ac_has_gthreads])
3383 if test x"$ac_has_gthreads" = x"yes"; then
3384 AC_DEFINE(_GLIBCXX_HAS_GTHREADS, 1,
3385 [Define if gthreads library is available.])
3386 fi
3388 CXXFLAGS="$ac_save_CXXFLAGS"
3389 AC_LANG_RESTORE
3390 ])
3393 # Check whether LC_MESSAGES is available in <locale.h>.
3394 # Ulrich Drepper <drepper@cygnus.com>, 1995.
3395 #
3396 # This file file be copied and used freely without restrictions. It can
3397 # be used in projects which are not available under the GNU Public License
3398 # but which still want to provide support for the GNU gettext functionality.
3399 # Please note that the actual code is *not* freely available.
3400 AC_DEFUN([AC_LC_MESSAGES], [
3401 AC_CHECK_HEADER(locale.h, [
3402 AC_CACHE_CHECK([for LC_MESSAGES], ac_cv_val_LC_MESSAGES,
3403 [AC_TRY_COMPILE([#include <locale.h>], [return LC_MESSAGES],
3404 ac_cv_val_LC_MESSAGES=yes, ac_cv_val_LC_MESSAGES=no)])
3405 if test $ac_cv_val_LC_MESSAGES = yes; then
3406 AC_DEFINE(HAVE_LC_MESSAGES, 1,
3407 [Define if LC_MESSAGES is available in <locale.h>.])
3408 fi
3409 ])
3410 ])
3412 dnl
3413 dnl Check whether rdrand is supported in the assembler.
3414 AC_DEFUN([GLIBCXX_CHECK_X86_RDRAND], [
3415 AC_MSG_CHECKING([for rdrand support in assembler])
3416 AC_CACHE_VAL(ac_cv_x86_rdrand, [
3417 ac_cv_x86_rdrand=no
3418 case "$target" in
3419 i?86-*-* | \
3420 x86_64-*-*)
3421 AC_TRY_COMPILE(, [asm("rdrand %eax");],
3422 [ac_cv_x86_rdrand=yes], [ac_cv_x86_rdrand=no])
3423 esac
3424 ])
3425 if test $ac_cv_x86_rdrand = yes; then
3426 AC_DEFINE(_GLIBCXX_X86_RDRAND, 1,
3427 [ Defined if as can handle rdrand. ])
3428 fi
3429 AC_MSG_RESULT($ac_cv_x86_rdrand)
3430 ])
3432 dnl
3433 dnl Check whether get_nprocs is available in <sys/sysinfo.h>, and define _GLIBCXX_USE_GET_NPROCS.
3434 dnl
3435 AC_DEFUN([GLIBCXX_CHECK_GET_NPROCS], [
3437 AC_LANG_SAVE
3438 AC_LANG_CPLUSPLUS
3439 ac_save_CXXFLAGS="$CXXFLAGS"
3440 CXXFLAGS="$CXXFLAGS -fno-exceptions"
3442 AC_MSG_CHECKING([for get_nprocs])
3443 AC_CACHE_VAL(glibcxx_cv_GET_NPROCS, [
3444 GCC_TRY_COMPILE_OR_LINK(
3445 [#include <sys/sysinfo.h>],
3446 [int n = get_nprocs();],
3447 [glibcxx_cv_GET_NPROCS=yes],
3448 [glibcxx_cv_GET_NPROCS=no])
3449 ])
3450 if test $glibcxx_cv_GET_NPROCS = yes; then
3451 AC_DEFINE(_GLIBCXX_USE_GET_NPROCS, 1, [Define if get_nprocs is available in <sys/sysinfo.h>.])
3452 fi
3453 AC_MSG_RESULT($glibcxx_cv_GET_NPROCS)
3455 CXXFLAGS="$ac_save_CXXFLAGS"
3456 AC_LANG_RESTORE
3457 ])
3459 dnl
3460 dnl Check whether sysconf(_SC_NPROCESSORS_ONLN) is available in <unistd.h>, and define _GLIBCXX_USE_SC_NPROCESSORS_ONLN.
3461 dnl
3462 AC_DEFUN([GLIBCXX_CHECK_SC_NPROCESSORS_ONLN], [
3464 AC_LANG_SAVE
3465 AC_LANG_CPLUSPLUS
3466 ac_save_CXXFLAGS="$CXXFLAGS"
3467 CXXFLAGS="$CXXFLAGS -fno-exceptions"
3469 AC_MSG_CHECKING([for _SC_NPROCESSORS_ONLN])
3470 AC_CACHE_VAL(glibcxx_cv_SC_NPROCESSORS_ONLN, [
3471 GCC_TRY_COMPILE_OR_LINK(
3472 [#include <unistd.h>],
3473 [int n = sysconf(_SC_NPROCESSORS_ONLN);],
3474 [glibcxx_cv_SC_NPROCESSORS_ONLN=yes],
3475 [glibcxx_cv_SC_NPROCESSORS_ONLN=no])
3476 ])
3477 if test $glibcxx_cv_SC_NPROCESSORS_ONLN = yes; then
3478 AC_DEFINE(_GLIBCXX_USE_SC_NPROCESSORS_ONLN, 1, [Define if _SC_NPROCESSORS_ONLN is available in <unistd.h>.])
3479 fi
3480 AC_MSG_RESULT($glibcxx_cv_SC_NPROCESSORS_ONLN)
3482 CXXFLAGS="$ac_save_CXXFLAGS"
3483 AC_LANG_RESTORE
3484 ])
3486 dnl
3487 dnl Check whether sysconf(_SC_NPROC_ONLN) is available in <unistd.h>, and define _GLIBCXX_USE_SC_NPROC_ONLN.
3488 dnl
3489 AC_DEFUN([GLIBCXX_CHECK_SC_NPROC_ONLN], [
3491 AC_LANG_SAVE
3492 AC_LANG_CPLUSPLUS
3493 ac_save_CXXFLAGS="$CXXFLAGS"
3494 CXXFLAGS="$CXXFLAGS -fno-exceptions"
3496 AC_MSG_CHECKING([for _SC_NPROC_ONLN])
3497 AC_CACHE_VAL(glibcxx_cv_SC_NPROC_ONLN, [
3498 GCC_TRY_COMPILE_OR_LINK(
3499 [#include <unistd.h>],
3500 [int n = sysconf(_SC_NPROC_ONLN);],
3501 [glibcxx_cv_SC_NPROC_ONLN=yes],
3502 [glibcxx_cv_SC_NPROC_ONLN=no])
3503 ])
3504 if test $glibcxx_cv_SC_NPROC_ONLN = yes; then
3505 AC_DEFINE(_GLIBCXX_USE_SC_NPROC_ONLN, 1, [Define if _SC_NPROC_ONLN is available in <unistd.h>.])
3506 fi
3507 AC_MSG_RESULT($glibcxx_cv_SC_NPROC_ONLN)
3509 CXXFLAGS="$ac_save_CXXFLAGS"
3510 AC_LANG_RESTORE
3511 ])
3513 dnl
3514 dnl Check whether pthread_num_processors_np is available in <pthread.h>, and define _GLIBCXX_USE_PTHREADS_NUM_PROCESSORS_NP.
3515 dnl
3516 AC_DEFUN([GLIBCXX_CHECK_PTHREADS_NUM_PROCESSORS_NP], [
3518 AC_LANG_SAVE
3519 AC_LANG_CPLUSPLUS
3520 ac_save_CXXFLAGS="$CXXFLAGS"
3521 CXXFLAGS="$CXXFLAGS -fno-exceptions"
3523 AC_MSG_CHECKING([for pthreads_num_processors_np])
3524 AC_CACHE_VAL(glibcxx_cv_PTHREADS_NUM_PROCESSORS_NP, [
3525 GCC_TRY_COMPILE_OR_LINK(
3526 [#include <pthread.h>],
3527 [int n = pthread_num_processors_np();],
3528 [glibcxx_cv_PTHREADS_NUM_PROCESSORS_NP=yes],
3529 [glibcxx_cv_PTHREADS_NUM_PROCESSORS_NP=no])
3530 ])
3531 if test $glibcxx_cv_PTHREADS_NUM_PROCESSORS_NP = yes; then
3532 AC_DEFINE(_GLIBCXX_USE_PTHREADS_NUM_PROCESSORS_NP, 1, [Define if pthreads_num_processors_np is available in <pthread.h>.])
3533 fi
3534 AC_MSG_RESULT($glibcxx_cv_PTHREADS_NUM_PROCESSORS_NP)
3536 CXXFLAGS="$ac_save_CXXFLAGS"
3537 AC_LANG_RESTORE
3538 ])
3540 dnl
3541 dnl Check whether sysctl is available in <pthread.h>, and define _GLIBCXX_USE_SYSCTL_HW_NCPU.
3542 dnl
3543 AC_DEFUN([GLIBCXX_CHECK_SYSCTL_HW_NCPU], [
3545 AC_LANG_SAVE
3546 AC_LANG_CPLUSPLUS
3547 ac_save_CXXFLAGS="$CXXFLAGS"
3548 CXXFLAGS="$CXXFLAGS -fno-exceptions"
3550 AC_MSG_CHECKING([for hw.ncpu sysctl])
3551 AC_CACHE_VAL(glibcxx_cv_SYSCTL_HW_NCPU, [
3552 GCC_TRY_COMPILE_OR_LINK(
3553 [
3554 #include <stddef.h>
3555 #include <sys/sysctl.h>
3556 ],
3557 [
3558 int count;
3559 size_t size = sizeof(count);
3560 int mib[] = { CTL_HW, HW_NCPU };
3561 sysctl(mib, 2, &count, &size, NULL, 0);
3562 ],
3563 [glibcxx_cv_SYSCTL_HW_NCPU=yes],
3564 [glibcxx_cv_SYSCTL_HW_NCPU=no])
3565 ])
3566 if test $glibcxx_cv_SYSCTL_HW_NCPU = yes; then
3567 AC_DEFINE(_GLIBCXX_USE_SYSCTL_HW_NCPU, 1, [Define if sysctl(), CTL_HW and HW_NCPU are available in <sys/sysctl.h>.])
3568 fi
3569 AC_MSG_RESULT($glibcxx_cv_SYSCTL_HW_NCPU)
3571 CXXFLAGS="$ac_save_CXXFLAGS"
3572 AC_LANG_RESTORE
3573 ])
3575 dnl
3576 dnl Check to see if python pretty printing can be activated.
3577 dnl
3578 dnl --with-python-dir=dir
3579 dnl installs directory into $prefix/dir
3580 AC_DEFUN([GLIBCXX_ENABLE_PYTHON], [
3582 AC_MSG_CHECKING([for custom python install directory])
3583 AC_ARG_WITH([python-dir],
3584 AS_HELP_STRING([--with-python-dir],
3585 [the location to install Python modules. This path is relative starting from the prefix.]),
3586 [with_python_dir=$withval], [with_python_dir="no"])
3587 AC_MSG_RESULT(${with_python_dir})
3589 # Needed for installing Python modules during make install.
3590 python_mod_dir="${with_python_dir}"
3591 AC_SUBST(python_mod_dir)
3592 GLIBCXX_CONDITIONAL(ENABLE_PYTHONDIR, test $python_mod_dir != no)
3593 ])
3595 dnl
3596 dnl Check to see if -Werror is disabled.
3597 dnl
3598 dnl --enable-werror/--disable-werror
3599 AC_DEFUN([GLIBCXX_ENABLE_WERROR], [
3600 AC_MSG_CHECKING([for -Werror])
3601 GLIBCXX_ENABLE(werror,$1,,[turns on -Werror])
3602 AC_MSG_RESULT($enable_werror)
3603 GLIBCXX_CONDITIONAL(ENABLE_WERROR, test $enable_werror = yes)
3604 ])
3607 # Macros from the top-level gcc directory.
3608 m4_include([../config/gc++filt.m4])
3609 m4_include([../config/tls.m4])