gcc/ada/libgnarl/s-tpopsp__vxworks.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                 GNAT RUN-TIME LIBRARY (GNARL) COMPONENTS                 --
   4 --                                                                          --
   5 --                SYSTEM.TASK_PRIMITIVES.OPERATIONS.SPECIFIC                --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --         Copyright (C) 1992-2023, Free Software Foundation, Inc.          --
  10 --                                                                          --
  11 -- GNARL is free software; you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  17 --                                                                          --
  18 -- As a special exception under Section 7 of GPL version 3, you are granted --
  19 -- additional permissions described in the GCC Runtime Library Exception,   --
  20 -- version 3.1, as published by the Free Software Foundation.               --
  21 --                                                                          --
  22 -- You should have received a copy of the GNU General Public License and    --
  23 -- a copy of the GCC Runtime Library Exception along with this program;     --
  24 -- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
  25 -- <http://www.gnu.org/licenses/>.                                          --
  26 --                                                                          --
  27 -- GNARL was developed by the GNARL team at Florida State University.       --
  28 -- Extensive contributions were provided by Ada Core Technologies, Inc.     --
  29 --                                                                          --
  30 ------------------------------------------------------------------------------
  31
  32 --  This is a VxWorks version of this package where foreign threads are
  33 --  recognized. The implementation is based on VxWorks taskVarLib.
  34
  35 separate (System.Task_Primitives.Operations)
  36 package body Specific is
  37
  38    ERROR  : constant STATUS := System.VxWorks.Ext.ERROR;
  39
  40    ATCB_Key : aliased System.Address := System.Null_Address;
  41    --  Key used to find the Ada Task_Id associated with a thread
  42
  43    ATCB_Key_Addr : System.Address := ATCB_Key'Address;
  44    pragma Export (Ada, ATCB_Key_Addr, "__gnat_ATCB_key_addr");
  45    --  Exported to support the temporary AE653 task registration
  46    --  implementation. This mechanism is used to minimize impact on other
  47    --  targets.
  48
  49    Stack_Limit : aliased System.Address;
  50
  51    pragma Import (C, Stack_Limit, "__gnat_stack_limit");
  52
  53    type Set_Stack_Limit_Proc_Acc is access procedure;
  54    pragma Convention (C, Set_Stack_Limit_Proc_Acc);
  55
  56    Set_Stack_Limit_Hook : Set_Stack_Limit_Proc_Acc;
  57    pragma Import (C, Set_Stack_Limit_Hook, "__gnat_set_stack_limit_hook");
  58    --  Procedure to be called when a task is created to set stack limit if
  59    --  limit checking is used.
  60
  61    ----------------
  62    -- Initialize --
  63    ----------------
  64
  65    procedure Initialize is
  66    begin
  67       null;
  68    end Initialize;
  69
  70    -------------------
  71    -- Is_Valid_Task --
  72    -------------------
  73
  74    function Is_Valid_Task return Boolean is
  75       IERR : constant := -1;
  76    begin
  77       return taskVarGet (taskIdSelf, ATCB_Key'Access) /= IERR;
  78    end Is_Valid_Task;
  79
  80    ---------
  81    -- Set --
  82    ---------
  83
  84    procedure Set (Self_Id : Task_Id) is
  85       Result : STATUS;
  86
  87    begin
  88       --  If argument is null, destroy task specific data, to make API
  89       --  consistent with other platforms, and thus compatible with the
  90       --  shared version of s-tpoaal.adb.
  91
  92       if Self_Id = null then
  93          Result := taskVarDelete (taskIdSelf, ATCB_Key'Access);
  94          pragma Assert (Result /= ERROR);
  95          return;
  96       end if;
  97
  98       if not Is_Valid_Task then
  99          Result := taskVarAdd (Self_Id.Common.LL.Thread, ATCB_Key'Access);
 100          pragma Assert (Result = OK);
 101
 102          if Stack_Check_Limits
 103            and then Result /= ERROR
 104            and then Set_Stack_Limit_Hook /= null
 105          then
 106             --  This will be initialized from taskInfoGet() once the task is
 107             --  is running.
 108
 109             Result :=
 110               taskVarAdd (Self_Id.Common.LL.Thread, Stack_Limit'Access);
 111             pragma Assert (Result /= ERROR);
 112          end if;
 113       end if;
 114
 115       Result :=
 116         taskVarSet
 117           (Self_Id.Common.LL.Thread,
 118            ATCB_Key'Access,
 119            To_Address (Self_Id));
 120       pragma Assert (Result /= ERROR);
 121    end Set;
 122
 123    ----------
 124    -- Self --
 125    ----------
 126
 127    --  To make Ada tasks and C threads interoperate better, we have added some
 128    --  functionality to Self. Suppose a C main program (with threads) calls an
 129    --  Ada procedure and the Ada procedure calls the tasking runtime system.
 130    --  Eventually, a call will be made to self. Since the call is not coming
 131    --  from an Ada task, there will be no corresponding ATCB.
 132
 133    --  What we do in Self is to catch references that do not come from
 134    --  recognized Ada tasks, and create an ATCB for the calling thread.
 135
 136    --  The new ATCB will be "detached" from the normal Ada task master
 137    --  hierarchy, much like the existing implicitly created signal-server
 138    --  tasks.
 139
 140    function Self return Task_Id is
 141       Result : constant Task_Id := To_Task_Id (ATCB_Key);
 142    begin
 143       if Result /= null then
 144          return Result;
 145       else
 146          --  If the value is Null then it is a non-Ada task
 147
 148          return Register_Foreign_Thread;
 149       end if;
 150    end Self;
 151
 152 end Specific;