libgomp/configure.ac

   1 # Process this file with autoconf to produce a configure script, like so:
   2 # aclocal -I ../config && autoconf && autoheader && automake
   3
   4 AC_INIT([GNU Offloading and Multi Processing Runtime Library], 1.0,,[libgomp])
   5 AC_CONFIG_HEADER(config.h)
   6
   7 # -------
   8 # Options
   9 # -------
  10
  11 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  12 LIBGOMP_ENABLE(version-specific-runtime-libs, no, ,
  13    [Specify that runtime libraries should be installed in a compiler-specific directory],
  14    permit yes|no)
  15 AC_MSG_RESULT($enable_version_specific_runtime_libs)
  16
  17 # We would like our source tree to be readonly. However when releases or
  18 # pre-releases are generated, the flex/bison generated files as well as the
  19 # various formats of manuals need to be included along with the rest of the
  20 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
  21 # just that.
  22 AC_MSG_CHECKING([for --enable-generated-files-in-srcdir])
  23 LIBGOMP_ENABLE(generated-files-in-srcdir, no, ,
  24    [put copies of generated files in source dir intended for creating source
  25     tarballs for users without texinfo bison or flex.],
  26    permit yes|no)
  27 AC_MSG_RESULT($enable_generated_files_in_srcdir)
  28 AM_CONDITIONAL(GENINSRC, test "$enable_generated_files_in_srcdir" = yes)
  29
  30
  31 # -------
  32 # -------
  33
  34 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  35 #
  36 # You will slowly go insane if you do not grok the following fact:  when
  37 # building this library, the top-level /target/ becomes the library's /host/.
  38 #
  39 # configure then causes --target to default to --host, exactly like any
  40 # other package using autoconf.  Therefore, 'target' and 'host' will
  41 # always be the same.  This makes sense both for native and cross compilers
  42 # just think about it for a little while.  :-)
  43 #
  44 # Also, if this library is being configured as part of a cross compiler, the
  45 # top-level configure script will pass the "real" host as $with_cross_host.
  46 #
  47 # Do not delete or change the following two lines.  For why, see
  48 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  49 AC_CANONICAL_SYSTEM
  50 target_alias=${target_alias-$host_alias}
  51
  52 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  53 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  54 #  1.9.0:  minimum required version
  55 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  56 #              of other PACKAGE_* variables will, however, and there's nothing
  57 #              we can do about that; they come from AC_INIT).
  58 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  59 #            file in the top srcdir, etc, etc), so stop complaining.
  60 #  no-dist:  we don't want 'dist' and related rules.
  61 #  -Wall:  turns on all automake warnings...
  62 #  -Wno-portability:  ...except this one, since GNU make is required.
  63 #  -Wno-override: ... and this one, since we do want this in testsuite.
  64 AM_INIT_AUTOMAKE([1.9.0 foreign no-dist -Wall -Wno-portability -Wno-override])
  65 AM_ENABLE_MULTILIB(, ..)
  66
  67 GCC_WITH_TOOLEXECLIBDIR
  68
  69 # Calculate toolexeclibdir
  70 # Also toolexecdir, though it's only used in toolexeclibdir
  71 case ${enable_version_specific_runtime_libs} in
  72   yes)
  73     # Need the gcc compiler version to know where to install libraries
  74     # and header files if --enable-version-specific-runtime-libs option
  75     # is selected.
  76     toolexecdir='$(libdir)/gcc/$(target_alias)'
  77     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
  78     ;;
  79   no)
  80     if test -n "$with_cross_host" &&
  81        test x"$with_cross_host" != x"no"; then
  82       # Install a library built with a cross compiler in tooldir, not libdir.
  83       toolexecdir='$(exec_prefix)/$(target_alias)'
  84       case ${with_toolexeclibdir} in
  85         no)
  86           toolexeclibdir='$(toolexecdir)/lib'
  87           ;;
  88         *)
  89           toolexeclibdir=${with_toolexeclibdir}
  90           ;;
  91       esac
  92     else
  93       toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
  94       toolexeclibdir='$(libdir)'
  95     fi
  96     multi_os_directory=`$CC -print-multi-os-directory`
  97     case $multi_os_directory in
  98       .) ;; # Avoid trailing /.
  99       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 100     esac
 101     ;;
 102 esac
 103 AC_SUBST(toolexecdir)
 104 AC_SUBST(toolexeclibdir)
 105
 106 # Check the compiler.
 107 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
 108 # We must force CC to /not/ be precious variables; otherwise
 109 # the wrong, non-multilib-adjusted value will be used in multilibs.
 110 # As a side effect, we have to subst CFLAGS ourselves.
 111
 112 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
 113 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 114 AC_PROG_CC
 115 m4_rename_force([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 116
 117 AC_SUBST(CFLAGS)
 118
 119 # In order to override CFLAGS_FOR_TARGET, all of our special flags go
 120 # in XCFLAGS.  But we need them in CFLAGS during configury.  So put them
 121 # in both places for now and restore CFLAGS at the end of config.
 122 save_CFLAGS="$CFLAGS"
 123
 124 AC_ARG_ENABLE([werror],
 125   [AS_HELP_STRING([--disable-werror], [disable building with -Werror])])
 126 # Add -Wall -Werror if we are using GCC.
 127 AS_IF([test "x$GCC" = "xyes"],
 128   [XCFLAGS="$XCFLAGS -Wall"])
 129 AS_IF([test "x$enable_werror" != "xno" && test "x$GCC" = "xyes"],
 130   [XCFLAGS="$XCFLAGS -Werror"])
 131
 132 # Find other programs we need.
 133 AC_CHECK_TOOL(AR, ar)
 134 AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
 135 AC_PROG_MAKE_SET
 136 AC_PROG_INSTALL
 137
 138 # See if makeinfo has been installed and is modern enough
 139 # that we can use it.
 140 ACX_CHECK_PROG_VER([MAKEINFO], [makeinfo], [--version],
 141                    [GNU texinfo.* \([0-9][0-9.]*\)],
 142                    [4.[4-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
 143 AM_CONDITIONAL(BUILD_INFO, test $gcc_cv_prog_makeinfo_modern = "yes")
 144
 145
 146 # Configure libtool
 147 AM_PROG_LIBTOOL
 148 ACX_LT_HOST_FLAGS
 149 AC_SUBST(enable_shared)
 150 AC_SUBST(enable_static)
 151
 152 AM_MAINTAINER_MODE
 153
 154 # Create a spec file, so that compile/link tests don't fail
 155 test -f libgfortran.spec || touch libgfortran.spec
 156 FCFLAGS="$FCFLAGS -L."
 157
 158 # We need gfortran to compile parts of the library
 159 # We can't use AC_PROG_FC because it expects a fully working gfortran.
 160 #AC_PROG_FC(gfortran)
 161 case `echo $GFORTRAN` in
 162   -* | no* )
 163     FC=no ;;
 164   *)
 165     set dummy $GFORTRAN; ac_word=$2
 166     if test -x "$ac_word"; then
 167       FC="$GFORTRAN"
 168     else
 169       FC=no
 170     fi ;;
 171 esac
 172 AC_PROG_FC(gfortran)
 173 FCFLAGS="$FCFLAGS -Wall -L../libgfortran"
 174
 175 # For libtool versioning info, format is CURRENT:REVISION:AGE
 176 libtool_VERSION=1:0:0
 177 AC_SUBST(libtool_VERSION)
 178
 179 # Check header files.
 180 AC_STDC_HEADERS
 181 AC_HEADER_TIME
 182 ACX_HEADER_STRING
 183 AC_CHECK_HEADERS(pthread.h unistd.h semaphore.h sys/loadavg.h sys/sysctl.h sys/time.h)
 184
 185 XPCFLAGS=""
 186 case "$host" in
 187   *-*-rtems*)
 188     # RTEMS supports Pthreads, but the library is not available at GCC build time.
 189     ;;
 190   nvptx*-*-* | amdgcn*-*-*)
 191     # NVPTX does not support Pthreads, has its own code replacement.
 192     libgomp_use_pthreads=no
 193     # NVPTX is an accelerator-only target
 194     libgomp_offloaded_only=yes
 195     ;;
 196   *)
 197     # Check to see if -pthread or -lpthread is needed.  Prefer the former.
 198     # In case the pthread.h system header is not found, this test will fail.
 199     CFLAGS="$CFLAGS -pthread"
 200     AC_LINK_IFELSE(
 201      [AC_LANG_PROGRAM(
 202       [#include <pthread.h>
 203        void *g(void *d) { return NULL; }],
 204       [pthread_t t; pthread_create(&t,NULL,g,NULL);])],
 205      [XPCFLAGS=" -Wc,-pthread"],
 206      [CFLAGS="$save_CFLAGS" LIBS="-lpthread $LIBS"
 207       AC_LINK_IFELSE(
 208        [AC_LANG_PROGRAM(
 209         [#include <pthread.h>
 210          void *g(void *d) { return NULL; }],
 211         [pthread_t t; pthread_create(&t,NULL,g,NULL);])],
 212        [],
 213        [AC_MSG_ERROR([Pthreads are required to build libgomp])])])
 214 esac
 215
 216 if test x$libgomp_use_pthreads != xno; then
 217   AC_DEFINE(LIBGOMP_USE_PTHREADS, 1,
 218             [Define to 1 if libgomp should use POSIX threads.])
 219 fi
 220
 221 if test x$libgomp_offloaded_only = xyes; then
 222   AC_DEFINE(LIBGOMP_OFFLOADED_ONLY, 1,
 223             [Define to 1 if building libgomp for an accelerator-only target.])
 224 fi
 225
 226 if test "x$enable_offload_defaulted" = xyes; then
 227   AC_DEFINE(OFFLOAD_DEFAULTED, 1,
 228     [Define to 1 to if -foffload is defaulted])
 229 fi
 230
 231 AC_CHECK_SIZEOF([void *])
 232
 233 m4_include([plugin/configfrag.ac])
 234
 235 # Check for functions needed.
 236 AC_CHECK_FUNCS(getloadavg clock_gettime strtoull)
 237 AC_CHECK_FUNCS(aligned_alloc posix_memalign memalign _aligned_malloc)
 238
 239 # Check for broken semaphore implementation on darwin.
 240 # sem_init returns: sem_init error: Function not implemented.
 241 case "$host" in
 242   *-darwin*)
 243     AC_DEFINE(HAVE_BROKEN_POSIX_SEMAPHORES, 1,
 244         Define if the POSIX Semaphores do not work on your system.)
 245     ;;
 246 esac
 247
 248 # RTEMS specific checks
 249 case "$host" in
 250   *-*-rtems*)
 251     AC_CHECK_TYPES([struct _Mutex_Control],[],[],[#include <sys/lock.h>])
 252     ;;
 253 esac
 254
 255 GCC_LINUX_FUTEX(:)
 256
 257 # Check for pthread_{,attr_}[sg]etaffinity_np.
 258 AC_LINK_IFELSE(
 259  [AC_LANG_PROGRAM(
 260   [#define _GNU_SOURCE
 261    #include <pthread.h>],
 262   [cpu_set_t cpuset;
 263    pthread_attr_t attr;
 264    pthread_getaffinity_np (pthread_self (), sizeof (cpu_set_t), &cpuset);
 265    if (CPU_ISSET (0, &cpuset))
 266      CPU_SET (1, &cpuset);
 267    else
 268      CPU_ZERO (&cpuset);
 269    pthread_setaffinity_np (pthread_self (), sizeof (cpu_set_t), &cpuset);
 270    pthread_attr_init (&attr);
 271    pthread_attr_getaffinity_np (&attr, sizeof (cpu_set_t), &cpuset);
 272    pthread_attr_setaffinity_np (&attr, sizeof (cpu_set_t), &cpuset);])],
 273   AC_DEFINE(HAVE_PTHREAD_AFFINITY_NP, 1,
 274 [       Define if pthread_{,attr_}{g,s}etaffinity_np is supported.]))
 275
 276 # At least for glibc, clock_gettime is in librt.  But don't pull that
 277 # in if it still doesn't give us the function we want.
 278 if test $ac_cv_func_clock_gettime = no; then
 279   AC_CHECK_LIB(rt, clock_gettime,
 280     [LIBS="-lrt $LIBS"
 281      AC_DEFINE(HAVE_CLOCK_GETTIME, 1,
 282                [Define to 1 if you have the `clock_gettime' function.])])
 283 fi
 284
 285 # Check for uname.
 286 AC_COMPILE_IFELSE(
 287  [AC_LANG_PROGRAM(
 288   [#include <string.h>
 289    #include <stdlib.h>
 290    #include <sys/utsname.h>],
 291   [struct utsname buf;
 292    volatile size_t len = 0;
 293    if (!uname (buf))
 294      len = strlen (buf.nodename);])],
 295   AC_DEFINE(HAVE_UNAME, 1,
 296 [       Define if uname is supported and struct utsname has nodename field.]))
 297
 298 # Check for gethostname.
 299 AC_COMPILE_IFELSE(
 300  [AC_LANG_PROGRAM(
 301   [#include <unistd.h>],
 302   [
 303 changequote(,)dnl
 304    char buf[256];
 305    if (gethostname (buf, sizeof (buf) - 1) == 0)
 306      buf[255] = '\0';
 307 changequote([,])dnl
 308   ])],
 309   AC_DEFINE(HAVE_GETHOSTNAME, 1,
 310 [       Define if gethostname is supported.]))
 311
 312 # Check for getpid.
 313 AC_COMPILE_IFELSE(
 314  [AC_LANG_PROGRAM(
 315   [#include <unistd.h>],
 316   [int pid = getpid ();])],
 317   AC_DEFINE(HAVE_GETPID, 1,
 318 [       Define if getpid is supported.]))
 319
 320 # See if we support thread-local storage.
 321 GCC_CHECK_TLS
 322
 323 # See if we have emulated thread-local storage.
 324 GCC_CHECK_EMUTLS
 325
 326 # See what sort of export controls are available.
 327 LIBGOMP_CHECK_ATTRIBUTE_VISIBILITY
 328 LIBGOMP_CHECK_ATTRIBUTE_DLLEXPORT
 329 LIBGOMP_CHECK_ATTRIBUTE_ALIAS
 330 LIBGOMP_ENABLE_SYMVERS
 331
 332 if test $enable_symvers = gnu; then
 333   AC_DEFINE(LIBGOMP_GNU_SYMBOL_VERSIONING, 1,
 334             [Define to 1 if GNU symbol versioning is used for libgomp.])
 335 fi
 336
 337 # Determine cpu count to limit testsuite parallelism.
 338 AX_COUNT_CPUS
 339 AC_SUBST(CPU_COUNT)
 340
 341 AC_MSG_NOTICE([checking for flock implementation])
 342 AC_CHECK_PROGS(FLOCK, flock)
 343 # Fallback if 'perl' is available.
 344 if test -z "$FLOCK"; then
 345   AC_CHECK_PROG(FLOCK, perl, $srcdir/testsuite/flock)
 346 fi
 347
 348 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
 349
 350 # Get target configury.
 351 . ${srcdir}/configure.tgt
 352 CFLAGS="$save_CFLAGS $XCFLAGS"
 353
 354 # Check for __sync_val_compare_and_swap, but only after the target has
 355 # had a chance to set XCFLAGS.
 356 LIBGOMP_CHECK_SYNC_BUILTINS
 357
 358 XCFLAGS="$XCFLAGS$XPCFLAGS"
 359
 360 # Add CET specific flags if CET is enabled
 361 GCC_CET_FLAGS(CET_FLAGS)
 362 XCFLAGS="$XCFLAGS $CET_FLAGS"
 363 FCFLAGS="$FCFLAGS $CET_FLAGS"
 364
 365 AC_SUBST(config_path)
 366 AC_SUBST(XCFLAGS)
 367 AC_SUBST(XLDFLAGS)
 368
 369 # Conditionalize the makefile for this target machine.
 370 tmake_file_=
 371 for f in ${tmake_file}
 372 do
 373         if test -f ${srcdir}/config/$f
 374         then
 375                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
 376         fi
 377 done
 378 tmake_file="${tmake_file_}"
 379 AC_SUBST(tmake_file)
 380
 381 # Cleanup and exit.
 382 CFLAGS="$save_CFLAGS"
 383 AC_CACHE_SAVE
 384
 385 if test ${multilib} = yes; then
 386   multilib_arg="--enable-multilib"
 387 else
 388   multilib_arg=
 389 fi
 390
 391 # Set up the set of libraries that we need to link against for libgomp.
 392 # Note that the GOMP_SELF_SPEC in gcc.c may force -pthread,
 393 # which will force linkage against -lpthread (or equivalent for the system).
 394 # That's not 100% ideal, but about the best we can do easily.
 395 if test $enable_shared = yes; then
 396   link_gomp="-lgomp %{static: $LIBS${DL_LIBS:+ $DL_LIBS}}"
 397 else
 398   link_gomp="-lgomp $LIBS${DL_LIBS:+ $DL_LIBS}"
 399 fi
 400 AC_SUBST(link_gomp)
 401
 402 AM_CONDITIONAL([USE_FORTRAN], [test "$ac_cv_fc_compiler_gnu" = yes])
 403
 404 # ??? 2006-01-24: Paulo committed to asking autoconf folk to document
 405 # and export AC_COMPUTE_INT.  If that happens, then we'll need to remove
 406 # the underscore here and update the PREREQ.  If it doesn't, then we'll
 407 # need to copy this macro to our acinclude.m4.
 408 save_CFLAGS="$CFLAGS"
 409 for i in $config_path; do
 410   if test -f $srcdir/config/$i/omp-lock.h; then
 411     CFLAGS="$CFLAGS -include confdefs.h -include $srcdir/config/$i/omp-lock.h"
 412     break
 413   fi
 414 done
 415
 416 _AC_COMPUTE_INT([sizeof (__INTPTR_TYPE__)], [INTPTR_T_KIND])
 417 _AC_COMPUTE_INT([sizeof (__int128)], [OMP_INT128_SIZE],,[OMP_INT128_SIZE=0])
 418 _AC_COMPUTE_INT([2*sizeof (__INTPTR_TYPE__)], [OMP_DEPEND_KIND],,
 419                 [OMP_DEPEND_KIND=0])
 420 _AC_COMPUTE_INT([sizeof (omp_lock_t)], [OMP_LOCK_SIZE],,
 421   [AC_MSG_ERROR([unsupported system, cannot find sizeof (omp_lock_t)])])
 422 _AC_COMPUTE_INT([__alignof (omp_lock_t)], [OMP_LOCK_ALIGN])
 423 _AC_COMPUTE_INT([sizeof (omp_nest_lock_t)], [OMP_NEST_LOCK_SIZE])
 424 _AC_COMPUTE_INT([__alignof (omp_nest_lock_t)], [OMP_NEST_LOCK_ALIGN])
 425 _AC_COMPUTE_INT([sizeof (omp_lock_25_t)], [OMP_LOCK_25_SIZE],,
 426   [AC_MSG_ERROR([unsupported system, cannot find sizeof (omp_lock_25_t)])])
 427 _AC_COMPUTE_INT([__alignof (omp_lock_25_t)], [OMP_LOCK_25_ALIGN])
 428 _AC_COMPUTE_INT([sizeof (omp_nest_lock_25_t)], [OMP_NEST_LOCK_25_SIZE])
 429 _AC_COMPUTE_INT([__alignof (omp_nest_lock_25_t)], [OMP_NEST_LOCK_25_ALIGN])
 430
 431 # If the lock fits in an integer, then arrange for Fortran to use that
 432 # integer.  If it doesn't, then arrange for Fortran to use a pointer.
 433 # Except that we don't have a way at present to multi-lib the installed
 434 # Fortran modules, so we assume 8 bytes for pointers, regardless of the
 435 # actual target.
 436 OMP_LOCK_KIND=$OMP_LOCK_SIZE
 437 OMP_NEST_LOCK_KIND=$OMP_NEST_LOCK_SIZE
 438 if test $OMP_LOCK_SIZE -gt 8 || test $OMP_LOCK_ALIGN -gt $OMP_LOCK_SIZE; then
 439   OMP_LOCK_KIND=8
 440 fi
 441 if test $OMP_NEST_LOCK_SIZE -gt 8 || test $OMP_NEST_LOCK_ALIGN -gt $OMP_NEST_LOCK_SIZE; then
 442   OMP_NEST_LOCK_KIND=8
 443 fi
 444 OMP_LOCK_25_KIND=$OMP_LOCK_25_SIZE
 445 OMP_NEST_LOCK_25_KIND=$OMP_NEST_LOCK_25_SIZE
 446 if test $OMP_LOCK_25_SIZE -gt 8 || test $OMP_LOCK_25_ALIGN -gt $OMP_LOCK_25_SIZE; then
 447   OMP_LOCK_25_KIND=8
 448 fi
 449 if test $OMP_NEST_LOCK_25_SIZE -gt 8 || test $OMP_NEST_LOCK_25_ALIGN -gt $OMP_NEST_LOCK_25_SIZE; then
 450   OMP_NEST_LOCK_25_KIND=8
 451 fi
 452 if test "$ac_cv_fc_compiler_gnu" = yes; then
 453   if test $OMP_DEPEND_KIND -eq 16; then
 454     if test $OMP_INT128_SIZE -ne 16; then
 455       AC_MSG_ERROR([unsupported system, cannot find Fortran int kind=16, needed for omp_depend_kind])
 456     fi
 457   else
 458     if test $OMP_DEPEND_KIND -ne 8; then
 459       AC_MSG_ERROR([unsupported system, cannot find Fortran integer kind for omp_depend_kind])
 460     fi
 461   fi
 462 fi
 463
 464 AC_SUBST(INTPTR_T_KIND)
 465 AC_SUBST(OMP_LOCK_SIZE)
 466 AC_SUBST(OMP_LOCK_ALIGN)
 467 AC_SUBST(OMP_NEST_LOCK_SIZE)
 468 AC_SUBST(OMP_NEST_LOCK_ALIGN)
 469 AC_SUBST(OMP_LOCK_KIND)
 470 AC_SUBST(OMP_NEST_LOCK_KIND)
 471 AC_SUBST(OMP_LOCK_25_SIZE)
 472 AC_SUBST(OMP_LOCK_25_ALIGN)
 473 AC_SUBST(OMP_NEST_LOCK_25_SIZE)
 474 AC_SUBST(OMP_NEST_LOCK_25_ALIGN)
 475 AC_SUBST(OMP_LOCK_25_KIND)
 476 AC_SUBST(OMP_NEST_LOCK_25_KIND)
 477 AC_SUBST(OMP_DEPEND_KIND)
 478 CFLAGS="$save_CFLAGS"
 479
 480 # Determine what GCC version number to use in filesystem paths.
 481 GCC_BASE_VER
 482
 483 AC_CONFIG_FILES(omp.h omp_lib.h omp_lib.f90 libgomp_f.h)
 484 AC_CONFIG_FILES(Makefile testsuite/Makefile libgomp.spec)
 485 AC_CONFIG_FILES([testsuite/libgomp-test-support.pt.exp:testsuite/libgomp-test-support.exp.in])
 486 AC_CONFIG_FILES([testsuite/libgomp-site-extra.exp])
 487 AC_OUTPUT