gcc/ada/5wmemory.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUN-TIME COMPONENTS                         --
   4 --                                                                          --
   5 --                         S Y S T E M . M E M O R Y                        --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2001-2002 Free Software Foundation, Inc.          --
  10 --                                                                          --
  11 -- This specification is derived from the Ada Reference Manual for use with --
  12 -- GNAT. The copyright notice above, and the license provisions that follow --
  13 -- apply solely to the  contents of the part following the private keyword. --
  14 --                                                                          --
  15 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  16 -- terms of the  GNU General Public License as published  by the Free Soft- --
  17 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  18 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  19 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  20 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  21 -- for  more details.  You should have  received  a copy of the GNU General --
  22 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  23 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  24 -- MA 02111-1307, USA.                                                      --
  25 --                                                                          --
  26 -- As a special exception,  if other files  instantiate  generics from this --
  27 -- unit, or you link  this unit with other files  to produce an executable, --
  28 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  29 -- covered  by the  GNU  General  Public  License.  This exception does not --
  30 -- however invalidate  any other reasons why  the executable file  might be --
  31 -- covered by the  GNU Public License.                                      --
  32 --                                                                          --
  33 -- GNAT was originally developed  by the GNAT team at  New York University. --
  34 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  35 --                                                                          --
  36 ------------------------------------------------------------------------------
  37
  38 --  This version provides ways to limit the amount of used memory for systems
  39 --  that do not have OS support for that.
  40
  41 --  The amount of available memory available for dynamic allocation is limited
  42 --  by setting the environment variable GNAT_MEMORY_LIMIT to the number of
  43 --  kilobytes that can be used.
  44 --
  45 --  Windows is currently using this version.
  46
  47 with Ada.Exceptions;
  48 with System.Soft_Links;
  49
  50 package body System.Memory is
  51
  52    use Ada.Exceptions;
  53    use System.Soft_Links;
  54
  55    function c_malloc (Size : size_t) return System.Address;
  56    pragma Import (C, c_malloc, "malloc");
  57
  58    procedure c_free (Ptr : System.Address);
  59    pragma Import (C, c_free, "free");
  60
  61    function c_realloc
  62      (Ptr : System.Address; Size : size_t) return System.Address;
  63    pragma Import (C, c_realloc, "realloc");
  64
  65    function msize (Ptr : System.Address) return size_t;
  66    pragma Import (C, msize, "_msize");
  67
  68    function getenv (Str : String) return System.Address;
  69    pragma Import (C, getenv);
  70
  71    function atoi (Str : System.Address) return Integer;
  72    pragma Import (C, atoi);
  73
  74    Available_Memory : size_t := 0;
  75    --  Amount of memory that is available for heap allocations.
  76    --  A value of 0 means that the amount is not yet initialized.
  77
  78    Msize_Accuracy   : constant := 4096;
  79    --  Defines the amount of memory to add to requested allocation sizes,
  80    --  because malloc may return a bigger block than requested. As msize
  81    --  is used when by Free, it must be used on allocation as well. To
  82    --  prevent underflow of available_memory we need to use a reserve.
  83
  84    procedure Check_Available_Memory (Size : size_t);
  85    --  This routine must be called while holding the task lock. When the
  86    --  memory limit is not yet initialized, it will be set to the value of
  87    --  the GNAT_MEMORY_LIMIT environment variable or to unlimited if that
  88    --  does not exist. If the size is larger than the amount of available
  89    --  memory, the task lock will be freed and a storage_error exception
  90    --  will be raised.
  91
  92    -----------
  93    -- Alloc --
  94    -----------
  95
  96    function Alloc (Size : size_t) return System.Address is
  97       Result      : System.Address;
  98       Actual_Size : size_t := Size;
  99
 100    begin
 101       if Size = size_t'Last then
 102          Raise_Exception (Storage_Error'Identity, "object too large");
 103       end if;
 104
 105       --  Change size from zero to non-zero. We still want a proper pointer
 106       --  for the zero case because pointers to zero length objects have to
 107       --  be distinct, but we can't just go ahead and allocate zero bytes,
 108       --  since some malloc's return zero for a zero argument.
 109
 110       if Size = 0 then
 111          Actual_Size := 1;
 112       end if;
 113
 114       Lock_Task.all;
 115
 116       if Actual_Size + Msize_Accuracy >= Available_Memory then
 117          Check_Available_Memory (Size + Msize_Accuracy);
 118       end if;
 119
 120       Result := c_malloc (Actual_Size);
 121
 122       if Result /= System.Null_Address then
 123          Available_Memory := Available_Memory - msize (Result);
 124       end if;
 125
 126       Unlock_Task.all;
 127
 128       if Result = System.Null_Address then
 129          Raise_Exception (Storage_Error'Identity, "heap exhausted");
 130       end if;
 131
 132       return Result;
 133    end Alloc;
 134
 135    ----------------------------
 136    -- Check_Available_Memory --
 137    ----------------------------
 138
 139    procedure Check_Available_Memory (Size : size_t) is
 140       Gnat_Memory_Limit : System.Address;
 141
 142    begin
 143       if Available_Memory = 0 then
 144
 145          --  The amount of available memory hasn't been initialized yet
 146
 147          Gnat_Memory_Limit := getenv ("GNAT_MEMORY_LIMIT" & ASCII.NUL);
 148
 149          if Gnat_Memory_Limit /= System.Null_Address then
 150             Available_Memory :=
 151               size_t (atoi (Gnat_Memory_Limit)) * 1024 + Msize_Accuracy;
 152          else
 153             Available_Memory := size_t'Last;
 154          end if;
 155       end if;
 156
 157       if Size >= Available_Memory then
 158
 159          --  There is a memory overflow
 160
 161          Unlock_Task.all;
 162          Raise_Exception
 163            (Storage_Error'Identity, "heap memory limit exceeded");
 164       end if;
 165    end Check_Available_Memory;
 166
 167    ----------
 168    -- Free --
 169    ----------
 170
 171    procedure Free (Ptr : System.Address) is
 172    begin
 173       Lock_Task.all;
 174
 175       if Ptr /= System.Null_Address then
 176          Available_Memory := Available_Memory + msize (Ptr);
 177       end if;
 178
 179       c_free (Ptr);
 180
 181       Unlock_Task.all;
 182    end Free;
 183
 184    -------------
 185    -- Realloc --
 186    -------------
 187
 188    function Realloc
 189      (Ptr  : System.Address;
 190       Size : size_t)
 191       return System.Address
 192    is
 193       Result      : System.Address;
 194       Actual_Size : constant size_t := Size;
 195       Old_Size    : size_t;
 196
 197    begin
 198       if Size = size_t'Last then
 199          Raise_Exception (Storage_Error'Identity, "object too large");
 200       end if;
 201
 202       Lock_Task.all;
 203
 204       Old_Size := msize (Ptr);
 205
 206       --  Conservative check - no need to try to be precise here
 207
 208       if Size + Msize_Accuracy >= Available_Memory then
 209          Check_Available_Memory (Size + Msize_Accuracy);
 210       end if;
 211
 212       Result := c_realloc (Ptr, Actual_Size);
 213
 214       if Result /= System.Null_Address then
 215          Available_Memory := Available_Memory + Old_Size - msize (Result);
 216       end if;
 217
 218       Unlock_Task.all;
 219
 220       if Result = System.Null_Address then
 221          Raise_Exception (Storage_Error'Identity, "heap exhausted");
 222       end if;
 223
 224       return Result;
 225    end Realloc;
 226
 227 end System.Memory;