zlib/configure.in

   1 dnl Process this with autoconf to create configure
   2
   3 AC_INIT(zlib.h)
   4
   5 # This works around the fact that libtool configuration may change LD
   6 # for this particular configuration, but some shells, instead of
   7 # keeping the changes in LD private, export them just because LD is
   8 # exported.
   9 ORIGINAL_LD_FOR_MULTILIBS=$LD
  10
  11 dnl We may get other options which we dont document:
  12 dnl --with-target-subdir, --with-multisrctop, --with-multisubdir
  13
  14 if test "x[$]{with_target_subdir}" != x && \
  15    test "[$]{srcdir}" = "."; then
  16   if test "[$]{with_target_subdir}" != "."; then
  17     zlib_basedir="[$]{srcdir}/[$]{with_multisrctop}../"
  18   else
  19     zlib_basedir="[$]{srcdir}/[$]{with_multisrctop}"
  20   fi
  21 else
  22   zlib_basedir="[$]{srcdir}/"
  23 fi
  24 AC_SUBST(zlib_basedir)
  25 AC_CONFIG_AUX_DIR($zlib_basedir..)
  26 if :; then :; else
  27   # This overrides the previous occurrence for automake, but not for
  28   # autoconf, which is exactly what we want.
  29   AC_CONFIG_AUX_DIR(..)
  30 fi
  31
  32 AC_CANONICAL_SYSTEM
  33
  34 # This works around an automake problem.
  35 mkinstalldirs="`cd $ac_aux_dir && ${PWDCMD-pwd}`/mkinstalldirs"
  36 AC_SUBST(mkinstalldirs)
  37
  38 AM_INIT_AUTOMAKE(zlib, 1.1.4)
  39
  40 AM_MAINTAINER_MODE
  41
  42 dnl We use these options to decide which functions to include.
  43 AC_ARG_WITH(target-subdir,
  44 [  --with-target-subdir=SUBDIR
  45                           configuring in a subdirectory])
  46 AC_ARG_WITH(cross-host,
  47 [  --with-cross-host=HOST  configuring with a cross compiler])
  48
  49 dnl Default to --enable-multilib
  50 AC_ARG_ENABLE(multilib,
  51 [  --enable-multilib       build many library versions (default)],
  52 [case "${enableval}" in
  53   yes) multilib=yes ;;
  54   no)  multilib=no ;;
  55   *)   AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
  56  esac], [test -z "$with_target_subdir" && multilib=no || multilib=yes])dnl
  57
  58 AC_ARG_WITH(system-zlib,
  59 [  --with-system-zlib      use installed libz])
  60
  61 LIB_AC_PROG_CC
  62 # We need AC_EXEEXT to keep automake happy in cygnus mode.  However,
  63 # at least currently, we never actually build a program, so we never
  64 # need to use $(EXEEXT).  Moreover, the test for EXEEXT normally
  65 # fails, because we are probably configuring with a cross compiler
  66 # which cant create executables.  So we include AC_EXEEXT to keep
  67 # automake happy, but we dont execute it, since we dont care about
  68 # the result.
  69 if false; then
  70   # autoconf 2.50 runs AC_EXEEXT by default, and the macro expands
  71   # to nothing, so nothing would remain between `then' and `fi' if it
  72   # were not for the `:' below.
  73   :
  74   AC_EXEEXT
  75 fi
  76 AM_PROG_LIBTOOL
  77
  78 if test -z "$with_target_subdir" || test "$with_target_subdir" = "."; then
  79    COMPPATH=.
  80 else
  81    COMPPATH=..
  82 fi
  83 AC_SUBST(COMPPATH)
  84
  85 # Find CPP now so that any conditional tests below won't do it and
  86 # thereby make the resulting definitions conditional.
  87 AC_PROG_CPP
  88
  89 if test -n "$with_cross_host"; then
  90    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
  91    # may not work correctly, because the compiler may not be able to
  92    # link executables.
  93
  94    # We assume newlib.  This lets us hard-code the functions we know
  95    # we'll have.
  96    AC_DEFINE(HAVE_MEMCPY)
  97    AC_DEFINE(HAVE_STRERROR)
  98
  99    # We ignore --with-system-zlib in this case.
 100    target_all=libzgcj.la
 101 else
 102    AC_FUNC_MMAP
 103    AC_CHECK_FUNCS(memcpy strerror)
 104
 105    if test "$with_system_zlib" = yes; then
 106       AC_CHECK_LIB(z, deflate, target_all=, target_all=libzgcj.la)
 107    else
 108       target_all=libzgcj.la
 109    fi
 110 fi
 111
 112 AC_SUBST(target_all)
 113
 114 AC_CHECK_HEADERS(unistd.h)
 115
 116 if test -n "$with_cross_host" &&
 117    test x"$with_cross_host" != x"no"; then
 118   toolexecdir='$(exec_prefix)/$(target_alias)'
 119   toolexeclibdir='$(toolexecdir)/lib'
 120 else
 121   toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
 122   toolexeclibdir='$(libdir)'
 123 fi
 124 if test "$GCC" = yes && $CC -print-multi-os-directory > /dev/null 2>&1; then
 125   multiosdir=/`$CC -print-multi-os-directory`
 126   case $multiosdir in
 127     /.) multiosdir= ;; # Avoid trailing /.
 128   esac
 129 else
 130   multiosdir=
 131 fi
 132 toolexeclibdir=${toolexeclibdir}${multiosdir}
 133 AC_SUBST(toolexecdir)
 134 AC_SUBST(toolexeclibdir)
 135
 136 AM_CONDITIONAL(TARGET_LIBRARY, test -n "$with_target_subdir")
 137
 138 if test "${multilib}" = "yes"; then
 139   multilib_arg="--enable-multilib"
 140 else
 141   multilib_arg=
 142 fi
 143
 144 AC_OUTPUT(Makefile,
 145 [if test -n "$CONFIG_FILES"; then
 146   LD="${ORIGINAL_LD_FOR_MULTILIBS}"
 147   ac_file=Makefile . ${zlib_basedir}/../config-ml.in
 148 fi],
 149 srcdir=${srcdir}
 150 host=${host}
 151 target=${target}
 152 with_multisubdir=${with_multisubdir}
 153 ac_configure_args="${multilib_arg} ${ac_configure_args}"
 154 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 155 zlib_basedir=${zlib_basedir}
 156 CC="${CC}"
 157 CXX="${CXX}"
 158 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
 159 )