gcc/ada/a-elchha.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUN-TIME COMPONENTS                         --
   4 --                                                                          --
   5 --    A D A . E X C E P T I O N S . L A S T _ C H A N C E _ H A N D L E R   --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2003-2009, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  17 --                                                                          --
  18 -- As a special exception under Section 7 of GPL version 3, you are granted --
  19 -- additional permissions described in the GCC Runtime Library Exception,   --
  20 -- version 3.1, as published by the Free Software Foundation.               --
  21 --                                                                          --
  22 -- You should have received a copy of the GNU General Public License and    --
  23 -- a copy of the GCC Runtime Library Exception along with this program;     --
  24 -- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
  25 -- <http://www.gnu.org/licenses/>.                                          --
  26 --                                                                          --
  27 -- GNAT was originally developed  by the GNAT team at  New York University. --
  28 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  29 --                                                                          --
  30 ------------------------------------------------------------------------------
  31
  32 --  Default version for most targets
  33
  34 pragma Warnings (Off);
  35 pragma Compiler_Unit;
  36 pragma Warnings (On);
  37
  38 with System.Standard_Library; use System.Standard_Library;
  39 with System.Soft_Links;
  40
  41 procedure Ada.Exceptions.Last_Chance_Handler
  42   (Except : Exception_Occurrence)
  43 is
  44    procedure Unhandled_Terminate;
  45    pragma No_Return (Unhandled_Terminate);
  46    pragma Import (C, Unhandled_Terminate, "__gnat_unhandled_terminate");
  47    --  Perform system dependent shutdown code
  48
  49    function Exception_Message_Length
  50      (X : Exception_Occurrence) return Natural;
  51    pragma Import (Ada, Exception_Message_Length, "__gnat_exception_msg_len");
  52
  53    procedure Append_Info_Exception_Message
  54      (X : Exception_Occurrence; Info : in out String; Ptr : in out Natural);
  55    pragma Import
  56      (Ada, Append_Info_Exception_Message, "__gnat_append_info_e_msg");
  57
  58    procedure Append_Info_Exception_Information
  59      (X : Exception_Occurrence; Info : in out String; Ptr : in out Natural);
  60    pragma Import
  61      (Ada, Append_Info_Exception_Information, "__gnat_append_info_e_info");
  62
  63    procedure To_Stderr (S : String);
  64    pragma Import (Ada, To_Stderr, "__gnat_to_stderr");
  65    --  Little routine to output string to stderr
  66
  67    Ptr   : Natural := 0;
  68    Nobuf : String (1 .. 0);
  69
  70    Nline : constant String := String'(1 => ASCII.LF);
  71    --  Convenient shortcut
  72
  73 begin
  74    --  Do not execute any task termination code when shutting down the system.
  75    --  The Adafinal procedure would execute the task termination routine for
  76    --  normal termination, but we have already executed the task termination
  77    --  procedure because of an unhandled exception.
  78
  79    System.Soft_Links.Task_Termination_Handler :=
  80      System.Soft_Links.Task_Termination_NT'Access;
  81
  82    --  We shutdown the runtime now. The rest of the procedure needs to be
  83    --  careful not to use anything that would require runtime support. In
  84    --  particular, functions returning strings are banned since the sec stack
  85    --  is no longer functional. This is particularly important to note for the
  86    --  Exception_Information output. We used to allow the tailored version to
  87    --  show up here, which turned out to be a bad idea as it might involve a
  88    --  traceback decorator the length of which we don't control. Potentially
  89    --  heavy primary/secondary stack use or dynamic allocations right before
  90    --  this point are not welcome, moving the output before the finalization
  91    --  raises order of outputs concerns, and decorators are intended to only
  92    --  be used with exception traces, which should have been issued already.
  93
  94    System.Standard_Library.Adafinal;
  95
  96    --  Print a message only when exception traces are not active
  97
  98    if Exception_Trace /= RM_Convention then
  99       null;
 100
 101    --  Check for special case of raising _ABORT_SIGNAL, which is not
 102    --  really an exception at all. We recognize this by the fact that
 103    --  it is the only exception whose name starts with underscore.
 104
 105    elsif To_Ptr (Except.Id.Full_Name) (1) = '_' then
 106       To_Stderr (Nline);
 107       To_Stderr ("Execution terminated by abort of environment task");
 108       To_Stderr (Nline);
 109
 110    --  If no tracebacks, we print the unhandled exception in the old style
 111    --  (i.e. the style used before ZCX was implemented). We do this to
 112    --  retain compatibility.
 113
 114    elsif Except.Num_Tracebacks = 0 then
 115       To_Stderr (Nline);
 116       To_Stderr ("raised ");
 117       To_Stderr
 118         (To_Ptr (Except.Id.Full_Name) (1 .. Except.Id.Name_Length - 1));
 119
 120       if Exception_Message_Length (Except) /= 0 then
 121          To_Stderr (" : ");
 122          Append_Info_Exception_Message (Except, Nobuf, Ptr);
 123       end if;
 124
 125       To_Stderr (Nline);
 126
 127    --  Traceback exists
 128
 129    else
 130       To_Stderr (Nline);
 131       To_Stderr ("Execution terminated by unhandled exception");
 132       To_Stderr (Nline);
 133
 134       Append_Info_Exception_Information (Except, Nobuf, Ptr);
 135    end if;
 136
 137    Unhandled_Terminate;
 138 end Ada.Exceptions.Last_Chance_Handler;