gcc/ada/s-osinte-darwin.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                 GNAT RUN-TIME LIBRARY (GNARL) COMPONENTS                 --
   4 --                                                                          --
   5 --                   S Y S T E M . O S _ I N T E R F A C E                  --
   6 --                                                                          --
   7 --                                  B o d y                                 --
   8 --                                                                          --
   9 --           Copyright (C) 1999-2006 Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNARL is free software; you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion. GNARL is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNARL; see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNARL was developed by the GNARL team at Florida State University.       --
  30 -- Extensive contributions were provided by Ada Core Technologies, Inc.     --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 --  This is a Darwin Threads version of this package
  35
  36 pragma Polling (Off);
  37 --  Turn off polling, we do not want ATC polling to take place during
  38 --  tasking operations. It causes infinite loops and other problems.
  39
  40 package body System.OS_Interface is
  41
  42    use Interfaces.C;
  43
  44    -----------------
  45    -- To_Duration --
  46    -----------------
  47
  48    function To_Duration (TS : timespec) return Duration is
  49    begin
  50       return Duration (TS.tv_sec) + Duration (TS.tv_nsec) / 10#1#E9;
  51    end To_Duration;
  52
  53    function To_Duration (TV : struct_timeval) return Duration is
  54    begin
  55       return Duration (TV.tv_sec) + Duration (TV.tv_usec) / 10#1#E6;
  56    end To_Duration;
  57
  58    -----------------
  59    -- To_Timespec --
  60    -----------------
  61
  62    function To_Timespec (D : Duration) return timespec is
  63       S : time_t;
  64       F : Duration;
  65
  66    begin
  67       S := time_t (Long_Long_Integer (D));
  68       F := D - Duration (S);
  69
  70       --  If F has negative value due to a round-up, adjust for positive F
  71       --  value.
  72
  73       if F < 0.0 then
  74          S := S - 1;
  75          F := F + 1.0;
  76       end if;
  77
  78       return timespec'(tv_sec => S,
  79         tv_nsec => int32_t (Long_Long_Integer (F * 10#1#E9)));
  80    end To_Timespec;
  81
  82    ----------------
  83    -- To_Timeval --
  84    ----------------
  85
  86    function To_Timeval (D : Duration) return struct_timeval is
  87       S : int32_t;
  88       F : Duration;
  89
  90    begin
  91       S := int32_t (D);
  92       F := D - Duration (S);
  93
  94       --  If F has negative value due to a round-up, adjust for positive F
  95       --  value.
  96
  97       if F < 0.0 then
  98          S := S - 1;
  99          F := F + 1.0;
 100       end if;
 101
 102       return struct_timeval'
 103                (Tv_Sec  => S,
 104                 tv_usec => int32_t (Long_Long_Integer (F * 10#1#E6)));
 105    end To_Timeval;
 106
 107    -------------------
 108    -- clock_gettime --
 109    -------------------
 110
 111    function clock_gettime
 112      (clock_id : clockid_t;
 113       tp       : access timespec) return int
 114    is
 115       pragma Unreferenced (clock_id);
 116       Result : int;
 117       tv     : aliased struct_timeval;
 118
 119       function gettimeofday
 120         (tv : access struct_timeval;
 121          tz : System.Address := System.Null_Address) return int;
 122       pragma Import (C, gettimeofday, "gettimeofday");
 123
 124    begin
 125       Result := gettimeofday (tv'Unchecked_Access);
 126       tp.all := To_Timespec (To_Duration (tv));
 127       return Result;
 128    end clock_gettime;
 129
 130    -----------------
 131    -- sched_yield --
 132    -----------------
 133
 134    function sched_yield return int is
 135       procedure sched_yield_base (arg : System.Address);
 136       pragma Import (C, sched_yield_base, "pthread_yield_np");
 137
 138    begin
 139       sched_yield_base (System.Null_Address);
 140       return 0;
 141    end sched_yield;
 142
 143    ------------------
 144    -- pthread_init --
 145    ------------------
 146
 147    procedure pthread_init is
 148    begin
 149       null;
 150    end pthread_init;
 151
 152    ----------------
 153    -- Stack_Base --
 154    ----------------
 155
 156    function Get_Stack_Base (thread : pthread_t) return Address is
 157       pragma Unreferenced (thread);
 158    begin
 159       return System.Null_Address;
 160    end Get_Stack_Base;
 161
 162 end System.OS_Interface;