gcc/ada/exp_ch13.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             E X P _ C H 1 3                              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2015, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 with Atree;    use Atree;
  27 with Checks;   use Checks;
  28 with Einfo;    use Einfo;
  29 with Exp_Ch3;  use Exp_Ch3;
  30 with Exp_Ch6;  use Exp_Ch6;
  31 with Exp_Imgv; use Exp_Imgv;
  32 with Exp_Tss;  use Exp_Tss;
  33 with Exp_Util; use Exp_Util;
  34 with Freeze;   use Freeze;
  35 with Namet;    use Namet;
  36 with Nlists;   use Nlists;
  37 with Nmake;    use Nmake;
  38 with Opt;      use Opt;
  39 with Restrict; use Restrict;
  40 with Rident;   use Rident;
  41 with Rtsfind;  use Rtsfind;
  42 with Sem;      use Sem;
  43 with Sem_Aux;  use Sem_Aux;
  44 with Sem_Ch7;  use Sem_Ch7;
  45 with Sem_Ch8;  use Sem_Ch8;
  46 with Sem_Eval; use Sem_Eval;
  47 with Sem_Util; use Sem_Util;
  48 with Sinfo;    use Sinfo;
  49 with Snames;   use Snames;
  50 with Targparm; use Targparm;
  51 with Tbuild;   use Tbuild;
  52 with Uintp;    use Uintp;
  53 with Validsw;  use Validsw;
  54
  55 package body Exp_Ch13 is
  56
  57    ------------------------------------------
  58    -- Expand_N_Attribute_Definition_Clause --
  59    ------------------------------------------
  60
  61    --  Expansion action depends on attribute involved
  62
  63    procedure Expand_N_Attribute_Definition_Clause (N : Node_Id) is
  64       Loc : constant Source_Ptr := Sloc (N);
  65       Exp : constant Node_Id    := Expression (N);
  66       Ent : Entity_Id;
  67       V   : Node_Id;
  68
  69    begin
  70       Ent := Entity (Name (N));
  71
  72       if Is_Type (Ent) then
  73          Ent := Underlying_Type (Ent);
  74       end if;
  75
  76       case Get_Attribute_Id (Chars (N)) is
  77
  78          -------------
  79          -- Address --
  80          -------------
  81
  82          when Attribute_Address =>
  83
  84             --  If there is an initialization which did not come from the
  85             --  source program, then it is an artifact of our expansion, and we
  86             --  suppress it. The case we are most concerned about here is the
  87             --  initialization of a packed array to all false, which seems
  88             --  inappropriate for variable to which an address clause is
  89             --  applied. The expression may itself have been rewritten if the
  90             --  type is packed array, so we need to examine whether the
  91             --  original node is in the source. An exception though is the case
  92             --  of an access variable which is default initialized to null, and
  93             --  such initialization is retained.
  94
  95             --  Furthermore, if the initialization is the equivalent aggregate
  96             --  of the type initialization procedure, it replaces an implicit
  97             --  call to the init proc, and must be respected. Note that for
  98             --  packed types we do not build equivalent aggregates.
  99
 100             --  Also, if Init_Or_Norm_Scalars applies, then we need to retain
 101             --  any default initialization for objects of scalar types and
 102             --  types with scalar components. Normally a composite type will
 103             --  have an init_proc in the presence of Init_Or_Norm_Scalars,
 104             --  so when that flag is set we have just have to do a test for
 105             --  scalar and string types (the predefined string types such as
 106             --  String and Wide_String don't have an init_proc).
 107
 108             declare
 109                Decl : constant Node_Id := Declaration_Node (Ent);
 110                Typ  : constant Entity_Id := Etype (Ent);
 111
 112             begin
 113                if Nkind (Decl) = N_Object_Declaration
 114                   and then Present (Expression (Decl))
 115                   and then Nkind (Expression (Decl)) /= N_Null
 116                   and then
 117                    not Comes_From_Source (Original_Node (Expression (Decl)))
 118                then
 119                   if Present (Base_Init_Proc (Typ))
 120                     and then
 121                       Present (Static_Initialization (Base_Init_Proc (Typ)))
 122                   then
 123                      null;
 124
 125                   elsif Init_Or_Norm_Scalars
 126                     and then
 127                       (Is_Scalar_Type (Typ) or else Is_String_Type (Typ))
 128                   then
 129                      null;
 130
 131                   else
 132                      Set_Expression (Decl, Empty);
 133                   end if;
 134
 135                --  An object declaration to which an address clause applies
 136                --  has a delayed freeze, but the address expression itself
 137                --  must be elaborated at the point it appears. If the object
 138                --  is controlled, additional checks apply elsewhere.
 139
 140                elsif Nkind (Decl) = N_Object_Declaration
 141                  and then not Needs_Constant_Address (Decl, Typ)
 142                then
 143                   Remove_Side_Effects (Exp);
 144                end if;
 145             end;
 146
 147          ---------------
 148          -- Alignment --
 149          ---------------
 150
 151          when Attribute_Alignment =>
 152
 153             --  As required by Gigi, we guarantee that the operand is an
 154             --  integer literal (this simplifies things in Gigi).
 155
 156             if Nkind (Exp) /= N_Integer_Literal then
 157                Rewrite
 158                  (Exp, Make_Integer_Literal (Loc, Expr_Value (Exp)));
 159             end if;
 160
 161             --  A complex case arises if the alignment clause applies to an
 162             --  unconstrained object initialized with a function call. The
 163             --  result of the call is placed on the secondary stack, and the
 164             --  declaration is rewritten as a renaming of a dereference, which
 165             --  fails expansion. We must introduce a temporary and assign its
 166             --  value to the existing entity.
 167
 168             if Nkind (Parent (Ent)) = N_Object_Renaming_Declaration
 169               and then not Is_Entity_Name (Renamed_Object (Ent))
 170             then
 171                declare
 172                   Loc      : constant Source_Ptr := Sloc (N);
 173                   Decl     : constant Node_Id    := Parent (Ent);
 174                   Temp     : constant Entity_Id  := Make_Temporary (Loc, 'T');
 175                   New_Decl : Node_Id;
 176
 177                begin
 178                   --  Replace entity with temporary and reanalyze
 179
 180                   Set_Defining_Identifier (Decl, Temp);
 181                   Set_Analyzed (Decl, False);
 182                   Analyze (Decl);
 183
 184                   --  Introduce new declaration for entity but do not reanalyze
 185                   --  because entity is already in scope. Type and expression
 186                   --  are already resolved.
 187
 188                   New_Decl :=
 189                     Make_Object_Declaration (Loc,
 190                       Defining_Identifier => Ent,
 191                       Object_Definition   =>
 192                         New_Occurrence_Of (Etype (Ent), Loc),
 193                       Expression          => New_Occurrence_Of (Temp, Loc));
 194
 195                   Set_Renamed_Object (Ent, Empty);
 196                   Insert_After (Decl, New_Decl);
 197                   Set_Analyzed (Decl);
 198                end;
 199             end if;
 200
 201          ------------------
 202          -- Storage_Size --
 203          ------------------
 204
 205          when Attribute_Storage_Size =>
 206
 207             --  If the type is a task type, then assign the value of the
 208             --  storage size to the Size variable associated with the task.
 209             --  Insert the assignment right after the declaration of the Size
 210             --  variable.
 211
 212             --  Generate:
 213
 214             --  task_typeZ := expression
 215
 216             if Ekind (Ent) = E_Task_Type then
 217                declare
 218                   Assign : Node_Id;
 219
 220                begin
 221                   Assign :=
 222                     Make_Assignment_Statement (Loc,
 223                       Name =>
 224                         New_Occurrence_Of (Storage_Size_Variable (Ent), Loc),
 225                       Expression =>
 226                         Convert_To (RTE (RE_Size_Type), Expression (N)));
 227
 228                   --  If the clause is not generated by an aspect, insert
 229                   --  the assignment here.  Freezing rules ensure that this
 230                   --  is safe, or clause will have been rejected already.
 231
 232                   if Is_List_Member (N) then
 233                      Insert_After (N, Assign);
 234
 235                   --  Otherwise, insert assignment after task declaration.
 236
 237                   else
 238                      Insert_After
 239                        (Parent (Storage_Size_Variable (Entity (N))), Assign);
 240                   end if;
 241
 242                   Analyze (Assign);
 243                end;
 244
 245             --  For Storage_Size for an access type, create a variable to hold
 246             --  the value of the specified size with name typeV and expand an
 247             --  assignment statement to initialize this value.
 248
 249             elsif Is_Access_Type (Ent) then
 250
 251                --  We don't need the variable for a storage size of zero
 252
 253                if not No_Pool_Assigned (Ent) then
 254                   V :=
 255                     Make_Defining_Identifier (Loc,
 256                       Chars => New_External_Name (Chars (Ent), 'V'));
 257
 258                   --  Insert the declaration of the object
 259
 260                   Insert_Action (N,
 261                     Make_Object_Declaration (Loc,
 262                       Defining_Identifier => V,
 263                       Object_Definition  =>
 264                         New_Occurrence_Of (RTE (RE_Storage_Offset), Loc),
 265                       Expression =>
 266                         Convert_To (RTE (RE_Storage_Offset), Expression (N))));
 267
 268                   Set_Storage_Size_Variable (Ent, Entity_Id (V));
 269                end if;
 270             end if;
 271
 272          --  Other attributes require no expansion
 273
 274          when others =>
 275             null;
 276
 277       end case;
 278    end Expand_N_Attribute_Definition_Clause;
 279
 280    -----------------------------
 281    -- Expand_N_Free_Statement --
 282    -----------------------------
 283
 284    procedure Expand_N_Free_Statement (N : Node_Id) is
 285       Expr : constant Node_Id := Expression (N);
 286       Typ  : Entity_Id;
 287
 288    begin
 289       --  Certain run-time configurations and targets do not provide support
 290       --  for controlled types.
 291
 292       if Restriction_Active (No_Finalization) then
 293          return;
 294
 295       --  Do not create a specialized Deallocate since .NET/JVM compilers do
 296       --  not support pools and address arithmetic.
 297
 298       elsif VM_Target /= No_VM then
 299          return;
 300       end if;
 301
 302       --  Use the base type to perform the check for finalization master
 303
 304       Typ := Etype (Expr);
 305
 306       if Ekind (Typ) = E_Access_Subtype then
 307          Typ := Etype (Typ);
 308       end if;
 309
 310       --  Handle private access types
 311
 312       if Is_Private_Type (Typ)
 313         and then Present (Full_View (Typ))
 314       then
 315          Typ := Full_View (Typ);
 316       end if;
 317
 318       --  Do not create a custom Deallocate when freeing an object with
 319       --  suppressed finalization. In such cases the object is never attached
 320       --  to a master, so it does not need to be detached. Use a regular free
 321       --  statement instead.
 322
 323       if No (Finalization_Master (Typ)) then
 324          return;
 325       end if;
 326
 327       --  Use a temporary to store the result of a complex expression. Perform
 328       --  the following transformation:
 329       --
 330       --     Free (Complex_Expression);
 331       --
 332       --     Temp : constant Type_Of_Expression := Complex_Expression;
 333       --     Free (Temp);
 334
 335       if Nkind (Expr) /= N_Identifier then
 336          declare
 337             Expr_Typ : constant Entity_Id  := Etype (Expr);
 338             Loc      : constant Source_Ptr := Sloc (N);
 339             New_Expr : Node_Id;
 340             Temp_Id  : Entity_Id;
 341
 342          begin
 343             Temp_Id := Make_Temporary (Loc, 'T');
 344             Insert_Action (N,
 345               Make_Object_Declaration (Loc,
 346                 Defining_Identifier => Temp_Id,
 347                 Object_Definition =>
 348                   New_Occurrence_Of (Expr_Typ, Loc),
 349                 Expression =>
 350                   Relocate_Node (Expr)));
 351
 352             New_Expr := New_Occurrence_Of (Temp_Id, Loc);
 353             Set_Etype (New_Expr, Expr_Typ);
 354
 355             Set_Expression (N, New_Expr);
 356          end;
 357       end if;
 358
 359       --  Create a custom Deallocate for a controlled object. This routine
 360       --  ensures that the hidden list header will be deallocated along with
 361       --  the actual object.
 362
 363       Build_Allocate_Deallocate_Proc (N, Is_Allocate => False);
 364    end Expand_N_Free_Statement;
 365
 366    ----------------------------
 367    -- Expand_N_Freeze_Entity --
 368    ----------------------------
 369
 370    procedure Expand_N_Freeze_Entity (N : Node_Id) is
 371       E              : constant Entity_Id := Entity (N);
 372       E_Scope        : Entity_Id;
 373       In_Other_Scope : Boolean;
 374       In_Outer_Scope : Boolean;
 375       Decl           : Node_Id;
 376       Delete         : Boolean := False;
 377
 378    begin
 379       --  If there are delayed aspect specifications, we insert them just
 380       --  before the freeze node. They are already analyzed so we don't need
 381       --  to reanalyze them (they were analyzed before the type was frozen),
 382       --  but we want them in the tree for the back end, and so that the
 383       --  listing from sprint is clearer on where these occur logically.
 384
 385       if Has_Delayed_Aspects (E) then
 386          declare
 387             Aitem : Node_Id;
 388             Ritem : Node_Id;
 389
 390          begin
 391             --  Look for aspect specs for this entity
 392
 393             Ritem := First_Rep_Item (E);
 394             while Present (Ritem) loop
 395                if Nkind (Ritem) = N_Aspect_Specification
 396                  and then Entity (Ritem) = E
 397                then
 398                   Aitem := Aspect_Rep_Item (Ritem);
 399
 400                   --  Skip this for aspects (e.g. Current_Value) for which
 401                   --  there is no corresponding pragma or attribute.
 402
 403                   if Present (Aitem)
 404
 405                     --  Also skip if we have a null statement rather than a
 406                     --  delayed aspect (this happens when we are ignoring rep
 407                     --  items from use of the -gnatI switch).
 408
 409                     and then Nkind (Aitem) /= N_Null_Statement
 410                   then
 411                      pragma Assert (Is_Delayed_Aspect (Aitem));
 412                      Insert_Before (N, Aitem);
 413                   end if;
 414                end if;
 415
 416                Next_Rep_Item (Ritem);
 417             end loop;
 418          end;
 419       end if;
 420
 421       --  Processing for objects
 422
 423       if Is_Object (E) then
 424          if Present (Address_Clause (E)) then
 425             Apply_Address_Clause_Check (E, N);
 426          end if;
 427
 428          --  Analyze actions in freeze node, if any
 429
 430          if Present (Actions (N)) then
 431             declare
 432                Act : Node_Id;
 433             begin
 434                Act := First (Actions (N));
 435                while Present (Act) loop
 436                   Analyze (Act);
 437                   Next (Act);
 438                end loop;
 439             end;
 440          end if;
 441
 442          --  If initialization statements have been captured in a compound
 443          --  statement, insert them back into the tree now.
 444
 445          Explode_Initialization_Compound_Statement (E);
 446
 447          return;
 448
 449       --  Only other items requiring any front end action are types and
 450       --  subprograms.
 451
 452       elsif not Is_Type (E) and then not Is_Subprogram (E) then
 453          return;
 454       end if;
 455
 456       --  Here E is a type or a subprogram
 457
 458       E_Scope := Scope (E);
 459
 460       --  This is an error protection against previous errors
 461
 462       if No (E_Scope) then
 463          Check_Error_Detected;
 464          return;
 465       end if;
 466
 467       --  The entity may be a subtype declared for a constrained record
 468       --  component, in which case the relevant scope is the scope of
 469       --  the record. This happens for class-wide subtypes created for
 470       --  a constrained type extension with inherited discriminants.
 471
 472       if Is_Type (E_Scope)
 473         and then Ekind (E_Scope) not in Concurrent_Kind
 474       then
 475          E_Scope := Scope (E_Scope);
 476       end if;
 477
 478       --  Remember that we are processing a freezing entity and its freezing
 479       --  nodes. This flag (non-zero = set) is used to avoid the need of
 480       --  climbing through the tree while processing the freezing actions (ie.
 481       --  to avoid generating spurious warnings or to avoid killing constant
 482       --  indications while processing the code associated with freezing
 483       --  actions). We use a counter to deal with nesting.
 484
 485       Inside_Freezing_Actions := Inside_Freezing_Actions + 1;
 486
 487       --  If we are freezing entities defined in protected types, they belong
 488       --  in the enclosing scope, given that the original type has been
 489       --  expanded away. The same is true for entities in task types, in
 490       --  particular the parameter records of entries (Entities in bodies are
 491       --  all frozen within the body). If we are in the task body, this is a
 492       --  proper scope. If we are within a subprogram body, the proper scope
 493       --  is the corresponding spec. This may happen for itypes generated in
 494       --  the bodies of protected operations.
 495
 496       if Ekind (E_Scope) = E_Protected_Type
 497         or else (Ekind (E_Scope) = E_Task_Type
 498                   and then not Has_Completion (E_Scope))
 499       then
 500          E_Scope := Scope (E_Scope);
 501
 502       elsif Ekind (E_Scope) = E_Subprogram_Body then
 503          E_Scope := Corresponding_Spec (Unit_Declaration_Node (E_Scope));
 504       end if;
 505
 506       --  If the scope of the entity is in open scopes, it is the current one
 507       --  or an enclosing one, including a loop, a block, or a subprogram.
 508
 509       if In_Open_Scopes (E_Scope) then
 510          In_Other_Scope := False;
 511          In_Outer_Scope := E_Scope /= Current_Scope;
 512
 513       --  Otherwise it is a local package or a different compilation unit
 514
 515       else
 516          In_Other_Scope := True;
 517          In_Outer_Scope := False;
 518       end if;
 519
 520       --  If the entity being frozen is defined in a scope that is not
 521       --  currently on the scope stack, we must establish the proper
 522       --  visibility before freezing the entity and related subprograms.
 523
 524       if In_Other_Scope then
 525          Push_Scope (E_Scope);
 526
 527          --  Finalizers are little odd in terms of freezing. The spec of the
 528          --  procedure appears in the declarations while the body appears in
 529          --  the statement part of a single construct. Since the finalizer must
 530          --  be called by the At_End handler of the construct, the spec is
 531          --  manually frozen right after its declaration. The only side effect
 532          --  of this action appears in contexts where the construct is not in
 533          --  its final resting place. These contexts are:
 534
 535          --    * Entry bodies - The declarations and statements are moved to
 536          --      the procedure equivalen of the entry.
 537          --    * Protected subprograms - The declarations and statements are
 538          --      moved to the non-protected version of the subprogram.
 539          --    * Task bodies - The declarations and statements are moved to the
 540          --      task body procedure.
 541
 542          --  Visible declarations do not need to be installed in these three
 543          --  cases since it does not make semantic sense to do so. All entities
 544          --  referenced by a finalizer are visible and already resolved, plus
 545          --  the enclosing scope may not have visible declarations at all.
 546
 547          if Ekind (E) = E_Procedure
 548            and then Is_Finalizer (E)
 549            and then
 550              (Is_Entry (E_Scope)
 551                 or else (Is_Subprogram (E_Scope)
 552                           and then Is_Protected_Type (Scope (E_Scope)))
 553                 or else Is_Task_Type (E_Scope))
 554          then
 555             null;
 556          else
 557             Install_Visible_Declarations (E_Scope);
 558          end if;
 559
 560          if Is_Package_Or_Generic_Package (E_Scope) or else
 561             Is_Protected_Type (E_Scope)             or else
 562             Is_Task_Type (E_Scope)
 563          then
 564             Install_Private_Declarations (E_Scope);
 565          end if;
 566
 567       --  If the entity is in an outer scope, then that scope needs to
 568       --  temporarily become the current scope so that operations created
 569       --  during type freezing will be declared in the right scope and
 570       --  can properly override any corresponding inherited operations.
 571
 572       elsif In_Outer_Scope then
 573          Push_Scope (E_Scope);
 574       end if;
 575
 576       --  If type, freeze the type
 577
 578       if Is_Type (E) then
 579          Delete := Freeze_Type (N);
 580
 581          --  And for enumeration type, build the enumeration tables
 582
 583          if Is_Enumeration_Type (E) then
 584             Build_Enumeration_Image_Tables (E, N);
 585          end if;
 586
 587       --  If subprogram, freeze the subprogram
 588
 589       elsif Is_Subprogram (E) then
 590          Exp_Ch6.Freeze_Subprogram (N);
 591
 592          --  Ada 2005 (AI-251): Remove the freezing node associated with the
 593          --  entities internally used by the frontend to register primitives
 594          --  covering abstract interfaces. The call to Freeze_Subprogram has
 595          --  already expanded the code that fills the corresponding entry in
 596          --  its secondary dispatch table and therefore the code generator
 597          --  has nothing else to do with this freezing node.
 598
 599          Delete := Present (Interface_Alias (E));
 600       end if;
 601
 602       --  Analyze actions generated by freezing. The init_proc contains source
 603       --  expressions that may raise Constraint_Error, and the assignment
 604       --  procedure for complex types needs checks on individual component
 605       --  assignments, but all other freezing actions should be compiled with
 606       --  all checks off.
 607
 608       if Present (Actions (N)) then
 609          Decl := First (Actions (N));
 610          while Present (Decl) loop
 611             if Nkind (Decl) = N_Subprogram_Body
 612               and then (Is_Init_Proc (Defining_Entity (Decl))
 613                           or else
 614                             Chars (Defining_Entity (Decl)) = Name_uAssign)
 615             then
 616                Analyze (Decl);
 617
 618             --  A subprogram body created for a renaming_as_body completes
 619             --  a previous declaration, which may be in a different scope.
 620             --  Establish the proper scope before analysis.
 621
 622             elsif Nkind (Decl) = N_Subprogram_Body
 623               and then Present (Corresponding_Spec (Decl))
 624               and then Scope (Corresponding_Spec (Decl)) /= Current_Scope
 625             then
 626                Push_Scope (Scope (Corresponding_Spec (Decl)));
 627                Analyze (Decl, Suppress => All_Checks);
 628                Pop_Scope;
 629
 630             --  We treat generated equality specially, if validity checks are
 631             --  enabled, in order to detect components default-initialized
 632             --  with invalid values.
 633
 634             elsif Nkind (Decl) = N_Subprogram_Body
 635               and then Chars (Defining_Entity (Decl)) = Name_Op_Eq
 636               and then Validity_Checks_On
 637               and then Initialize_Scalars
 638             then
 639                declare
 640                   Save_Force : constant Boolean := Force_Validity_Checks;
 641                begin
 642                   Force_Validity_Checks := True;
 643                   Analyze (Decl);
 644                   Force_Validity_Checks := Save_Force;
 645                end;
 646
 647             --  All other freezing actions
 648
 649             else
 650                Analyze (Decl, Suppress => All_Checks);
 651             end if;
 652
 653             Next (Decl);
 654          end loop;
 655       end if;
 656
 657       --  If we are to delete this N_Freeze_Entity, do so by rewriting so that
 658       --  a loop on all nodes being inserted will work propertly.
 659
 660       if Delete then
 661          Rewrite (N, Make_Null_Statement (Sloc (N)));
 662       end if;
 663
 664       --  Pop scope if we installed one for the analysis
 665
 666       if In_Other_Scope then
 667          if Ekind (Current_Scope) = E_Package then
 668             End_Package_Scope (E_Scope);
 669          else
 670             End_Scope;
 671          end if;
 672
 673       elsif In_Outer_Scope then
 674          Pop_Scope;
 675       end if;
 676
 677       --  Restore previous value of the nesting-level counter that records
 678       --  whether we are inside a (possibly nested) call to this procedure.
 679
 680       Inside_Freezing_Actions := Inside_Freezing_Actions - 1;
 681    end Expand_N_Freeze_Entity;
 682
 683    -------------------------------------------
 684    -- Expand_N_Record_Representation_Clause --
 685    -------------------------------------------
 686
 687    --  The only expansion required is for the case of a mod clause present,
 688    --  which is removed, and translated into an alignment representation
 689    --  clause inserted immediately after the record rep clause with any
 690    --  initial pragmas inserted at the start of the component clause list.
 691
 692    procedure Expand_N_Record_Representation_Clause (N : Node_Id) is
 693       Loc     : constant Source_Ptr := Sloc (N);
 694       Rectype : constant Entity_Id  := Entity (Identifier (N));
 695       Mod_Val : Uint;
 696       Citems  : List_Id;
 697       Repitem : Node_Id;
 698       AtM_Nod : Node_Id;
 699
 700    begin
 701       if Present (Mod_Clause (N)) and then not Ignore_Rep_Clauses then
 702          Mod_Val := Expr_Value (Expression (Mod_Clause (N)));
 703          Citems  := Pragmas_Before (Mod_Clause (N));
 704
 705          if Present (Citems) then
 706             Append_List_To (Citems, Component_Clauses (N));
 707             Set_Component_Clauses (N, Citems);
 708          end if;
 709
 710          AtM_Nod :=
 711            Make_Attribute_Definition_Clause (Loc,
 712              Name       => New_Occurrence_Of (Base_Type (Rectype), Loc),
 713              Chars      => Name_Alignment,
 714              Expression => Make_Integer_Literal (Loc, Mod_Val));
 715
 716          Set_From_At_Mod (AtM_Nod);
 717          Insert_After (N, AtM_Nod);
 718          Set_Mod_Clause (N, Empty);
 719       end if;
 720
 721       --  If the record representation clause has no components, then
 722       --  completely remove it.  Note that we also have to remove
 723       --  ourself from the Rep Item list.
 724
 725       if Is_Empty_List (Component_Clauses (N)) then
 726          if First_Rep_Item (Rectype) = N then
 727             Set_First_Rep_Item (Rectype, Next_Rep_Item (N));
 728          else
 729             Repitem := First_Rep_Item (Rectype);
 730             while Present (Next_Rep_Item (Repitem)) loop
 731                if Next_Rep_Item (Repitem) = N then
 732                   Set_Next_Rep_Item (Repitem, Next_Rep_Item (N));
 733                   exit;
 734                end if;
 735
 736                Next_Rep_Item (Repitem);
 737             end loop;
 738          end if;
 739
 740          Rewrite (N,
 741            Make_Null_Statement (Loc));
 742       end if;
 743    end Expand_N_Record_Representation_Clause;
 744
 745 end Exp_Ch13;