libbacktrace/configure.ac

   1 # configure.ac -- Backtrace configure script.
   2 # Copyright (C) 2012-2023 Free Software Foundation, Inc.
   3
   4 # Redistribution and use in source and binary forms, with or without
   5 # modification, are permitted provided that the following conditions are
   6 # met:
   7
   8 #     (1) Redistributions of source code must retain the above copyright
   9 #     notice, this list of conditions and the following disclaimer.
  10
  11 #     (2) Redistributions in binary form must reproduce the above copyright
  12 #     notice, this list of conditions and the following disclaimer in
  13 #     the documentation and/or other materials provided with the
  14 #     distribution.
  15
  16 #     (3) The name of the author may not be used to
  17 #     endorse or promote products derived from this software without
  18 #     specific prior written permission.
  19
  20 # THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  21 # IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
  22 # WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
  23 # DISCLAIMED. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT,
  24 # INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
  25 # (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
  26 # SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  27 # HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT,
  28 # STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING
  29 # IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
  30 # POSSIBILITY OF SUCH DAMAGE.
  31
  32 AC_INIT(package-unused, version-unused,, libbacktrace)
  33 AC_CONFIG_SRCDIR(backtrace.h)
  34 AC_CONFIG_HEADER(config.h)
  35
  36 if test -n "${with_target_subdir}"; then
  37   AM_ENABLE_MULTILIB(, ..)
  38 fi
  39
  40 AC_CANONICAL_SYSTEM
  41 target_alias=${target_alias-$host_alias}
  42
  43 AC_USE_SYSTEM_EXTENSIONS
  44
  45 libtool_VERSION=1:0:0
  46 AC_SUBST(libtool_VERSION)
  47
  48 # 1.11.1: Require that version of automake.
  49 # foreign: Don't require README, INSTALL, NEWS, etc.
  50 # no-define: Don't define PACKAGE and VERSION.
  51 # no-dependencies: Don't generate automatic dependencies.
  52 #    (because it breaks when using bootstrap-lean, since some of the
  53 #    headers are gone at "make install" time).
  54 # -Wall: Issue all automake warnings.
  55 # -Wno-portability: Don't warn about constructs supported by GNU make.
  56 #    (because GCC requires GNU make anyhow).
  57 AM_INIT_AUTOMAKE([1.11.1 foreign no-dist no-define no-dependencies -Wall -Wno-portability])
  58
  59 AM_MAINTAINER_MODE
  60
  61 AC_ARG_WITH(target-subdir,
  62 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory for target])
  63
  64 # We must force CC to /not/ be precious variables; otherwise
  65 # the wrong, non-multilib-adjusted value will be used in multilibs.
  66 # As a side effect, we have to subst CFLAGS ourselves.
  67 m4_rename([_AC_ARG_VAR_PRECIOUS],[backtrace_PRECIOUS])
  68 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  69 AC_PROG_CC
  70 m4_rename_force([backtrace_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  71
  72 AC_SUBST(CFLAGS)
  73
  74 AC_PROG_RANLIB
  75
  76 AC_PROG_AWK
  77 case "$AWK" in
  78 "") AC_MSG_ERROR([can't build without awk]) ;;
  79 esac
  80
  81 AC_CHECK_PROG(DWZ, dwz, dwz)
  82 AM_CONDITIONAL(HAVE_DWZ, test "$DWZ" != "")
  83
  84 LT_INIT
  85 AM_PROG_LIBTOOL
  86
  87 AC_SYS_LARGEFILE
  88
  89 backtrace_supported=yes
  90
  91 if test -n "${with_target_subdir}"; then
  92   # We are compiling a GCC library.  We can assume that the unwind
  93   # library exists.
  94   BACKTRACE_FILE="backtrace.lo simple.lo"
  95 else
  96   AC_CHECK_HEADER([unwind.h],
  97     [AC_CHECK_FUNC([_Unwind_Backtrace],
  98                    [BACKTRACE_FILE="backtrace.lo simple.lo"],
  99                    [BACKTRACE_FILE="nounwind.lo"
 100                     backtrace_supported=no])],
 101     [BACKTRACE_FILE="nounwind.lo"
 102      backtrace_supported=no])
 103 fi
 104 AC_SUBST(BACKTRACE_FILE)
 105
 106 EXTRA_FLAGS=
 107 if test -n "${with_target_subdir}"; then
 108   EXTRA_FLAGS="-funwind-tables -frandom-seed=\$@"
 109 else
 110   AC_CACHE_CHECK([for -funwind-tables option],
 111     [libbacktrace_cv_c_unwind_tables],
 112     [CFLAGS_hold="$CFLAGS"
 113      CFLAGS="$CFLAGS -funwind-tables"
 114      AC_COMPILE_IFELSE(
 115        [AC_LANG_PROGRAM([static int f() { return 0; }], [return f();])],
 116        [libbacktrace_cv_c_unwind_tables=yes],
 117        [libbacktrace_cv_c_unwind_tables=no])
 118      CFLAGS="$CFLAGS_hold"])
 119   if test "$libbacktrace_cv_c_unwind_tables" = "yes"; then
 120     EXTRA_FLAGS=-funwind-tables
 121   fi
 122   AC_CACHE_CHECK([for -frandom-seed=string option],
 123     [libbacktrace_cv_c_random_seed_string],
 124     [CFLAGS_hold="$CFLAGS"
 125      CFLAGS="$CFLAGS -frandom-seed=conftest.lo"
 126      AC_COMPILE_IFELSE(
 127        [AC_LANG_PROGRAM([], [return 0;])],
 128        [libbacktrace_cv_c_random_seed_string=yes],
 129        [libbacktrace_cv_c_random_seed_string=no])
 130      CFLAGS="$CFLAGS_hold"])
 131   if test "$libbacktrace_cv_c_random_seed_string" = "yes"; then
 132     EXTRA_FLAGS="$EXTRA_FLAGS -frandom-seed=\$@"
 133   fi
 134 fi
 135
 136 if test -n "${with_target_subdir}"; then
 137   # Add CET specific flags is Intel CET is enabled.
 138   GCC_CET_FLAGS(CET_FLAGS)
 139   EXTRA_FLAGS="$EXTRA_FLAGS $CET_FLAGS"
 140 fi
 141 AC_SUBST(EXTRA_FLAGS)
 142
 143 ACX_PROG_CC_WARNING_OPTS([-W -Wall -Wwrite-strings -Wstrict-prototypes \
 144                           -Wmissing-prototypes -Wold-style-definition \
 145                           -Wmissing-format-attribute -Wcast-qual],
 146                           [WARN_FLAGS])
 147
 148 AC_ARG_ENABLE([werror],
 149   [AS_HELP_STRING([--disable-werror], [disable building with -Werror])])
 150 AS_IF([test "x$enable_werror" != "xno" && test -n "${with_target_subdir}"],
 151   [WARN_FLAGS="$WARN_FLAGS -Werror"])
 152 AC_SUBST(WARN_FLAGS)
 153
 154 if test -n "${with_target_subdir}"; then
 155   GCC_CHECK_UNWIND_GETIPINFO
 156 else
 157   ac_save_CFFLAGS="$CFLAGS"
 158   CFLAGS="$CFLAGS -Werror-implicit-function-declaration"
 159   AC_MSG_CHECKING([for _Unwind_GetIPInfo])
 160   AC_LINK_IFELSE(
 161     [AC_LANG_PROGRAM(
 162        [#include "unwind.h"
 163         struct _Unwind_Context *context;
 164         int ip_before_insn = 0;],
 165         [return _Unwind_GetIPInfo (context, &ip_before_insn);])],
 166         [have_unwind_getipinfo=yes], [have_unwind_getipinfo=no])
 167   CFLAGS="$ac_save_CFLAGS"
 168   AC_MSG_RESULT([$have_unwind_getipinfo])
 169   if test "$have_unwind_getipinfo" = "yes"; then
 170     AC_DEFINE(HAVE_GETIPINFO, 1, [Define if _Unwind_GetIPInfo is available.])
 171   fi
 172 fi
 173
 174 # Enable --enable-host-shared.
 175 AC_ARG_ENABLE(host-shared,
 176 [AS_HELP_STRING([--enable-host-shared],
 177                 [build host code as shared libraries])],
 178 [PIC_FLAG=-fPIC], [PIC_FLAG=])
 179 AC_SUBST(PIC_FLAG)
 180
 181 # Enable Intel CET on Intel CET enabled host if jit is enabled.
 182 GCC_CET_HOST_FLAGS(CET_HOST_FLAGS)
 183 case x$enable_languages in
 184 *jit*)
 185   ;;
 186 *)
 187   CET_HOST_FLAGS=
 188   ;;
 189 esac
 190 AC_SUBST(CET_HOST_FLAGS)
 191
 192 # Test for __sync support.
 193 AC_CACHE_CHECK([__sync extensions],
 194 [libbacktrace_cv_sys_sync],
 195 [if test -n "${with_target_subdir}"; then
 196    case "${host}" in
 197    hppa*-*-hpux*) libbacktrace_cv_sys_sync=no ;;
 198    *) libbacktrace_cv_sys_sync=yes ;;
 199    esac
 200  else
 201    AC_LINK_IFELSE(
 202      [AC_LANG_PROGRAM([int i;],
 203                       [__sync_bool_compare_and_swap (&i, i, i);
 204                        __sync_lock_test_and_set (&i, 1);
 205                        __sync_lock_release (&i);])],
 206      [libbacktrace_cv_sys_sync=yes],
 207      [libbacktrace_cv_sys_sync=no])
 208  fi])
 209 BACKTRACE_SUPPORTS_THREADS=0
 210 if test "$libbacktrace_cv_sys_sync" = "yes"; then
 211   BACKTRACE_SUPPORTS_THREADS=1
 212   AC_DEFINE([HAVE_SYNC_FUNCTIONS], 1,
 213             [Define to 1 if you have the __sync functions])
 214 fi
 215 AC_SUBST(BACKTRACE_SUPPORTS_THREADS)
 216
 217 # Test for __atomic support.
 218 AC_CACHE_CHECK([__atomic extensions],
 219 [libbacktrace_cv_sys_atomic],
 220 [if test -n "${with_target_subdir}"; then
 221    libbacktrace_cv_sys_atomic=yes
 222  else
 223    AC_LINK_IFELSE(
 224      [AC_LANG_PROGRAM([int i;],
 225                       [__atomic_load_n (&i, __ATOMIC_ACQUIRE);
 226                        __atomic_store_n (&i, 1, __ATOMIC_RELEASE);])],
 227      [libbacktrace_cv_sys_atomic=yes],
 228      [libbacktrace_cv_sys_atomic=no])
 229  fi])
 230 if test "$libbacktrace_cv_sys_atomic" = "yes"; then
 231   AC_DEFINE([HAVE_ATOMIC_FUNCTIONS], 1,
 232             [Define to 1 if you have the __atomic functions])
 233 fi
 234
 235 # The library needs to be able to read the executable itself.  Compile
 236 # a file to determine the executable format.  The awk script
 237 # filetype.awk prints out the file type.
 238 AC_CACHE_CHECK([output filetype],
 239 [libbacktrace_cv_sys_filetype],
 240 [filetype=
 241 AC_COMPILE_IFELSE(
 242   [AC_LANG_PROGRAM([int i;], [int j;])],
 243   [filetype=`${AWK} -f $srcdir/filetype.awk conftest.$ac_objext`],
 244   [AC_MSG_FAILURE([compiler failed])])
 245 libbacktrace_cv_sys_filetype=$filetype])
 246
 247 # Match the file type to decide what files to compile.
 248 FORMAT_FILE=
 249 backtrace_supports_data=yes
 250 case "$libbacktrace_cv_sys_filetype" in
 251 elf*) FORMAT_FILE="elf.lo" ;;
 252 macho) FORMAT_FILE="macho.lo" ;;
 253 pecoff) FORMAT_FILE="pecoff.lo"
 254         backtrace_supports_data=no
 255         ;;
 256 xcoff*) FORMAT_FILE="xcoff.lo"
 257         backtrace_supports_data=no
 258         ;;
 259 *) AC_MSG_WARN([could not determine output file type])
 260    FORMAT_FILE="unknown.lo"
 261    backtrace_supported=no
 262    ;;
 263 esac
 264 AC_SUBST(FORMAT_FILE)
 265
 266 # ELF defines.
 267 elfsize=
 268 case "$libbacktrace_cv_sys_filetype" in
 269 elf32) elfsize=32 ;;
 270 elf64) elfsize=64 ;;
 271 *)     elfsize=unused
 272 esac
 273 AC_DEFINE_UNQUOTED([BACKTRACE_ELF_SIZE], [$elfsize], [ELF size: 32 or 64])
 274 AM_CONDITIONAL(HAVE_ELF, test "$FORMAT_FILE" = "elf.lo")
 275
 276 # XCOFF defines.
 277 xcoffsize=
 278 case "$libbacktrace_cv_sys_filetype" in
 279 xcoff32) xcoffsize=32 ;;
 280 xcoff64) xcoffsize=64 ;;
 281 *)       xcoffsize=unused
 282 esac
 283 AC_DEFINE_UNQUOTED([BACKTRACE_XCOFF_SIZE], [$xcoffsize], [XCOFF size: 32 or 64])
 284
 285 BACKTRACE_SUPPORTED=0
 286 if test "$backtrace_supported" = "yes"; then
 287   BACKTRACE_SUPPORTED=1
 288 fi
 289 AC_SUBST(BACKTRACE_SUPPORTED)
 290
 291 BACKTRACE_SUPPORTS_DATA=0
 292 if test "$backtrace_supports_data" = "yes"; then
 293   BACKTRACE_SUPPORTS_DATA=1
 294 fi
 295 AC_SUBST(BACKTRACE_SUPPORTS_DATA)
 296
 297 GCC_HEADER_STDINT(gstdint.h)
 298
 299 AC_CHECK_HEADERS(sys/mman.h)
 300 if test "$ac_cv_header_sys_mman_h" = "no"; then
 301   have_mmap=no
 302 else
 303   if test -n "${with_target_subdir}"; then
 304     # When built as a GCC target library, we can't do a link test.  We
 305     # simply assume that if we have mman.h, we have mmap.
 306     have_mmap=yes
 307     case "${host}" in
 308     *-*-msdosdjgpp)
 309         # DJGPP has sys/man.h, but no mmap
 310         have_mmap=no ;;
 311     esac
 312   else
 313     AC_CHECK_FUNC(mmap, [have_mmap=yes], [have_mmap=no])
 314   fi
 315 fi
 316 if test "$have_mmap" = "no"; then
 317   VIEW_FILE=read.lo
 318   ALLOC_FILE=alloc.lo
 319 else
 320   VIEW_FILE=mmapio.lo
 321   AC_PREPROC_IFELSE([AC_LANG_SOURCE([
 322 #include <sys/mman.h>
 323 #if !defined(MAP_ANONYMOUS) && !defined(MAP_ANON)
 324   #error no MAP_ANONYMOUS
 325 #endif
 326 ])], [ALLOC_FILE=mmap.lo], [ALLOC_FILE=alloc.lo])
 327 fi
 328 AC_SUBST(VIEW_FILE)
 329 AC_SUBST(ALLOC_FILE)
 330
 331 BACKTRACE_USES_MALLOC=0
 332 if test "$ALLOC_FILE" = "alloc.lo"; then
 333   BACKTRACE_USES_MALLOC=1
 334 fi
 335 AC_SUBST(BACKTRACE_USES_MALLOC)
 336
 337 # Check for dl_iterate_phdr.
 338 AC_CHECK_HEADERS(link.h sys/link.h)
 339 if test "$ac_cv_header_link_h" = "no" -a "$ac_cv_header_sys_link_h" = "no"; then
 340   have_dl_iterate_phdr=no
 341 else
 342   if test -n "${with_target_subdir}"; then
 343     link_h=link.h
 344     if test "$ac_cv_header_link_h" = "no"; then
 345        link_h=sys/link.h
 346     fi
 347     # When built as a GCC target library, we can't do a link test.
 348     AC_EGREP_HEADER([dl_iterate_phdr], [$link_h], [have_dl_iterate_phdr=yes],
 349                     [have_dl_iterate_phdr=no])
 350   else
 351     AC_CHECK_FUNC([dl_iterate_phdr], [have_dl_iterate_phdr=yes],
 352                   [have_dl_iterate_phdr=no])
 353   fi
 354 fi
 355 if test "$have_dl_iterate_phdr" = "yes"; then
 356   AC_DEFINE(HAVE_DL_ITERATE_PHDR, 1, [Define if dl_iterate_phdr is available.])
 357 fi
 358
 359 # Check for header file for Mach-O image functions.
 360 AC_CHECK_HEADERS(mach-o/dyld.h)
 361
 362 # Check for loadquery.
 363 AC_CHECK_HEADERS(sys/ldr.h)
 364 if test "$ac_cv_header_sys_ldr_h" = "no"; then
 365   have_loadquery=no
 366 else
 367   if test -n "${with_target_subdir}"; then
 368     # When built as a GCC target library, we can't do a link test.
 369     AC_EGREP_HEADER([loadquery], [sys/ldr.h], [have_loadquery=yes],
 370                     [have_loadquery=no])
 371   else
 372     AC_CHECK_FUNC([loadquery], [have_loadquery=yes],
 373                   [have_loadquery=no])
 374   fi
 375 fi
 376 if test "$have_loadquery" = "yes"; then
 377   AC_DEFINE(HAVE_LOADQUERY, 1, [Define if AIX loadquery is available.])
 378 fi
 379
 380 # Check for the fcntl function.
 381 if test -n "${with_target_subdir}"; then
 382    case "${host}" in
 383    *-*-mingw*) have_fcntl=no ;;
 384    *) have_fcntl=yes ;;
 385    esac
 386 else
 387   AC_CHECK_FUNC(fcntl, [have_fcntl=yes], [have_fcntl=no])
 388 fi
 389 if test "$have_fcntl" = "yes"; then
 390   AC_DEFINE([HAVE_FCNTL], 1,
 391             [Define to 1 if you have the fcntl function])
 392 fi
 393
 394 AC_CHECK_DECLS([strnlen, getpagesize])
 395 AC_CHECK_FUNCS(lstat readlink)
 396
 397 # Check for getexecname function.
 398 if test -n "${with_target_subdir}"; then
 399    case "${host}" in
 400    *-*-solaris2*) have_getexecname=yes ;;
 401    *) have_getexecname=no ;;
 402    esac
 403 else
 404   AC_CHECK_FUNC(getexecname, [have_getexecname=yes], [have_getexecname=no])
 405 fi
 406 if test "$have_getexecname" = "yes"; then
 407   AC_DEFINE(HAVE_GETEXECNAME, 1, [Define if getexecname is available.])
 408 fi
 409
 410 # Check for _pgmptr variable, contains the executable filename on windows
 411 AC_CHECK_DECLS([_pgmptr])
 412
 413 # Check for sysctl definitions.
 414
 415 AC_CACHE_CHECK([for KERN_PROC],
 416 [libbacktrace_cv_proc],
 417 [AC_COMPILE_IFELSE(
 418   [AC_LANG_PROGRAM([
 419 #include <sys/types.h>
 420 #include <sys/sysctl.h>
 421 ], [int mib0 = CTL_KERN; int mib1 = KERN_PROC; int mib2 = KERN_PROC_PATHNAME;])],
 422   [libbacktrace_cv_proc=yes],
 423   [libbacktrace_cv_proc=no])])
 424 if test "$libbacktrace_cv_proc" = "yes"; then
 425   AC_DEFINE([HAVE_KERN_PROC], 1,
 426             [Define to 1 if you have KERN_PROC and KERN_PROC_PATHNAME in <sys/sysctl.h>.])
 427 fi
 428
 429 AC_CACHE_CHECK([for KERN_PROG_ARGS],
 430 [libbacktrace_cv_procargs],
 431 [AC_COMPILE_IFELSE(
 432   [AC_LANG_PROGRAM([
 433 #include <sys/types.h>
 434 #include <sys/sysctl.h>
 435 ], [int mib0 = CTL_KERN; int mib1 = KERN_PROC_ARGS; int mib2 = KERN_PROC_PATHNAME;])],
 436   [libbacktrace_cv_procargs=yes],
 437   [libbacktrace_cv_procargs=no])])
 438 if test "$libbacktrace_cv_procargs" = "yes"; then
 439   AC_DEFINE([HAVE_KERN_PROC_ARGS], 1,
 440             [Define to 1 if you have KERN_PROCARGS and KERN_PROC_PATHNAME in <sys/sysctl.h>.])
 441 fi
 442
 443 # Check for the clock_gettime function.
 444 AC_CHECK_FUNCS(clock_gettime)
 445 clock_gettime_link=
 446 # At least for glibc, clock_gettime is in librt.  But don't
 447 # pull that in if it still doesn't give us the function we want.  This
 448 # test is copied from libgomp, and modified to not link in -lrt as
 449 # we're using this for test timing only.
 450 if test "$ac_cv_func_clock_gettime" = no; then
 451   AC_CHECK_LIB(rt, clock_gettime,
 452     [CLOCK_GETTIME_LINK=-lrt
 453      AC_DEFINE(HAVE_CLOCK_GETTIME, 1,
 454                [Define to 1 if you have the `clock_gettime' function.])])
 455 fi
 456 AC_SUBST(CLOCK_GETTIME_LINK)
 457
 458 dnl Test whether the compiler supports the -pthread option.
 459 AC_CACHE_CHECK([whether -pthread is supported],
 460 [libgo_cv_lib_pthread],
 461 [CFLAGS_hold=$CFLAGS
 462 CFLAGS="$CFLAGS -pthread"
 463 AC_COMPILE_IFELSE([AC_LANG_SOURCE([int i;])],
 464 [libgo_cv_lib_pthread=yes],
 465 [libgo_cv_lib_pthread=no])
 466 CFLAGS=$CFLAGS_hold])
 467 PTHREAD_CFLAGS=
 468 if test "$libgo_cv_lib_pthread" = yes; then
 469   PTHREAD_CFLAGS=-pthread
 470 fi
 471 AC_SUBST(PTHREAD_CFLAGS)
 472
 473 AM_CONDITIONAL(HAVE_PTHREAD, test "$libgo_cv_lib_pthread" = yes)
 474
 475 dnl Test whether the compiler and the linker support the -gdwarf-5 option.
 476 AC_CACHE_CHECK([whether -gdwarf-5 is supported],
 477 [libbacktrace_cv_lib_dwarf5],
 478 [CFLAGS_hold=$CFLAGS
 479 CFLAGS="$CFLAGS -gdwarf-5"
 480 AC_LINK_IFELSE([AC_LANG_PROGRAM([int i;], [return 0;])],
 481 [libbacktrace_cv_lib_dwarf5=yes],
 482 [libbacktrace_cv_lib_dwarf5=no])
 483 CFLAGS=$CFLAGS_hold])
 484 AM_CONDITIONAL(HAVE_DWARF5, test "$libbacktrace_cv_lib_dwarf5" = yes)
 485
 486 AC_CHECK_LIB([z], [compress],
 487     [AC_DEFINE(HAVE_ZLIB, 1, [Define if -lz is available.])])
 488 AM_CONDITIONAL(HAVE_ZLIB, test "$ac_cv_lib_z_compress" = yes)
 489
 490 dnl Test whether the linker supports the --build-id option.
 491 AC_CACHE_CHECK([whether --build-id is supported],
 492 [libbacktrace_cv_ld_buildid],
 493 [LDFLAGS_hold=$LDFLAGS
 494 LDFLAGS="$LDFLAGS -Wl,--build-id"
 495 AC_LINK_IFELSE([AC_LANG_PROGRAM(,)],
 496 [libbacktrace_cv_ld_buildid=yes],
 497 [libbacktrace_cv_ld_buildid=no])
 498 LDFLAGS=$LDFLAGS_hold])
 499 AM_CONDITIONAL(HAVE_BUILDID, test "$libbacktrace_cv_ld_buildid" = yes)
 500
 501 dnl Test whether the linker supports the --compress-debug-sections option.
 502 AC_CACHE_CHECK([whether --compress-debug-sections is supported],
 503 [libgo_cv_ld_compress],
 504 [LDFLAGS_hold=$LDFLAGS
 505 LDFLAGS="$LDFLAGS -Wl,--compress-debug-sections=zlib-gnu"
 506 AC_LINK_IFELSE([AC_LANG_PROGRAM(,)],
 507 [libgo_cv_ld_compress=yes],
 508 [libgo_cv_ld_compress=no])
 509 LDFLAGS=$LDFLAGS_hold])
 510 AM_CONDITIONAL(HAVE_COMPRESSED_DEBUG, test "$libgo_cv_ld_compress" = yes)
 511
 512 AC_CHECK_LIB([zstd], [ZSTD_compress],
 513     [AC_DEFINE(HAVE_ZSTD, 1, [Define if -lzstd is available.])])
 514 AM_CONDITIONAL(HAVE_ZSTD, test "$ac_cv_lib_zstd_ZSTD_compress" = yes)
 515
 516 dnl Test whether the linker supports --compress-debug-sections=zstd option.
 517 AC_CACHE_CHECK([whether --compress-debug-sections=zstd is supported],
 518 [libgo_cv_ld_compress_zstd],
 519 [LDFLAGS_hold=$LDFLAGS
 520 LDFLAGS="$LDFLAGS -Wl,--compress-debug-sections=zstd"
 521 AC_LINK_IFELSE([AC_LANG_PROGRAM(,)],
 522 [libgo_cv_ld_compress_zstd=yes],
 523 [libgo_cv_ld_compress_zstd=no])
 524 LDFLAGS=$LDFLAGS_hold])
 525 AM_CONDITIONAL(HAVE_COMPRESSED_DEBUG_ZSTD, test "$libgo_cv_ld_compress_zstd" = yes)
 526
 527 AC_ARG_VAR(OBJCOPY, [location of objcopy])
 528 AC_CHECK_PROG(OBJCOPY, objcopy, objcopy,)
 529 AC_CHECK_PROG(READELF, readelf, readelf)
 530 AC_CACHE_CHECK([whether objcopy supports debuglink],
 531 [libbacktrace_cv_objcopy_debuglink],
 532 [if test -n "${with_target_subdir}"; then
 533   libbacktrace_cv_objcopy_debuglink=no
 534 elif ! test -n "${OBJCOPY}"; then
 535   libbacktrace_cv_objcopy_debuglink=no
 536 elif ${OBJCOPY} --help | grep add-gnu-debuglink >/dev/null 2>&1; then
 537   libbacktrace_cv_objcopy_debuglink=yes
 538 else
 539   libbacktrace_cv_objcopy_debuglink=no
 540 fi])
 541 AM_CONDITIONAL(HAVE_OBJCOPY_DEBUGLINK, test "$libbacktrace_cv_objcopy_debuglink" = yes)
 542
 543 AC_ARG_VAR(DSYMUTIL, [location of dsymutil])
 544 AC_CHECK_PROG(DSYMUTIL, dsymutil, dsymutil)
 545 AM_CONDITIONAL(USE_DSYMUTIL, test -n "${DSYMUTIL}" -a "$FORMAT_FILE" = "macho.lo")
 546
 547 AC_ARG_VAR(NM, [location of nm])
 548 AC_CHECK_PROG(NM, nm, nm)
 549
 550 AC_CHECK_PROG(XZ, xz, xz)
 551 AM_CONDITIONAL(HAVE_XZ, test "$XZ" != "")
 552 AC_CHECK_PROG(COMM, comm, comm)
 553 AM_CONDITIONAL(HAVE_COMM, test "$COMM" != "")
 554
 555 AM_CONDITIONAL(HAVE_MINIDEBUG,
 556   test "${with_target_subdir}" = "" -a "$FORMAT_FILE" = "elf.lo" -a "${OBJCOPY}" != "" -a "${NM}" != "" -a "${XZ}" != "" -a "${COMM}" != "")
 557
 558 AC_CHECK_LIB([lzma], [lzma_auto_decoder],
 559     [AC_DEFINE(HAVE_LIBLZMA, 1, [Define if -llzma is available.])])
 560 AM_CONDITIONAL(HAVE_LIBLZMA, test "$ac_cv_lib_lzma_lzma_auto_decoder" = yes)
 561
 562 AC_CACHE_CHECK([whether tests can run],
 563   [libbacktrace_cv_sys_native],
 564   [AC_RUN_IFELSE([AC_LANG_PROGRAM([], [return 0;])],
 565      [libbacktrace_cv_sys_native=yes],
 566      [libbacktrace_cv_sys_native=no],
 567      [libbacktrace_cv_sys_native=no])])
 568 AM_CONDITIONAL(NATIVE, test "$libbacktrace_cv_sys_native" = "yes")
 569
 570 if test "${multilib}" = "yes"; then
 571   multilib_arg="--enable-multilib"
 572 else
 573   multilib_arg=
 574 fi
 575
 576 AC_CONFIG_FILES(Makefile backtrace-supported.h)
 577 AC_CONFIG_FILES(install-debuginfo-for-buildid.sh, chmod +x install-debuginfo-for-buildid.sh)
 578
 579 # We need multilib support, but only if configuring for the target.
 580 AC_CONFIG_COMMANDS([default],
 581 [if test -n "$CONFIG_FILES"; then
 582    if test -n "${with_target_subdir}"; then
 583      # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 584      # that multilib installs will end up installed in the correct place.
 585      # The testsuite needs it for multilib-aware ABI baseline files.
 586      # To work around this not being passed down from config-ml.in ->
 587      # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 588      # append it here.  Only modify Makefiles that have just been created.
 589      #
 590      # Also, get rid of this simulated-VPATH thing that automake does.
 591      cat > vpsed << \_EOF
 592   s!`test -f '$<' || echo '$(srcdir)/'`!!
 593 _EOF
 594      for i in $SUBDIRS; do
 595       case $CONFIG_FILES in
 596        *${i}/Makefile*)
 597          #echo "Adding MULTISUBDIR to $i/Makefile"
 598          sed -f vpsed $i/Makefile > tmp
 599          grep '^MULTISUBDIR =' Makefile >> tmp
 600          mv tmp $i/Makefile
 601          ;;
 602       esac
 603      done
 604      rm vpsed
 605    fi
 606  fi
 607 ],
 608 [
 609 # Variables needed in config.status (file generation) which aren't already
 610 # passed by autoconf.
 611 SUBDIRS="$SUBDIRS"
 612 ])
 613
 614 AC_OUTPUT