libjava/configure.ac

   1 dnl # Process this with autoconf to create configure
   2 AC_PREREQ(2.59)
   3 # Still use "libjava" here to placate dejagnu.
   4 AC_INIT([libjava], [version-unused],, [libjava])
   5
   6 AC_CONFIG_SRCDIR(java/lang/System.java)
   7
   8 GCC_TOPLEV_SUBDIRS
   9
  10 # We use these options to decide which functions to include.
  11 AC_ARG_WITH(target-subdir,
  12   AS_HELP_STRING([--with-target-subdir=SUBDIR],
  13                  [configure in a subdirectory]))
  14
  15 # We may get other options which we don't document:
  16 # --with-target-subdir, --with-multisrctop, --with-multisubdir
  17
  18 # When building with srcdir == objdir, links to the source files will
  19 # be created in directories within the target_subdir.  We have to
  20 # adjust toplevel_srcdir accordingly, so that configure finds
  21 # install-sh and other auxiliary files that live in the top-level
  22 # source directory.
  23 if test "${srcdir}" = "."; then
  24   if test -z "${with_target_subdir}"; then
  25     toprel=".."
  26   else
  27     if test "${with_target_subdir}" != "."; then
  28       toprel="${with_multisrctop}../.."
  29     else
  30       toprel="${with_multisrctop}.."
  31     fi
  32   fi
  33 else
  34   toprel=".."
  35 fi
  36
  37 libgcj_basedir=$srcdir/$toprel/./libjava
  38 AC_SUBST(libgcj_basedir)
  39
  40 AC_CANONICAL_SYSTEM
  41 _GCC_TOPLEV_NONCANONICAL_BUILD
  42 _GCC_TOPLEV_NONCANONICAL_TARGET
  43
  44 AC_SUBST(target_noncanonical)
  45
  46 # This works around the fact that libtool configuration may change LD
  47 # for this particular configuration, but some shells, instead of
  48 # keeping the changes in LD private, export them just because LD is
  49 # exported.
  50 ORIGINAL_LD_FOR_MULTILIBS=$LD
  51
  52 AC_PROG_LN_S
  53
  54 # This works around an automake problem.
  55 mkinstalldirs="`cd $ac_aux_dir && ${PWDCMD-pwd}`/mkinstalldirs"
  56 AC_SUBST(mkinstalldirs)
  57
  58 AC_ARG_WITH(cross-host,
  59   AS_HELP_STRING([--with-cross-host=HOST],
  60                  [configure with a cross compiler from HOST]))
  61
  62 AC_ARG_WITH(newlib,
  63   AS_HELP_STRING([--with-newlib],
  64                  [configure with newlib]))
  65
  66 AC_ARG_ENABLE(version-specific-runtime-libs,
  67   AS_HELP_STRING([--enable-version-specific-runtime-libs],
  68                  [specify that runtime libraries should be installed in a compiler-specific directory]),
  69     [case "$enableval" in
  70       yes) version_specific_libs=yes ;;
  71       no)  version_specific_libs=no ;;
  72       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  73      esac],
  74     [version_specific_libs=no]
  75 )
  76
  77 # Default to --enable-multilib
  78 AC_ARG_ENABLE(multilib,
  79   AS_HELP_STRING([--enable-multilib],
  80                  [build many library versions (default)]),
  81 [case "${enableval}" in
  82   yes) multilib=yes ;;
  83   no)  multilib=no ;;
  84   *)   AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
  85  esac], [multilib=yes])dnl
  86
  87 # It may not be safe to run linking tests in AC_PROG_CC/AC_PROG_CXX.
  88 GCC_NO_EXECUTABLES
  89
  90 # (1) We use an abnormal CXX (without library references), so we
  91 # must cache it under a different name.
  92 # (2) CC, CFLAGS, CXX, CXXFLAGS, LDFLAGS must not be 'precious', or
  93 # the non-multilib-adjusted value will be used in multilibs.
  94 # (3) As a side effect, we must SUBST CXXFLAGS, CFLAGS, and LDFLAGS ourselves.
  95 # (4) As another side effect, automake doesn't automatically include them
  96 # in Makefile.in.
  97 # (5) For libstdc++-v3, -fno-builtin must be present here so that a
  98 # non-conflicting form of std::exit can be guessed by AC_PROG_CXX, and
  99 # used in later tests.  This may not be necessary in libjava; I don't know.
 100 m4_define([ac_cv_prog_CXX],[glibcxx_cv_prog_CXX])
 101 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
 102 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 103 save_CXXFLAGS="$CXXFLAGS"
 104 CXXFLAGS="$CXXFLAGS -fno-builtin"
 105 AC_PROG_CC
 106 AC_PROG_CXX
 107 CXXFLAGS="$save_CXXFLAGS"
 108 m4_rename([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 109 AC_SUBST(CFLAGS)
 110 AC_SUBST(CXXFLAGS)
 111 AC_SUBST(LDFLAGS)
 112
 113 AM_INIT_AUTOMAKE([1.9.0])
 114
 115 AC_CHECK_TOOL(AS, as)
 116 AC_CHECK_TOOL(AR, ar)
 117 AC_CHECK_TOOL(RANLIB, ranlib, :)
 118
 119 AC_PROG_INSTALL
 120
 121 AM_MAINTAINER_MODE
 122
 123 AC_EXEEXT
 124
 125 # configure.host sets the following important variables
 126 #       libgcj_cflags    - host specific C compiler flags
 127 #       libgcj_cxxflags  - host specific C++ compiler flags
 128 #       libgcj_javaflags - host specific Java compiler flags
 129
 130 libgcj_cflags=
 131 libgcj_cxxflags=
 132 libgcj_javaflags=
 133
 134 . ${srcdir}/configure.host
 135
 136 LIBGCJ_CFLAGS="${libgcj_cflags}"
 137 LIBGCJ_CXXFLAGS="${libgcj_cxxflags}"
 138 LIBGCJ_JAVAFLAGS="${libgcj_javaflags}"
 139 LIBGCJ_LD_SYMBOLIC="${libgcj_ld_symbolic}"
 140 AC_SUBST(LIBGCJ_CFLAGS)
 141 AC_SUBST(LIBGCJ_CXXFLAGS)
 142 AC_SUBST(LIBGCJ_JAVAFLAGS)
 143 AC_SUBST(LIBGCJ_LD_SYMBOLIC)
 144
 145 # Only use libltdl for non-newlib builds.
 146 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 147    AC_LTDL_SHLIBPATH
 148 fi
 149
 150 AC_CONFIG_HEADERS([include/config.h gcj/libgcj-config.h])
 151
 152 # See if the user has requested runtime debugging.
 153 LIBGCJDEBUG="disable"
 154 AC_SUBST(LIBGCJDEBUG)
 155 AC_ARG_ENABLE(libgcj-debug,
 156   AS_HELP_STRING([--enable-libgcj-debug],
 157                  [enable runtime debugging code]),
 158   [if test "$enable_libgcj_debug" = yes; then
 159     AC_DEFINE(DEBUG, 1, [Define this if you want runtime debugging enabled.])
 160     LIBGCJDEBUG="enable"
 161   fi])
 162
 163 # Determine which AWT peer libraries to build
 164 AC_ARG_ENABLE(java-awt,
 165   AS_HELP_STRING([--enable-java-awt],
 166                  [list of AWT peer implementations to be built]))
 167
 168 peerlibs="`echo ${enable_java_awt} | tr ',' ' '`"
 169 use_xlib_awt=""
 170 use_gtk_awt=""
 171 # The default toolkit to use is the first one specified.
 172 TOOLKIT=
 173 AC_SUBST(TOOLKIT)
 174
 175 for peer in $peerlibs ; do
 176   case $peer in
 177     xlib)
 178       if test "$no_x" = yes; then
 179         echo "*** xlib peers requested but no X library available" 1>&2
 180         exit 1
 181       else
 182         use_xlib_awt="yes"
 183         if test -z "$TOOLKIT"; then
 184            TOOLKIT=gnu.awt.xlib.XToolkit
 185         fi
 186       fi
 187       ;;
 188     gtk)
 189       if test "$no_x" = yes; then
 190          echo "*** xlib peers requested but no X library available" 1>&2
 191          exit 1
 192       else
 193          use_gtk_awt=yes
 194          if test -z "$TOOLKIT"; then
 195             TOOLKIT=gnu.java.awt.peer.gtk.GtkToolkit
 196          fi
 197       fi
 198       ;;
 199     no)
 200       use_xlib_awt=
 201       use_gtk_awt=
 202       break
 203       ;;
 204     *)
 205       echo "*** unrecognised argument \"${peer}\" for --enable-java-awt" 1>&2
 206       exit 1
 207   esac
 208 done
 209
 210 AM_CONDITIONAL(XLIB_AWT, test "$use_xlib_awt" = yes)
 211 AM_CONDITIONAL(GTK_AWT, test "$use_gtk_awt" = yes)
 212
 213 # Create standard.omit based on decisions we just made.
 214 cp $srcdir/standard.omit.in standard.omit
 215 if test "$use_xlib_awt" != yes; then
 216    echo gnu/awt/xlib >> standard.omit
 217    echo gnu/gcj/xlib >> standard.omit
 218 fi
 219 if test "$use_gtk_awt" != yes; then
 220    echo gnu/java/awt/peer/gtk >> standard.omit
 221 fi
 222
 223 if test -z "${with_multisubdir}"; then
 224    builddotdot=.
 225 else
 226    builddotdot=`echo ${with_multisubdir} | sed -e 's:[[^/]][[^/]]*:..:g'`
 227 fi
 228
 229 NATIVE=yes
 230
 231 # Which gcj do we use?
 232 which_gcj=default
 233 built_gcc_dir="`cd ${builddotdot}/../../${host_subdir}/gcc && ${PWDCMD-pwd}`"
 234 if test -n "${with_cross_host}"; then
 235   # We are being configured with a cross compiler. We can't
 236   # use ac_exeext, because that is for the target platform.
 237   NATIVE=no
 238   cross_host_exeext=
 239   case "${with_cross_host}" in
 240      *mingw* | *cygwin*)
 241          cross_host_exeext=.exe
 242      ;;
 243   esac
 244   if test -x "${built_gcc_dir}/gcj${cross_host_exeext}"; then
 245      if test x"$build_noncanonical" = x"$with_cross_host"; then
 246         # Ordinary cross (host!=target and host=build)
 247         which_gcj=built
 248      else
 249         # Canadian cross (host!=target and host!=build)
 250         which_gcj=cross
 251      fi
 252   else
 253      which_gcj=cross
 254   fi
 255 else
 256   # We are being configured with a native or crossed-native compiler
 257   if test -x "${built_gcc_dir}/gcj${ac_exeext}"; then
 258      if test x"$build" = x"$host"; then
 259         # True native build (host=target and host=build)
 260         which_gcj=built
 261      else
 262         # Crossed-native build (host=target and host!=build)
 263         which_gcj=cross
 264      fi
 265   else
 266      which_gcj=path
 267   fi
 268 fi
 269 case "${which_gcj}" in
 270    built)
 271       GCJ="$built_gcc_dir/gcj -B`${PWDCMD-pwd}`/ -B$built_gcc_dir/"
 272       GCJH='$(top_builddir)/$(MULTIBUILDTOP)../../$(host_subdir)/gcc/gcjh'
 273       ZIP='$(top_builddir)/$(MULTIBUILDTOP)../../$(host_subdir)/fastjar/fastjar'
 274    ;;
 275    cross)
 276       if test "x${with_newlib}" = "xyes"; then
 277          # FIXME (comment): Why is this needed?
 278          GCC_UNWIND_INCLUDE=
 279          GCJ="${target_noncanonical}-gcj"
 280       else
 281          GCJ="${target_noncanonical}-gcj -B`${PWDCMD-pwd}`/"
 282       fi
 283       ZIP='$(target_noncanonical)-fastjar'
 284       GCJH='$(target_noncanonical)-gcjh'
 285    ;;
 286    path)
 287       GCJ="gcj -B`${PWDCMD-pwd}`/"
 288       ## In this case, gcj is found outside the build tree.  However, zip is
 289       ## found in the build tree.
 290       ZIP='$(top_builddir)/$(MULTIBUILDTOP)../$(COMPPATH)/fastjar/fastjar'
 291       GCJH=gcjh
 292    ;;
 293 esac
 294
 295 AC_SUBST(GCJH)
 296 AC_SUBST(ZIP)
 297
 298 # Create it, so that compile/link tests don't fail
 299 test -f libgcj.spec || touch libgcj.spec
 300
 301
 302
 303 # Set up to configure Classpath.
 304 # FIXME: no supported way to pass args in autoconf.
 305 ac_configure_args="$ac_configure_args --disable-load-library"
 306 ac_configure_args="$ac_configure_args --${LIBGCJDEBUG}-debug"
 307 ac_configure_args="$ac_configure_args --enable-default-toolkit=$TOOLKIT"
 308 dir1=`cd $srcdir && pwd`
 309 dir2=`pwd`
 310 ac_configure_args="$ac_configure_args --with-vm-classes=$dir1:$dir2"
 311 ac_configure_args="$ac_configure_args --disable-core-jni"
 312 dnl FIXME?
 313 ac_configure_args="$ac_configure_args --disable-examples"
 314 ac_configure_args="$ac_configure_args --with-glibj=build"
 315 if test "$use_gtk_awt" != yes; then
 316   ac_configure_args="$ac_configure_args --disable-gtk-peer"
 317 fi
 318 dnl --with-gcj=$GCJ
 319 dnl --with-javah=$GCJH
 320 dnl gjdoc?
 321 dnl gtk-cairo -- just export here...
 322 dnl --enable-regen-headers?
 323
 324 # Only use libltdl for non-newlib builds.
 325 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 326    AC_LIBLTDL_CONVENIENCE
 327    AC_LIBTOOL_DLOPEN
 328    DIRLTDL=libltdl
 329    AC_DEFINE(USE_LTDL, 1, [Define if libltdl is in use.])
 330    # Sigh.  Libtool's macro doesn't do the right thing.
 331    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
 332    # FIXME: this is a hack.
 333    sub_auxdir="`cd $ac_aux_dir && ${PWDCMD-pwd}`"
 334    ac_configure_args="$ac_configure_args --with-auxdir=$sub_auxdir"
 335 fi
 336 AC_SUBST(INCLTDL)
 337 AC_SUBST(LIBLTDL)
 338 AC_SUBST(DIRLTDL)
 339 AC_PROG_LIBTOOL
 340 AM_PROG_GCJ
 341 AM_PROG_CC_C_O
 342
 343 AC_CONFIG_SUBDIRS(classpath libltdl)
 344
 345 # The -no-testsuite modules omit the test subdir.
 346 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
 347
 348 # Should the runtime set system properties by examining the
 349 # environment variable GCJ_PROPERTIES?
 350 AC_ARG_ENABLE(getenv-properties,
 351   AS_HELP_STRING([--disable-getenv-properties],
 352                  [don't set system properties from GCJ_PROPERTIES]))
 353
 354 # Whether GCJ_PROPERTIES is used depends on the target.
 355 if test -z "$enable_getenv_properties"; then
 356    enable_getenv_properties=${enable_getenv_properties_default-yes}
 357 fi
 358 if test "$enable_getenv_properties" = no; then
 359    AC_DEFINE(DISABLE_GETENV_PROPERTIES, 1,
 360      [Define if system properties shouldn't be read from getenv("GCJ_PROPERTIES").])
 361 fi
 362
 363 # Whether we should use arguments to main()
 364 if test -z "$enable_main_args"; then
 365    enable_main_args=${enable_main_args_default-yes}
 366 fi
 367 if test "$enable_main_args" = no; then
 368    AC_DEFINE(DISABLE_MAIN_ARGS, 1, [Define if we should ignore arguments to main().])
 369 fi
 370
 371
 372 # Should we use hashtable-based synchronization?
 373 # Currently works only for Linux X86/ia64
 374 # Typically faster and more space-efficient
 375 AC_ARG_ENABLE(hash-synchronization,
 376   AS_HELP_STRING([--enable-hash-synchronization],
 377                  [use global hash table for monitor locks]))
 378
 379 if test -z "$enable_hash_synchronization"; then
 380    enable_hash_synchronization=$enable_hash_synchronization_default
 381 fi
 382
 383 AC_ARG_WITH(java-home,
 384   AS_HELP_STRING([--with-java-home=DIRECTORY],
 385                  [value of java.home system property]),
 386                  [JAVA_HOME="${withval}"], [JAVA_HOME=""])
 387 AM_CONDITIONAL(JAVA_HOME_SET, test ! -z "$JAVA_HOME")
 388 AC_SUBST(JAVA_HOME)
 389
 390 # What is the native OS API for MinGW?
 391 AC_ARG_WITH(win32-nlsapi,
 392   AS_HELP_STRING([--with-win32-nlsapi=ansi or unicows or unicode],
 393                  [native MinGW libgcj Win32 OS API (default is ansi)]),
 394 [case "${withval}" in
 395   ansi) with_win32_nlsapi=ansi ;;
 396   unicows) with_win32_nlsapi=unicows ;;
 397   unicode) with_win32_nlsapi=unicode ;;
 398   *) AC_MSG_ERROR(Bad value ${withval} for --with-win32-nlsapi.) ;;
 399 esac],[with_win32_nlsapi=ansi])
 400
 401 case "${with_win32_nlsapi}" in
 402   unicows | unicode)
 403     AC_DEFINE(MINGW_LIBGCJ_UNICODE, 1,
 404       [Define if MinGW libgcj uses the Windows UNICODE OS API.])
 405     ;;
 406 esac
 407
 408 # configure.host sets slow_pthread_self if the synchronization code should
 409 # try to avoid pthread_self calls by caching thread IDs in a hashtable.
 410 if test "${slow_pthread_self}" = "yes"; then
 411   AC_DEFINE(SLOW_PTHREAD_SELF, 1,
 412     [Define if if the synchronization code should try to avoid pthread_self calls by caching thread IDs in a hashtable.])
 413 fi
 414
 415 # Check for gc debugging.  This option is handled both here and in the GC.
 416 AC_ARG_ENABLE(gc-debug,
 417    AS_HELP_STRING([--enable-gc-debug],
 418                   [include full support for pointer backtracing etc.]),
 419 [ if test "$enable_gc_debug" = "yes"; then
 420     AC_DEFINE(LIBGCJ_GC_DEBUG, 1,
 421               [Define if we want to use debug calls into the garbage collector.])
 422   fi])
 423
 424 # See if the user has the interpreter included.
 425 AC_ARG_ENABLE(interpreter,
 426   AS_HELP_STRING([--enable-interpreter],
 427                  [enable interpreter]),
 428   [if test "$enable_interpreter" = yes; then
 429     # This can also be set in configure.host.
 430     libgcj_interpreter=yes
 431   elif test "$enable_interpreter" = no; then
 432     libgcj_interpreter=no
 433   fi])
 434
 435 if test "$libgcj_interpreter" = yes; then
 436    AC_DEFINE(INTERPRETER, 1, [Define if you want a bytecode interpreter.])
 437 fi
 438 INTERPRETER="$libgcj_interpreter"
 439 AC_SUBST(INTERPRETER)
 440
 441 AC_MSG_CHECKING([for exception model to use])
 442 AC_LANG_PUSH(C++)
 443 AC_ARG_ENABLE(sjlj-exceptions,
 444   AS_HELP_STRING([--enable-sjlj-exceptions],
 445                  [force use of builtin_setjmp for exceptions]),
 446 [:],
 447 [dnl Botheration.  Now we've got to detect the exception model.
 448 dnl Link tests against libgcc.a are problematic since -- at least
 449 dnl as of this writing -- we've not been given proper -L bits for
 450 dnl single-tree newlib and libgloss.
 451 dnl
 452 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 453 dnl conftest files before we got a change to grep them first.
 454 cat > conftest.$ac_ext << EOF
 455 [#]line __oline__ "configure"
 456 struct S { ~S(); };
 457 void bar();
 458 void foo()
 459 {
 460   S s;
 461   bar();
 462 }
 463 EOF
 464 old_CXXFLAGS="$CXXFLAGS"
 465 CXXFLAGS=-S
 466 if AC_TRY_EVAL(ac_compile); then
 467   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 468     enable_sjlj_exceptions=yes
 469   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 470     enable_sjlj_exceptions=no
 471   fi
 472 fi
 473 CXXFLAGS="$old_CXXFLAGS"
 474 rm -f conftest*])
 475 if test x$enable_sjlj_exceptions = xyes; then
 476   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 477         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 478   ac_exception_model_name=sjlj
 479 elif test x$enable_sjlj_exceptions = xno; then
 480   ac_exception_model_name="call frame"
 481 else
 482   AC_MSG_ERROR([unable to detect exception model])
 483 fi
 484 AC_LANG_POP(C++)
 485 AC_MSG_RESULT($ac_exception_model_name)
 486
 487 # If we are non using SJLJ exceptions, and this host does not have support
 488 # for unwinding from a signal handler, enable checked dereferences and divides.
 489 if test $can_unwind_signal = no && test $enable_sjlj_exceptions = no; then
 490   CHECKREFSPEC=-fcheck-references
 491   DIVIDESPEC=-fuse-divide-subroutine
 492   EXCEPTIONSPEC=
 493 fi
 494
 495 # See if the user wants to disable java.net.  This is the mildly
 496 # ugly way that we admit that target-side configuration sucks.
 497 AC_ARG_ENABLE(java-net,
 498   AS_HELP_STRING([--disable-java-net],
 499                  [disable java.net]))
 500
 501 # Whether java.net is built by default can depend on the target.
 502 if test -z "$enable_java_net"; then
 503    enable_java_net=${enable_java_net_default-yes}
 504 fi
 505 if test "$enable_java_net" = no; then
 506    AC_DEFINE(DISABLE_JAVA_NET, 1, [Define if java.net native functions should be stubbed out.])
 507 fi
 508
 509 # See if the user wants to configure without libffi.  Some
 510 # architectures don't support it, and default values are set in
 511 # configure.host.
 512 AC_ARG_WITH(libffi,
 513   AS_HELP_STRING([--without-libffi],
 514                  [don't use libffi]),
 515   [:],
 516   [with_libffi=${with_libffi_default-yes}])
 517
 518 LIBFFI=
 519 LIBFFIINCS=
 520 if test "$with_libffi" != no; then
 521    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 522    LIBFFI=../libffi/libffi_convenience.la
 523    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 524 fi
 525 AC_SUBST(LIBFFI)
 526 AC_SUBST(LIBFFIINCS)
 527
 528 # See if the user wants to disable JVMPI support.
 529 AC_ARG_ENABLE(jvmpi,
 530   AS_HELP_STRING([--disable-jvmpi],
 531                  [disable JVMPI support]))
 532
 533 if test "$enable_jvmpi" != no; then
 534     AC_DEFINE(ENABLE_JVMPI, 1, [Define if you are using JVMPI.])
 535 fi
 536
 537 # If the target is an eCos system, use the appropriate eCos
 538 # I/O routines.
 539 # FIXME: this should not be a local option but a global target
 540 # system; at present there is no eCos target.
 541 TARGET_ECOS=${PROCESS-"no"}
 542 AC_ARG_WITH(ecos,
 543 [  --with-ecos             enable runtime eCos target support],
 544 TARGET_ECOS="$with_ecos"
 545 )
 546
 547 supply_backtrace=no
 548
 549 PLATFORM_INNER_NAT_HDRS=
 550 case "$TARGET_ECOS" in
 551    no) case "$host" in
 552       *mingw*)
 553             PLATFORM=Win32
 554             PLATFORMNET=Win32
 555             PLATFORMH=win32.h
 556         CHECK_FOR_BROKEN_MINGW_LD
 557       ;;
 558       *)
 559             PLATFORM=Posix
 560             PLATFORMNET=Posix
 561             PLATFORMH=posix.h
 562             PLATFORM_INNER_NAT_HDRS='java/lang/ConcreteProcess$$ProcessManager.h'
 563       ;;
 564       esac
 565       ;;
 566    *)
 567       PLATFORM=Ecos
 568       PLATFORMNET=NoNet
 569       AC_DEFINE(ECOS, 1, [Define if you're running eCos.])
 570       PLATFORMH=posix.h
 571       ;;
 572 esac
 573 AC_SUBST(PLATFORM_INNER_NAT_HDRS)
 574 AC_CONFIG_LINKS(include/platform.h:include/$PLATFORMH)
 575
 576 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 577                                       [Define if you have int32_t and uint32_t.]))
 578 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 579                                         [Define if you have int32_t and uint32_t.]))
 580 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 581                                           [Define if you have u_int32_t]))
 582 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 583                                            [Define if you have u_int32_t]))
 584
 585 AM_CONDITIONAL(USING_WIN32_PLATFORM, test "$PLATFORM" = Win32)
 586 AM_CONDITIONAL(USING_POSIX_PLATFORM, test "$PLATFORM" = Posix || test "$PLATFORM" = Ecos)
 587
 588 case "$host" in
 589   *-darwin*) DARWIN_CRT=true ;;
 590   *) DARWIN_CRT=false ;;
 591 esac
 592 AM_CONDITIONAL(USING_DARWIN_CRT, $DARWIN_CRT)
 593
 594 # These may not be defined in a non-ANS conformant embedded system.
 595 # FIXME: Should these case a runtime exception in that case?
 596 AC_EGREP_HEADER(mktime, time.h, AC_DEFINE(HAVE_MKTIME, 1,
 597                                   [Define is you have 'mktime' in <time.h>]))
 598 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME, 1,
 599                                   [Define is you have 'localtime' in <time.h>]))
 600
 601 # Create the subdirectory for natFile.cc, or the attempt
 602 # to create the link will fail.
 603 test -d java || mkdir java
 604 test -d java/io || mkdir java/io
 605 test -d gnu || mkdir gnu
 606 AC_CONFIG_LINKS(java/io/natFile.cc:java/io/natFile${FILE-${PLATFORM}}.cc)
 607
 608 # Likewise for ConcreteProcess.java and natConcreteProcess.cc.
 609 test -d java/lang || mkdir java/lang
 610 AC_CONFIG_LINKS(java/lang/ConcreteProcess.java:java/lang/${PLATFORM}Process.java)
 611 AC_CONFIG_LINKS(java/lang/natConcreteProcess.cc:java/lang/nat${PLATFORM}Process.cc)
 612
 613 # Likewise for natInetAddress.cc and natVMNetworkInterface.cc.
 614 test -d java/net || mkdir java/net
 615 AC_CONFIG_LINKS(java/net/natInetAddress.cc:java/net/natInetAddress${PLATFORMNET}.cc)
 616 AC_CONFIG_LINKS(java/net/natVMNetworkInterface.cc:java/net/natVMNetworkInterface${PLATFORMNET}.cc)
 617
 618 # Likewise for natPlainSocketImpl.cc and natPlainDatagramSocketImpl.cc.
 619 test -d gnu/java || mkdir gnu/java
 620 test -d gnu/java/net || mkdir gnu/java/net
 621 AC_CONFIG_LINKS(gnu/java/net/natPlainSocketImpl.cc:gnu/java/net/natPlainSocketImpl${PLATFORMNET}.cc)
 622 AC_CONFIG_LINKS(gnu/java/net/natPlainDatagramSocketImpl.cc:gnu/java/net/natPlainDatagramSocketImpl${PLATFORMNET}.cc)
 623
 624 # Likewise for natPipeImpl.cc and natSelectorImpl.cc.
 625 test -d gnu/java/nio || mkdir gnu/java/nio
 626 AC_CONFIG_LINKS(gnu/java/nio/natPipeImpl.cc:gnu/java/nio/natPipeImpl${PLATFORM}.cc)
 627 AC_CONFIG_LINKS(gnu/java/nio/natSelectorImpl.cc:gnu/java/nio/natSelectorImpl${PLATFORM}.cc)
 628 test -d gnu/java/nio/channels || mkdir gnu/java/nio/channels
 629 AC_CONFIG_LINKS(gnu/java/nio/channels/natFileChannelImpl.cc:gnu/java/nio/channels/natFileChannel${FILE-${PLATFORM}}.cc)
 630
 631 case "${host}" in
 632     *mingw*)
 633       SYSTEMSPEC="-lgdi32 -lws2_32"
 634       if test "${with_win32_nlsapi}" = "unicows"; then
 635         SYSTEMSPEC="-lunicows $SYSTEMSPEC"
 636       fi
 637     ;;
 638     *)
 639       SYSTEMSPEC=
 640     ;;
 641 esac
 642 AC_SUBST(SYSTEMSPEC)
 643
 644 LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -rpath `${PWDCMD-pwd}`/.libs"
 645 AC_SUBST(LIBGCJTESTSPEC)
 646
 647 AC_ARG_WITH(system-zlib,
 648   AS_HELP_STRING([--with-system-zlib],
 649                  [use installed libz]))
 650 ZLIBSPEC=
 651 AC_SUBST(ZLIBSPEC)
 652 ZLIBTESTSPEC=
 653 AC_SUBST(ZLIBTESTSPEC)
 654
 655 AC_PATH_XTRA
 656
 657 # determine whether to enable the cairo GTK Graphics2D backend
 658 AC_ARG_ENABLE(gtk-cairo,
 659   AS_HELP_STRING([--enable-gtk-cairo],
 660                  [build the cairo Graphics2D implementation on GTK]))
 661 AM_CONDITIONAL(GTK_CAIRO, test "x${enable_gtk_cairo}" = xyes)
 662 if test "x${enable_gtk_cairo}" = xyes
 663 then
 664         PKG_CHECK_MODULES(CAIRO, cairo)
 665         PKG_CHECK_MODULES(PANGOFT2, pangoft2)
 666 fi
 667 AC_SUBST(CAIRO_LIBS)
 668 AC_SUBST(CAIRO_CFLAGS)
 669 AC_SUBST(PANGOFT2_LIBS)
 670 AC_SUBST(PANGOFT2_CFLAGS)
 671
 672 # FIXME: this should be _libs on some hosts.
 673 libsubdir=.libs
 674
 675 # extra LD Flags which are required for targets
 676 case "${host}" in
 677 *-*-darwin[[0-7]].*)
 678     # For now we have to disable it on darwin[8-9] because it slows down
 679     # the linking phase. A possible bug in ld?
 680     # on Darwin -single_module speeds up loading of the dynamic libraries.
 681     extra_ldflags_libjava=-Wl,-single_module
 682     ;;
 683 esac
 684 AC_SUBST(extra_ldflags_libjava)
 685
 686 # Allow the GC to be disabled.  Can be useful when debugging.
 687 AC_MSG_CHECKING([for garbage collector to use])
 688 AC_ARG_ENABLE(java-gc,
 689   AS_HELP_STRING([--enable-java-gc=TYPE],
 690                  [choose garbage collector (default is boehm)]),
 691   [GC=$enableval],
 692   [GC=boehm])
 693 GCLIBS=
 694 GCINCS=
 695 GCDEPS=
 696 GCSPEC=
 697 JC1GCSPEC=
 698 GCTESTSPEC=
 699 case "$GC" in
 700  boehm)
 701     AC_MSG_RESULT(boehm)
 702     GCLIBS=../boehm-gc/libgcjgc_convenience.la
 703     JC1GCSPEC='-fuse-boehm-gc'
 704     GCTESTSPEC="-L`${PWDCMD-pwd}`/../boehm-gc/.libs -rpath `${PWDCMD-pwd}`/../boehm-gc/.libs"
 705     GCINCS='-I$(top_srcdir)/../boehm-gc/include -I../boehm-gc/include'
 706     GCOBJS=boehm.lo
 707     GCHDR=boehm-gc.h
 708     # The POSIX thread support needs to know this.
 709     AC_DEFINE(HAVE_BOEHM_GC, 1, [Define if Boehm GC in use.])
 710     ;;
 711  no)
 712     AC_MSG_RESULT(none)
 713     GCHDR=no-gc.h
 714     ;;
 715  *)
 716     AC_MSG_ERROR([unrecognized collector "$GC"])
 717     ;;
 718 esac
 719 AC_SUBST(GCLIBS)
 720 AC_SUBST(GCINCS)
 721 AC_SUBST(GCDEPS)
 722 AC_SUBST(GCSPEC)
 723 AC_SUBST(JC1GCSPEC)
 724 AC_SUBST(GCTESTSPEC)
 725 AC_CONFIG_LINKS(include/java-gc.h:include/$GCHDR)
 726 AM_CONDITIONAL(USING_BOEHMGC, test "$GC" = boehm)
 727 AM_CONDITIONAL(USING_NOGC, test "$GC" = no)
 728
 729
 730 AC_MSG_CHECKING([for thread model used by GCC])
 731 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 732 AC_MSG_RESULT([$THREADS])
 733
 734 case "$THREADS" in
 735  no | none | single)
 736     THREADS=none
 737     ;;
 738  posix | posix95 | pthreads)
 739     THREADS=posix
 740     case "$host" in
 741      *-*-linux*)
 742         AC_DEFINE(LINUX_THREADS, 1, [Define if using POSIX threads on Linux.])
 743         ;;
 744     esac
 745     ;;
 746  win32)
 747     ;;
 748  decosf1 | irix | mach | os2 | solaris | dce | vxworks)
 749     AC_MSG_ERROR(thread package $THREADS not yet supported)
 750     ;;
 751  *)
 752     AC_MSG_ERROR($THREADS is an unknown thread package)
 753     ;;
 754 esac
 755
 756 THREADCXXFLAGS=
 757 THREADLDFLAGS=
 758 THREADLIBS=
 759 THREADINCS=
 760 THREADDEPS=
 761 THREADH=
 762 THREADSPEC=
 763 case "$THREADS" in
 764  posix)
 765     case "$host" in
 766      *-*-cygwin*)
 767         # Don't set THREADLIBS here.  Cygwin doesn't have -lpthread.
 768         ;;
 769      *-*-freebsd[[1234]]*)
 770         # Before FreeBSD 5, it didn't have -lpthread (or any library which
 771         # merely adds pthread_* functions) but it does have a -pthread switch
 772         # which is required at link-time to select -lc_r *instead* of -lc.
 773         THREADLDFLAGS=-pthread
 774         # Don't set THREADSPEC here as might be expected since -pthread is
 775         # not processed when found within a spec file, it must come from
 776         # the command line.  For now, the user must provide the -pthread
 777         # switch to link code compiled with gcj.  In future, consider adding
 778         # support for weak references to pthread_* functions ala gthr.h API.
 779         THREADSPEC='%{!pthread: %{!shared: %eUnder this configuration, the user must provide -pthread when linking.}}'
 780         ;;
 781      *-*-freebsd*)
 782         # FreeBSD 5 implements a model much closer to other modern UNIX
 783         # which support threads.  However, it still does not support
 784         # -lpthread.
 785         THREADLDFLAGS=-pthread
 786         THREADSPEC=-lc_r
 787         ;;
 788      alpha*-dec-osf*)
 789         THREADCXXFLAGS=-pthread
 790         # boehm-gc needs some functions from librt, so link that too.
 791         THREADLIBS='-lpthread -lrt'
 792         THREADSPEC='-lpthread -lrt'
 793         ;;
 794      *)
 795         THREADLIBS=-lpthread
 796         THREADSPEC=-lpthread
 797         ;;
 798     esac
 799     THREADH=posix-threads.h
 800     # MIT pthreads doesn't seem to have the mutexattr functions.
 801     # But for now we don't check for it.  We just assume you aren't
 802     # using MIT pthreads.
 803     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
 804
 805     # If we're using the Boehm GC, then we happen to know that it
 806     # defines _REENTRANT, so we don't bother.  Eww.
 807     if test "$GC" != boehm; then
 808        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 809     fi
 810     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
 811     ;;
 812
 813  win32)
 814     THREADH=win32-threads.h
 815     ;;
 816
 817  none)
 818     THREADH=no-threads.h
 819     ;;
 820 esac
 821 AC_CONFIG_LINKS(include/java-threads.h:include/$THREADH)
 822 AC_SUBST(THREADLIBS)
 823 AC_SUBST(THREADINCS)
 824 AC_SUBST(THREADDEPS)
 825 AC_SUBST(THREADSPEC)
 826 AC_SUBST(THREADLDFLAGS)
 827 AC_SUBST(THREADCXXFLAGS)
 828 AM_CONDITIONAL(USING_POSIX_THREADS, test "$THREADS" = posix)
 829 AM_CONDITIONAL(USING_WIN32_THREADS, test "$THREADS" = win32)
 830 AM_CONDITIONAL(USING_NO_THREADS, test "$THREADS" = none)
 831
 832 if test -d sysdep; then true; else mkdir sysdep; fi
 833 AC_CONFIG_LINKS(sysdep/locks.h:sysdep/$sysdeps_dir/locks.h)
 834 AC_CONFIG_LINKS(sysdep/backtrace.h:$fallback_backtrace_h)
 835 AC_CONFIG_LINKS(sysdep/descriptor.h:$descriptor_h)
 836
 837 HASH_SYNC_SPEC=
 838 # Hash synchronization is only useful with posix threads right now.
 839 if test "$enable_hash_synchronization" = yes && test "$THREADS" != "none"; then
 840    HASH_SYNC_SPEC=-fhash-synchronization
 841    AC_DEFINE(JV_HASH_SYNCHRONIZATION, 1, [Define if hash synchronization is in use])
 842 fi
 843 AC_SUBST(HASH_SYNC_SPEC)
 844
 845 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
 846
 847 # We're in the tree with gcc, and need to include some of its headers.
 848 GCC_UNWIND_INCLUDE='-I$(libgcj_basedir)/../gcc'
 849
 850 if test "x${with_newlib}" = "xyes"; then
 851    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
 852    # may not work correctly, because the compiler may not be able to
 853    # link executables.
 854
 855    # We assume newlib.  This lets us hard-code the functions we know
 856    # we'll have.
 857    AC_DEFINE(HAVE_MEMMOVE, 1, [Define if you have memmove.])
 858    AC_DEFINE(HAVE_MEMCPY, 1, [Define if you have memcpy.])
 859    AC_DEFINE(HAVE_STRERROR, 1, [Define if you have strerror.])
 860    AC_DEFINE(HAVE_TIME, 1, [Define if you have time.])
 861    AC_DEFINE(HAVE_GMTIME_R, 1, [Define if you have the 'gmtime_r' function])
 862    AC_DEFINE(HAVE_LOCALTIME_R, 1, [Define if you have the 'localtime_r' function.])
 863    AC_DEFINE(HAVE_USLEEP_DECL, 1, [Define if usleep is declared in <unistd.h>.])
 864    # This is only for POSIX threads.
 865    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
 866    # We also assume we are using gcc, which provides alloca.
 867    AC_DEFINE(HAVE_ALLOCA)
 868
 869    # Assume we do not have getuid and friends.
 870    AC_DEFINE(NO_GETUID, 1, [Define if getuid() and friends are missing.])
 871    PLATFORMNET=NoNet
 872 else
 873    AC_CHECK_FUNCS([strerror ioctl select fstat open fsync sleep opendir \
 874                    gmtime_r localtime_r readdir_r getpwuid_r getcwd \
 875                    access stat mkdir rename rmdir unlink realpath utime chmod \
 876                    nl_langinfo setlocale \
 877                    inet_pton uname inet_ntoa \
 878                    fork execvp pipe sigaction ftruncate])
 879    AC_CHECK_FUNCS(inet_aton inet_addr, break)
 880    AC_CHECK_HEADERS(execinfo.h unistd.h dlfcn.h)
 881    AC_CHECK_FUNC(backtrace, [
 882      case "$host" in
 883        ia64-*-linux*)
 884          # Has broken backtrace()
 885          ;;
 886        mips*-*-linux*)
 887          # Has broken backtrace(), but we supply our own.
 888          if test -d sysdep; then true; else mkdir -p sysdep; fi
 889          supply_backtrace=yes
 890          AC_DEFINE(HAVE_BACKTRACE, 1,
 891            [Define if your platform has a working backtrace() function.])
 892          ;;
 893        *)
 894          AC_DEFINE(HAVE_BACKTRACE, 1,
 895            [Define if your platform has a working backtrace() function.])
 896          ;;
 897      esac
 898    ], [
 899      case "$host" in
 900        *mingw*)
 901          # Has backtrace() defined in libgcj itself
 902          AC_DEFINE(HAVE_BACKTRACE, 1,
 903            [Define if your platform has a working backtrace() function.])
 904          ;;
 905      esac
 906    ])
 907
 908    AC_CHECK_LIB(dl, dladdr, [
 909      if test "x${disable_dladdr}" = "xyes"; then
 910        #Broken dladdr().
 911        true
 912      else
 913        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])
 914      fi
 915    ])
 916    if test x"$build" = x"$host"; then
 917      AC_CHECK_FILES(/proc/self/exe, [
 918        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])])
 919    else
 920      case $host in
 921      *-linux*)
 922        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])
 923        ;;
 924      esac
 925    fi
 926
 927    AM_ICONV
 928    AM_LC_MESSAGES
 929    AC_STRUCT_TIMEZONE
 930
 931    AC_CHECK_FUNCS(gethostbyname_r, [
 932      AC_DEFINE(HAVE_GETHOSTBYNAME_R, 1,
 933        [Define if you have the 'gethostbyname_r' function.])
 934      # There are two different kinds of gethostbyname_r.
 935      # We look for the one that returns `int'.
 936      # Hopefully this check is robust enough.
 937      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
 938        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT, 1, [Define if gethostbyname_r returns 'int'.])])
 939
 940      case " $GCINCS " in
 941      *" -D_REENTRANT "*) ;;
 942      *)
 943         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
 944         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
 945         [libjava_cv_gethostbyname_r_needs_reentrant],
 946         [ AC_LANG_PUSH(C++)
 947           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
 948             [[gethostbyname_r("", 0, 0);]])],
 949             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
 950                 CPPFLAGS_SAVE="$CPPFLAGS"
 951                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
 952                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]], [[gethostbyname_r("", 0, 0);]])],
 953                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
 954                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
 955                 CPPFLAGS="$CPPFLAGS_SAVE"
 956           ])
 957           AC_LANG_POP(C++)
 958         ])
 959         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
 960           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 961         fi
 962      ;;
 963      esac
 964
 965      AC_CACHE_CHECK([for struct hostent_data],
 966         [libjava_cv_struct_hostent_data], [dnl
 967         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 968 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
 969 # define _REENTRANT 1
 970 #endif
 971 #include <netdb.h>]], [[struct hostent_data data;]])],
 972           [libjava_cv_struct_hostent_data=yes],
 973           [libjava_cv_struct_hostent_data=no])])
 974      if test "x$libjava_cv_struct_hostent_data" = xyes; then
 975        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
 976          [Define if struct hostent_data is defined in netdb.h])
 977      fi
 978    ])
 979
 980    # FIXME: libjava source code expects to find a prototype for
 981    # gethostbyaddr_r in netdb.h.  The outer check ensures that
 982    # HAVE_GETHOSTBYADDR_R will not be defined if the prototype fails
 983    # to exist where expected.  (The root issue: AC_CHECK_FUNCS assumes C
 984    # linkage check is enough, yet C++ code requires proper prototypes.)
 985    AC_EGREP_HEADER(gethostbyaddr_r, netdb.h, [
 986    AC_CHECK_FUNCS(gethostbyaddr_r, [
 987      AC_DEFINE(HAVE_GETHOSTBYADDR_R, 1,
 988        [Define if you have the 'gethostbyaddr_r' function.])
 989      # There are two different kinds of gethostbyaddr_r.
 990      # We look for the one that returns `int'.
 991      # Hopefully this check is robust enough.
 992      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
 993        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT, 1,
 994          [Define if gethostbyaddr_r returns 'int'.])])])])
 995
 996    AC_CHECK_FUNCS(gethostname, [
 997      AC_DEFINE(HAVE_GETHOSTNAME, 1,
 998        [Define if you have the 'gethostname' function.])
 999      AC_EGREP_HEADER(gethostname, unistd.h, [
1000        AC_DEFINE(HAVE_GETHOSTNAME_DECL, 1,
1001          [Define if gethostname is declared in <unistd.h>.])])])
1002
1003    AC_CHECK_FUNCS(usleep, [
1004      AC_EGREP_HEADER(usleep, unistd.h, [
1005        AC_DEFINE(HAVE_USLEEP_DECL, 1,
1006           [Define if usleep is declared in <unistd.h>.])])])
1007
1008    # Look for these functions in the thread library, but only bother
1009    # if using POSIX threads.
1010    if test "$THREADS" = posix; then
1011       save_LIBS="$LIBS"
1012       LIBS="$LIBS $THREADLIBS"
1013       # Some POSIX thread systems don't have pthread_mutexattr_settype.
1014       # E.g., Solaris.
1015       AC_CHECK_FUNCS(pthread_mutexattr_settype pthread_mutexattr_setkind_np)
1016
1017       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
1018       # Solaris 7 the name librt is preferred.
1019       AC_CHECK_FUNCS(sched_yield, , [
1020         AC_CHECK_LIB(rt, sched_yield, [
1021           AC_DEFINE(HAVE_SCHED_YIELD)
1022           THREADLIBS="$THREADLIBS -lrt"
1023           THREADSPEC="$THREADSPEC -lrt"], [
1024           AC_CHECK_LIB(posix4, sched_yield, [
1025             AC_DEFINE(HAVE_SCHED_YIELD)
1026             THREADLIBS="$THREADLIBS -lposix4"
1027             THREADSPEC="$THREADSPEC -lposix4"])])])
1028       LIBS="$save_LIBS"
1029
1030       # We can save a little space at runtime if the mutex has m_count
1031       # or __m_count.  This is a nice hack for Linux.
1032       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1033           extern pthread_mutex_t *mutex; int q = mutex->m_count;
1034         ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT, 1,
1035              [Define if pthread_mutex_t has m_count member.]), [
1036         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1037             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
1038           ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT, 1,
1039             [Define if pthread_mutex_t has __m_count member.]))])
1040    fi
1041
1042    # We require a way to get the time.
1043    time_found=no
1044    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
1045    if test "$time_found" = no; then
1046       AC_MSG_ERROR([no function found to get the time])
1047    fi
1048
1049    AC_CHECK_FUNCS(memmove)
1050
1051    # We require memcpy.
1052    memcpy_found=no
1053    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
1054    if test "$memcpy_found" = no; then
1055       AC_MSG_ERROR([memcpy is required])
1056    fi
1057
1058    AC_CHECK_LIB(dl, dlopen, [
1059        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])])
1060
1061    # Some library-finding code we stole from Tcl.
1062    #--------------------------------------------------------------------
1063    #    Check for the existence of the -lsocket and -lnsl libraries.
1064    #    The order here is important, so that they end up in the right
1065    #    order in the command line generated by make.  Here are some
1066    #    special considerations:
1067    #    1. Use "connect" and "accept" to check for -lsocket, and
1068    #       "gethostbyname" to check for -lnsl.
1069    #    2. Use each function name only once:  can't redo a check because
1070    #       autoconf caches the results of the last check and won't redo it.
1071    #    3. Use -lnsl and -lsocket only if they supply procedures that
1072    #       aren't already present in the normal libraries.  This is because
1073    #       IRIX 5.2 has libraries, but they aren't needed and they're
1074    #       bogus:  they goof up name resolution if used.
1075    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
1076    #       To get around this problem, check for both libraries together
1077    #       if -lsocket doesn't work by itself.
1078    #--------------------------------------------------------------------
1079
1080    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
1081     [gcj_cv_lib_sockets=
1082      gcj_checkBoth=0
1083      unset ac_cv_func_connect
1084      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
1085      if test "$gcj_checkSocket" = 1; then
1086          unset ac_cv_func_connect
1087          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
1088                       gcj_checkBoth=1)
1089      fi
1090      if test "$gcj_checkBoth" = 1; then
1091          gcj_oldLibs=$LIBS
1092          LIBS="$LIBS -lsocket -lnsl"
1093          unset ac_cv_func_accept
1094          AC_CHECK_FUNC(accept,
1095                        [gcj_checkNsl=0
1096                         gcj_cv_lib_sockets="-lsocket -lnsl"])
1097          unset ac_cv_func_accept
1098          LIBS=$gcj_oldLibs
1099      fi
1100      unset ac_cv_func_gethostbyname
1101      gcj_oldLibs=$LIBS
1102      LIBS="$LIBS $gcj_cv_lib_sockets"
1103      AC_CHECK_FUNC(gethostbyname, ,
1104                    [AC_CHECK_LIB(nsl, main,
1105                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
1106      unset ac_cv_func_gethostbyname
1107      LIBS=$gcj_oldLIBS
1108    ])
1109    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
1110
1111    if test "$with_system_zlib" = yes; then
1112       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=)
1113    fi
1114
1115    # Test for Gtk stuff, if asked for.
1116    if test "$use_gtk_awt" = yes; then
1117       PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.4)
1118       AC_SUBST(GTK_CFLAGS)
1119       AC_SUBST(GTK_LIBS)
1120
1121       PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.4 gthread-2.0 >= 2.4)
1122       AC_SUBST(GLIB_CFLAGS)
1123       AC_SUBST(GLIB_LIBS)
1124
1125       PKG_CHECK_MODULES(LIBART, libart-2.0 >= 2.1)
1126       AC_SUBST(LIBART_CFLAGS)
1127       AC_SUBST(LIBART_LIBS)
1128
1129       # We require the XTest Extension to support java.awt.Robot.
1130       AC_CHECK_LIB([Xtst], [XTestQueryExtension], [true],
1131                    [AC_MSG_ERROR([libXtst not found, required by java.awt.Robot])],
1132                    [${X_LIBS}])
1133    fi
1134
1135    # On Solaris, and maybe other architectures, the Boehm collector
1136    # requires -ldl.
1137    if test "$GC" = boehm; then
1138       AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
1139    fi
1140 fi
1141 AM_CONDITIONAL(SUPPLY_BACKTRACE, test "$supply_backtrace" = yes)
1142
1143 # Use a semicolon as CLASSPATH separator for MinGW, otherwise a colon.
1144 case $build in
1145     *-mingw32) CLASSPATH_SEPARATOR=';' ;;
1146     *)         CLASSPATH_SEPARATOR=':' ;;
1147 esac
1148 AC_SUBST(CLASSPATH_SEPARATOR)
1149
1150 # We must search the source tree for java.lang, since we still don't
1151 # have libgcj.jar nor java/lang/*.class
1152 GCJ_SAVE_CPPFLAGS=$CPPFLAGS
1153 CPPFLAGS="$CPPFLAGS -I`${PWDCMD-pwd}` -I`cd $srcdir && ${PWDCMD-pwd}`"
1154
1155 # Since some classes depend on this one, we need its source available
1156 # before we can do any GCJ compilation test :-(
1157 if test ! -f gnu/classpath/Configuration.java; then
1158   test -d gnu || mkdir gnu
1159   test -d gnu/classpath || mkdir gnu/classpath
1160   # Note that it is not crucial that all the values here be correct.
1161   sed -e "s,@prefix@,$prefix," \
1162       -e "s,@VERSION@,$VERSION," \
1163       -e "s,@LIBDEBUG@,false," \
1164       -e "s,@INIT_LOAD_LIBRARY@,false," \
1165       -e "s,@@,$LIBGCJDEBUG," \
1166       -e "s,@default_toolkit@,$TOOLKIT," \
1167       -e "s,@JAVA_LANG_SYSTEM_EXPLICIT_INITIALIZATION@,false," \
1168       -e "s,@GTK_CAIRO_ENABLED@,false," \
1169         < $srcdir/classpath/gnu/classpath/Configuration.java.in \
1170         > gnu/classpath/Configuration.java
1171   # We do not want to redirect the output of the grep below to /dev/null,
1172   # but we add /dev/null to the input list so that grep will print the
1173   # filename of Configuration.java in case it finds any matches.
1174   if grep '@.*@' gnu/classpath/Configuration.java /dev/null; then
1175     AC_MSG_ERROR([configure.ac is missing the substitutions above])
1176   fi
1177 fi
1178
1179 LT_AC_PROG_GCJ
1180
1181 # Now remove it.
1182 rm -f gnu/classpath/Configuration.java
1183
1184 CPPFLAGS=$GCJ_SAVE_CPPFLAGS
1185
1186 AC_CHECK_SIZEOF(void *)
1187
1188 AC_C_BIGENDIAN
1189
1190 ZLIBS=
1191 SYS_ZLIBS=
1192 ZINCS=
1193
1194 if test -z "$ZLIBSPEC"; then
1195    # Use zlib from the GCC tree.
1196    ZINCS='-I$(top_srcdir)/../zlib'
1197    ZLIBS=../zlib/libzgcj_convenience.la
1198 else
1199    # System's zlib.
1200    SYS_ZLIBS="$ZLIBSPEC"
1201 fi
1202 AC_SUBST(ZLIBS)
1203 AC_SUBST(SYS_ZLIBS)
1204 AC_SUBST(ZINCS)
1205 AC_SUBST(DIVIDESPEC)
1206 AC_SUBST(CHECKREFSPEC)
1207 AC_SUBST(EXCEPTIONSPEC)
1208 AC_SUBST(BACKTRACESPEC)
1209 AC_SUBST(IEEESPEC)
1210
1211 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes)
1212 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
1213 AC_SUBST(GCC_UNWIND_INCLUDE)
1214
1215 # Process the option "--enable-version-specific-runtime-libs"
1216 # Calculate toolexeclibdir
1217 case ${version_specific_libs} in
1218   yes)
1219     # Need the gcc compiler version to know where to install libraries
1220     # and header files if --enable-version-specific-runtime-libs option
1221     # is selected.
1222     includedir='$(libdir)/gcc/$(target_noncanonical)/$(gcc_version)/include/'
1223     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
1224     toolexecmainlibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
1225     toolexeclibdir=$toolexecmainlibdir
1226     ;;
1227   no)
1228     if test -n "$with_cross_host" &&
1229        test x"$with_cross_host" != x"no"; then
1230       # Install a library built with a cross compiler in tooldir, not libdir.
1231       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
1232       toolexecmainlibdir='$(toolexecdir)/lib'
1233     else
1234       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
1235       toolexecmainlibdir='$(libdir)'
1236     fi
1237     multi_os_directory=`$CC -print-multi-os-directory`
1238     case $multi_os_directory in
1239       .) toolexeclibdir=$toolexecmainlibdir ;; # Avoid trailing /.
1240       *) toolexeclibdir=$toolexecmainlibdir/$multi_os_directory ;;
1241     esac
1242     ;;
1243 esac
1244 AC_SUBST(toolexecdir)
1245 AC_SUBST(toolexecmainlibdir)
1246 AC_SUBST(toolexeclibdir)
1247
1248 # Determine gcj version number.
1249 gcjversion=`$GCJ -v 2>&1 | sed -n 's/^.*version \([[^ ]]*\).*$/\1/p'`
1250 GCJVERSION=$gcjversion
1251 AC_SUBST(GCJVERSION)
1252 AC_DEFINE_UNQUOTED(GCJVERSION, "$GCJVERSION", [Short GCJ version ID])
1253
1254 AC_DEFINE(JV_VERSION, "1.4.2", [Compatibility version string])
1255 AC_DEFINE(JV_API_VERSION, "1.4", [API compatibility version string])
1256
1257 TL_AC_GXX_INCLUDE_DIR
1258
1259 # We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
1260 # On that system, sys/ioctl.h will not include sys/filio.h unless
1261 # BSD_COMP is defined; just including sys/filio.h is simpler.
1262 # We avoid AC_HEADER_DIRENT since we really only care about dirent.h
1263 # for now.  If you change this, you also must update natFile.cc.
1264 AC_CHECK_HEADERS([unistd.h bstring.h sys/time.h sys/types.h fcntl.h \
1265                   sys/ioctl.h sys/filio.h sys/stat.h sys/select.h \
1266                   sys/socket.h netinet/in.h arpa/inet.h netdb.h net/if.h \
1267                   pwd.h sys/config.h stdint.h langinfo.h locale.h \
1268                   dirent.h])
1269 AC_CHECK_HEADERS(inttypes.h, [
1270     AC_DEFINE(HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1271     AC_DEFINE(JV_HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1272 ])
1273 AC_HEADER_SYS_WAIT
1274
1275 AC_CHECK_TYPE([ssize_t], [int])
1276
1277 AC_MSG_CHECKING([for in_addr_t])
1278 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1279 #if STDC_HEADERS
1280 #include <stdlib.h>
1281 #include <stddef.h>
1282 #endif
1283 #if HAVE_NETINET_IN_H
1284 #include <netinet/in.h>
1285 #endif]], [[in_addr_t foo;]])],
1286   [AC_DEFINE(HAVE_IN_ADDR_T, 1,
1287      [Define to 1 if 'in_addr_t' is defined in sys/types.h or netinet/in.h.])
1288    AC_MSG_RESULT(yes)],
1289   [AC_MSG_RESULT(no)])
1290
1291 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
1292 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ip_mreq mreq;]])],
1293   [AC_DEFINE(HAVE_STRUCT_IP_MREQ, 1,
1294      [Define if struct ip_mreq is defined in netinet/in.h.])
1295    AC_MSG_RESULT(yes)],
1296   [AC_MSG_RESULT(no)])
1297
1298 AC_MSG_CHECKING([whether struct ipv6_mreq is in netinet/in.h])
1299 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ipv6_mreq mreq6;]])],
1300   [AC_DEFINE(HAVE_STRUCT_IPV6_MREQ, 1,
1301      [Define if struct ipv6_mreq is defined in netinet/in.h.])
1302    AC_MSG_RESULT(yes)],
1303   [AC_MSG_RESULT(no)])
1304
1305 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
1306 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct sockaddr_in6 addr6;]])],
1307   [AC_DEFINE(HAVE_INET6, 1,
1308      [Define if inet6 structures are defined in netinet/in.h.])
1309    AC_MSG_RESULT(yes)],
1310   [AC_MSG_RESULT(no)])
1311
1312 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
1313 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _POSIX_PII_SOCKET
1314 #include <sys/types.h>
1315 #include <sys/socket.h>]], [[socklen_t x = 5;]])],
1316   [AC_DEFINE(HAVE_SOCKLEN_T, 1, [Define it socklen_t typedef is in sys/socket.h.])
1317    AC_MSG_RESULT(yes)],
1318   [AC_MSG_RESULT(no)])
1319
1320 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
1321 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[struct tm tim; tim.tm_gmtoff = 0;]])],
1322   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF, 1, [Define if struct tm has tm_gmtoff field.])
1323    AC_MSG_RESULT(yes)],
1324   [AC_MSG_RESULT(no)
1325    AC_MSG_CHECKING([for global timezone variable])
1326    dnl FIXME: we don't want a link check here because that won't work
1327    dnl when cross-compiling.  So instead we make an assumption that
1328    dnl the header file will mention timezone if it exists.
1329    dnl Don't find the win32 function timezone
1330    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[void i(){long z2 = 2*timezone;}]])],
1331      [AC_DEFINE(HAVE_TIMEZONE, 1, [Define if global 'timezone' exists.])
1332       AC_MSG_RESULT(yes)],
1333      [AC_MSG_RESULT(no)
1334        AC_MSG_CHECKING([for global _timezone variable])
1335        dnl FIXME: As above, don't want link check
1336        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[long z2 = _timezone;]])],
1337          [AC_DEFINE(HAVE_UNDERSCORE_TIMEZONE, 1,
1338             [Define if your platform has the global _timezone variable.])
1339           AC_MSG_RESULT(yes)],
1340           [AC_MSG_RESULT(no)])])])
1341
1342 AC_FUNC_ALLOCA
1343 AC_FUNC_MMAP
1344
1345 AC_CHECK_PROGS(PERL, perl, false)
1346
1347 SYSDEP_SOURCES=
1348 SIGNAL_HANDLER_AUX=
1349
1350 case "${host}" in
1351  i?86-*-linux*)
1352     SIGNAL_HANDLER=include/i386-signal.h
1353     ;;
1354  sparc*-sun-solaris*)
1355     SIGNAL_HANDLER=include/sparc-signal.h
1356     ;;
1357 # ia64-*)
1358 #    SYSDEP_SOURCES=sysdep/ia64.c
1359 #    test -d sysdep || mkdir sysdep
1360 #    ;;
1361  hppa*-*-linux*)
1362     SIGNAL_HANDLER=include/pa-signal.h
1363     ;;
1364  ia64-*-linux*)
1365     SIGNAL_HANDLER=include/dwarf2-signal.h
1366     ;;
1367  powerpc*-*-linux*)
1368     SIGNAL_HANDLER=include/powerpc-signal.h
1369     ;;
1370  alpha*-*-linux*)
1371     SIGNAL_HANDLER=include/dwarf2-signal.h
1372     ;;
1373  s390*-*-linux*)
1374     SIGNAL_HANDLER=include/s390-signal.h
1375     ;;
1376  x86_64*-*-linux*)
1377     SIGNAL_HANDLER=include/x86_64-signal.h
1378     SIGNAL_HANDLER_AUX=include/i386-signal.h
1379     ;;
1380  sparc*-*-linux*)
1381     SIGNAL_HANDLER=include/dwarf2-signal.h
1382     ;;
1383  sh*-*-linux*)
1384     SIGNAL_HANDLER=include/sh-signal.h
1385     ;;
1386  *mingw*)
1387     SIGNAL_HANDLER=include/win32-signal.h
1388     ;;
1389  mips*-*-linux*)
1390     SIGNAL_HANDLER=include/mips-signal.h
1391     ;;
1392  *-*-darwin*)
1393     SIGNAL_HANDLER=include/darwin-signal.h
1394     ;;
1395  *)
1396     SIGNAL_HANDLER=include/default-signal.h
1397     ;;
1398 esac
1399
1400 # If we're using sjlj exceptions, forget what we just learned.
1401 if test "$enable_sjlj_exceptions" = yes; then
1402    SIGNAL_HANDLER=include/default-signal.h
1403    SIGNAL_HANDLER_AUX=
1404 fi
1405
1406 AC_SUBST(SYSDEP_SOURCES)
1407
1408 if test -z "$SIGNAL_HANDLER_AUX"; then
1409   SIGNAL_HANDLER_AUX=$SIGNAL_HANDLER
1410 fi
1411
1412 AC_CONFIG_LINKS(include/java-signal.h:$SIGNAL_HANDLER
1413                 include/java-signal-aux.h:$SIGNAL_HANDLER_AUX)
1414
1415 if test "${multilib}" = "yes"; then
1416   multilib_arg="--enable-multilib"
1417 else
1418   multilib_arg=
1419 fi
1420
1421
1422
1423 here=`${PWDCMD-pwd}`
1424 AC_SUBST(here)
1425
1426 # We get this from the environment.
1427 AC_SUBST(GCJFLAGS)
1428
1429 AC_CONFIG_FILES([
1430 Makefile
1431 libgcj.pc
1432 libgcj.spec
1433 libgcj-test.spec
1434 gcj/Makefile
1435 include/Makefile
1436 testsuite/Makefile
1437 ])
1438
1439 AC_CONFIG_COMMANDS([default],
1440 [# Only add multilib support code if we just rebuilt top-level Makefile.
1441 case " $CONFIG_FILES " in
1442  *" Makefile "*)
1443    LD="${ORIGINAL_LD_FOR_MULTILIBS}"
1444    ac_file=Makefile . ${libgcj_basedir}/../config-ml.in
1445    ;;
1446 esac
1447 for ac_multi_file in $CONFIG_FILES; do
1448   case $ac_multi_file in
1449   */Makefile)
1450     grep "^MULTI[[^ ]]* =" Makefile >> "$ac_multi_file" ;;
1451   esac
1452 done
1453 ],
1454 srcdir=${srcdir}
1455 host=${host}
1456 target=${target}
1457 with_multisubdir=${with_multisubdir}
1458 ac_configure_args="${multilib_arg} ${ac_configure_args}"
1459 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
1460 libgcj_basedir=${libgcj_basedir}
1461 CC="${CC}"
1462 CXX="${CXX}"
1463 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
1464 )
1465
1466 AC_OUTPUT