libiberty/configure.ac

   1 dnl Process this file with autoconf to produce a configure script
   2
   3 AC_PREREQ(2.64)
   4 AC_INIT
   5 AC_CONFIG_SRCDIR([xmalloc.c])
   6
   7 # This works around the fact that libtool configuration may change LD
   8 # for this particular configuration, but some shells, instead of
   9 # keeping the changes in LD private, export them just because LD is
  10 # exported.  We don't use libtool yet, but some day we might, so...
  11 ORIGINAL_LD_FOR_MULTILIBS=$LD
  12
  13 dnl We use these options to decide which functions to include.
  14 AC_ARG_WITH(target-subdir,
  15 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory for target])
  16 AC_ARG_WITH(build-subdir,
  17 [  --with-build-subdir=SUBDIR       Configuring in a subdirectory for build])
  18 AC_ARG_WITH(cross-host,
  19 [  --with-cross-host=HOST           Configuring with a cross compiler])
  20 AC_ARG_WITH(newlib,
  21 [  --with-newlib                    Configuring with newlib])
  22
  23 if test "${srcdir}" = "."; then
  24   if test -n "${with_build_subdir}"; then
  25     libiberty_topdir="${srcdir}/../.."
  26     with_target_subdir=
  27   elif test -z "${with_target_subdir}"; then
  28     libiberty_topdir="${srcdir}/.."
  29   else
  30     if test "${with_target_subdir}" != "."; then
  31       libiberty_topdir="${srcdir}/${with_multisrctop}../.."
  32     else
  33       libiberty_topdir="${srcdir}/${with_multisrctop}.."
  34     fi
  35   fi
  36 else
  37   libiberty_topdir="${srcdir}/.."
  38 fi
  39 AC_SUBST(libiberty_topdir)
  40 AC_CONFIG_AUX_DIR($libiberty_topdir)
  41
  42 dnl Very limited version of automake's enable-maintainer-mode
  43
  44 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
  45   dnl maintainer-mode is disabled by default
  46   AC_ARG_ENABLE(maintainer-mode,
  47 [  --enable-maintainer-mode
  48                           enable make rules and dependencies not useful
  49                           (and sometimes confusing) to the casual installer],
  50       maintainer_mode=$enableval,
  51       maintainer_mode=no)
  52
  53 AC_MSG_RESULT($maintainer_mode)
  54
  55 if test "$maintainer_mode" = "yes"; then
  56   MAINT=''
  57   NOTMAINT='#'
  58 else
  59   MAINT='#'
  60   NOTMAINT=''
  61 fi
  62 AC_SUBST(MAINT)dnl
  63 AC_SUBST(NOTMAINT)dnl
  64
  65 # Do we have a single-tree copy of texinfo?  Even if we do, we can't
  66 # rely on it - libiberty is built before texinfo.
  67 AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo, )
  68 if test "x$MAKEINFO" = "x"; then
  69     MAKEINFO="@echo makeinfo missing; true"
  70     BUILD_INFO=
  71 else
  72     BUILD_INFO=info
  73     case "$MAKEINFO" in
  74       */missing\ makeinfo*)
  75         BUILD_INFO=
  76         AC_MSG_WARN([
  77 *** Makeinfo is missing. Info documentation will not be built.])
  78         ;;
  79       *)
  80         case x"`$MAKEINFO --version | grep 'GNU texinfo'`" in
  81           x*\ [[1-3]].* )
  82             MAKEINFO="@echo $MAKEINFO is too old, 4.0 or newer required; true"
  83             BUILD_INFO=
  84             AC_MSG_WARN([
  85 *** Makeinfo is too old. Info documentation will not be built.])
  86           ;;
  87         esac
  88         ;;
  89     esac
  90 fi
  91 AC_SUBST(MAKEINFO)
  92 AC_SUBST(BUILD_INFO)
  93
  94 AC_CHECK_PROG(PERL, perl, perl, )
  95 if test x"$PERL" = x""; then
  96   HAVE_PERL='#'
  97 else
  98   HAVE_PERL=''
  99 fi
 100 AC_SUBST(HAVE_PERL)
 101
 102 AC_CANONICAL_HOST
 103
 104 dnl When we start using automake:
 105 dnl AM_INIT_AUTOMAKE(libiberty, 1.0)
 106
 107 dnl These must be called before AM_PROG_LIBTOOL, because it may want
 108 dnl to call AC_CHECK_PROG.
 109 AC_CHECK_TOOL(AR, ar)
 110 AC_CHECK_TOOL(RANLIB, ranlib, :)
 111
 112 dnl When switching to automake, replace the following with AM_ENABLE_MULTILIB.
 113 # Add --enable-multilib to configure.
 114 # Default to --enable-multilib
 115 AC_ARG_ENABLE(multilib,
 116 [  --enable-multilib       build many library versions (default)],
 117 [case "$enableval" in
 118   yes) multilib=yes ;;
 119   no)  multilib=no ;;
 120   *)   AC_MSG_ERROR([bad value $enableval for multilib option]) ;;
 121  esac],
 122               [multilib=yes])
 123
 124 # Even if the default multilib is not a cross compilation,
 125 # it may be that some of the other multilibs are.
 126 if test $cross_compiling = no && test $multilib = yes \
 127    && test "x${with_multisubdir}" != x ; then
 128    cross_compiling=maybe
 129 fi
 130
 131 # We may wish to install the target headers somewhere.
 132 AC_MSG_CHECKING([whether to install libiberty headers and static library])
 133 dnl install-libiberty is disabled by default
 134
 135 AC_ARG_ENABLE(install-libiberty,
 136 [  --enable-install-libiberty       Install headers and library for end users],
 137 enable_install_libiberty=$enableval,
 138 enable_install_libiberty=no)dnl
 139
 140 # Option parsed, now set things appropriately.
 141 case x"$enable_install_libiberty" in
 142   xyes|x)
 143     target_header_dir=libiberty
 144     ;;
 145   xno)
 146     target_header_dir=
 147     ;;
 148   *)
 149     # This could be sanity-checked in various ways...
 150     target_header_dir="${enable_install_libiberty}"
 151     ;;
 152 esac
 153 AC_MSG_RESULT($enable_install_libiberty)
 154 AC_MSG_NOTICE([target_header_dir = $target_header_dir])
 155
 156 GCC_NO_EXECUTABLES
 157 AC_PROG_CC
 158 AC_GNU_SOURCE
 159 AC_SYS_LARGEFILE
 160 AC_PROG_CPP_WERROR
 161
 162 ACX_PROG_CC_WARNING_OPTS([-W -Wall -Wwrite-strings -Wc++-compat \
 163                           -Wstrict-prototypes], [ac_libiberty_warn_cflags])
 164 ACX_PROG_CC_WARNING_ALMOST_PEDANTIC([], [ac_libiberty_warn_cflags])
 165
 166 AC_PROG_CC_C_O
 167 # autoconf is lame and doesn't give us any substitution variable for this.
 168 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 169   NO_MINUS_C_MINUS_O=yes
 170 else
 171   OUTPUT_OPTION='-o $@'
 172 fi
 173 AC_SUBST(NO_MINUS_C_MINUS_O)
 174 AC_SUBST(OUTPUT_OPTION)
 175
 176 AC_C_CONST
 177 AC_C_INLINE
 178 AC_C_BIGENDIAN
 179
 180 dnl When we start using libtool:
 181 dnl Default to a non shared library.  This may be overridden by the
 182 dnl configure option --enable-shared.
 183 dnl AM_DISABLE_SHARED
 184
 185 dnl When we start using libtool:
 186 dnl AM_PROG_LIBTOOL
 187
 188 dnl When we start using automake:
 189 dnl AM_CONFIG_HEADER(config.h:config.in)
 190 AC_CONFIG_HEADER(config.h:config.in)
 191
 192 dnl When we start using automake:
 193 dnl AM_MAINTAINER_MODE
 194 dnl AC_EXEEXT
 195
 196 dnl When we start using automake:
 197 dnl AM_PROG_INSTALL
 198 AC_PROG_INSTALL
 199
 200 # Don't build the shared library for build.
 201 if [[ -n "${with_build_subdir}" ]]; then
 202   enable_shared=no
 203 fi
 204
 205 frag=
 206 case "${host}" in
 207   rs6000-ibm-aix3.1 | rs6000-ibm-aix)
 208                         frag=mh-aix ;;
 209   *-*-cxux7*)           frag=mh-cxux7 ;;
 210   *-*-freebsd2.1.*)     frag=mh-fbsd21 ;;
 211   *-*-freebsd2.2.[[012]])       frag=mh-fbsd21 ;;
 212   i370-*-opened*)       frag=mh-openedition ;;
 213   i[[34567]]86-*-windows*)      frag=mh-windows ;;
 214 esac
 215
 216 if [[ -n "${frag}" ]]; then
 217   frag=${libiberty_topdir}/libiberty/config/$frag
 218 fi
 219
 220 GCC_PICFLAG
 221
 222 # If they didn't specify --enable-shared, don't generate shared libs.
 223 case "${enable_shared}" in
 224   yes) shared=yes ;;
 225   no) shared=no ;;
 226   "") shared=no ;;
 227   *) shared=yes ;;
 228 esac
 229
 230 # ...unless --enable-host-shared was passed from top-level config:
 231 if [[ "${enable_host_shared}" = "yes" ]]; then
 232   shared=yes
 233 fi
 234
 235 if [[ "${shared}" != "yes" ]]; then
 236   PICFLAG=
 237 fi
 238 AC_SUBST(PICFLAG)
 239
 240 NOASANFLAG=
 241 case " ${CFLAGS} " in
 242   *\ -fsanitize=address\ *) NOASANFLAG=-fno-sanitize=address ;;
 243 esac
 244 AC_SUBST(NOASANFLAG)
 245
 246 echo "# Warning: this fragment is automatically generated" > temp-frag
 247
 248 if [[ -n "${frag}" ]] && [[ -f "${frag}" ]]; then
 249   echo "Appending ${frag} to xhost-mkfrag"
 250   echo "# Following fragment copied from ${frag}" >> temp-frag
 251   cat ${frag} >> temp-frag
 252 fi
 253
 254 # record if we want to build shared libs.
 255 if [[ "${shared}" = "yes" ]]; then
 256   echo enable_shared = yes >> temp-frag
 257 else
 258   echo enable_shared = no >> temp-frag
 259 fi
 260
 261 frag=xhost-mkfrag
 262 ${CONFIG_SHELL-/bin/sh} ${libiberty_topdir}/move-if-change temp-frag xhost-mkfrag
 263
 264 host_makefile_frag=${frag}
 265 AC_SUBST_FILE(host_makefile_frag)
 266
 267 # It's OK to check for header files.  Although the compiler may not be
 268 # able to link anything, it had better be able to at least compile
 269 # something.
 270 AC_CHECK_HEADERS(sys/file.h sys/param.h limits.h stdlib.h malloc.h string.h unistd.h strings.h sys/time.h time.h sys/resource.h sys/stat.h sys/mman.h fcntl.h alloca.h sys/pstat.h sys/sysmp.h sys/sysinfo.h machine/hal_sysinfo.h sys/table.h sys/sysctl.h sys/systemcfg.h stdint.h stdio_ext.h process.h sys/prctl.h)
 271 AC_HEADER_SYS_WAIT
 272 AC_HEADER_TIME
 273
 274 libiberty_AC_DECLARE_ERRNO
 275
 276 # Determine sizes of some types.
 277 AC_CHECK_SIZEOF([int])
 278 AC_CHECK_SIZEOF([long])
 279
 280 # Check for presense of long long
 281 AC_CHECK_TYPE([long long],
 282   [AC_DEFINE(HAVE_LONG_LONG, 1, [Define if you have the `long long' type.]) AC_CHECK_SIZEOF([long long])],
 283   [])
 284
 285 # Look for a 64-bit type.
 286 AC_MSG_CHECKING([for a 64-bit type])
 287 AC_CACHE_VAL(liberty_cv_uint64,
 288 [AC_TRY_COMPILE(
 289 [#ifdef HAVE_STDINT_H
 290 #include <stdint.h>
 291 #endif],
 292 [extern uint64_t foo;],
 293 liberty_cv_uint64=uint64_t,
 294 [AC_TRY_COMPILE(
 295 [#ifdef HAVE_LIMITS_H
 296 #include <limits.h>
 297 #endif
 298 #ifndef CHAR_BIT
 299 #define CHAR_BIT 8
 300 #endif],
 301 [extern char foo[sizeof(long) * CHAR_BIT >= 64 ? 1 : -1];],
 302 liberty_cv_uint64="unsigned long",
 303 [AC_TRY_COMPILE(
 304 [#ifdef HAVE_LIMITS_H
 305 #include <limits.h>
 306 #endif
 307 #ifndef CHAR_BIT
 308 #define CHAR_BIT 8
 309 #endif],
 310 [extern char foo[sizeof(long long) * CHAR_BIT >= 64 ? 1 : -1];],
 311 liberty_cv_uint64="unsigned long long", liberty_cv_uint64=none)])])])
 312 AC_MSG_RESULT($liberty_cv_uint64)
 313 if test "$liberty_cv_uint64" != none; then
 314   AC_DEFINE_UNQUOTED(UNSIGNED_64BIT_TYPE, $liberty_cv_uint64,
 315                      [Define to an unsigned 64-bit type available in the compiler.])
 316 fi
 317
 318 AC_TYPE_INTPTR_T
 319 AC_TYPE_UINTPTR_T
 320 AC_TYPE_SSIZE_T
 321
 322 # Given the above check, we always have uintptr_t or a fallback
 323 # definition.  So define HAVE_UINTPTR_T in case any imported code
 324 # relies on it.
 325 AC_DEFINE(HAVE_UINTPTR_T, 1, [Define if you have the \`uintptr_t' type.])
 326
 327 AC_TYPE_PID_T
 328
 329 # This is the list of functions which libiberty will provide if they
 330 # are not available on the host.
 331
 332 funcs="asprintf"
 333 funcs="$funcs atexit"
 334 funcs="$funcs basename"
 335 funcs="$funcs bcmp"
 336 funcs="$funcs bcopy"
 337 funcs="$funcs bsearch"
 338 funcs="$funcs bzero"
 339 funcs="$funcs calloc"
 340 funcs="$funcs clock"
 341 funcs="$funcs ffs"
 342 funcs="$funcs getcwd"
 343 funcs="$funcs getpagesize"
 344 funcs="$funcs gettimeofday"
 345 funcs="$funcs index"
 346 funcs="$funcs insque"
 347 funcs="$funcs memchr"
 348 funcs="$funcs memcmp"
 349 funcs="$funcs memcpy"
 350 funcs="$funcs memmem"
 351 funcs="$funcs memmove"
 352 funcs="$funcs mempcpy"
 353 funcs="$funcs memset"
 354 funcs="$funcs mkstemps"
 355 funcs="$funcs putenv"
 356 funcs="$funcs random"
 357 funcs="$funcs rename"
 358 funcs="$funcs rindex"
 359 funcs="$funcs setenv"
 360 funcs="$funcs snprintf"
 361 funcs="$funcs sigsetmask"
 362 funcs="$funcs stpcpy"
 363 funcs="$funcs stpncpy"
 364 funcs="$funcs strcasecmp"
 365 funcs="$funcs strchr"
 366 funcs="$funcs strdup"
 367 funcs="$funcs strncasecmp"
 368 funcs="$funcs strndup"
 369 funcs="$funcs strnlen"
 370 funcs="$funcs strrchr"
 371 funcs="$funcs strstr"
 372 funcs="$funcs strtod"
 373 funcs="$funcs strtol"
 374 funcs="$funcs strtoul"
 375 funcs="$funcs strtoll"
 376 funcs="$funcs strtoull"
 377 funcs="$funcs strverscmp"
 378 funcs="$funcs tmpnam"
 379 funcs="$funcs vasprintf"
 380 funcs="$funcs vfprintf"
 381 funcs="$funcs vprintf"
 382 funcs="$funcs vsnprintf"
 383 funcs="$funcs vsprintf"
 384 funcs="$funcs waitpid"
 385 funcs="$funcs setproctitle"
 386
 387 # Also in the old function.def file: alloca, vfork, getopt.
 388
 389 vars="sys_errlist sys_nerr sys_siglist"
 390
 391 checkfuncs="__fsetlocking canonicalize_file_name dup3 getrlimit getrusage \
 392  getsysinfo gettimeofday on_exit psignal pstat_getdynamic pstat_getstatic \
 393  realpath setrlimit sbrk spawnve spawnvpe strerror strsignal sysconf sysctl \
 394  sysmp table times wait3 wait4"
 395
 396 # These are neither executed nor required, but they help keep
 397 # autoheader happy without adding a bunch of text to acconfig.h.
 398 if test "x" = "y"; then
 399   AC_CHECK_FUNCS(asprintf atexit \
 400     basename bcmp bcopy bsearch bzero \
 401     calloc canonicalize_file_name clock \
 402     dup3 \
 403     ffs __fsetlocking \
 404     getcwd getpagesize getrlimit getrusage getsysinfo gettimeofday \
 405     index insque \
 406     memchr memcmp memcpy memmem memmove memset mkstemps \
 407     on_exit \
 408     psignal pstat_getdynamic pstat_getstatic putenv \
 409     random realpath rename rindex \
 410     sbrk setenv setproctitle setrlimit sigsetmask snprintf spawnve spawnvpe \
 411      stpcpy stpncpy strcasecmp strchr strdup \
 412      strerror strncasecmp strndup strnlen strrchr strsignal strstr strtod \
 413      strtol strtoul strtoll strtoull strverscmp sysconf sysctl sysmp \
 414     table times tmpnam \
 415     vasprintf vfprintf vprintf vsprintf \
 416     wait3 wait4 waitpid)
 417   AC_CHECK_DECLS([basename(char *), ffs, asprintf, vasprintf, snprintf, vsnprintf, strtol, strtoul, strtoll, strtoull])
 418   AC_DEFINE(HAVE_SYS_ERRLIST, 1, [Define if you have the sys_errlist variable.])
 419   AC_DEFINE(HAVE_SYS_NERR,    1, [Define if you have the sys_nerr variable.])
 420   AC_DEFINE(HAVE_SYS_SIGLIST, 1, [Define if you have the sys_siglist variable.])
 421 fi
 422
 423 # For each of these functions, if the host does not provide the
 424 # function we want to put FN.o in LIBOBJS, and if the host does
 425 # provide the function, we want to define HAVE_FN in config.h.
 426
 427 setobjs=
 428 CHECK=
 429 if test -n "${with_target_subdir}"; then
 430
 431   # We are being configured as a target library.  AC_REPLACE_FUNCS
 432   # may not work correctly, because the compiler may not be able to
 433   # link executables.  Note that we may still be being configured
 434   # native.
 435
 436   # If we are being configured for newlib, we know which functions
 437   # newlib provide and which ones we will be expected to provide.
 438
 439   if test "x${with_newlib}" = "xyes"; then
 440     AC_LIBOBJ([asprintf])
 441     AC_LIBOBJ([basename])
 442     AC_LIBOBJ([insque])
 443     AC_LIBOBJ([random])
 444     AC_LIBOBJ([strdup])
 445     AC_LIBOBJ([vasprintf])
 446
 447     for f in $funcs; do
 448       case "$f" in
 449         asprintf | basename | insque | random | strdup | vasprintf)
 450           ;;
 451         *)
 452           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 453           AC_DEFINE_UNQUOTED($n)
 454           ;;
 455       esac
 456     done
 457
 458     # newlib doesnt provide any of the variables in $vars, so we
 459     # dont have to check them here.
 460
 461     # Of the functions in $checkfuncs, newlib only has strerror.
 462     AC_DEFINE(HAVE_STRERROR)
 463
 464     setobjs=yes
 465
 466   fi
 467
 468   # If we are being configured for Mingw, we know which functions
 469   # Mingw provides and which ones we will be expected to provide.
 470
 471   case "${host}" in
 472   *-*-mingw*)
 473     AC_LIBOBJ([asprintf])
 474     AC_LIBOBJ([basename])
 475     AC_LIBOBJ([bcmp])
 476     AC_LIBOBJ([bcopy])
 477     AC_LIBOBJ([bzero])
 478     AC_LIBOBJ([clock])
 479     AC_LIBOBJ([ffs])
 480     AC_LIBOBJ([getpagesize])
 481     AC_LIBOBJ([index])
 482     AC_LIBOBJ([insque])
 483     AC_LIBOBJ([mempcpy])
 484     AC_LIBOBJ([mkstemps])
 485     AC_LIBOBJ([random])
 486     AC_LIBOBJ([rindex])
 487     AC_LIBOBJ([sigsetmask])
 488     AC_LIBOBJ([stpcpy])
 489     AC_LIBOBJ([stpncpy])
 490     AC_LIBOBJ([strndup])
 491     AC_LIBOBJ([strnlen])
 492     AC_LIBOBJ([strverscmp])
 493     AC_LIBOBJ([vasprintf])
 494     AC_LIBOBJ([waitpid])
 495
 496     for f in $funcs; do
 497       case "$f" in
 498         asprintf | basename | bcmp | bcopy | bzero | clock | ffs | getpagesize | index | insque | mempcpy | mkstemps | random | rindex | sigsetmask | stpcpy | stpncpy | strdup | strndup | strnlen | strverscmp | vasprintf | waitpid)
 499           ;;
 500         *)
 501           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 502           AC_DEFINE_UNQUOTED($n)
 503           ;;
 504       esac
 505     done
 506
 507     # Mingw doesnt provide any of the variables in $vars, so we
 508     # dont have to check them here.
 509
 510     # Of the functions in $checkfuncs, Mingw only has strerror.
 511     AC_DEFINE(HAVE_STRERROR)
 512
 513     setobjs=yes
 514     ;;
 515
 516   *-*-msdosdjgpp)
 517     AC_LIBOBJ([vasprintf])
 518     AC_LIBOBJ([vsnprintf])
 519     AC_LIBOBJ([snprintf])
 520     AC_LIBOBJ([asprintf])
 521
 522     for f in atexit basename bcmp bcopy bsearch bzero calloc clock ffs \
 523              getcwd getpagesize getrusage gettimeofday \
 524              index insque memchr memcmp memcpy memmove memset psignal \
 525              putenv random rename rindex sbrk setenv stpcpy strcasecmp \
 526              strchr strdup strerror strncasecmp strrchr strstr strtod \
 527              strtol strtoul sysconf times tmpnam vfprintf vprintf \
 528              vsprintf waitpid
 529     do
 530       n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 531       AC_DEFINE_UNQUOTED($n)
 532     done
 533
 534
 535     setobjs=yes
 536     ;;
 537
 538   esac
 539
 540 else
 541
 542    # Not a target library, so we set things up to run the test suite.
 543    CHECK=really-check
 544
 545 fi
 546
 547 AC_SUBST(CHECK)
 548 AC_SUBST(target_header_dir)
 549
 550 case "${host}" in
 551   *-*-cygwin* | *-*-mingw*)
 552     AC_DEFINE(HAVE_SYS_ERRLIST)
 553     AC_DEFINE(HAVE_SYS_NERR)
 554     ;;
 555 esac
 556
 557 if test -z "${setobjs}"; then
 558   case "${host}" in
 559
 560   *-*-vxworks*)
 561     # Handle VxWorks configuration specially, since on VxWorks the
 562     # libraries are actually on the target board, not in the file
 563     # system.
 564     AC_LIBOBJ([basename])
 565     AC_LIBOBJ([getpagesize])
 566     AC_LIBOBJ([insque])
 567     AC_LIBOBJ([random])
 568     AC_LIBOBJ([strcasecmp])
 569     AC_LIBOBJ([strncasecmp])
 570     AC_LIBOBJ([strdup])
 571     AC_LIBOBJ([vfork])
 572     AC_LIBOBJ([waitpid])
 573     AC_LIBOBJ([vasprintf])
 574     for f in $funcs; do
 575       case "$f" in
 576         basename | getpagesize | insque | random | strcasecmp)
 577           ;;
 578         strncasecmp | strdup | vfork | waitpid | vasprintf)
 579           ;;
 580         *)
 581           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 582           AC_DEFINE_UNQUOTED($n)
 583           ;;
 584       esac
 585     done
 586
 587     # VxWorks doesn't provide any of the variables in $vars, so we
 588     # don't have to check them here.
 589
 590     # Of the functions in $checkfuncs, VxWorks only has strerror.
 591     AC_DEFINE(HAVE_STRERROR)
 592
 593     setobjs=yes
 594     ;;
 595
 596   esac
 597 fi
 598
 599 if test -z "${setobjs}"; then
 600
 601   case "${host}" in
 602
 603   *-*-mingw32*)
 604     # Under mingw32, sys_nerr and sys_errlist exist, but they are
 605     # macros, so the test below won't find them.
 606     libiberty_cv_var_sys_nerr=yes
 607     libiberty_cv_var_sys_errlist=yes
 608     ;;
 609
 610   *-*-msdosdjgpp*)
 611     # vfork and fork are stubs.
 612     ac_cv_func_vfork_works=no
 613     ;;
 614
 615   *-*-uwin*)
 616     # Under some versions of uwin, vfork is notoriously buggy and the test
 617     # can hang configure; on other versions, vfork exists just as a stub.
 618     # FIXME: This should be removed once vfork in uwin's runtime is fixed.
 619     ac_cv_func_vfork_works=no
 620     # Under uwin 2.0+, sys_nerr and sys_errlist exist, but they are
 621     # macros (actually, these are imported from a DLL, but the end effect
 622     # is the same), so the test below won't find them.
 623     libiberty_cv_var_sys_nerr=yes
 624     libiberty_cv_var_sys_errlist=yes
 625     ;;
 626
 627   *-*-*vms*)
 628     # Under VMS, vfork works very different than on Unix. The standard test
 629     # won't work, and it isn't easily adaptable. It makes more sense to
 630     # just force it.
 631     ac_cv_func_vfork_works=yes
 632     ;;
 633
 634   esac
 635
 636   # We haven't set the list of objects yet.  Use the standard autoconf
 637   # tests.  This will only work if the compiler works.
 638   AC_ISC_POSIX
 639   AC_REPLACE_FUNCS($funcs)
 640   libiberty_AC_FUNC_C_ALLOCA
 641   AC_FUNC_FORK
 642   if test $ac_cv_func_vfork_works = no; then
 643     AC_LIBOBJ([vfork])
 644   fi
 645   # We only need _doprnt if we might use it to implement v*printf.
 646   if test $ac_cv_func_vprintf != yes \
 647      || test $ac_cv_func_vfprintf != yes \
 648      || test $ac_cv_func_vsprintf != yes; then
 649     AC_REPLACE_FUNCS(_doprnt)
 650   else
 651     AC_CHECK_FUNCS(_doprnt)
 652   fi
 653
 654   for v in $vars; do
 655     AC_MSG_CHECKING([for $v])
 656     AC_CACHE_VAL(libiberty_cv_var_$v,
 657       [AC_LINK_IFELSE([AC_LANG_PROGRAM([[int *p;]],[[extern int $v []; p = $v;]])],
 658                       [eval "libiberty_cv_var_$v=yes"],
 659                       [eval "libiberty_cv_var_$v=no"])])
 660     if eval "test \"`echo '$libiberty_cv_var_'$v`\" = yes"; then
 661       AC_MSG_RESULT(yes)
 662       n=HAVE_`echo $v | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 663       AC_DEFINE_UNQUOTED($n)
 664     else
 665       AC_MSG_RESULT(no)
 666     fi
 667   done
 668
 669   # special check for _system_configuration because AIX <4.3.2 do not
 670   # contain the `physmem' member.
 671   AC_MSG_CHECKING([for external symbol _system_configuration])
 672   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/systemcfg.h>]],
 673                         [[double x = _system_configuration.physmem;]])],
 674     [AC_MSG_RESULT([yes])
 675     AC_DEFINE(HAVE__SYSTEM_CONFIGURATION, 1,
 676               [Define if you have the _system_configuration variable.])],
 677     [AC_MSG_RESULT([no])])
 678
 679   AC_CHECK_FUNCS($checkfuncs)
 680   AC_CHECK_DECLS([basename(char *), ffs, asprintf, vasprintf, snprintf, vsnprintf])
 681   AC_CHECK_DECLS([calloc, getenv, getopt, malloc, realloc, sbrk])
 682   AC_CHECK_DECLS([strtol, strtoul, strtoll, strtoull])
 683   AC_CHECK_DECLS([strverscmp])
 684   libiberty_NEED_DECLARATION(canonicalize_file_name)
 685 fi
 686
 687 # Figure out which version of pexecute to use.
 688 case "${host}" in
 689      *-*-mingw* | *-*-winnt*)   pexecute=pex-win32  ;;
 690      *-*-msdosdjgpp*)           pexecute=pex-djgpp  ;;
 691      *-*-msdos*)                pexecute=pex-msdos  ;;
 692      *)                         pexecute=pex-unix   ;;
 693 esac
 694 AC_SUBST(pexecute)
 695
 696 libiberty_AC_FUNC_STRNCMP
 697
 698 # Install a library built with a cross compiler in $(tooldir) rather
 699 # than $(libdir).
 700 if test -z "${with_cross_host}"; then
 701   INSTALL_DEST=libdir
 702 else
 703   INSTALL_DEST=tooldir
 704 fi
 705 AC_SUBST(INSTALL_DEST)
 706
 707 m4_pattern_allow(LIBOBJS)
 708 L=""
 709 for l in x $LIBOBJS; do
 710   case $l in
 711     x) ;;
 712     *) L="$L ./$l" ;;
 713   esac
 714 done
 715 LIBOBJS="$L"
 716
 717 dnl Required by html and install-html
 718 AC_SUBST(datarootdir)
 719 AC_SUBST(docdir)
 720 AC_SUBST(htmldir)
 721
 722 # We need multilib support, but only if configuring for the target.
 723 AC_CONFIG_FILES([Makefile testsuite/Makefile])
 724 AC_CONFIG_COMMANDS([default],
 725   [[test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 726 if test -n "$CONFIG_FILES"; then
 727   if test -n "${with_target_subdir}"; then
 728     # FIXME: We shouldn't need to set ac_file
 729     ac_file=Makefile
 730     LD="${ORIGINAL_LD_FOR_MULTILIBS}"
 731     . ${libiberty_topdir}/config-ml.in
 732   fi
 733 fi]],
 734 [[srcdir=${srcdir}
 735 host=${host}
 736 target=${target}
 737 with_target_subdir=${with_target_subdir}
 738 with_multisubdir=${with_multisubdir}
 739 ac_configure_args="--enable-multilib ${ac_configure_args}"
 740 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 741 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
 742 libiberty_topdir=${libiberty_topdir}
 743 ]])
 744 AC_OUTPUT