gcc/ada/itypes.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                               I T Y P E S                                --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2018, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 --  This package contains declarations for handling of implicit types
  27
  28 with Einfo;    use Einfo;
  29 with Sem_Util; use Sem_Util;
  30 with Types;    use Types;
  31
  32 package Itypes is
  33
  34    --------------------
  35    -- Implicit Types --
  36    --------------------
  37
  38    --  Implicit types (Itypes) are types and subtypes created by the semantic
  39    --  phase or the expander to reflect the underlying semantics. These could
  40    --  be generated by building trees for corresponding declarations and then
  41    --  analyzing these trees, but there are three reasons for not doing this
  42    --  in some cases:
  43
  44    --    1. The declarations would require more tree nodes
  45
  46    --    2. In some cases, the elaboration of these types is associated
  47    --       with internal nodes in the tree.
  48
  49    --    3. For some types, notably class wide types, there is no Ada
  50    --       declaration that would correspond to the desired entity.
  51
  52    --  So instead, implicit types are constructed by simply creating an
  53    --  appropriate entity with the help of routines in this package. These
  54    --  entities are fully decorated, as described in Einfo (just as though
  55    --  they had been created by the normal analysis procedure).
  56
  57    --  The type declaration declaring an Itype must be analyzed with checks
  58    --  off because this declaration has not been inserted in the tree (if it
  59    --  has been then it is not an Itype), and hence checks that would be
  60    --  generated during the analysis cannot be inserted in the tree. At any
  61    --  rate, Itype analysis should always be done with checks off, otherwise
  62    --  duplicate checks will most likely be emitted.
  63
  64    --  Unlike types declared explicitly, implicit types are defined on first
  65    --  use, which means that Gigi detects the use of such types, and defines
  66    --  them at the point of the first use automatically.
  67
  68    --  Although Itypes are not explicitly declared, they are associated with
  69    --  a specific node in the tree (roughly the node that caused them to be
  70    --  created), via the Associated_Node_For_Itype field. This association is
  71    --  used particularly by New_Copy_Tree, which uses it to determine whether
  72    --  or not to copy a referenced Itype. If the associated node is part of
  73    --  the tree to be copied by New_Copy_Tree, then (since the idea of the
  74    --  call to New_Copy_Tree is to create a complete duplicate of a tree,
  75    --  as though it had appeared separately in the source), the Itype in
  76    --  question is duplicated as part of the New_Copy_Tree processing.
  77
  78    --  As a consequence of this copying mechanism, the association between
  79    --  Itypes and associated nodes must be one-to-one: several Itypes must
  80    --  not share an associated node. For example, the semantic decoration
  81    --  of an array aggregate generates several Itypes: for each index subtype
  82    --  and for the array subtype. The associated node of each index subtype
  83    --  is the corresponding range expression.
  84
  85    --  Notes on the use of the Parent field of an Itype
  86
  87    --    In some cases, we do create a declaration node for an itype, and in
  88    --    such cases, the Parent field of the Itype points to this declaration
  89    --    in the normal manner. This case can be detected by checking for a
  90    --    non-empty Parent field referencing a declaration whose Defining_Entity
  91    --    is the Itype in question.
  92
  93    --    In some other cases, where we don't generate such a declaration, as
  94    --    described above, the Itype is attached to the tree implicitly by being
  95    --    referenced elsewhere, e.g. as the Etype of some object. In this case
  96    --    the Parent field may be Empty.
  97
  98    --    In other cases where we don't generate a declaration for the Itype,
  99    --    the Itype may be attached to an arbitrary node in the tree, using
 100    --    the Parent field. This Parent field may even reference a declaration
 101    --    for a related different entity (hence the description of the tests
 102    --    needed for the case where a declaration for the Itype is created).
 103
 104    ------------------
 105    -- Create_Itype --
 106    ------------------
 107
 108    function Create_Itype
 109      (Ekind        : Entity_Kind;
 110       Related_Nod  : Node_Id;
 111       Related_Id   : Entity_Id := Empty;
 112       Suffix       : Character := ' ';
 113       Suffix_Index : Nat       := 0;
 114       Scope_Id     : Entity_Id := Current_Scope) return Entity_Id;
 115    --  Used to create a new Itype
 116    --
 117    --  Related_Nod is the node for which this Itype was created. It is
 118    --  set as the Associated_Node_For_Itype of the new Itype. The Sloc of
 119    --  the new Itype is that of this node.
 120    --
 121    --  Related_Id is present only if the implicit type name may be referenced
 122    --  as a public symbol, and thus needs a unique external name. The name
 123    --  is created by a call to:
 124    --
 125    --    New_External_Name (Chars (Related_Id), Suffix, Suffix_Index, 'T')
 126    --
 127    --  If the implicit type does not need an external name, then the
 128    --  Related_Id parameter is omitted (and hence Empty). In this case
 129    --  Suffix and Suffix_Index are ignored and the implicit type name is
 130    --  created by a call to Make_Temporary.
 131    --
 132    --  Note that in all cases, the name starts with "T". This is used
 133    --  to identify implicit types in the error message handling circuits.
 134    --
 135    --  The Scope_Id parameter specifies the scope of the created type, and
 136    --  is normally the Current_Scope as shown, but can be set otherwise.
 137    --
 138    --  The size/align fields are initialized to unknown (Uint_0).
 139    --
 140    --  If Ekind is in Access_Subprogram_Kind, Can_Use_Internal_Rep is set True,
 141    --  unless Always_Compatible_Rep_On_Target is True.
 142
 143    ---------------------------------
 144    -- Create_Null_Excluding_Itype --
 145    ---------------------------------
 146
 147    function Create_Null_Excluding_Itype
 148       (T           : Entity_Id;
 149        Related_Nod : Node_Id;
 150        Scope_Id    : Entity_Id := Current_Scope) return Entity_Id;
 151    --  Ada 2005 (AI-231): T is an access type and this subprogram creates and
 152    --  returns an internal access-subtype declaration of T that has the null
 153    --  exclusion attribute set to True.
 154    --
 155    --  Usage of null-excluding Itypes
 156    --  ------------------------------
 157    --
 158    --      type T1 is access ...
 159    --      type T2 is not null T1;
 160    --
 161    --      type Rec is record
 162    --         Comp : not null T1;
 163    --      end record;
 164    --
 165    --      type Arr is array (...) of not null T1;
 166    --
 167    --  Instead of associating the not-null attribute with the defining ids of
 168    --  these declarations, we generate an internal subtype declaration of T1
 169    --  that has the null exclusion attribute set to true.
 170
 171 end Itypes;