gcc/ada/a-ciormu.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT LIBRARY COMPONENTS                          --
   4 --                                                                          --
   5 --                      A D A . C O N T A I N E R S .                       --
   6 --         I N D E F I N I T E _ O R D E R E D _ M U L T I S E T S          --
   7 --                                                                          --
   8 --                                 S p e c                                  --
   9 --                                                                          --
  10 --          Copyright (C) 2004-2006, Free Software Foundation, Inc.         --
  11 --                                                                          --
  12 -- This specification is derived from the Ada Reference Manual for use with --
  13 -- GNAT. The copyright notice above, and the license provisions that follow --
  14 -- apply solely to the  contents of the part following the private keyword. --
  15 --                                                                          --
  16 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  17 -- terms of the  GNU General Public License as published  by the Free Soft- --
  18 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  19 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  20 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  21 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  22 -- for  more details.  You should have  received  a copy of the GNU General --
  23 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  24 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  25 -- Boston, MA 02110-1301, USA.                                              --
  26 --                                                                          --
  27 -- As a special exception,  if other files  instantiate  generics from this --
  28 -- unit, or you link  this unit with other files  to produce an executable, --
  29 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  30 -- covered  by the  GNU  General  Public  License.  This exception does not --
  31 -- however invalidate  any other reasons why  the executable file  might be --
  32 -- covered by the  GNU Public License.                                      --
  33 --                                                                          --
  34 -- This unit was originally developed by Matthew J Heaney.                  --
  35 ------------------------------------------------------------------------------
  36
  37 with Ada.Containers.Red_Black_Trees;
  38 with Ada.Finalization;
  39 with Ada.Streams;
  40
  41 generic
  42    type Element_Type (<>) is private;
  43
  44    with function "<" (Left, Right : Element_Type) return Boolean is <>;
  45    with function "=" (Left, Right : Element_Type) return Boolean is <>;
  46
  47 package Ada.Containers.Indefinite_Ordered_Multisets is
  48    pragma Preelaborate;
  49
  50    function Equivalent_Elements (Left, Right : Element_Type) return Boolean;
  51
  52    type Set is tagged private;
  53
  54    type Cursor is private;
  55
  56    Empty_Set : constant Set;
  57
  58    No_Element : constant Cursor;
  59
  60    function "=" (Left, Right : Set) return Boolean;
  61
  62    function Equivalent_Sets (Left, Right : Set) return Boolean;
  63
  64    function To_Set (New_Item : Element_Type) return Set;
  65
  66    function Length (Container : Set) return Count_Type;
  67
  68    function Is_Empty (Container : Set) return Boolean;
  69
  70    procedure Clear (Container : in out Set);
  71
  72    function Element (Position : Cursor) return Element_Type;
  73
  74    procedure Replace_Element
  75      (Container : in out Set;
  76       Position  : Cursor;
  77       New_Item  : Element_Type);
  78
  79    procedure Query_Element
  80      (Position : Cursor;
  81       Process  : not null access procedure (Element : Element_Type));
  82
  83    procedure Move (Target : in out Set; Source : in out Set);
  84
  85    procedure Insert
  86      (Container : in out Set;
  87       New_Item  : Element_Type;
  88       Position  : out Cursor);
  89
  90    procedure Insert (Container : in out Set; New_Item : Element_Type);
  91
  92 --  TODO: include Replace too???
  93 --
  94 --     procedure Replace
  95 --       (Container : in out Set;
  96 --        New_Item  : Element_Type);
  97
  98    procedure Exclude (Container : in out Set; Item : Element_Type);
  99
 100    procedure Delete (Container : in out Set; Item : Element_Type);
 101
 102    procedure Delete (Container : in out Set; Position : in out Cursor);
 103
 104    procedure Delete_First (Container : in out Set);
 105
 106    procedure Delete_Last (Container : in out Set);
 107
 108    procedure Union (Target : in out Set; Source : Set);
 109
 110    function Union (Left, Right : Set) return Set;
 111
 112    function "or" (Left, Right : Set) return Set renames Union;
 113
 114    procedure Intersection (Target : in out Set; Source : Set);
 115
 116    function Intersection (Left, Right : Set) return Set;
 117
 118    function "and" (Left, Right : Set) return Set renames Intersection;
 119
 120    procedure Difference (Target : in out Set; Source : Set);
 121
 122    function Difference (Left, Right : Set) return Set;
 123
 124    function "-" (Left, Right : Set) return Set renames Difference;
 125
 126    procedure Symmetric_Difference (Target : in out Set; Source : Set);
 127
 128    function Symmetric_Difference (Left, Right : Set) return Set;
 129
 130    function "xor" (Left, Right : Set) return Set renames Symmetric_Difference;
 131
 132    function Overlap (Left, Right : Set) return Boolean;
 133
 134    function Is_Subset (Subset : Set; Of_Set : Set) return Boolean;
 135
 136    function First (Container : Set) return Cursor;
 137
 138    function First_Element (Container : Set) return Element_Type;
 139
 140    function Last (Container : Set) return Cursor;
 141
 142    function Last_Element (Container : Set) return Element_Type;
 143
 144    function Next (Position : Cursor) return Cursor;
 145
 146    procedure Next (Position : in out Cursor);
 147
 148    function Previous (Position : Cursor) return Cursor;
 149
 150    procedure Previous (Position : in out Cursor);
 151
 152    function Find (Container : Set; Item : Element_Type) return Cursor;
 153
 154    function Floor (Container : Set; Item : Element_Type) return Cursor;
 155
 156    function Ceiling (Container : Set; Item : Element_Type) return Cursor;
 157
 158    function Contains (Container : Set; Item : Element_Type) return Boolean;
 159
 160    function Has_Element (Position : Cursor) return Boolean;
 161
 162    function "<" (Left, Right : Cursor) return Boolean;
 163
 164    function ">" (Left, Right : Cursor) return Boolean;
 165
 166    function "<" (Left : Cursor; Right : Element_Type) return Boolean;
 167
 168    function ">" (Left : Cursor; Right : Element_Type) return Boolean;
 169
 170    function "<" (Left : Element_Type; Right : Cursor) return Boolean;
 171
 172    function ">" (Left : Element_Type; Right : Cursor) return Boolean;
 173
 174    procedure Iterate
 175      (Container : Set;
 176       Process   : not null access procedure (Position : Cursor));
 177
 178    procedure Reverse_Iterate
 179      (Container : Set;
 180       Process   : not null access procedure (Position : Cursor));
 181
 182    procedure Iterate
 183      (Container : Set;
 184       Item      : Element_Type;
 185       Process   : not null access procedure (Position : Cursor));
 186
 187    procedure Reverse_Iterate
 188      (Container : Set;
 189       Item      : Element_Type;
 190       Process   : not null access procedure (Position : Cursor));
 191
 192    generic
 193       type Key_Type (<>) is private;
 194
 195       with function Key (Element : Element_Type) return Key_Type;
 196
 197       with function "<" (Left, Right : Key_Type) return Boolean is <>;
 198
 199    package Generic_Keys is
 200
 201       function Equivalent_Keys (Left, Right : Key_Type) return Boolean;
 202
 203       function Key (Position : Cursor) return Key_Type;
 204
 205       function Element (Container : Set; Key : Key_Type) return Element_Type;
 206
 207       procedure Exclude (Container : in out Set; Key : Key_Type);
 208
 209       procedure Delete (Container : in out Set; Key : Key_Type);
 210
 211       function Find (Container : Set; Key : Key_Type) return Cursor;
 212
 213       function Floor (Container : Set; Key : Key_Type) return Cursor;
 214
 215       function Ceiling (Container : Set; Key : Key_Type) return Cursor;
 216
 217       function Contains (Container : Set; Key : Key_Type) return Boolean;
 218
 219       procedure Update_Element
 220         (Container : in out Set;
 221          Position  : Cursor;
 222          Process   : not null access
 223                        procedure (Element : in out Element_Type));
 224
 225       procedure Iterate
 226         (Container : Set;
 227          Key       : Key_Type;
 228          Process   : not null access procedure (Position : Cursor));
 229
 230       procedure Reverse_Iterate
 231         (Container : Set;
 232          Key       : Key_Type;
 233          Process   : not null access procedure (Position : Cursor));
 234
 235    end Generic_Keys;
 236
 237 private
 238
 239    type Node_Type;
 240    type Node_Access is access Node_Type;
 241
 242    type Element_Access is access Element_Type;
 243
 244    type Node_Type is limited record
 245       Parent  : Node_Access;
 246       Left    : Node_Access;
 247       Right   : Node_Access;
 248       Color   : Red_Black_Trees.Color_Type := Red_Black_Trees.Red;
 249       Element : Element_Access;
 250    end record;
 251
 252    package Tree_Types is new Red_Black_Trees.Generic_Tree_Types
 253      (Node_Type,
 254       Node_Access);
 255
 256    type Set is new Ada.Finalization.Controlled with record
 257       Tree : Tree_Types.Tree_Type;
 258    end record;
 259
 260    procedure Adjust (Container : in out Set);
 261
 262    procedure Finalize (Container : in out Set) renames Clear;
 263
 264    use Red_Black_Trees;
 265    use Tree_Types;
 266    use Ada.Finalization;
 267    use Ada.Streams;
 268
 269    type Set_Access is access all Set;
 270    for Set_Access'Storage_Size use 0;
 271
 272    type Cursor is record
 273       Container : Set_Access;
 274       Node      : Node_Access;
 275    end record;
 276
 277    procedure Write
 278      (Stream : access Root_Stream_Type'Class;
 279       Item   : Cursor);
 280
 281    for Cursor'Write use Write;
 282
 283    procedure Read
 284      (Stream : access Root_Stream_Type'Class;
 285       Item   : out Cursor);
 286
 287    for Cursor'Read use Read;
 288
 289    No_Element : constant Cursor := Cursor'(null, null);
 290
 291    procedure Write (Stream : access Root_Stream_Type'Class; Container : Set);
 292
 293    for Set'Write use Write;
 294
 295    procedure Read
 296      (Stream    : access Root_Stream_Type'Class;
 297       Container : out Set);
 298
 299    for Set'Read use Read;
 300
 301    Empty_Set : constant Set :=
 302                  (Controlled with Tree => (First  => null,
 303                                            Last   => null,
 304                                            Root   => null,
 305                                            Length => 0,
 306                                            Busy   => 0,
 307                                            Lock   => 0));
 308
 309 end Ada.Containers.Indefinite_Ordered_Multisets;