gcc/ada/s-tpopsp-solaris.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                 GNAT RUN-TIME LIBRARY (GNARL) COMPONENTS                 --
   4 --                                                                          --
   5 --    S Y S T E M . T A S K _ P R I M I T I V E S . O P E R A T I O N S .   --
   6 --                             S P E C I F I C                              --
   7 --                                                                          --
   8 --                                B o d y                                   --
   9 --                                                                          --
  10 --         Copyright (C) 1992-2005, Free Software Foundation, Inc.          --
  11 --                                                                          --
  12 -- GNARL is free software; you can  redistribute it  and/or modify it under --
  13 -- terms of the  GNU General Public License as published  by the Free Soft- --
  14 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  15 -- sion. GNARL is distributed in the hope that it will be useful, but WITH- --
  16 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  17 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  18 -- for  more details.  You should have  received  a copy of the GNU General --
  19 -- Public License  distributed with GNARL; see file COPYING.  If not, write --
  20 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  21 -- Boston, MA 02110-1301, USA.                                              --
  22 --                                                                          --
  23 -- As a special exception,  if other files  instantiate  generics from this --
  24 -- unit, or you link  this unit with other files  to produce an executable, --
  25 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  26 -- covered  by the  GNU  General  Public  License.  This exception does not --
  27 -- however invalidate  any other reasons why  the executable file  might be --
  28 -- covered by the  GNU Public License.                                      --
  29 --                                                                          --
  30 -- GNARL was developed by the GNARL team at Florida State University.       --
  31 -- Extensive contributions were provided by Ada Core Technologies, Inc.     --
  32 --                                                                          --
  33 ------------------------------------------------------------------------------
  34
  35 --  This is a version for Solaris native threads
  36
  37 separate (System.Task_Primitives.Operations)
  38 package body Specific is
  39
  40    ----------------
  41    -- Initialize --
  42    ----------------
  43
  44    procedure Initialize (Environment_Task : Task_Id) is
  45       pragma Unreferenced (Environment_Task);
  46       Result : Interfaces.C.int;
  47    begin
  48       Result := thr_keycreate (ATCB_Key'Access, System.Null_Address);
  49       pragma Assert (Result = 0);
  50    end Initialize;
  51
  52    -------------------
  53    -- Is_Valid_Task --
  54    -------------------
  55
  56    function Is_Valid_Task return Boolean is
  57       Unknown_Task : aliased System.Address;
  58       Result       : Interfaces.C.int;
  59    begin
  60       Result := thr_getspecific (ATCB_Key, Unknown_Task'Unchecked_Access);
  61       pragma Assert (Result = 0);
  62       return Unknown_Task /= System.Null_Address;
  63    end Is_Valid_Task;
  64
  65    ---------
  66    -- Set --
  67    ---------
  68
  69    procedure Set (Self_Id : Task_Id) is
  70       Result : Interfaces.C.int;
  71    begin
  72       Result := thr_setspecific (ATCB_Key, To_Address (Self_Id));
  73       pragma Assert (Result = 0);
  74    end Set;
  75
  76    ----------
  77    -- Self --
  78    ----------
  79
  80    --  To make Ada tasks and C threads interoperate better, we have
  81    --  added some functionality to Self. Suppose a C main program
  82    --  (with threads) calls an Ada procedure and the Ada procedure
  83    --  calls the tasking run-time system. Eventually, a call will be
  84    --  made to self. Since the call is not coming from an Ada task,
  85    --  there will be no corresponding ATCB.
  86
  87    --  What we do in Self is to catch references that do not come
  88    --  from recognized Ada tasks, and create an ATCB for the calling
  89    --  thread.
  90
  91    --  The new ATCB will be "detached" from the normal Ada task
  92    --  master hierarchy, much like the existing implicitly created
  93    --  signal-server tasks.
  94
  95    function Self return Task_Id is
  96       Result  : Interfaces.C.int;
  97       Self_Id : aliased System.Address;
  98    begin
  99       Result := thr_getspecific (ATCB_Key, Self_Id'Unchecked_Access);
 100       pragma Assert (Result = 0);
 101
 102       if Self_Id = System.Null_Address then
 103          return Register_Foreign_Thread;
 104       else
 105          return To_Task_Id (Self_Id);
 106       end if;
 107    end Self;
 108
 109 end Specific;