libobjc/configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 #   Copyright 1994, 1995, 1996, 1997, 1998, 1999, 2001, 2002, 2003, 2004
   3 #   2005, 2006 Free Software Foundation, Inc.
   4 #   Originally contributed by Dave Love (d.love@dl.ac.uk).
   5 #
   6 #This file is part of GCC.
   7 #
   8 #GCC is free software; you can redistribute it and/or modify
   9 #it under the terms of the GNU General Public License as published by
  10 #the Free Software Foundation; either version 2, or (at your option)
  11 #any later version.
  12 #
  13 #GCC is distributed in the hope that it will be useful,
  14 #but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 #GNU General Public License for more details.
  17 #
  18 #You should have received a copy of the GNU General Public License
  19 #along with GCC; see the file COPYING.  If not, write to
  20 #the Free Software Foundation, 51 Franklin Street, Fifth Floor, Boston, MA
  21 #02110-1301, USA.
  22
  23 AC_PREREQ(2.59)
  24 AC_INIT(package-unused, version-unused,, libobjc)
  25 AC_CONFIG_SRCDIR([objc/objc.h])
  26 GCC_TOPLEV_SUBDIRS
  27
  28 # We need the following definitions because AC_PROG_LIBTOOL relies on them
  29 PACKAGE=libobjc
  30 # Version is pulled out to make it a bit easier to change using sed.
  31 VERSION=2:0:0
  32 AC_SUBST(VERSION)
  33
  34 # This works around the fact that libtool configuration may change LD
  35 # for this particular configuration, but some shells, instead of
  36 # keeping the changes in LD private, export them just because LD is
  37 # exported.
  38 ORIGINAL_LD_FOR_MULTILIBS=$LD
  39
  40 # -------
  41 # Options
  42 # -------
  43
  44 # We use these options to decide which functions to include.
  45 AC_ARG_WITH(target-subdir,
  46 [  --with-target-subdir=SUBDIR
  47                            configuring in a subdirectory])
  48 AC_ARG_WITH(cross-host,
  49 [  --with-cross-host=HOST  configuring with a cross compiler])
  50
  51 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  52 AC_ARG_ENABLE(version-specific-runtime-libs,
  53 [  --enable-version-specific-runtime-libs    Specify that runtime libraries should be installed in a compiler-specific directory ],
  54 [case "$enableval" in
  55  yes) version_specific_libs=yes ;;
  56  no)  version_specific_libs=no ;;
  57  *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  58  esac],
  59 [version_specific_libs=no])
  60 AC_MSG_RESULT($version_specific_libs)
  61
  62 AC_ARG_ENABLE(objc-gc,
  63 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
  64                           the GNU Objective-C runtime.],
  65 [case $enable_objc_gc in
  66   no)
  67     OBJC_BOEHM_GC=''
  68     OBJC_BOEHM_GC_INCLUDES=''
  69     ;;
  70   *)
  71     OBJC_BOEHM_GC=libobjc_gc.la
  72     OBJC_BOEHM_GC_INCLUDES='-I$(top_srcdir)/../boehm-gc/include -I../boehm-gc/include'
  73     ;;
  74 esac],
  75 [OBJC_BOEHM_GC=''; OBJC_BOEHM_GC_INCLUDES=''])
  76 AC_SUBST(OBJC_BOEHM_GC)
  77 AC_SUBST(OBJC_BOEHM_GC_INCLUDES)
  78
  79 # -----------
  80 # Directories
  81 # -----------
  82
  83 # Find the rest of the source tree framework.
  84 AM_ENABLE_MULTILIB(, ..)
  85
  86 AC_CANONICAL_SYSTEM
  87 ACX_NONCANONICAL_TARGET
  88
  89 # Export source directory.
  90 # These need to be absolute paths, yet at the same time need to
  91 # canonicalize only relative paths, because then amd will not unmount
  92 # drives. Thus the use of PWDCMD: set it to 'pawd' or 'amq -w' if using amd.
  93 case $srcdir in
  94   [\\/$]* | ?:[\\/]*) glibcpp_srcdir=${srcdir} ;;
  95   *) glibcpp_srcdir=`cd "$srcdir" && ${PWDCMD-pwd} || echo "$srcdir"` ;;
  96 esac
  97 AC_SUBST(glibcpp_srcdir)
  98
  99 # Calculate toolexeclibdir
 100 # Also toolexecdir, though it's only used in toolexeclibdir
 101 case ${version_specific_libs} in
 102   yes)
 103     # Need the gcc compiler version to know where to install libraries
 104     # and header files if --enable-version-specific-runtime-libs option
 105     # is selected.
 106     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
 107     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
 108     ;;
 109   no)
 110     if test -n "$with_cross_host" &&
 111        test x"$with_cross_host" != x"no"; then
 112       # Install a library built with a cross compiler in tooldir, not libdir.
 113       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
 114       toolexeclibdir='$(toolexecdir)/lib'
 115     else
 116       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
 117       toolexeclibdir='$(libdir)'
 118     fi
 119     multi_os_directory=`$CC -print-multi-os-directory`
 120     case $multi_os_directory in
 121       .) ;; # Avoid trailing /.
 122       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 123     esac
 124     ;;
 125 esac
 126 AC_SUBST(toolexecdir)
 127 AC_SUBST(toolexeclibdir)
 128
 129 # Figure out if we want to name the include directory and the
 130 #  library name changes differently.
 131 includedirname=include
 132 libext=
 133 case "${host}" in
 134   *-darwin*)
 135     # Darwin is the only target so far that needs a different include directory.
 136     includedirname=include-gnu-runtime
 137     libext=-gnu
 138     ;;
 139 esac
 140 AC_SUBST(includedirname)
 141 AC_SUBST(libext)
 142
 143 AC_CONFIG_HEADERS(config.h)
 144
 145 # --------
 146 # Programs
 147 # --------
 148
 149 GCC_NO_EXECUTABLES
 150
 151 # We must force CC to /not/ be a precious variable; otherwise
 152 # the wrong, non-multilib-adjusted value will be used in multilibs.
 153 # As a side effect, we have to subst CFLAGS ourselves.
 154 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
 155 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 156 AC_PROG_CC
 157 m4_rename([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 158
 159 # extra LD Flags which are required for targets
 160 case "${host}" in
 161   *-darwin*)
 162     # Darwin needs -single_module when linking libobjc
 163     extra_ldflags_libobjc=-Wl,-single_module
 164     ;;
 165 esac
 166 AC_SUBST(extra_ldflags_libobjc)
 167
 168 AC_SUBST(CFLAGS)
 169
 170 AC_CHECK_TOOL(AS, as)
 171 AC_CHECK_TOOL(AR, ar)
 172 AC_CHECK_TOOL(RANLIB, ranlib, :)
 173 AC_PROG_INSTALL
 174
 175 AM_MAINTAINER_MODE
 176
 177 # Enable Win32 DLL on MS Windows - FIXME
 178 AC_LIBTOOL_WIN32_DLL
 179
 180 AC_PROG_LIBTOOL
 181
 182 AM_PROG_CC_C_O
 183
 184 AC_PROG_MAKE_SET
 185
 186 # -------
 187 # Headers
 188 # -------
 189
 190 # Sanity check for the cross-compilation case:
 191 AC_CHECK_HEADER(stdio.h,:,
 192   [AC_MSG_ERROR([Can't find stdio.h.
 193 You must have a usable C system for the target already installed, at least
 194 including headers and, preferably, the library, before you can configure
 195 the Objective C runtime system.  If necessary, install gcc now with
 196 \`LANGUAGES=c', then the target library, then build with \`LANGUAGES=objc'.])])
 197
 198 AC_HEADER_STDC
 199
 200 AC_CHECK_HEADERS(sched.h)
 201
 202 # -----------
 203 # Miscellanea
 204 # -----------
 205
 206 AC_MSG_CHECKING([for thread model used by GCC])
 207 target_thread_file=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 208 AC_MSG_RESULT([$target_thread_file])
 209
 210 if test $target_thread_file != single; then
 211   AC_DEFINE(HAVE_GTHR_DEFAULT, 1,
 212         [Define if the compiler has a thread header that is non single.])
 213 fi
 214
 215
 216 AC_MSG_CHECKING([for exception model to use])
 217 AC_LANG_PUSH(C)
 218 AC_ARG_ENABLE(sjlj-exceptions,
 219   AS_HELP_STRING([--enable-sjlj-exceptions],
 220                  [force use of builtin_setjmp for exceptions]),
 221 [:],
 222 [dnl Botheration.  Now we've got to detect the exception model.
 223 dnl Link tests against libgcc.a are problematic since -- at least
 224 dnl as of this writing -- we've not been given proper -L bits for
 225 dnl single-tree newlib and libgloss.
 226 dnl
 227 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 228 dnl conftest files before we got a change to grep them first.
 229 cat > conftest.$ac_ext << EOF
 230 [#]line __oline__ "configure"
 231 @interface Frob
 232 @end
 233 @implementation Frob
 234 @end
 235 int proc();
 236 int foo()
 237 {
 238   @try {
 239    return proc();
 240   }
 241   @catch (Frob* ex) {
 242     return 0;
 243   }
 244 }
 245 EOF
 246 old_CFLAGS="$CFLAGS"
 247 dnl work around that we don't have Objective-C support in autoconf
 248 CFLAGS="-x objective-c -fgnu-runtime -fobjc-exceptions -S"
 249 if AC_TRY_EVAL(ac_compile); then
 250   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 251     enable_sjlj_exceptions=yes
 252   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 253     enable_sjlj_exceptions=no
 254   fi
 255 fi
 256 CFLAGS="$old_CFLAGS"
 257 rm -f conftest*])
 258 if test x$enable_sjlj_exceptions = xyes; then
 259   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 260         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 261   ac_exception_model_name=sjlj
 262 elif test x$enable_sjlj_exceptions = xno; then
 263   ac_exception_model_name="call frame"
 264 else
 265   AC_MSG_ERROR([unable to detect exception model])
 266 fi
 267 AC_LANG_POP(C)
 268 AC_MSG_RESULT($ac_exception_model_name)
 269
 270 # ------
 271 # Output
 272 # ------
 273
 274 AC_CONFIG_FILES([Makefile])
 275
 276 AC_CONFIG_COMMANDS([default],
 277 [[if test -n "$CONFIG_FILES"; then
 278   if test -n "${with_target_subdir}"; then
 279     # FIXME: We shouldn't need to set ac_file
 280     ac_file=Makefile
 281     LD="${ORIGINAL_LD_FOR_MULTILIBS}"
 282     . ${multi_basedir}/config-ml.in
 283   fi
 284 fi]],
 285 [[srcdir=${srcdir}
 286 host=${host}
 287 target=${target}
 288 with_target_subdir=${with_target_subdir}
 289 with_multisubdir=${with_multisubdir}
 290 ac_configure_args="--enable-multilib ${ac_configure_args}"
 291 multi_basedir=${multi_basedir}
 292 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 293 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
 294 ]])
 295
 296 AC_OUTPUT