gcc/ada/libgnarl/s-taspri__solaris.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                  GNAT RUN-TIME LIBRARY (GNARL) COMPONENTS                --
   4 --                                                                          --
   5 --                 S Y S T E M . T A S K _ P R I M I T I V E S              --
   6 --                                                                          --
   7 --                                  S p e c                                 --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2023, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNARL is free software; you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  17 --                                                                          --
  18 -- As a special exception under Section 7 of GPL version 3, you are granted --
  19 -- additional permissions described in the GCC Runtime Library Exception,   --
  20 -- version 3.1, as published by the Free Software Foundation.               --
  21 --                                                                          --
  22 -- You should have received a copy of the GNU General Public License and    --
  23 -- a copy of the GCC Runtime Library Exception along with this program;     --
  24 -- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
  25 -- <http://www.gnu.org/licenses/>.                                          --
  26 --                                                                          --
  27 -- GNARL was developed by the GNARL team at Florida State University.       --
  28 -- Extensive contributions were provided by Ada Core Technologies, Inc.     --
  29 --                                                                          --
  30 ------------------------------------------------------------------------------
  31
  32 --  This is a Solaris version of this package
  33
  34 --  This package provides low-level support for most tasking features
  35
  36 with Ada.Unchecked_Conversion;
  37
  38 with System.OS_Interface;
  39
  40 package System.Task_Primitives is
  41    pragma Preelaborate;
  42
  43    type Lock is limited private;
  44    type Lock_Ptr is access all Lock;
  45    --  Should be used for implementation of protected objects
  46
  47    type RTS_Lock is limited private;
  48    type RTS_Lock_Ptr is access all RTS_Lock;
  49    --  Should be used inside the runtime system. The difference between Lock
  50    --  and the RTS_Lock is that the later one serves only as a semaphore so
  51    --  that do not check for ceiling violations.
  52
  53    function To_Lock_Ptr is
  54      new Ada.Unchecked_Conversion (RTS_Lock_Ptr, Lock_Ptr);
  55
  56    type Suspension_Object is limited private;
  57    --  Should be used for the implementation of Ada.Synchronous_Task_Control
  58
  59    type Task_Body_Access is access procedure;
  60    --  Pointer to the task body's entry point (or possibly a wrapper
  61    --  declared local to the GNARL).
  62
  63    type Private_Data is limited private;
  64    --  Any information that the GNULLI needs maintained on a per-task basis.
  65    --  A component of this type is guaranteed to be included in the
  66    --  Ada_Task_Control_Block.
  67
  68    subtype Task_Address is System.Address;
  69    Task_Address_Size : constant := Standard'Address_Size;
  70    --  Type used for task addresses and its size
  71
  72    Alternate_Stack_Size : constant := 0;
  73    --  No alternate signal stack is used on this platform
  74
  75 private
  76
  77    type Private_Task_Serial_Number is mod 2 ** Long_Long_Integer'Size;
  78    --  Used to give each task a unique serial number
  79
  80    type Base_Lock is new System.OS_Interface.mutex_t;
  81
  82    type Owner_Int is new Integer;
  83    for Owner_Int'Alignment use Standard'Maximum_Alignment;
  84
  85    type Owner_ID is access all Owner_Int;
  86
  87    function To_Owner_ID is
  88      new Ada.Unchecked_Conversion (System.Address, Owner_ID);
  89
  90    type Lock is record
  91       L              : aliased Base_Lock;
  92       Ceiling        : System.Any_Priority := System.Any_Priority'First;
  93       Saved_Priority : System.Any_Priority := System.Any_Priority'First;
  94       Owner          : Owner_ID;
  95       Next           : Lock_Ptr;
  96       Level          : Private_Task_Serial_Number := 0;
  97       Buddy          : Owner_ID;
  98       Frozen         : Boolean := False;
  99    end record;
 100
 101    type RTS_Lock is new Lock;
 102
 103    type Suspension_Object is record
 104       State : Boolean;
 105       pragma Atomic (State);
 106       --  Boolean that indicates whether the object is open. This field is
 107       --  marked Atomic to ensure that we can read its value without locking
 108       --  the access to the Suspension_Object.
 109
 110       Waiting : Boolean;
 111       --  Flag showing if there is a task already suspended on this object
 112
 113       L : aliased System.OS_Interface.mutex_t;
 114       --  Protection for ensuring mutual exclusion on the Suspension_Object
 115
 116       CV : aliased System.OS_Interface.cond_t;
 117       --  Condition variable used to queue threads until condition is signaled
 118    end record;
 119
 120    --  Note that task support on gdb relies on the fact that the first two
 121    --  fields of Private_Data are Thread and LWP.
 122
 123    type Private_Data is limited record
 124       Thread : aliased System.OS_Interface.thread_t;
 125       pragma Atomic (Thread);
 126       --  Thread field may be updated by two different threads of control.
 127       --  (See, Enter_Task and Create_Task in s-taprop.adb). They put the same
 128       --  value (thr_self value). We do not want to use lock on those
 129       --  operations and the only thing we have to make sure is that they are
 130       --  updated in atomic fashion.
 131
 132       LWP : System.OS_Interface.lwpid_t;
 133       --  The LWP id of the thread. Set by self in Enter_Task
 134
 135       CV : aliased System.OS_Interface.cond_t;
 136       L  : aliased RTS_Lock;
 137       --  Protection for all components is lock L
 138
 139       Active_Priority : System.Any_Priority := System.Any_Priority'First;
 140       --  Simulated active priority, used iff Priority_Ceiling_Support is True
 141
 142       Locking : Lock_Ptr;
 143       Locks   : Lock_Ptr;
 144       Wakeups : Natural := 0;
 145    end record;
 146
 147 end System.Task_Primitives;