gcc/ada/aspects.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                              A S P E C T S                               --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2010-2015, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  17 --                                                                          --
  18 -- As a special exception under Section 7 of GPL version 3, you are granted --
  19 -- additional permissions described in the GCC Runtime Library Exception,   --
  20 -- version 3.1, as published by the Free Software Foundation.               --
  21 --                                                                          --
  22 -- You should have received a copy of the GNU General Public License and    --
  23 -- a copy of the GCC Runtime Library Exception along with this program;     --
  24 -- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
  25 -- <http://www.gnu.org/licenses/>.                                          --
  26 --                                                                          --
  27 -- GNAT was originally developed  by the GNAT team at  New York University. --
  28 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  29 --                                                                          --
  30 ------------------------------------------------------------------------------
  31
  32 with Atree;    use Atree;
  33 with Einfo;    use Einfo;
  34 with Nlists;   use Nlists;
  35 with Sinfo;    use Sinfo;
  36 with Tree_IO;  use Tree_IO;
  37
  38 with GNAT.HTable;           use GNAT.HTable;
  39
  40 package body Aspects is
  41
  42    --  The following array indicates aspects that a subtype inherits from its
  43    --  base type. True means that the subtype inherits the aspect from its base
  44    --  type. False means it is not inherited.
  45
  46    Base_Aspect : constant array (Aspect_Id) of Boolean :=
  47      (Aspect_Atomic                  => True,
  48       Aspect_Atomic_Components       => True,
  49       Aspect_Constant_Indexing       => True,
  50       Aspect_Default_Iterator        => True,
  51       Aspect_Discard_Names           => True,
  52       Aspect_Independent_Components  => True,
  53       Aspect_Iterator_Element        => True,
  54       Aspect_Type_Invariant          => True,
  55       Aspect_Unchecked_Union         => True,
  56       Aspect_Variable_Indexing       => True,
  57       Aspect_Volatile                => True,
  58       Aspect_Volatile_Full_Access    => True,
  59       others                         => False);
  60
  61    --  The following array indicates type aspects that are inherited and apply
  62    --  to the class-wide type as well.
  63
  64    Inherited_Aspect : constant array (Aspect_Id) of Boolean :=
  65      (Aspect_Constant_Indexing    => True,
  66       Aspect_Default_Iterator     => True,
  67       Aspect_Implicit_Dereference => True,
  68       Aspect_Iterator_Element     => True,
  69       Aspect_Remote_Types         => True,
  70       Aspect_Variable_Indexing    => True,
  71       others                      => False);
  72
  73    procedure Set_Aspect_Specifications_No_Check (N : Node_Id; L : List_Id);
  74    --  Same as Set_Aspect_Specifications, but does not contain the assertion
  75    --  that checks that N does not already have aspect specifications. This
  76    --  subprogram is supposed to be used as a part of Tree_Read. When reading
  77    --  tree, first read nodes with their basic properties (as Atree.Tree_Read),
  78    --  this includes reading the Has_Aspects flag for each node, then we reed
  79    --  all the list tables and only after that we call Tree_Read for Aspects.
  80    --  That is, when reading the tree, the list of aspects is attached to the
  81    --  node that already has Has_Aspects flag set ON.
  82
  83    ------------------------------------------
  84    -- Hash Table for Aspect Specifications --
  85    ------------------------------------------
  86
  87    type AS_Hash_Range is range 0 .. 510;
  88    --  Size of hash table headers
  89
  90    function AS_Hash (F : Node_Id) return AS_Hash_Range;
  91    --  Hash function for hash table
  92
  93    function AS_Hash (F : Node_Id) return AS_Hash_Range is
  94    begin
  95       return AS_Hash_Range (F mod 511);
  96    end AS_Hash;
  97
  98    package Aspect_Specifications_Hash_Table is new
  99      GNAT.HTable.Simple_HTable
 100        (Header_Num => AS_Hash_Range,
 101         Element    => List_Id,
 102         No_Element => No_List,
 103         Key        => Node_Id,
 104         Hash       => AS_Hash,
 105         Equal      => "=");
 106
 107    -------------------------------------
 108    -- Hash Table for Aspect Id Values --
 109    -------------------------------------
 110
 111    type AI_Hash_Range is range 0 .. 112;
 112    --  Size of hash table headers
 113
 114    function AI_Hash (F : Name_Id) return AI_Hash_Range;
 115    --  Hash function for hash table
 116
 117    function AI_Hash (F : Name_Id) return AI_Hash_Range is
 118    begin
 119       return AI_Hash_Range (F mod 113);
 120    end AI_Hash;
 121
 122    package Aspect_Id_Hash_Table is new
 123      GNAT.HTable.Simple_HTable
 124        (Header_Num => AI_Hash_Range,
 125         Element    => Aspect_Id,
 126         No_Element => No_Aspect,
 127         Key        => Name_Id,
 128         Hash       => AI_Hash,
 129         Equal      => "=");
 130
 131    ---------------------------
 132    -- Aspect_Specifications --
 133    ---------------------------
 134
 135    function Aspect_Specifications (N : Node_Id) return List_Id is
 136    begin
 137       if Has_Aspects (N) then
 138          return Aspect_Specifications_Hash_Table.Get (N);
 139       else
 140          return No_List;
 141       end if;
 142    end Aspect_Specifications;
 143
 144    --------------------------------
 145    -- Aspects_On_Body_Or_Stub_OK --
 146    --------------------------------
 147
 148    function Aspects_On_Body_Or_Stub_OK (N : Node_Id) return Boolean is
 149       Aspect  : Node_Id;
 150       Aspects : List_Id;
 151
 152    begin
 153       --  The routine should be invoked on a body [stub] with aspects
 154
 155       pragma Assert (Has_Aspects (N));
 156       pragma Assert (Nkind (N) in N_Body_Stub
 157                        or else Nkind_In (N, N_Package_Body,
 158                                             N_Protected_Body,
 159                                             N_Subprogram_Body,
 160                                             N_Task_Body));
 161
 162       --  Look through all aspects and see whether they can be applied to a
 163       --  body [stub].
 164
 165       Aspects := Aspect_Specifications (N);
 166       Aspect  := First (Aspects);
 167       while Present (Aspect) loop
 168          if not Aspect_On_Body_Or_Stub_OK (Get_Aspect_Id (Aspect)) then
 169             return False;
 170          end if;
 171
 172          Next (Aspect);
 173       end loop;
 174
 175       return True;
 176    end Aspects_On_Body_Or_Stub_OK;
 177
 178    ----------------------
 179    -- Exchange_Aspects --
 180    ----------------------
 181
 182    procedure Exchange_Aspects (N1 : Node_Id; N2 : Node_Id) is
 183    begin
 184       pragma Assert
 185         (Permits_Aspect_Specifications (N1)
 186            and then Permits_Aspect_Specifications (N2));
 187
 188       --  Perform the exchange only when both nodes have lists to be swapped
 189
 190       if Has_Aspects (N1) and then Has_Aspects (N2) then
 191          declare
 192             L1 : constant List_Id := Aspect_Specifications (N1);
 193             L2 : constant List_Id := Aspect_Specifications (N2);
 194          begin
 195             Set_Parent (L1, N2);
 196             Set_Parent (L2, N1);
 197             Aspect_Specifications_Hash_Table.Set (N1, L2);
 198             Aspect_Specifications_Hash_Table.Set (N2, L1);
 199          end;
 200       end if;
 201    end Exchange_Aspects;
 202
 203    -----------------
 204    -- Find_Aspect --
 205    -----------------
 206
 207    function Find_Aspect (Id : Entity_Id; A : Aspect_Id) return Node_Id is
 208       Decl  : Node_Id;
 209       Item  : Node_Id;
 210       Owner : Entity_Id;
 211       Spec  : Node_Id;
 212
 213    begin
 214       Owner := Id;
 215
 216       --  Handle various cases of base or inherited aspects for types
 217
 218       if Is_Type (Id) then
 219          if Base_Aspect (A) then
 220             Owner := Base_Type (Owner);
 221          end if;
 222
 223          if Is_Class_Wide_Type (Owner) and then Inherited_Aspect (A) then
 224             Owner := Root_Type (Owner);
 225          end if;
 226
 227          if Is_Private_Type (Owner) and then Present (Full_View (Owner)) then
 228             Owner := Full_View (Owner);
 229          end if;
 230       end if;
 231
 232       --  Search the representation items for the desired aspect
 233
 234       Item := First_Rep_Item (Owner);
 235       while Present (Item) loop
 236          if Nkind (Item) = N_Aspect_Specification
 237            and then Get_Aspect_Id (Item) = A
 238          then
 239             return Item;
 240          end if;
 241
 242          Next_Rep_Item (Item);
 243       end loop;
 244
 245       --  Note that not all aspects are added to the chain of representation
 246       --  items. In such cases, search the list of aspect specifications. First
 247       --  find the declaration node where the aspects reside. This is usually
 248       --  the parent or the parent of the parent.
 249
 250       Decl := Parent (Owner);
 251       if not Permits_Aspect_Specifications (Decl) then
 252          Decl := Parent (Decl);
 253       end if;
 254
 255       --  Search the list of aspect specifications for the desired aspect
 256
 257       if Permits_Aspect_Specifications (Decl) then
 258          Spec := First (Aspect_Specifications (Decl));
 259          while Present (Spec) loop
 260             if Get_Aspect_Id (Spec) = A then
 261                return Spec;
 262             end if;
 263
 264             Next (Spec);
 265          end loop;
 266       end if;
 267
 268       --  The entity does not carry any aspects or the desired aspect was not
 269       --  found.
 270
 271       return Empty;
 272    end Find_Aspect;
 273
 274    --------------------------
 275    -- Find_Value_Of_Aspect --
 276    --------------------------
 277
 278    function Find_Value_Of_Aspect
 279      (Id : Entity_Id;
 280       A  : Aspect_Id) return Node_Id
 281    is
 282       Spec : constant Node_Id := Find_Aspect (Id, A);
 283
 284    begin
 285       if Present (Spec) then
 286          if A = Aspect_Default_Iterator then
 287             return Expression (Aspect_Rep_Item (Spec));
 288          else
 289             return Expression (Spec);
 290          end if;
 291       end if;
 292
 293       return Empty;
 294    end Find_Value_Of_Aspect;
 295
 296    -------------------
 297    -- Get_Aspect_Id --
 298    -------------------
 299
 300    function Get_Aspect_Id (Name : Name_Id) return Aspect_Id is
 301    begin
 302       return Aspect_Id_Hash_Table.Get (Name);
 303    end Get_Aspect_Id;
 304
 305    function Get_Aspect_Id (Aspect : Node_Id) return Aspect_Id is
 306    begin
 307       pragma Assert (Nkind (Aspect) = N_Aspect_Specification);
 308       return Aspect_Id_Hash_Table.Get (Chars (Identifier (Aspect)));
 309    end Get_Aspect_Id;
 310
 311    ----------------
 312    -- Has_Aspect --
 313    ----------------
 314
 315    function Has_Aspect (Id : Entity_Id; A : Aspect_Id) return Boolean is
 316    begin
 317       return Present (Find_Aspect (Id, A));
 318    end Has_Aspect;
 319
 320    ------------------
 321    -- Move_Aspects --
 322    ------------------
 323
 324    procedure Move_Aspects (From : Node_Id; To : Node_Id) is
 325       pragma Assert (not Has_Aspects (To));
 326    begin
 327       if Has_Aspects (From) then
 328          Set_Aspect_Specifications (To, Aspect_Specifications (From));
 329          Aspect_Specifications_Hash_Table.Remove (From);
 330          Set_Has_Aspects (From, False);
 331       end if;
 332    end Move_Aspects;
 333
 334    ---------------------------
 335    -- Move_Or_Merge_Aspects --
 336    ---------------------------
 337
 338    procedure Move_Or_Merge_Aspects (From : Node_Id; To : Node_Id) is
 339       procedure Relocate_Aspect (Asp : Node_Id);
 340       --  Asp denotes an aspect specification of node From. Relocate the Asp to
 341       --  the aspect specifications of node To (if any).
 342
 343       ---------------------
 344       -- Relocate_Aspect --
 345       ---------------------
 346
 347       procedure Relocate_Aspect (Asp : Node_Id) is
 348          Asps : List_Id;
 349
 350       begin
 351          if Has_Aspects (To) then
 352             Asps := Aspect_Specifications (To);
 353
 354          --  Create a new aspect specification list for node To
 355
 356          else
 357             Asps := New_List;
 358             Set_Aspect_Specifications (To, Asps);
 359             Set_Has_Aspects (To);
 360          end if;
 361
 362          --  Remove the aspect from node From's aspect specifications and
 363          --  append it to node To.
 364
 365          Remove (Asp);
 366          Append (Asp, Asps);
 367       end Relocate_Aspect;
 368
 369       --  Local variables
 370
 371       Asp      : Node_Id;
 372       Asp_Id   : Aspect_Id;
 373       Next_Asp : Node_Id;
 374
 375    --  Start of processing for Move_Or_Merge_Aspects
 376
 377    begin
 378       if Has_Aspects (From) then
 379          Asp := First (Aspect_Specifications (From));
 380          while Present (Asp) loop
 381
 382             --  Store the next aspect now as a potential relocation will alter
 383             --  the contents of the list.
 384
 385             Next_Asp := Next (Asp);
 386
 387             --  When moving or merging aspects from a subprogram body stub that
 388             --  also acts as a spec, relocate only those aspects that may apply
 389             --  to a body [stub]. Note that a precondition must also be moved
 390             --  to the proper body as the pre/post machinery expects it to be
 391             --  there.
 392
 393             if Nkind (From) = N_Subprogram_Body_Stub
 394               and then No (Corresponding_Spec_Of_Stub (From))
 395             then
 396                Asp_Id := Get_Aspect_Id (Asp);
 397
 398                if Aspect_On_Body_Or_Stub_OK (Asp_Id)
 399                  or else Asp_Id = Aspect_Pre
 400                  or else Asp_Id = Aspect_Precondition
 401                then
 402                   Relocate_Aspect (Asp);
 403                end if;
 404
 405             --  Default case - relocate the aspect to its new owner
 406
 407             else
 408                Relocate_Aspect (Asp);
 409             end if;
 410
 411             Asp := Next_Asp;
 412          end loop;
 413
 414          --  The relocations may have left node From's aspect specifications
 415          --  list empty. If this is the case, simply remove the aspects.
 416
 417          if Is_Empty_List (Aspect_Specifications (From)) then
 418             Remove_Aspects (From);
 419          end if;
 420       end if;
 421    end Move_Or_Merge_Aspects;
 422
 423    -----------------------------------
 424    -- Permits_Aspect_Specifications --
 425    -----------------------------------
 426
 427    Has_Aspect_Specifications_Flag : constant array (Node_Kind) of Boolean :=
 428      (N_Abstract_Subprogram_Declaration        => True,
 429       N_Component_Declaration                  => True,
 430       N_Entry_Declaration                      => True,
 431       N_Exception_Declaration                  => True,
 432       N_Exception_Renaming_Declaration         => True,
 433       N_Expression_Function                    => True,
 434       N_Formal_Abstract_Subprogram_Declaration => True,
 435       N_Formal_Concrete_Subprogram_Declaration => True,
 436       N_Formal_Object_Declaration              => True,
 437       N_Formal_Package_Declaration             => True,
 438       N_Formal_Type_Declaration                => True,
 439       N_Full_Type_Declaration                  => True,
 440       N_Function_Instantiation                 => True,
 441       N_Generic_Package_Declaration            => True,
 442       N_Generic_Renaming_Declaration           => True,
 443       N_Generic_Subprogram_Declaration         => True,
 444       N_Object_Declaration                     => True,
 445       N_Object_Renaming_Declaration            => True,
 446       N_Package_Body                           => True,
 447       N_Package_Body_Stub                      => True,
 448       N_Package_Declaration                    => True,
 449       N_Package_Instantiation                  => True,
 450       N_Package_Specification                  => True,
 451       N_Package_Renaming_Declaration           => True,
 452       N_Private_Extension_Declaration          => True,
 453       N_Private_Type_Declaration               => True,
 454       N_Procedure_Instantiation                => True,
 455       N_Protected_Body                         => True,
 456       N_Protected_Body_Stub                    => True,
 457       N_Protected_Type_Declaration             => True,
 458       N_Single_Protected_Declaration           => True,
 459       N_Single_Task_Declaration                => True,
 460       N_Subprogram_Body                        => True,
 461       N_Subprogram_Body_Stub                   => True,
 462       N_Subprogram_Declaration                 => True,
 463       N_Subprogram_Renaming_Declaration        => True,
 464       N_Subtype_Declaration                    => True,
 465       N_Task_Body                              => True,
 466       N_Task_Body_Stub                         => True,
 467       N_Task_Type_Declaration                  => True,
 468       others                                   => False);
 469
 470    function Permits_Aspect_Specifications (N : Node_Id) return Boolean is
 471    begin
 472       return Has_Aspect_Specifications_Flag (Nkind (N));
 473    end Permits_Aspect_Specifications;
 474
 475    --------------------
 476    -- Remove_Aspects --
 477    --------------------
 478
 479    procedure Remove_Aspects (N : Node_Id) is
 480    begin
 481       if Has_Aspects (N) then
 482          Aspect_Specifications_Hash_Table.Remove (N);
 483          Set_Has_Aspects (N, False);
 484       end if;
 485    end Remove_Aspects;
 486
 487    -----------------
 488    -- Same_Aspect --
 489    -----------------
 490
 491    --  Table used for Same_Aspect, maps aspect to canonical aspect
 492
 493    Canonical_Aspect : constant array (Aspect_Id) of Aspect_Id :=
 494    (No_Aspect                           => No_Aspect,
 495     Aspect_Abstract_State               => Aspect_Abstract_State,
 496     Aspect_Address                      => Aspect_Address,
 497     Aspect_Alignment                    => Aspect_Alignment,
 498     Aspect_All_Calls_Remote             => Aspect_All_Calls_Remote,
 499     Aspect_Annotate                     => Aspect_Annotate,
 500     Aspect_Async_Readers                => Aspect_Async_Readers,
 501     Aspect_Async_Writers                => Aspect_Async_Writers,
 502     Aspect_Asynchronous                 => Aspect_Asynchronous,
 503     Aspect_Atomic                       => Aspect_Atomic,
 504     Aspect_Atomic_Components            => Aspect_Atomic_Components,
 505     Aspect_Attach_Handler               => Aspect_Attach_Handler,
 506     Aspect_Bit_Order                    => Aspect_Bit_Order,
 507     Aspect_Component_Size               => Aspect_Component_Size,
 508     Aspect_Constant_Indexing            => Aspect_Constant_Indexing,
 509     Aspect_Contract_Cases               => Aspect_Contract_Cases,
 510     Aspect_Convention                   => Aspect_Convention,
 511     Aspect_CPU                          => Aspect_CPU,
 512     Aspect_Default_Component_Value      => Aspect_Default_Component_Value,
 513     Aspect_Default_Initial_Condition    => Aspect_Default_Initial_Condition,
 514     Aspect_Default_Iterator             => Aspect_Default_Iterator,
 515     Aspect_Default_Storage_Pool         => Aspect_Default_Storage_Pool,
 516     Aspect_Default_Value                => Aspect_Default_Value,
 517     Aspect_Depends                      => Aspect_Depends,
 518     Aspect_Dimension                    => Aspect_Dimension,
 519     Aspect_Dimension_System             => Aspect_Dimension_System,
 520     Aspect_Discard_Names                => Aspect_Discard_Names,
 521     Aspect_Dispatching_Domain           => Aspect_Dispatching_Domain,
 522     Aspect_Dynamic_Predicate            => Aspect_Predicate,
 523     Aspect_Effective_Reads              => Aspect_Effective_Reads,
 524     Aspect_Effective_Writes             => Aspect_Effective_Writes,
 525     Aspect_Elaborate_Body               => Aspect_Elaborate_Body,
 526     Aspect_Export                       => Aspect_Export,
 527     Aspect_Extensions_Visible           => Aspect_Extensions_Visible,
 528     Aspect_External_Name                => Aspect_External_Name,
 529     Aspect_External_Tag                 => Aspect_External_Tag,
 530     Aspect_Favor_Top_Level              => Aspect_Favor_Top_Level,
 531     Aspect_Ghost                        => Aspect_Ghost,
 532     Aspect_Global                       => Aspect_Global,
 533     Aspect_Implicit_Dereference         => Aspect_Implicit_Dereference,
 534     Aspect_Import                       => Aspect_Import,
 535     Aspect_Independent                  => Aspect_Independent,
 536     Aspect_Independent_Components       => Aspect_Independent_Components,
 537     Aspect_Inline                       => Aspect_Inline,
 538     Aspect_Inline_Always                => Aspect_Inline,
 539     Aspect_Initial_Condition            => Aspect_Initial_Condition,
 540     Aspect_Initializes                  => Aspect_Initializes,
 541     Aspect_Input                        => Aspect_Input,
 542     Aspect_Interrupt_Handler            => Aspect_Interrupt_Handler,
 543     Aspect_Interrupt_Priority           => Aspect_Priority,
 544     Aspect_Invariant                    => Aspect_Invariant,
 545     Aspect_Iterable                     => Aspect_Iterable,
 546     Aspect_Iterator_Element             => Aspect_Iterator_Element,
 547     Aspect_Link_Name                    => Aspect_Link_Name,
 548     Aspect_Linker_Section               => Aspect_Linker_Section,
 549     Aspect_Lock_Free                    => Aspect_Lock_Free,
 550     Aspect_Machine_Radix                => Aspect_Machine_Radix,
 551     Aspect_No_Elaboration_Code_All      => Aspect_No_Elaboration_Code_All,
 552     Aspect_No_Return                    => Aspect_No_Return,
 553     Aspect_No_Tagged_Streams            => Aspect_No_Tagged_Streams,
 554     Aspect_Obsolescent                  => Aspect_Obsolescent,
 555     Aspect_Object_Size                  => Aspect_Object_Size,
 556     Aspect_Output                       => Aspect_Output,
 557     Aspect_Pack                         => Aspect_Pack,
 558     Aspect_Part_Of                      => Aspect_Part_Of,
 559     Aspect_Persistent_BSS               => Aspect_Persistent_BSS,
 560     Aspect_Post                         => Aspect_Post,
 561     Aspect_Postcondition                => Aspect_Post,
 562     Aspect_Pre                          => Aspect_Pre,
 563     Aspect_Precondition                 => Aspect_Pre,
 564     Aspect_Predicate                    => Aspect_Predicate,
 565     Aspect_Preelaborate                 => Aspect_Preelaborate,
 566     Aspect_Preelaborable_Initialization => Aspect_Preelaborable_Initialization,
 567     Aspect_Priority                     => Aspect_Priority,
 568     Aspect_Pure                         => Aspect_Pure,
 569     Aspect_Pure_Function                => Aspect_Pure_Function,
 570     Aspect_Refined_Depends              => Aspect_Refined_Depends,
 571     Aspect_Refined_Global               => Aspect_Refined_Global,
 572     Aspect_Refined_Post                 => Aspect_Refined_Post,
 573     Aspect_Refined_State                => Aspect_Refined_State,
 574     Aspect_Remote_Access_Type           => Aspect_Remote_Access_Type,
 575     Aspect_Remote_Call_Interface        => Aspect_Remote_Call_Interface,
 576     Aspect_Remote_Types                 => Aspect_Remote_Types,
 577     Aspect_Read                         => Aspect_Read,
 578     Aspect_Relative_Deadline            => Aspect_Relative_Deadline,
 579     Aspect_Scalar_Storage_Order         => Aspect_Scalar_Storage_Order,
 580     Aspect_Shared                       => Aspect_Atomic,
 581     Aspect_Shared_Passive               => Aspect_Shared_Passive,
 582     Aspect_Simple_Storage_Pool          => Aspect_Simple_Storage_Pool,
 583     Aspect_Simple_Storage_Pool_Type     => Aspect_Simple_Storage_Pool_Type,
 584     Aspect_Size                         => Aspect_Size,
 585     Aspect_Small                        => Aspect_Small,
 586     Aspect_SPARK_Mode                   => Aspect_SPARK_Mode,
 587     Aspect_Static_Predicate             => Aspect_Predicate,
 588     Aspect_Storage_Pool                 => Aspect_Storage_Pool,
 589     Aspect_Storage_Size                 => Aspect_Storage_Size,
 590     Aspect_Stream_Size                  => Aspect_Stream_Size,
 591     Aspect_Suppress                     => Aspect_Suppress,
 592     Aspect_Suppress_Debug_Info          => Aspect_Suppress_Debug_Info,
 593     Aspect_Suppress_Initialization      => Aspect_Suppress_Initialization,
 594     Aspect_Synchronization              => Aspect_Synchronization,
 595     Aspect_Test_Case                    => Aspect_Test_Case,
 596     Aspect_Thread_Local_Storage         => Aspect_Thread_Local_Storage,
 597     Aspect_Type_Invariant               => Aspect_Invariant,
 598     Aspect_Unchecked_Union              => Aspect_Unchecked_Union,
 599     Aspect_Unimplemented                => Aspect_Unimplemented,
 600     Aspect_Universal_Aliasing           => Aspect_Universal_Aliasing,
 601     Aspect_Universal_Data               => Aspect_Universal_Data,
 602     Aspect_Unmodified                   => Aspect_Unmodified,
 603     Aspect_Unreferenced                 => Aspect_Unreferenced,
 604     Aspect_Unreferenced_Objects         => Aspect_Unreferenced_Objects,
 605     Aspect_Unsuppress                   => Aspect_Unsuppress,
 606     Aspect_Variable_Indexing            => Aspect_Variable_Indexing,
 607     Aspect_Value_Size                   => Aspect_Value_Size,
 608     Aspect_Volatile                     => Aspect_Volatile,
 609     Aspect_Volatile_Components          => Aspect_Volatile_Components,
 610     Aspect_Volatile_Full_Access         => Aspect_Volatile_Full_Access,
 611     Aspect_Warnings                     => Aspect_Warnings,
 612     Aspect_Write                        => Aspect_Write);
 613
 614    function Same_Aspect (A1 : Aspect_Id; A2 : Aspect_Id) return Boolean is
 615    begin
 616       return Canonical_Aspect (A1) = Canonical_Aspect (A2);
 617    end Same_Aspect;
 618
 619    -------------------------------
 620    -- Set_Aspect_Specifications --
 621    -------------------------------
 622
 623    procedure Set_Aspect_Specifications (N : Node_Id; L : List_Id) is
 624    begin
 625       pragma Assert (Permits_Aspect_Specifications (N));
 626       pragma Assert (not Has_Aspects (N));
 627       pragma Assert (L /= No_List);
 628
 629       Set_Has_Aspects (N);
 630       Set_Parent (L, N);
 631       Aspect_Specifications_Hash_Table.Set (N, L);
 632    end Set_Aspect_Specifications;
 633
 634    ----------------------------------------
 635    -- Set_Aspect_Specifications_No_Check --
 636    ----------------------------------------
 637
 638    procedure Set_Aspect_Specifications_No_Check (N : Node_Id; L : List_Id) is
 639    begin
 640       pragma Assert (Permits_Aspect_Specifications (N));
 641       pragma Assert (L /= No_List);
 642
 643       Set_Has_Aspects (N);
 644       Set_Parent (L, N);
 645       Aspect_Specifications_Hash_Table.Set (N, L);
 646    end Set_Aspect_Specifications_No_Check;
 647
 648    ---------------
 649    -- Tree_Read --
 650    ---------------
 651
 652    procedure Tree_Read is
 653       Node : Node_Id;
 654       List : List_Id;
 655    begin
 656       loop
 657          Tree_Read_Int (Int (Node));
 658          Tree_Read_Int (Int (List));
 659          exit when List = No_List;
 660          Set_Aspect_Specifications_No_Check (Node, List);
 661       end loop;
 662    end Tree_Read;
 663
 664    ----------------
 665    -- Tree_Write --
 666    ----------------
 667
 668    procedure Tree_Write is
 669       Node : Node_Id := Empty;
 670       List : List_Id;
 671    begin
 672       Aspect_Specifications_Hash_Table.Get_First (Node, List);
 673       loop
 674          Tree_Write_Int (Int (Node));
 675          Tree_Write_Int (Int (List));
 676          exit when List = No_List;
 677          Aspect_Specifications_Hash_Table.Get_Next (Node, List);
 678       end loop;
 679    end Tree_Write;
 680
 681 --  Package initialization sets up Aspect Id hash table
 682
 683 begin
 684    for J in Aspect_Id loop
 685       Aspect_Id_Hash_Table.Set (Aspect_Names (J), J);
 686    end loop;
 687 end Aspects;