libgo/configure.ac

   1 # configure.ac -- Go library configure script.
   2
   3 # Copyright 2009 The Go Authors. All rights reserved.
   4 # Use of this source code is governed by a BSD-style
   5 # license that can be found in the LICENSE file.
   6
   7 # Process this file with autoreconf to produce configure.
   8
   9 AC_PREREQ(2.64)
  10 AC_INIT(package-unused, version-unused,, libgo)
  11 AC_CONFIG_SRCDIR(Makefile.am)
  12 AC_CONFIG_HEADER(config.h)
  13
  14 libtool_VERSION=1:0:0
  15 AC_SUBST(libtool_VERSION)
  16
  17 AM_ENABLE_MULTILIB(, ..)
  18
  19 AC_CANONICAL_SYSTEM
  20 target_alias=${target_alias-$host_alias}
  21
  22 AM_INIT_AUTOMAKE([1.9.3 no-define foreign -Wall])
  23 AH_TEMPLATE(PACKAGE, [Name of package])
  24 AH_TEMPLATE(VERSION, [Version number of package])
  25
  26 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibgo_PRECIOUS])
  27 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  28 AC_PROG_CC
  29 AC_PROG_GO
  30 m4_rename_force([glibgo_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  31
  32 AC_SUBST(CFLAGS)
  33
  34 AM_MAINTAINER_MODE
  35
  36 AC_PROG_LD
  37 AC_PROG_RANLIB
  38 AC_CHECK_TOOL(OBJCOPY, objcopy, missing-objcopy)
  39
  40 AC_LIBTOOL_DLOPEN
  41 AM_PROG_LIBTOOL
  42 AC_SUBST(enable_shared)
  43 AC_SUBST(enable_static)
  44
  45 CC_FOR_BUILD=${CC_FOR_BUILD:-gcc}
  46 AC_SUBST(CC_FOR_BUILD)
  47
  48 AC_PROG_AWK
  49
  50 WARN_FLAGS='-Wall -Wextra -Wwrite-strings -Wcast-qual'
  51 AC_SUBST(WARN_FLAGS)
  52
  53 dnl FIXME: This should be controlled by --enable-maintainer-mode.
  54 WERROR="-Werror"
  55 AC_SUBST(WERROR)
  56
  57 glibgo_toolexecdir=no
  58 glibgo_toolexeclibdir=no
  59 glibgo_prefixdir=$prefix
  60
  61 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  62 AC_ARG_ENABLE([version-specific-runtime-libs],
  63   AC_HELP_STRING([--enable-version-specific-runtime-libs],
  64                  [Specify that runtime libraries should be installed in a compiler-specific directory]),
  65   [case "$enableval" in
  66     yes) version_specific_libs=yes ;;
  67     no)  version_specific_libs=no ;;
  68     *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  69    esac],
  70   [version_specific_libs=no])
  71 AC_MSG_RESULT($version_specific_libs)
  72
  73 # Version-specific runtime libs processing.
  74 if test $version_specific_libs = yes; then
  75   glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
  76   glibgo_toolexeclibdir='${toolexecdir}/${gcc_version}$(MULTISUBDIR)'
  77 fi
  78
  79 # Calculate glibgo_toolexecdir, glibgo_toolexeclibdir
  80 # Install a library built with a cross compiler in tooldir, not libdir.
  81 if test x"$glibgo_toolexecdir" = x"no"; then
  82   if test -n "$with_cross_host" &&
  83      test x"$with_cross_host" != x"no"; then
  84     glibgo_toolexecdir='${exec_prefix}/${host_alias}'
  85     glibgo_toolexeclibdir='${toolexecdir}/lib'
  86   else
  87     glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
  88     glibgo_toolexeclibdir='${libdir}'
  89   fi
  90   multi_os_directory=`$CC -print-multi-os-directory`
  91   case $multi_os_directory in
  92     .) ;; # Avoid trailing /.
  93     *) glibgo_toolexeclibdir=$glibgo_toolexeclibdir/$multi_os_directory ;;
  94   esac
  95 fi
  96
  97 AC_SUBST(glibgo_prefixdir)
  98 AC_SUBST(glibgo_toolexecdir)
  99 AC_SUBST(glibgo_toolexeclibdir)
 100
 101 # See if the user wants to configure without libffi.  Some
 102 # architectures don't support it.  FIXME: We should set a default
 103 # based on the host.
 104 AC_ARG_WITH(libffi,
 105   AS_HELP_STRING([--without-libffi],
 106                  [don't use libffi]),
 107   [:],
 108   [with_libffi=${with_libffi_default-yes}])
 109
 110 LIBFFI=
 111 LIBFFIINCS=
 112 if test "$with_libffi" != no; then
 113    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 114    LIBFFI=../libffi/libffi_convenience.la
 115    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 116 fi
 117 AC_SUBST(LIBFFI)
 118 AC_SUBST(LIBFFIINCS)
 119
 120 # Used to tell GNU make to include a file without telling automake to
 121 # include it.
 122 go_include="-include"
 123 AC_SUBST(go_include)
 124
 125 is_darwin=no
 126 is_freebsd=no
 127 is_irix=no
 128 is_linux=no
 129 is_rtems=no
 130 is_solaris=no
 131 GOOS=unknown
 132 case ${host} in
 133   *-*-darwin*)   is_darwin=yes;  GOOS=darwin ;;
 134   *-*-freebsd*)  is_freebsd=yes; GOOS=freebsd ;;
 135   *-*-irix6*)    is_irix=yes;    GOOS=irix ;;
 136   *-*-linux*)    is_linux=yes;   GOOS=linux ;;
 137   *-*-rtems*)    is_rtems=yes;   GOOS=rtems ;;
 138   *-*-solaris2*) is_solaris=yes; GOOS=solaris ;;
 139 esac
 140 AM_CONDITIONAL(LIBGO_IS_DARWIN, test $is_darwin = yes)
 141 AM_CONDITIONAL(LIBGO_IS_FREEBSD, test $is_freebsd = yes)
 142 AM_CONDITIONAL(LIBGO_IS_IRIX, test $is_irix = yes)
 143 AM_CONDITIONAL(LIBGO_IS_LINUX, test $is_linux = yes)
 144 AM_CONDITIONAL(LIBGO_IS_RTEMS, test $is_rtems = yes)
 145 AM_CONDITIONAL(LIBGO_IS_SOLARIS, test $is_solaris = yes)
 146 AC_SUBST(GOOS)
 147
 148 dnl N.B. Keep in sync with gcc/testsuite/go.test/go-test.exp (go-set-goarch).
 149 is_386=no
 150 is_alpha=no
 151 is_arm=no
 152 is_m68k=no
 153 mips_abi=unknown
 154 is_ppc=no
 155 is_ppc64=no
 156 is_sparc=no
 157 is_sparc64=no
 158 is_x86_64=no
 159 GOARCH=unknown
 160 case ${host} in
 161   alpha*-*-*)
 162     is_alpha=yes
 163     GOARCH=alpha
 164     ;;
 165   arm*-*-* | strongarm*-*-* | ep9312*-*-* | xscale-*-*)
 166     is_arm=yes
 167     GOARCH=arm
 168     ;;
 169 changequote(,)dnl
 170   i[34567]86-*-* | x86_64-*-*)
 171 changequote([,])dnl
 172     AC_COMPILE_IFELSE([
 173 #ifdef __x86_64__
 174 #error 64-bit
 175 #endif],
 176 [is_386=yes], [is_x86_64=yes])
 177     if test "$is_386" = "yes"; then
 178       GOARCH=386
 179     else
 180       GOARCH=amd64
 181     fi
 182     ;;
 183   m68k*-*-*)
 184     is_m68k=yes
 185     GOARCH=m68k
 186     ;;
 187   mips*-*-*)
 188     AC_COMPILE_IFELSE([
 189 #if _MIPS_SIM != _ABIO32
 190 #error not o32
 191 #endif],
 192 [mips_abi="o32"],
 193         [AC_COMPILE_IFELSE([
 194 #if _MIPS_SIM != _ABIN32
 195 #error not n32
 196 #endif],
 197 [mips_abi="n32"],
 198         [AC_COMPILE_IFELSE([
 199 #if _MIPS_SIM != _ABI64
 200 #error not n64
 201 #endif],
 202 [mips_abi="n64"],
 203         [AC_COMPILE_IFELSE([
 204 #if _MIPS_SIM != _ABIO64
 205 #error not o64
 206 #endif],
 207 [mips_abi="o64"],
 208         [AC_MSG_ERROR([unknown MIPS ABI])
 209 [mips_abi="n32"]])])])])
 210     case "$mips_abi" in
 211     "o32") GOARCH=mipso32 ;;
 212     "n32") GOARCH=mipsn32 ;;
 213     "n64") GOARCH=mipsn64 ;;
 214     "o64") GOARCH=mipso64 ;;
 215     esac
 216     ;;
 217   rs6000*-*-* | powerpc*-*-*)
 218     AC_COMPILE_IFELSE([
 219 #ifdef _ARCH_PPC64
 220 #error 64-bit
 221 #endif],
 222 [is_ppc=yes], [is_ppc64=yes])
 223     if test "$is_ppc" = "yes"; then
 224       GOARCH=ppc
 225     else
 226       GOARCH=ppc64
 227     fi
 228     ;;
 229   sparc*-*-*)
 230     AC_COMPILE_IFELSE([
 231 #if defined(__sparcv9) || defined(__arch64__)
 232 #error 64-bit
 233 #endif],
 234 [is_sparc=yes], [is_sparc64=yes])
 235     if test "$is_sparc" = "yes"; then
 236       GOARCH=sparc
 237     else
 238       GOARCH=sparc64
 239     fi
 240     ;;
 241 esac
 242 AM_CONDITIONAL(LIBGO_IS_386, test $is_386 = yes)
 243 AM_CONDITIONAL(LIBGO_IS_ALPHA, test $is_alpha = yes)
 244 AM_CONDITIONAL(LIBGO_IS_ARM, test $is_arm = yes)
 245 AM_CONDITIONAL(LIBGO_IS_M68K, test $is_m68k = yes)
 246 AM_CONDITIONAL(LIBGO_IS_MIPS, test $mips_abi != unknown)
 247 AM_CONDITIONAL(LIBGO_IS_MIPSO32, test $mips_abi = o32)
 248 AM_CONDITIONAL(LIBGO_IS_MIPSN32, test $mips_abi = n32)
 249 AM_CONDITIONAL(LIBGO_IS_MIPSN64, test $mips_abi = n64)
 250 AM_CONDITIONAL(LIBGO_IS_MIPSO64, test $mips_abi = o64)
 251 AM_CONDITIONAL(LIBGO_IS_PPC, test $is_ppc = yes)
 252 AM_CONDITIONAL(LIBGO_IS_PPC64, test $is_ppc64 = yes)
 253 AM_CONDITIONAL(LIBGO_IS_SPARC, test $is_sparc = yes)
 254 AM_CONDITIONAL(LIBGO_IS_SPARC64, test $is_sparc64 = yes)
 255 AM_CONDITIONAL(LIBGO_IS_X86_64, test $is_x86_64 = yes)
 256 AC_SUBST(GOARCH)
 257
 258 dnl Some files are only present when needed for specific architectures.
 259 GO_LIBCALL_OS_FILE=
 260 GO_LIBCALL_OS_ARCH_FILE=
 261 GO_SYSCALL_OS_FILE=
 262 GO_SYSCALL_OS_ARCH_FILE=
 263 if test -f ${srcdir}/go/syscall/libcall_${GOOS}.go; then
 264   GO_LIBCALL_OS_FILE=go/syscall/libcall_${GOOS}.go
 265 fi
 266 if test -f ${srcdir}/go/syscall/libcall_${GOOS}_${GOARCH}.go; then
 267   GO_LIBCALL_OS_ARCH_FILE=go/syscall/libcall_${GOOS}_${GOARCH}.go
 268 fi
 269 if test -f ${srcdir}/go/syscall/syscall_${GOOS}.go; then
 270   GO_SYSCALL_OS_FILE=go/syscall/syscall_${GOOS}.go
 271 fi
 272 if test -f ${srcdir}/go/syscall/syscall_${GOOS}_${GOARCH}.go; then
 273   GO_SYSCALL_OS_ARCH_FILE=go/syscall/syscall_${GOOS}_${GOARCH}.go
 274 fi
 275 AC_SUBST(GO_LIBCALL_OS_FILE)
 276 AC_SUBST(GO_LIBCALL_OS_ARCH_FILE)
 277 AC_SUBST(GO_SYSCALL_OS_FILE)
 278 AC_SUBST(GO_SYSCALL_OS_ARCH_FILE)
 279
 280 dnl Special flags used to generate sysinfo.go.
 281 OSCFLAGS="-D_GNU_SOURCE -D_LARGEFILE_SOURCE -D_FILE_OFFSET_BITS=64"
 282 case "$target" in
 283     mips-sgi-irix6.5*)
 284         # IRIX 6 needs _XOPEN_SOURCE=500 for the XPG5 version of struct
 285         # msghdr in <sys/socket.h>.
 286         OSCFLAGS="$OSCFLAGS -D_XOPEN_SOURCE=500"
 287         ;;
 288     *-*-solaris2.[[89]])
 289         # Solaris 8/9 need this so struct msghdr gets the msg_control
 290         # etc. fields in <sys/socket.h> (_XPG4_2).
 291         OSCFLAGS="$OSCFLAGS -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D__EXTENSIONS__"
 292         ;;
 293     *-*-solaris2.1[[01]])
 294         # Solaris 10+ needs this so struct msghdr gets the msg_control
 295         # etc. fields in <sys/socket.h> (_XPG4_2).  _XOPEN_SOURCE=600 as
 296         # above doesn't work with C99.
 297         OSCFLAGS="$OSCFLAGS -std=gnu99 -D_XOPEN_SOURCE=600 -D__EXTENSIONS__"
 298         ;;
 299 esac
 300 AC_SUBST(OSCFLAGS)
 301
 302 dnl Use -fsplit-stack when compiling C code if available.
 303 AC_CACHE_CHECK([whether -fsplit-stack is supported],
 304 [libgo_cv_c_split_stack_supported],
 305 [CFLAGS_hold=$CFLAGS
 306 CFLAGS="$CFLAGS -fsplit-stack"
 307 AC_COMPILE_IFELSE([[int i;]],
 308 [libgo_cv_c_split_stack_supported=yes],
 309 [libgo_cv_c_split_stack_supported=no])
 310 CFLAGS=$CFLAGS_hold])
 311 if test "$libgo_cv_c_split_stack_supported" = yes; then
 312   SPLIT_STACK=-fsplit-stack
 313   AC_DEFINE(USING_SPLIT_STACK, 1,
 314                 [Define if the compiler supports -fsplit-stack])
 315 else
 316   SPLIT_STACK=
 317 fi
 318 AC_SUBST(SPLIT_STACK)
 319 AM_CONDITIONAL(USING_SPLIT_STACK,
 320         test "$libgo_cv_c_split_stack_supported" = yes)
 321
 322 dnl Check whether the linker does stack munging when calling from
 323 dnl split-stack into non-split-stack code.  We check this by looking
 324 dnl at the --help output.  FIXME: This is only half right: it's
 325 dnl possible for the linker to support this for some targets but not
 326 dnl others.
 327 AC_CACHE_CHECK([whether linker supports split stack],
 328 [libgo_cv_c_linker_supports_split_stack],
 329 libgo_cv_c_linker_supports_split_stack=no
 330 if $LD --help 2>/dev/null | grep split-stack-adjust-size >/dev/null 2>&1; then
 331   libgo_cv_c_linker_supports_split_stack=yes
 332 fi)
 333 if test "$libgo_cv_c_linker_supports_split_stack" = yes; then
 334   AC_DEFINE(LINKER_SUPPORTS_SPLIT_STACK, 1,
 335             [Define if the linker support split stack adjustments])
 336 fi
 337
 338 dnl Test for the -lm library.
 339 MATH_LIBS=
 340 AC_CHECK_LIB([m], [sqrt], MATH_LIBS=-lm)
 341 AC_SUBST(MATH_LIBS)
 342
 343 dnl Test for -lsocket and -lnsl.  Copied from libjava/configure.ac.
 344 AC_CACHE_CHECK([for socket libraries], libgo_cv_lib_sockets,
 345   [libgo_cv_lib_sockets=
 346    libgo_check_both=no
 347    AC_CHECK_FUNC(connect, libgo_check_socket=no, libgo_check_socket=yes)
 348    if test "$libgo_check_socket" = "yes"; then
 349      unset ac_cv_func_connect
 350      AC_CHECK_LIB(socket, main, libgo_cv_lib_sockets="-lsocket",
 351                   libgo_check_both=yes)
 352    fi
 353    if test "$libgo_check_both" = "yes"; then
 354      libgo_old_libs=$LIBS
 355      LIBS="$LIBS -lsocket -lnsl"
 356      unset ac_cv_func_accept
 357      AC_CHECK_FUNC(accept,
 358                    [libgo_check_nsl=no
 359                     libgo_cv_lib_sockets="-lsocket -lnsl"])
 360      unset ac_cv_func_accept
 361      LIBS=$libgo_old_libs
 362    fi
 363    unset ac_cv_func_gethostbyname
 364    libgo_old_libs="$LIBS"
 365    AC_CHECK_FUNC(gethostbyname, ,
 366                  [AC_CHECK_LIB(nsl, main,
 367                         [libgo_cv_lib_sockets="$libgo_cv_lib_sockets -lnsl"])])
 368    unset ac_cv_func_gethostbyname
 369    LIBS=$libgo_old_libs
 370 ])
 371 NET_LIBS="$libgo_cv_lib_sockets"
 372 AC_SUBST(NET_LIBS)
 373
 374 dnl Test whether the compiler supports the -pthread option.
 375 AC_CACHE_CHECK([whether -pthread is supported],
 376 [libgo_cv_lib_pthread],
 377 [CFLAGS_hold=$CFLAGS
 378 CFLAGS="$CFLAGS -pthread"
 379 AC_COMPILE_IFELSE([[int i;]],
 380 [libgo_cv_lib_pthread=yes],
 381 [libgo_cv_lib_pthread=no])
 382 CFLAGS=$CFLAGS_hold])
 383 PTHREAD_CFLAGS=
 384 if test "$libgo_cv_lib_pthread" = yes; then
 385   PTHREAD_CFLAGS=-pthread
 386 fi
 387 AC_SUBST(PTHREAD_CFLAGS)
 388
 389 dnl Test for the -lpthread library.
 390 PTHREAD_LIBS=
 391 AC_CHECK_LIB([pthread], [pthread_create], PTHREAD_LIBS=-lpthread)
 392 AC_SUBST(PTHREAD_LIBS)
 393
 394 dnl Test if -lrt is required for sched_yield.
 395 AC_SEARCH_LIBS([sched_yield], [rt])
 396
 397 AC_C_BIGENDIAN
 398
 399 GCC_CHECK_UNWIND_GETIPINFO
 400
 401 AC_ARG_ENABLE(sjlj-exceptions,
 402   AC_HELP_STRING([--enable-sjlj-exceptions],
 403                  [force use of builtin_setjmp for exceptions]),
 404   [case "$enableval" in
 405    yes|no|auto) ;;
 406    *) AC_MSG_ERROR([unknown argument to --enable-sjlj-exceptions]) ;;
 407    esac],
 408   [enable_sjlj_exceptions=auto])
 409
 410 AC_CACHE_CHECK([whether to use setjmp/longjmp exceptions],
 411 [libgo_cv_lib_sjlj_exceptions],
 412 [AC_LANG_CONFTEST(
 413   [AC_LANG_SOURCE([
 414 void bar ();
 415 void clean (int *);
 416 void foo ()
 417 {
 418   int i __attribute__ ((cleanup (clean)));
 419   bar();
 420 }
 421 ])])
 422 CFLAGS_hold=$CFLAGS
 423 CFLAGS="--save-temps -fexceptions"
 424 libgo_cv_lib_sjlj_exceptions=unknown
 425 AS_IF([ac_fn_c_try_compile],
 426   [if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1; then
 427     libgo_cv_lib_sjlj_exceptions=yes
 428   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1; then
 429     libgo_cv_lib_sjlj_exceptions=no
 430   fi])
 431 CFLAGS=$CFLAGS_hold
 432 rm -f conftest*
 433 ])
 434
 435 if test "$enable_sjlj_exceptions" = "auto"; then
 436   enable_sjlj_exceptions=$libgo_cv_lib_sjlj_exceptions
 437 fi
 438
 439 case $enable_sjlj_exceptions in
 440 yes)
 441   AC_DEFINE(LIBGO_SJLJ_EXCEPTIONS, 1,
 442         [Define if the C++ compiler is configured for setjmp/longjmp exceptions.])
 443   ;;
 444 no)
 445   ;;
 446 *)
 447   AC_MSG_ERROR([unable to detect exception model])
 448   ;;
 449 esac
 450
 451 AC_CHECK_HEADERS(sys/mman.h syscall.h sys/epoll.h sys/ptrace.h sys/syscall.h sys/user.h sys/utsname.h sys/select.h sys/socket.h net/if.h)
 452
 453 AC_CHECK_HEADERS([linux/filter.h linux/netlink.h linux/rtnetlink.h], [], [],
 454 [#ifdef HAVE_SYS_SOCKET_H
 455 #include <sys/socket.h>
 456 #endif
 457 ])
 458
 459 AM_CONDITIONAL(HAVE_SYS_MMAN_H, test "$ac_cv_header_sys_mman_h" = yes)
 460
 461 AC_CHECK_FUNCS(strerror_r strsignal wait4 mincore setenv)
 462 AM_CONDITIONAL(HAVE_STRERROR_R, test "$ac_cv_func_strerror_r" = yes)
 463 AM_CONDITIONAL(HAVE_WAIT4, test "$ac_cv_func_wait4" = yes)
 464
 465 CFLAGS_hold="$CFLAGS"
 466 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 467 LIBS_hold="$LIBS"
 468 LIBS="$LIBS $PTHREAD_LIBS"
 469 AC_CHECK_FUNCS(sem_timedwait)
 470 CFLAGS="$CFLAGS_hold"
 471 LIBS="$LIBS_hold"
 472
 473 AC_CACHE_CHECK([for __sync_bool_compare_and_swap_4],
 474 [libgo_cv_func___sync_bool_compare_and_swap_4],
 475 [AC_LINK_IFELSE([
 476 typedef unsigned int uint32  __attribute__ ((mode (SI)));
 477 uint32 i;
 478 int main() { return __sync_bool_compare_and_swap (&i, 0, 1); }
 479 ],
 480 [libgo_cv_func___sync_bool_compare_and_swap_4=yes],
 481 [libgo_cv_func___sync_bool_compare_and_swap_4=no])])
 482 if test "$libgo_cv_func___sync_bool_compare_and_swap_4" = "yes"; then
 483   AC_DEFINE(HAVE_SYNC_BOOL_COMPARE_AND_SWAP_4, 1,
 484     [Define to 1 if the compiler provides the __sync_bool_compare_and_swap function for uint32])
 485 fi
 486
 487 AC_CACHE_CHECK([for __sync_fetch_and_add_4],
 488 [libgo_cv_func___sync_fetch_and_add_4],
 489 [AC_LINK_IFELSE([
 490 typedef unsigned int uint32  __attribute__ ((mode (SI)));
 491 uint32 i;
 492 int main() { return __sync_fetch_and_add (&i, 1); }
 493 ],
 494 [libgo_cv_func___sync_fetch_and_add_4=yes],
 495 [libgo_cv_func___sync_fetch_and_add_4=no])])
 496 if test "$libgo_cv_func___sync_fetch_and_add_4" = "yes"; then
 497   AC_DEFINE(HAVE_SYNC_FETCH_AND_ADD_4, 1,
 498     [Define to 1 if the compiler provides the __sync_fetch_and_add function for uint32])
 499 fi
 500
 501 dnl For x86 we want to use the -minline-all-stringops option to avoid
 502 dnl forcing a stack split when calling memcpy and friends.
 503 AC_CACHE_CHECK([whether compiler supports -minline-all-stringops],
 504 [libgo_cv_c_stringops],
 505 [CFLAGS_hold=$CFLAGS
 506 CFLAGS="$CFLAGS -minline-all-stringops"
 507 AC_COMPILE_IFELSE([int i;],
 508 [libgo_cv_c_stringops=yes],
 509 [libgo_cv_c_stringops=no])
 510 CFLAGS=$CFLAGS_hold])
 511 STRINGOPS_FLAG=
 512 if test "$libgo_cv_c_stringops" = yes; then
 513   STRINGOPS_FLAG=-minline-all-stringops
 514 fi
 515 AC_SUBST(STRINGOPS_FLAG)
 516
 517 CFLAGS_hold=$CFLAGS
 518 CFLAGS="$CFLAGS -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE"
 519 AC_CHECK_TYPES(off64_t)
 520 CFLAGS=$CFLAGS_hold
 521
 522 dnl Work out the size of the epoll_events struct on GNU/Linux.
 523 AC_CACHE_CHECK([epoll_event size],
 524 [libgo_cv_c_epoll_event_size],
 525 [AC_COMPUTE_INT(libgo_cv_c_epoll_event_size,
 526 [sizeof (struct epoll_event)],
 527 [#include <sys/epoll.h>],
 528 [libgo_cv_c_epoll_event_size=0])])
 529 SIZEOF_STRUCT_EPOLL_EVENT=${libgo_cv_c_epoll_event_size}
 530 AC_SUBST(SIZEOF_STRUCT_EPOLL_EVENT)
 531
 532 dnl Work out the offset of the fd field in the epoll_events struct on
 533 dnl GNU/Linux.
 534 AC_CACHE_CHECK([epoll_event data.fd offset],
 535 [libgo_cv_c_epoll_event_fd_offset],
 536 [AC_COMPUTE_INT(libgo_cv_c_epoll_event_fd_offset,
 537 [offsetof (struct epoll_event, data.fd)],
 538 [#include <stddef.h>
 539 #include <sys/epoll.h>],
 540 [libgo_cv_c_epoll_event_fd_offset=0])])
 541 STRUCT_EPOLL_EVENT_FD_OFFSET=${libgo_cv_c_epoll_event_fd_offset}
 542 AC_SUBST(STRUCT_EPOLL_EVENT_FD_OFFSET)
 543
 544 AC_CACHE_SAVE
 545
 546 if test ${multilib} = yes; then
 547   multilib_arg="--enable-multilib"
 548 else
 549   multilib_arg=
 550 fi
 551
 552 AC_CONFIG_FILES(Makefile testsuite/Makefile)
 553
 554 AC_CONFIG_COMMANDS([default],
 555 [if test -n "$CONFIG_FILES"; then
 556    # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 557    # that multilib installs will end up installed in the correct place.
 558    # The testsuite needs it for multilib-aware ABI baseline files.
 559    # To work around this not being passed down from config-ml.in ->
 560    # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 561    # append it here.  Only modify Makefiles that have just been created.
 562    #
 563    # Also, get rid of this simulated-VPATH thing that automake does.
 564    cat > vpsed << \_EOF
 565 s!`test -f '$<' || echo '$(srcdir)/'`!!
 566 _EOF
 567    for i in $SUBDIRS; do
 568     case $CONFIG_FILES in
 569      *${i}/Makefile*)
 570        #echo "Adding MULTISUBDIR to $i/Makefile"
 571        sed -f vpsed $i/Makefile > tmp
 572        grep '^MULTISUBDIR =' Makefile >> tmp
 573        mv tmp $i/Makefile
 574        ;;
 575     esac
 576    done
 577    rm vpsed
 578  fi
 579 ],
 580 [
 581 # Variables needed in config.status (file generation) which aren't already
 582 # passed by autoconf.
 583 SUBDIRS="$SUBDIRS"
 584 ])
 585
 586 AC_OUTPUT