gcc/ada/ali.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                                  A L I                                   --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2014, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 --  This package defines the internal data structures used for representation
  27 --  of Ada Library Information (ALI) acquired from the ALI files generated by
  28 --  the front end.
  29
  30 with Casing;  use Casing;
  31 with Gnatvsn; use Gnatvsn;
  32 with Namet;   use Namet;
  33 with Rident;  use Rident;
  34 with Table;
  35 with Types;   use Types;
  36
  37 with GNAT.HTable; use GNAT.HTable;
  38
  39 package ALI is
  40
  41    --------------
  42    -- Id Types --
  43    --------------
  44
  45    --  The various entries are stored in tables with distinct subscript ranges.
  46    --  The following type definitions show the ranges used for the subscripts
  47    --  (Id values) for the various tables.
  48
  49    type ALI_Id is range 0 .. 999_999;
  50    --  Id values used for ALIs table entries
  51
  52    type Unit_Id is range 1_000_000 .. 1_999_999;
  53    --  Id values used for Unit table entries
  54
  55    type With_Id is range 2_000_000 .. 2_999_999;
  56    --  Id values used for Withs table entries
  57
  58    type Arg_Id is range 3_000_000 .. 3_999_999;
  59    --  Id values used for argument table entries
  60
  61    type Sdep_Id is range 4_000_000 .. 4_999_999;
  62    --  Id values used for Sdep table entries
  63
  64    type Source_Id is range 5_000_000 .. 5_999_999;
  65    --  Id values used for Source table entries
  66
  67    type Interrupt_State_Id is range 6_000_000 .. 6_999_999;
  68    --  Id values used for Interrupt_State table entries
  69
  70    type Priority_Specific_Dispatching_Id is range 7_000_000 .. 7_999_999;
  71    --  Id values used for Priority_Specific_Dispatching table entries
  72
  73    --------------------
  74    -- ALI File Table --
  75    --------------------
  76
  77    --  Each ALI file read generates an entry in the ALIs table
  78
  79    No_ALI_Id : constant ALI_Id := ALI_Id'First;
  80    --  Special value indicating no ALI entry
  81
  82    First_ALI_Entry : constant ALI_Id := No_ALI_Id + 1;
  83    --  Id of first actual entry in table
  84
  85    type Main_Program_Type is (None, Proc, Func);
  86    --  Indicator of whether unit can be used as main program
  87
  88    type ALIs_Record is record
  89
  90       Afile : File_Name_Type;
  91       --  Name of ALI file
  92
  93       Ofile_Full_Name : File_Name_Type;
  94       --  Full name of object file corresponding to the ALI file
  95
  96       Sfile : File_Name_Type;
  97       --  Name of source file that generates this ALI file (which is equal
  98       --  to the name of the source file in the first unit table entry for
  99       --  this ALI file, since the body if present is always first).
 100
 101       Ver : String (1 .. Ver_Len_Max);
 102       --  Value of library version (V line in ALI file). Not set if
 103       --  V lines are ignored as a result of the Ignore_Lines parameter.
 104
 105       Ver_Len : Natural;
 106       --  Length of characters stored in Ver. Not set if V lines are ignored as
 107       --  a result of the Ignore_Lines parameter.
 108
 109       SAL_Interface : Boolean;
 110       --  Set True when this is an interface to a standalone library
 111
 112       First_Unit : Unit_Id;
 113       --  Id of first Unit table entry for this file
 114
 115       Last_Unit : Unit_Id;
 116       --  Id of last Unit table entry for this file
 117
 118       First_Sdep : Sdep_Id;
 119       --  Id of first Sdep table entry for this file
 120
 121       Last_Sdep : Sdep_Id;
 122       --  Id of last Sdep table entry for this file
 123
 124       Main_Program : Main_Program_Type;
 125       --  Indicator of whether first unit can be used as main program. Not set
 126       --  if 'M' appears in Ignore_Lines.
 127
 128       Main_Priority : Int;
 129       --  Indicates priority value if Main_Program field indicates that this
 130       --  can be a main program. A value of -1 (No_Main_Priority) indicates
 131       --  that no parameter was found, or no M line was present. Not set if
 132       --  'M' appears in Ignore_Lines.
 133
 134       Main_CPU : Int;
 135       --  Indicates processor if Main_Program field indicates that this can
 136       --  be a main program. A value of -1 (No_Main_CPU) indicates that no C
 137       --  parameter was found, or no M line was present. Not set if 'M' appears
 138       --  in Ignore_Lines.
 139
 140       Time_Slice_Value : Int;
 141       --  Indicates value of time slice parameter from T=xxx on main program
 142       --  line. A value of -1 indicates that no T=xxx parameter was found, or
 143       --  no M line was present. Not set if 'M' appears in Ignore_Lines.
 144
 145       WC_Encoding : Character;
 146       --  Wide character encoding if main procedure. Otherwise not relevant.
 147       --  Not set if 'M' appears in Ignore_Lines.
 148
 149       Locking_Policy : Character;
 150       --  Indicates locking policy for units in this file. Space means tasking
 151       --  was not used, or that no Locking_Policy pragma was present or that
 152       --  this is a language defined unit. Otherwise set to first character
 153       --  (upper case) of policy name. Not set if 'P' appears in Ignore_Lines.
 154
 155       Partition_Elaboration_Policy : Character;
 156       --  Indicates partition elaboration policy for units in this file. Space
 157       --  means that no Partition_Elaboration_Policy pragma was present or that
 158       --  this is a language defined unit. Otherwise set to first character
 159       --  (upper case) of policy name. Not set if 'P' appears in Ignore_Lines.
 160
 161       Queuing_Policy : Character;
 162       --  Indicates queuing policy for units in this file. Space means tasking
 163       --  was not used, or that no Queuing_Policy pragma was present or that
 164       --  this is a language defined unit. Otherwise set to first character
 165       --  (upper case) of policy name. Not set if 'P' appears in Ignore_Lines.
 166
 167       Task_Dispatching_Policy : Character;
 168       --  Indicates task dispatching policy for units in this file. Space means
 169       --  tasking was not used, or that no Task_Dispatching_Policy pragma was
 170       --  present or that this is a language defined unit. Otherwise set to
 171       --  first character (upper case) of policy name. Not set if 'P' appears
 172       --  in Ignore_Lines.
 173
 174       Compile_Errors : Boolean;
 175       --  Set to True if compile errors for unit. Note that No_Object will
 176       --  always be set as well in this case. Not set if 'P' appears in
 177       --  Ignore_Lines.
 178
 179       No_Object : Boolean;
 180       --  Set to True if no object file generated. Not set if 'P' appears in
 181       --  Ignore_Lines.
 182
 183       Normalize_Scalars : Boolean;
 184       --  Set to True if file was compiled with Normalize_Scalars. Not set if
 185       --  'P' appears in Ignore_Lines.
 186
 187       SSO_Default : Character;
 188       --  Set to 'H' or 'L' if file was compiled with a configuration pragma
 189       --  file containing Default_Scalar_Storage_Order (High/Low_Order_First).
 190       --  Set to ' ' if neither pragma was present. Not set if 'P' appears in
 191       --  Ignore_Lines.
 192
 193       Unit_Exception_Table : Boolean;
 194       --  Set to True if unit exception table pointer generated. Not set if 'P'
 195       --  appears in Ignore_Lines.
 196
 197       Zero_Cost_Exceptions : Boolean;
 198       --  Set to True if file was compiled with zero cost exceptions. Not set
 199       --  if 'P' appears in Ignore_Lines.
 200
 201       Restrictions : Restrictions_Info;
 202       --  Restrictions information reconstructed from R lines
 203
 204       First_Interrupt_State : Interrupt_State_Id;
 205       Last_Interrupt_State  : Interrupt_State_Id'Base;
 206       --  These point to the first and last entries in the interrupt state
 207       --  table for this unit. If no entries, then Last_Interrupt_State =
 208       --  First_Interrupt_State - 1 (that's why the 'Base reference is there,
 209       --  it can be one less than the lower bound of the subtype). Not set if
 210       --  'I' appears in Ignore_Lines
 211
 212       First_Specific_Dispatching : Priority_Specific_Dispatching_Id;
 213       Last_Specific_Dispatching  : Priority_Specific_Dispatching_Id'Base;
 214       --  These point to the first and last entries in the priority specific
 215       --  dispatching table for this unit. If there are no entries, then
 216       --  Last_Specific_Dispatching = First_Specific_Dispatching - 1. That
 217       --  is why the 'Base reference is there, it can be one less than the
 218       --  lower bound of the subtype. Not set if 'S' appears in Ignore_Lines.
 219
 220    end record;
 221
 222    No_Main_Priority : constant Int := -1;
 223    --  Code for no main priority set
 224
 225    No_Main_CPU : constant Int := -1;
 226    --  Code for no main cpu set
 227
 228    package ALIs is new Table.Table (
 229      Table_Component_Type => ALIs_Record,
 230      Table_Index_Type     => ALI_Id,
 231      Table_Low_Bound      => First_ALI_Entry,
 232      Table_Initial        => 500,
 233      Table_Increment      => 200,
 234      Table_Name           => "ALIs");
 235
 236    ----------------
 237    -- Unit Table --
 238    ----------------
 239
 240    --  Each unit within an ALI file generates an entry in the unit table
 241
 242    No_Unit_Id : constant Unit_Id := Unit_Id'First;
 243    --  Special value indicating no unit table entry
 244
 245    First_Unit_Entry : constant Unit_Id := No_Unit_Id + 1;
 246    --  Id of first actual entry in table
 247
 248    type Unit_Type is (Is_Spec, Is_Body, Is_Spec_Only, Is_Body_Only);
 249    --  Indicates type of entry, if both body and spec appear in the ALI file,
 250    --  then the first unit is marked Is_Body, and the second is marked Is_Spec.
 251    --  If only a spec appears, then it is marked as Is_Spec_Only, and if only
 252    --  a body appears, then it is marked Is_Body_Only).
 253
 254    subtype Version_String is String (1 .. 8);
 255    --  Version string, taken from unit record
 256
 257    type Unit_Record is record
 258
 259       My_ALI : ALI_Id;
 260       --  Corresponding ALI entry
 261
 262       Uname : Unit_Name_Type;
 263       --  Name of Unit
 264
 265       Sfile : File_Name_Type;
 266       --  Name of source file
 267
 268       Preelab : Boolean;
 269       --  Indicates presence of PR parameter for a preelaborated package
 270
 271       No_Elab : Boolean;
 272       --  Indicates presence of NE parameter for a unit that has does not
 273       --  have an elaboration routine (since it has no elaboration code).
 274
 275       Pure : Boolean;
 276       --  Indicates presence of PU parameter for a package having pragma Pure
 277
 278       Dynamic_Elab : Boolean;
 279       --  Set to True if the unit was compiled with dynamic elaboration checks
 280       --  (i.e. either -gnatE or pragma Elaboration_Checks (RM) was used to
 281       --  compile the unit).
 282
 283       Elaborate_Body : Boolean;
 284       --  Indicates presence of EB parameter for a package which has a pragma
 285       --  Elaborate_Body, and also for generic package instantiations.
 286
 287       Set_Elab_Entity : Boolean;
 288       --  Indicates presence of EE parameter for a unit which has an
 289       --  elaboration entity which must be set true as part of the
 290       --  elaboration of the unit.
 291
 292       Has_RACW : Boolean;
 293       --  Indicates presence of RA parameter for a package that declares at
 294       --  least one Remote Access to Class_Wide (RACW) object.
 295
 296       Remote_Types : Boolean;
 297       --  Indicates presence of RT parameter for a package which has a
 298       --  pragma Remote_Types.
 299
 300       Shared_Passive : Boolean;
 301       --  Indicates presence of SP parameter for a package which has a pragma
 302       --  Shared_Passive.
 303
 304       RCI : Boolean;
 305       --  Indicates presence of RC parameter for a package which has a pragma
 306       --  Remote_Call_Interface.
 307
 308       Predefined : Boolean;
 309       --  Indicates if unit is language predefined (or a child of such a unit)
 310
 311       Internal : Boolean;
 312       --  Indicates if unit is an internal unit (or a child of such a unit)
 313
 314       First_With : With_Id;
 315       --  Id of first withs table entry for this file
 316
 317       Last_With : With_Id;
 318       --  Id of last withs table entry for this file
 319
 320       First_Arg : Arg_Id;
 321       --  Id of first args table entry for this file
 322
 323       Last_Arg : Arg_Id;
 324       --  Id of last args table entry for this file
 325
 326       Utype : Unit_Type;
 327       --  Type of entry
 328
 329       Is_Generic : Boolean;
 330       --  True for generic unit (i.e. a generic declaration, or a generic
 331       --  body). False for a non-generic unit.
 332
 333       Unit_Kind : Character;
 334       --  Indicates the nature of the unit. 'p' for Packages and 's' for
 335       --  subprograms.
 336
 337       Version : Version_String;
 338       --  Version of unit
 339
 340       Icasing : Casing_Type;
 341       --  Indicates casing of identifiers in source file for this unit. This
 342       --  is used for informational output, and also for constructing the main
 343       --  unit if it is being built in Ada.
 344
 345       Kcasing : Casing_Type;
 346       --  Indicates casing of keywords in source file for this unit. This is
 347       --  used for informational output, and also for constructing the main
 348       --  unit if it is being built in Ada.
 349
 350       Elab_Position : aliased Natural;
 351       --  Initialized to zero. Set non-zero when a unit is chosen and
 352       --  placed in the elaboration order. The value represents the
 353       --  ordinal position in the elaboration order.
 354
 355       Init_Scalars : Boolean;
 356       --  Set True if IS qualifier appears in ALI file, indicating that
 357       --  an Initialize_Scalars pragma applies to the unit.
 358
 359       SAL_Interface : Boolean;
 360       --  Set True when this is an interface to a standalone library
 361
 362       Directly_Scanned : Boolean;
 363       --  True iff it is a unit from an ALI file specified to gnatbind
 364
 365       Body_Needed_For_SAL : Boolean;
 366       --  Indicates that the source for the body of the unit (subprogram,
 367       --  package, or generic unit) must be included in a standalone library.
 368
 369       Elaborate_Body_Desirable : Boolean;
 370       --  Indicates that the front end elaboration circuitry decided that it
 371       --  would be a good idea if this package had Elaborate_Body. The binder
 372       --  will attempt, but does not promise, to place the elaboration call
 373       --  for the body right after the call for the spec, or at least as close
 374       --  together as possible.
 375
 376       Optimize_Alignment : Character;
 377       --  Optimize_Alignment setting. Set to L/S/T/O for OL/OS/OT/OO present
 378
 379       Has_Finalizer : Boolean;
 380       --  Indicates whether a package body or a spec has a library-level
 381       --  finalization routine.
 382    end record;
 383
 384    package Units is new Table.Table (
 385      Table_Component_Type => Unit_Record,
 386      Table_Index_Type     => Unit_Id,
 387      Table_Low_Bound      => First_Unit_Entry,
 388      Table_Initial        => 100,
 389      Table_Increment      => 200,
 390      Table_Name           => "Unit");
 391
 392    ---------------------------
 393    -- Interrupt State Table --
 394    ---------------------------
 395
 396    --  An entry is made in this table for each I (interrupt state) line
 397    --  encountered in the input ALI file. The First/Last_Interrupt_Id
 398    --  fields of the ALI file entry show the range of entries defined
 399    --  within a particular ALI file.
 400
 401    type Interrupt_State_Record is record
 402       Interrupt_Id : Nat;
 403       --  Id from interrupt state entry
 404
 405       Interrupt_State : Character;
 406       --  State from interrupt state entry ('u'/'r'/'s')
 407
 408       IS_Pragma_Line : Nat;
 409       --  Line number of Interrupt_State pragma
 410    end record;
 411
 412    package Interrupt_States is new Table.Table (
 413      Table_Component_Type => Interrupt_State_Record,
 414      Table_Index_Type     => Interrupt_State_Id'Base,
 415      Table_Low_Bound      => Interrupt_State_Id'First,
 416      Table_Initial        => 100,
 417      Table_Increment      => 200,
 418      Table_Name           => "Interrupt_States");
 419
 420    -----------------------------------------
 421    -- Priority Specific Dispatching Table --
 422    -----------------------------------------
 423
 424    --  An entry is made in this table for each S (priority specific
 425    --  dispatching) line encountered in the input ALI file. The
 426    --  First/Last_Specific_Dispatching_Id fields of the ALI file
 427    --  entry show the range of entries defined within a particular
 428    --  ALI file.
 429
 430    type Specific_Dispatching_Record is record
 431       Dispatching_Policy : Character;
 432       --  First character (upper case) of the corresponding policy name
 433
 434       First_Priority     : Nat;
 435       --  Lower bound of the priority range to which the specified dispatching
 436       --  policy applies.
 437
 438       Last_Priority      : Nat;
 439       --  Upper bound of the priority range to which the specified dispatching
 440       --  policy applies.
 441
 442       PSD_Pragma_Line : Nat;
 443       --  Line number of Priority_Specific_Dispatching pragma
 444    end record;
 445
 446    package Specific_Dispatching is new Table.Table (
 447      Table_Component_Type => Specific_Dispatching_Record,
 448      Table_Index_Type     => Priority_Specific_Dispatching_Id'Base,
 449      Table_Low_Bound      => Priority_Specific_Dispatching_Id'First,
 450      Table_Initial        => 100,
 451      Table_Increment      => 200,
 452      Table_Name           => "Priority_Specific_Dispatching");
 453
 454    --------------
 455    -- Switches --
 456    --------------
 457
 458    --  These switches record status information about ali files that
 459    --  have been read, for quick reference without searching tables.
 460
 461    --  Note: a switch will be left set at its default value if the line
 462    --  which might otherwise set it is ignored (from Ignore_Lines).
 463
 464    Dynamic_Elaboration_Checks_Specified : Boolean := False;
 465    --  Set to False by Initialize_ALI. Set to True if Scan_ALI reads
 466    --  a unit for which dynamic elaboration checking is enabled.
 467
 468    Initialize_Scalars_Used : Boolean := False;
 469    --  Set True if an ali file contains the Initialize_Scalars flag
 470
 471    Locking_Policy_Specified : Character := ' ';
 472    --  Set to blank by Initialize_ALI. Set to the appropriate locking policy
 473    --  character if an ali file contains a P line setting the locking policy.
 474
 475    No_Normalize_Scalars_Specified : Boolean := False;
 476    --  Set to False by Initialize_ALI. Set to True if an ali file indicates
 477    --  that the file was compiled without normalize scalars.
 478
 479    No_Object_Specified : Boolean := False;
 480    --  Set to False by Initialize_ALI. Set to True if an ali file contains
 481    --  the No_Object flag.
 482
 483    Normalize_Scalars_Specified : Boolean := False;
 484    --  Set to False by Initialize_ALI. Set to True if an ali file indicates
 485    --  that the file was compiled in Normalize_Scalars mode.
 486
 487    Partition_Elaboration_Policy_Specified : Character := ' ';
 488    --  Set to blank by Initialize_ALI. Set to the appropriate partition
 489    --  elaboration policy character if an ali file contains a P line setting
 490    --  the policy.
 491
 492    Queuing_Policy_Specified : Character := ' ';
 493    --  Set to blank by Initialize_ALI. Set to the appropriate queuing policy
 494    --  character if an ali file contains a P line setting the queuing policy.
 495
 496    Cumulative_Restrictions : Restrictions_Info := No_Restrictions;
 497    --  This variable records the cumulative contributions of R lines in all
 498    --  ali files, showing whether a restriction pragma exists anywhere, and
 499    --  accumulating the aggregate knowledge of violations.
 500
 501    SSO_Default_Specified : Boolean := False;
 502    --  Set to True if at least one ALI file contains an OH/OL flag indicating
 503    --  that it was compiled with a configuration pragmas file containing the
 504    --  pragma Default_Scalar_Storage_Order (OH/OL present in ALI file P line).
 505
 506    Stack_Check_Switch_Set : Boolean := False;
 507    --  Set to True if at least one ALI file contains '-fstack-check' in its
 508    --  argument list.
 509
 510    Static_Elaboration_Model_Used : Boolean := False;
 511    --  Set to False by Initialize_ALI. Set to True if any ALI file for a
 512    --  non-internal unit compiled with the static elaboration model is
 513    --  encountered.
 514
 515    Task_Dispatching_Policy_Specified : Character := ' ';
 516    --  Set to blank by Initialize_ALI. Set to the appropriate task dispatching
 517    --  policy character if an ali file contains a P line setting the
 518    --  task dispatching policy.
 519
 520    Unreserve_All_Interrupts_Specified : Boolean := False;
 521    --  Set to False by Initialize_ALI. Set to True if an ali file is read that
 522    --  has  P line specifying unreserve all interrupts mode.
 523
 524    Zero_Cost_Exceptions_Specified : Boolean := False;
 525    --  Set to False by Initialize_ALI. Set to True if an ali file is read that
 526    --  has a P line specifying the generation of zero cost exceptions.
 527
 528    -----------------
 529    -- Withs Table --
 530    -----------------
 531
 532    --  Each With line (W line) in an ALI file generates a Withs table entry
 533
 534    --  Note: there will be no entries in this table if 'W' lines are ignored
 535
 536    No_With_Id : constant With_Id := With_Id'First;
 537    --  Special value indicating no withs table entry
 538
 539    First_With_Entry : constant With_Id := No_With_Id + 1;
 540    --  Id of first actual entry in table
 541
 542    type With_Record is record
 543
 544       Uname : Unit_Name_Type;
 545       --  Name of Unit
 546
 547       Sfile : File_Name_Type;
 548       --  Name of source file, set to No_File in generic case
 549
 550       Afile : File_Name_Type;
 551       --  Name of ALI file, set to No_File in generic case
 552
 553       Elaborate : Boolean;
 554       --  Indicates presence of E parameter
 555
 556       Elaborate_All : Boolean;
 557       --  Indicates presence of EA parameter
 558
 559       Elab_All_Desirable : Boolean;
 560       --  Indicates presence of AD parameter
 561
 562       Elab_Desirable     : Boolean;
 563       --  Indicates presence of ED parameter
 564
 565       SAL_Interface : Boolean := False;
 566       --  True if the Unit is an Interface of a Stand-Alone Library
 567
 568       Limited_With : Boolean := False;
 569       --  True if unit is named in a limited_with_clause
 570
 571       Implicit_With_From_Instantiation : Boolean := False;
 572       --  True if this is an implicit with from a generic instantiation
 573    end record;
 574
 575    package Withs is new Table.Table (
 576      Table_Component_Type => With_Record,
 577      Table_Index_Type     => With_Id,
 578      Table_Low_Bound      => First_With_Entry,
 579      Table_Initial        => 5000,
 580      Table_Increment      => 200,
 581      Table_Name           => "Withs");
 582
 583    ---------------------
 584    -- Arguments Table --
 585    ---------------------
 586
 587    --  Each Arg line (A line) in an ALI file generates an Args table entry
 588
 589    --  Note: there will be no entries in this table if 'A' lines are ignored
 590
 591    No_Arg_Id : constant Arg_Id := Arg_Id'First;
 592    --  Special value indicating no args table entry
 593
 594    First_Arg_Entry : constant Arg_Id := No_Arg_Id + 1;
 595    --  Id of first actual entry in table
 596
 597    package Args is new Table.Table (
 598      Table_Component_Type => String_Ptr,
 599      Table_Index_Type     => Arg_Id,
 600      Table_Low_Bound      => First_Arg_Entry,
 601      Table_Initial        => 1000,
 602      Table_Increment      => 100,
 603      Table_Name           => "Args");
 604
 605    --------------------------
 606    -- Linker_Options Table --
 607    --------------------------
 608
 609    --  If an ALI file has one of more Linker_Options lines, then a single
 610    --  entry is made in this table. If more than one Linker_Options lines
 611    --  appears in a given ALI file, then the arguments are concatenated
 612    --  to form the entry in this table, using a NUL character as the
 613    --  separator, and a final NUL character is appended to the end.
 614
 615    --  Note: there will be no entries in this table if 'L' lines are ignored
 616
 617    type Linker_Option_Record is record
 618       Name : Name_Id;
 619       --  Name entry containing concatenated list of Linker_Options
 620       --  arguments separated by NUL and ended by NUL as described above.
 621
 622       Unit : Unit_Id;
 623       --  Unit_Id for the entry
 624
 625       Internal_File : Boolean;
 626       --  Set True if the linker options are from an internal file. This is
 627       --  used to insert certain standard entries after all the user entries
 628       --  but before the entries from the run-time.
 629
 630       Original_Pos : Positive;
 631       --  Keep track of original position in the linker options table. This
 632       --  is used to implement a stable sort when we sort the linker options
 633       --  table.
 634    end record;
 635
 636    --  The indexes of active entries in this table range from 1 to the
 637    --  value of Linker_Options.Last. The zero'th element is for sort call.
 638
 639    package Linker_Options is new Table.Table (
 640      Table_Component_Type => Linker_Option_Record,
 641      Table_Index_Type     => Integer,
 642      Table_Low_Bound      => 0,
 643      Table_Initial        => 200,
 644      Table_Increment      => 400,
 645      Table_Name           => "Linker_Options");
 646
 647    -----------------
 648    -- Notes Table --
 649    -----------------
 650
 651    --  The notes table records entries from N lines
 652
 653    type Notes_Record is record
 654       Pragma_Type : Character;
 655       --  'A', 'C', 'I', 'S', 'T' for Annotate/Comment/Ident/Subtitle/Title
 656
 657       Pragma_Line : Nat;
 658       --  Line number of pragma
 659
 660       Pragma_Col : Nat;
 661       --  Column number of pragma
 662
 663       Pragma_Source_File : File_Name_Type;
 664       --  Source file of pragma
 665
 666       Pragma_Args : Name_Id;
 667       --  Pragma arguments. No_Name if no arguments, otherwise a single
 668       --  name table entry consisting of all the characters on the notes
 669       --  line from the first non-blank character following the source
 670       --  location to the last character on the line.
 671    end record;
 672
 673    --  The indexes of active entries in this table range from 1 to the
 674    --  value of Linker_Options.Last. The zero'th element is for convenience
 675    --  if the table needs to be sorted.
 676
 677    package Notes is new Table.Table (
 678      Table_Component_Type => Notes_Record,
 679      Table_Index_Type     => Integer,
 680      Table_Low_Bound      => 0,
 681      Table_Initial        => 200,
 682      Table_Increment      => 400,
 683      Table_Name           => "Notes");
 684
 685    -------------------------------------------
 686    -- External Version Reference Hash Table --
 687    -------------------------------------------
 688
 689    --  This hash table keeps track of external version reference strings
 690    --  as read from E lines in the ali file. The stored values do not
 691    --  include the terminating quote characters.
 692
 693    --  Note: there will be no entries in this table if 'E' lines are ignored
 694
 695    type Vindex is range 0 .. 98;
 696    --  Type to define range of headers
 697
 698    function SHash (S : String_Ptr) return Vindex;
 699    --  Hash function for this table
 700
 701    function SEq (F1, F2 : String_Ptr) return Boolean;
 702    --  Equality function for this table
 703
 704    package Version_Ref is new Simple_HTable (
 705      Header_Num => Vindex,
 706      Element    => Boolean,
 707      No_Element => False,
 708      Key        => String_Ptr,
 709      Hash       => SHash,
 710      Equal      => SEq);
 711
 712    -------------------------
 713    -- No_Dependency Table --
 714    -------------------------
 715
 716    --  Each R line for a No_Dependency Restriction generates an entry in
 717    --  this No_Dependency table.
 718
 719    type No_Dep_Record is record
 720       ALI_File : ALI_Id;
 721       --  ALI File containing the entry
 722
 723       No_Dep_Unit : Name_Id;
 724       --  Id for names table entry including entire name, including periods
 725    end record;
 726
 727    package No_Deps is new Table.Table (
 728      Table_Component_Type => No_Dep_Record,
 729      Table_Index_Type     => Integer,
 730      Table_Low_Bound      => 0,
 731      Table_Initial        => 200,
 732      Table_Increment      => 400,
 733      Table_Name           => "No_Deps");
 734
 735    ------------------------------------
 736    -- Sdep (Source Dependency) Table --
 737    ------------------------------------
 738
 739    --  Each source dependency (D line) in an ALI file generates an entry in the
 740    --  Sdep table.
 741
 742    --  Note: there will be no entries in this table if 'D' lines are ignored
 743
 744    No_Sdep_Id : constant Sdep_Id := Sdep_Id'First;
 745    --  Special value indicating no Sdep table entry
 746
 747    First_Sdep_Entry : Sdep_Id := No_Sdep_Id + 1;
 748    --  Id of first Sdep entry for current ali file. This is initialized to the
 749    --  first Sdep entry in the table, and then incremented appropriately as
 750    --  successive ALI files are scanned.
 751
 752    type Sdep_Record is record
 753
 754       Sfile : File_Name_Type;
 755       --  Name of source file
 756
 757       Stamp : Time_Stamp_Type;
 758       --  Time stamp value. Note that this will be all zero characters for the
 759       --  dummy entries for missing or non-dependent files.
 760
 761       Checksum : Word;
 762       --  Checksum value. Note that this will be all zero characters for the
 763       --  dummy entries for missing or non-dependent files
 764
 765       Dummy_Entry : Boolean;
 766       --  Set True for dummy entries that correspond to missing files or files
 767       --  where no dependency relationship exists.
 768
 769       Subunit_Name : Name_Id;
 770       --  Name_Id for subunit name if present, else No_Name
 771
 772       Unit_Name : Name_Id;
 773       --  Name_Id for the unit name if not a subunit (No_Name for a subunit)
 774       Rfile : File_Name_Type;
 775       --  Reference file name. Same as Sfile unless a Source_Reference pragma
 776       --  was used, in which case it reflects the name used in the pragma.
 777
 778       Start_Line : Nat;
 779       --  Starting line number in file. Always 1, unless a Source_Reference
 780       --  pragma was used, in which case it reflects the line number value
 781       --  given in the pragma.
 782
 783    end record;
 784
 785    package Sdep is new Table.Table (
 786      Table_Component_Type => Sdep_Record,
 787      Table_Index_Type     => Sdep_Id,
 788      Table_Low_Bound      => First_Sdep_Entry,
 789      Table_Initial        => 5000,
 790      Table_Increment      => 200,
 791      Table_Name           => "Sdep");
 792
 793    ----------------------------
 794    -- Use of Name Table Info --
 795    ----------------------------
 796
 797    --  All unit names and file names are entered into the Names table. The Info
 798    --  fields of these entries are used as follows:
 799
 800    --    Unit name           Info field has Unit_Id of unit table entry
 801    --    ALI file name       Info field has ALI_Id of ALI table entry
 802    --    Source file name    Info field has Source_Id of source table entry
 803
 804    --------------------------
 805    -- Cross-Reference Data --
 806    --------------------------
 807
 808    --  The following table records cross-reference sections, there is one entry
 809    --  for each X header line in the ALI file for an xref section.
 810
 811    --  Note: there will be no entries in this table if 'X' lines are ignored
 812
 813    type Xref_Section_Record is record
 814       File_Num : Sdep_Id;
 815       --  Dependency number for file (entry in Sdep.Table)
 816
 817       File_Name : File_Name_Type;
 818       --  Name of file
 819
 820       First_Entity : Nat;
 821       --  First entry in Xref_Entity table
 822
 823       Last_Entity : Nat;
 824       --  Last entry in Xref_Entity table
 825    end record;
 826
 827    package Xref_Section is new Table.Table (
 828      Table_Component_Type => Xref_Section_Record,
 829      Table_Index_Type     => Nat,
 830      Table_Low_Bound      => 1,
 831      Table_Initial        => 50,
 832      Table_Increment      => 300,
 833      Table_Name           => "Xref_Section");
 834
 835    --  The following is used to indicate whether a typeref field is present
 836    --  for the entity, and if so what kind of typeref field.
 837
 838    type Tref_Kind is (
 839      Tref_None,    --  No typeref present
 840      Tref_Access,  --  Access type typeref (points to designated type)
 841      Tref_Derived, --  Derived type typeref (points to parent type)
 842      Tref_Type);   --  All other cases
 843
 844    type Visibility_Kind is
 845      (Global, --  Library level entity
 846       Static, --  Static C/C++ entity
 847       Other); --  Local and other entity
 848
 849    --  The following table records entities for which xrefs are recorded
 850
 851    type Xref_Entity_Record is record
 852       Line : Pos;
 853       --  Line number of definition
 854
 855       Etype : Character;
 856       --  Set to the identification character for the entity. See section
 857       --  "Cross-Reference Entity Identifiers" in lib-xref.ads for details.
 858
 859       Col : Pos;
 860       --  Column number of definition
 861
 862       Visibility : Visibility_Kind;
 863       --  Visibility of entity
 864
 865       Entity : Name_Id;
 866       --  Name of entity
 867
 868       Iref_File_Num : Sdep_Id;
 869       --  This field is set to the dependency reference for the file containing
 870       --  the generic entity that this one instantiates, or to No_Sdep_Id if
 871       --  the current entity is not an instantiation
 872
 873       Iref_Line : Nat;
 874       --  This field is set to the line number in Iref_File_Num of the generic
 875       --  entity that this one instantiates, or to zero if the current entity
 876       --  is not an instantiation.
 877
 878       Rref_Line : Nat;
 879       --  This field is set to the line number of a renaming reference if
 880       --  one is present, or to zero if no renaming reference is present
 881
 882       Rref_Col : Nat;
 883       --  This field is set to the column number of a renaming reference
 884       --  if one is present, or to zero if no renaming reference is present.
 885
 886       Tref : Tref_Kind;
 887       --  Indicates if a typeref is present, and if so what kind. Set to
 888       --  Tref_None if no typeref field is present.
 889
 890       Tref_File_Num : Sdep_Id;
 891       --  This field is set to No_Sdep_Id if no typeref is present, or
 892       --  if the typeref refers to an entity in standard. Otherwise it
 893       --  it is the dependency reference for the file containing the
 894       --  declaration of the typeref entity.
 895
 896       Tref_Line : Nat;
 897       --  This field is set to zero if no typeref is present, or if the
 898       --  typeref refers to an entity in standard. Otherwise it contains
 899       --  the line number of the declaration of the typeref entity.
 900
 901       Tref_Type : Character;
 902       --  This field is set to blank if no typeref is present, or if the
 903       --  typeref refers to an entity in standard. Otherwise it contains
 904       --  the identification character for the typeref entity. See section
 905       --  "Cross-Reference Entity Identifiers" in lib-xref.ads for details.
 906
 907       Tref_Col : Nat;
 908       --  This field is set to zero if no typeref is present, or if the
 909       --  typeref refers to an entity in standard. Otherwise it contains
 910       --  the column number of the declaration of the parent type.
 911
 912       Tref_Standard_Entity : Name_Id;
 913       --  This field is set to No_Name if no typeref is present or if the
 914       --  typeref refers to a declared entity rather than an entity in
 915       --  package Standard. If there is a typeref that references an
 916       --  entity in package Standard, then this field is a Name_Id
 917       --  reference for the entity name.
 918
 919       Oref_File_Num : Sdep_Id;
 920       --  This field is set to No_Sdep_Id if the entity doesn't override any
 921       --  other entity, or to the dependency reference for the overridden
 922       --  entity.
 923
 924       Oref_Line : Nat;
 925       Oref_Col  : Nat;
 926       --  These two fields are set to the line and column of the overridden
 927       --  entity.
 928
 929       First_Xref : Nat;
 930       --  Index into Xref table of first cross-reference
 931
 932       Last_Xref : Nat;
 933       --  Index into Xref table of last cross-reference. The value in
 934       --  Last_Xref can be less than the First_Xref value to indicate
 935       --  that no entries are present in the Xref Table.
 936    end record;
 937
 938    package Xref_Entity is new Table.Table (
 939      Table_Component_Type => Xref_Entity_Record,
 940      Table_Index_Type     => Nat,
 941      Table_Low_Bound      => 1,
 942      Table_Initial        => 500,
 943      Table_Increment      => 300,
 944      Table_Name           => "Xref_Entity");
 945
 946    Array_Index_Reference : constant Character := '*';
 947    Interface_Reference   : constant Character := 'I';
 948    --  Some special types of references. In the ALI file itself, these
 949    --  are output as attributes of the entity, not as references, but
 950    --  there is no provision in Xref_Entity_Record for storing multiple
 951    --  such references.
 952
 953    --  The following table records actual cross-references
 954
 955    type Xref_Record is record
 956       File_Num : Sdep_Id;
 957       --  Set to the file dependency number for the cross-reference. Note
 958       --  that if no file entry is present explicitly, this is just a copy
 959       --  of the reference for the current cross-reference section.
 960
 961       Line : Nat;
 962       --  Line number for the reference. This is zero when referencing a
 963       --  predefined entity, but in this case Name is set.
 964
 965       Rtype : Character;
 966       --  Indicates type of reference, using code used in ALI file:
 967       --    r = reference
 968       --    m = modification
 969       --    b = body entity
 970       --    c = completion of private or incomplete type
 971       --    x = type extension
 972       --    i = implicit reference
 973       --    Array_Index_Reference = reference to the index of an array
 974       --    Interface_Reference   = reference to an interface implemented
 975       --                            by the type
 976       --  See description in lib-xref.ads for further details
 977
 978       Col : Nat;
 979       --  Column number for the reference
 980
 981       Name : Name_Id := No_Name;
 982       --  This is only used when referencing a predefined entity. Currently,
 983       --  this only occurs for array indexes.
 984
 985       --  Note: for instantiation references, Rtype is set to ' ', and Col is
 986       --  set to zero. One or more such entries can follow any other reference.
 987       --  When there is more than one such entry, this is to be read as:
 988       --     e.g. ref1  ref2  ref3
 989       --     ref1 is a reference to an entity that was instantied at ref2.
 990       --     ref2 itself is also the result of an instantiation, that took
 991       --     place at ref3
 992
 993       Imported_Lang : Name_Id := No_Name;
 994       Imported_Name : Name_Id := No_Name;
 995       --  Language and name of imported entity reference
 996    end record;
 997
 998    package Xref is new Table.Table (
 999      Table_Component_Type => Xref_Record,
1000      Table_Index_Type     => Nat,
1001      Table_Low_Bound      => 1,
1002      Table_Initial        => 2000,
1003      Table_Increment      => 300,
1004      Table_Name           => "Xref");
1005
1006    --------------------------------------
1007    -- Subprograms for Reading ALI File --
1008    --------------------------------------
1009
1010    procedure Initialize_ALI;
1011    --  Initialize the ALI tables. Also resets all switch values to defaults
1012
1013    function Scan_ALI
1014      (F                : File_Name_Type;
1015       T                : Text_Buffer_Ptr;
1016       Ignore_ED        : Boolean;
1017       Err              : Boolean;
1018       Read_Xref        : Boolean := False;
1019       Read_Lines       : String  := "";
1020       Ignore_Lines     : String  := "X";
1021       Ignore_Errors    : Boolean := False;
1022       Directly_Scanned : Boolean := False) return ALI_Id;
1023    --  Given the text, T, of an ALI file, F, scan and store the information
1024    --  from the file, and return the Id of the resulting entry in the ALI
1025    --  table. Switch settings may be modified as described above in the
1026    --  switch description settings.
1027    --
1028    --    Ignore_ED is normally False. If set to True, it indicates that
1029    --    all AD/ED (elaboration desirable) indications in the ALI file are
1030    --    to be ignored. This parameter is obsolete now that the -f switch
1031    --    is removed from gnatbind, and should be removed ???
1032    --
1033    --    Err determines the action taken on an incorrectly formatted file.
1034    --    If Err is False, then an error message is output, and the program
1035    --    is terminated. If Err is True, then no error message is output,
1036    --    and No_ALI_Id is returned.
1037    --
1038    --    Ignore_Lines requests that Scan_ALI ignore any lines that start
1039    --    with any given key character. The default value of X causes all
1040    --    Xref lines to be ignored. The corresponding data in the ALI
1041    --    tables will not be filled in this case. It is not possible
1042    --    to ignore U (unit) lines, they are always read.
1043    --
1044    --    Read_Lines requests that Scan_ALI process only lines that start
1045    --    with one of the given characters. The corresponding data in the
1046    --    ALI file for any characters not given in the list will not be
1047    --    set. The default value of the null string indicates that all
1048    --    lines should be read (unless Ignore_Lines is specified). U
1049    --    (unit) lines are always read regardless of the value of this
1050    --    parameter.
1051    --
1052    --    Note: either Ignore_Lines or Read_Lines should be non-null, but not
1053    --    both. If both are provided then only the Read_Lines value is used,
1054    --    and the Ignore_Lines parameter is ignored.
1055    --
1056    --    Read_XREF is set True to read and acquire the cross-reference
1057    --    information. If Read_XREF is set to True, then the effect is to ignore
1058    --    all lines other than U, W, D and X lines and the Ignore_Lines and
1059    --    Read_Lines parameters are ignored (i.e. the use of True for Read_XREF
1060    --    is equivalent to specifying an argument of "UWDX" for Read_Lines.
1061    --
1062    --    Ignore_Errors is normally False. If it is set True, then Scan_ALI
1063    --    will do its best to scan through a file and extract all information
1064    --    it can, even if there are errors. In this case Err is only set if
1065    --    Scan_ALI was completely unable to process the file (e.g. it did not
1066    --    look like an ALI file at all). Ignore_Errors is intended to improve
1067    --    the downward compatibility of new compilers with old tools.
1068    --
1069    --    Directly_Scanned is normally False. If it is set to True, then the
1070    --    units (spec and/or body) corresponding to the ALI file are marked as
1071    --    such. It is used to decide for what units gnatbind should generate
1072    --    the symbols corresponding to 'Version or 'Body_Version in
1073    --    Stand-Alone Libraries.
1074
1075 end ALI;