gcc/optc-gen.awk

   1 #  Copyright (C) 2003,2004 Free Software Foundation, Inc.
   2 #  Contributed by Kelley Cook, June 2004.
   3 #  Original code from Neil Booth, May 2003.
   4 #
   5 # This program is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by the
   7 # Free Software Foundation; either version 2, or (at your option) any
   8 # later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; if not, write to the Free Software
  17 # Foundation, 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA.
  18
  19 # This Awk script reads in the option records generated from
  20 # opt-gather.awk, combines the flags of duplicat options and generates a
  21 # C file.
  22 #
  23 # This program uses functions from opt-functions.awk
  24 #
  25 # Usage: awk -f opt-functions.awk -f optc-gen.awk \
  26 #            [-v header_name=header.h] < inputfile > options.c
  27
  28 BEGIN {
  29         n_opts = 0
  30         n_langs = 0
  31         quote = "\042"
  32         comma = ","
  33         FS=SUBSEP
  34         # Default the name of header created from opth-gen.awk to options.h
  35         if (header_name == "") header_name="options.h"
  36 }
  37
  38 # Collect the text and flags of each option into an array
  39         {
  40                 if ($1 == "Language") {
  41                         langs[n_langs] = $2
  42                         n_langs++;
  43                 }
  44                 else {
  45                         name = opt_args("Mask", $1)
  46                         if (name == "") {
  47                                 opts[n_opts]  = $1
  48                                 flags[n_opts] = $2
  49                                 help[n_opts]  = $3
  50                                 n_opts++;
  51                         }
  52                 }
  53         }
  54
  55 # Dump that array of options into a C file.
  56 END {
  57 print "/* This file is auto-generated by opts.sh.  */"
  58 print ""
  59 n_headers = split(header_name, headers, " ")
  60 for (i = 1; i <= n_headers; i++)
  61         print "#include " quote headers[i] quote
  62 print "#include " quote "opts.h" quote
  63 print "#include " quote "intl.h" quote
  64 print ""
  65 print "#ifdef GCC_DRIVER"
  66 print "int target_flags;"
  67 print "#endif /* GCC_DRIVER */"
  68 print ""
  69
  70 for (i = 0; i < n_opts; i++) {
  71         name = var_name(flags[i]);
  72         if (name == "")
  73                 continue;
  74
  75         if (flag_set_p("VarExists", flags[i])) {
  76                 # Need it for the gcc driver.
  77                 if (name in var_seen)
  78                         continue;
  79                 init = ""
  80                 gcc_driver = 1
  81         }
  82         else {
  83                 init = opt_args("Init", flags[i])
  84                 if (init != "")
  85                         init = " = " init;
  86                 else if (name in var_seen)
  87                         continue;
  88                 gcc_driver = 0
  89         }
  90
  91         if (gcc_driver == 1)
  92                 print "#ifdef GCC_DRIVER"
  93         print "/* Set by -" opts[i] "."
  94         print "   " help[i] "  */"
  95         print var_type(flags[i]) name init ";"
  96         if (gcc_driver == 1)
  97                 print "#endif /* GCC_DRIVER */"
  98         print ""
  99
 100         var_seen[name] = 1;
 101 }
 102
 103 print ""
 104 print "/* Local state variables.  */"
 105 for (i = 0; i < n_opts; i++) {
 106         name = static_var(opts[i], flags[i]);
 107         if (name != "")
 108                 print "static " var_type(flags[i]) name ";"
 109 }
 110 print ""
 111
 112 print "const char * const lang_names[] =\n{"
 113 for (i = 0; i < n_langs; i++) {
 114         macros[i] = "CL_" langs[i]
 115         gsub( "[^A-Za-z0-9_]", "X", macros[i] )
 116         s = substr("         ", length (macros[i]))
 117         print "  " quote langs[i] quote ","
 118     }
 119
 120 print "  0\n};\n"
 121 print "const unsigned int cl_options_count = N_OPTS;\n"
 122
 123 print "const struct cl_option cl_options[] =\n{"
 124
 125 j = 0
 126 for (i = 0; i < n_opts; i++) {
 127         back_chain[i] = "N_OPTS";
 128         indices[opts[i]] = j;
 129         # Combine the flags of identical switches.  Switches
 130         # appear many times if they are handled by many front
 131         # ends, for example.
 132         while( i + 1 != n_opts && opts[i] == opts[i + 1] ) {
 133                 flags[i + 1] = flags[i] " " flags[i + 1];
 134                 i++;
 135                 back_chain[i] = "N_OPTS";
 136                 indices[opts[i]] = j;
 137         }
 138         j++;
 139 }
 140
 141 for (i = 0; i < n_opts; i++) {
 142         # Combine the flags of identical switches.  Switches
 143         # appear many times if they are handled by many front
 144         # ends, for example.
 145         while( i + 1 != n_opts && opts[i] == opts[i + 1] ) {
 146                 flags[i + 1] = flags[i] " " flags[i + 1];
 147                 i++;
 148         }
 149
 150         len = length (opts[i]);
 151         enum = "OPT_" opts[i]
 152         if (opts[i] == "finline-limit=")
 153                 enum = enum "eq"
 154         gsub ("[^A-Za-z0-9]", "_", enum)
 155
 156         # If this switch takes joined arguments, back-chain all
 157         # subsequent switches to it for which it is a prefix.  If
 158         # a later switch S is a longer prefix of a switch T, T
 159         # will be back-chained to S in a later iteration of this
 160         # for() loop, which is what we want.
 161         if (flag_set_p("Joined.*", flags[i])) {
 162                 for (j = i + 1; j < n_opts; j++) {
 163                         if (substr (opts[j], 1, len) != opts[i])
 164                                 break;
 165                         back_chain[j] = enum;
 166                 }
 167         }
 168
 169         s = substr("                                  ", length (opts[i]))
 170         if (i + 1 == n_opts)
 171                 comma = ""
 172
 173         if (help[i] == "")
 174                 hlp = "0"
 175         else
 176                 hlp = quote help[i] quote;
 177
 178         neg = opt_args("Negative", flags[i]);
 179         if (neg != "")
 180                 idx = indices[neg]
 181         else {
 182                 if (flag_set_p("RejectNegative", flags[i]))
 183                         idx = -1;
 184                 else {
 185                         if (opts[i] ~ "^[Wfm]")
 186                                 idx = indices[opts[i]];
 187                         else
 188                                 idx = -1;
 189                 }
 190         }
 191         printf("  { %c-%s%c,\n    %s,\n    %s, %u, %d,\n",
 192                quote, opts[i], quote, hlp, back_chain[i], len, idx)
 193         condition = opt_args("Condition", flags[i])
 194         cl_flags = switch_flags(flags[i])
 195         if (condition != "")
 196                 printf("#if %s\n" \
 197                        "    %s,\n" \
 198                        "#else\n" \
 199                        "    CL_DISABLED,\n" \
 200                        "#endif\n",
 201                        condition, cl_flags, cl_flags)
 202         else
 203                 printf("    %s,\n", cl_flags)
 204         printf("    %s, %s }%s\n", var_ref(opts[i], flags[i]),
 205                var_set(flags[i]), comma)
 206 }
 207
 208 print "};"
 209 }